1: *> \brief \b ZTZRQF
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZTZRQF + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztzrqf.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztzrqf.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztzrqf.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZTZRQF( M, N, A, LDA, TAU, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * COMPLEX*16 A( LDA, * ), TAU( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> This routine is deprecated and has been replaced by routine ZTZRZF.
37: *>
38: *> ZTZRQF reduces the M-by-N ( M<=N ) complex upper trapezoidal matrix A
39: *> to upper triangular form by means of unitary transformations.
40: *>
41: *> The upper trapezoidal matrix A is factored as
42: *>
43: *> A = ( R 0 ) * Z,
44: *>
45: *> where Z is an N-by-N unitary matrix and R is an M-by-M upper
46: *> triangular matrix.
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] M
53: *> \verbatim
54: *> M is INTEGER
55: *> The number of rows of the matrix A. M >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in] N
59: *> \verbatim
60: *> N is INTEGER
61: *> The number of columns of the matrix A. N >= M.
62: *> \endverbatim
63: *>
64: *> \param[in,out] A
65: *> \verbatim
66: *> A is COMPLEX*16 array, dimension (LDA,N)
67: *> On entry, the leading M-by-N upper trapezoidal part of the
68: *> array A must contain the matrix to be factorized.
69: *> On exit, the leading M-by-M upper triangular part of A
70: *> contains the upper triangular matrix R, and elements M+1 to
71: *> N of the first M rows of A, with the array TAU, represent the
72: *> unitary matrix Z as a product of M elementary reflectors.
73: *> \endverbatim
74: *>
75: *> \param[in] LDA
76: *> \verbatim
77: *> LDA is INTEGER
78: *> The leading dimension of the array A. LDA >= max(1,M).
79: *> \endverbatim
80: *>
81: *> \param[out] TAU
82: *> \verbatim
83: *> TAU is COMPLEX*16 array, dimension (M)
84: *> The scalar factors of the elementary reflectors.
85: *> \endverbatim
86: *>
87: *> \param[out] INFO
88: *> \verbatim
89: *> INFO is INTEGER
90: *> = 0: successful exit
91: *> < 0: if INFO = -i, the i-th argument had an illegal value
92: *> \endverbatim
93: *
94: * Authors:
95: * ========
96: *
97: *> \author Univ. of Tennessee
98: *> \author Univ. of California Berkeley
99: *> \author Univ. of Colorado Denver
100: *> \author NAG Ltd.
101: *
102: *> \ingroup complex16OTHERcomputational
103: *
104: *> \par Further Details:
105: * =====================
106: *>
107: *> \verbatim
108: *>
109: *> The factorization is obtained by Householder's method. The kth
110: *> transformation matrix, Z( k ), whose conjugate transpose is used to
111: *> introduce zeros into the (m - k + 1)th row of A, is given in the form
112: *>
113: *> Z( k ) = ( I 0 ),
114: *> ( 0 T( k ) )
115: *>
116: *> where
117: *>
118: *> T( k ) = I - tau*u( k )*u( k )**H, u( k ) = ( 1 ),
119: *> ( 0 )
120: *> ( z( k ) )
121: *>
122: *> tau is a scalar and z( k ) is an ( n - m ) element vector.
123: *> tau and z( k ) are chosen to annihilate the elements of the kth row
124: *> of X.
125: *>
126: *> The scalar tau is returned in the kth element of TAU and the vector
127: *> u( k ) in the kth row of A, such that the elements of z( k ) are
128: *> in a( k, m + 1 ), ..., a( k, n ). The elements of R are returned in
129: *> the upper triangular part of A.
130: *>
131: *> Z is given by
132: *>
133: *> Z = Z( 1 ) * Z( 2 ) * ... * Z( m ).
134: *> \endverbatim
135: *>
136: * =====================================================================
137: SUBROUTINE ZTZRQF( M, N, A, LDA, TAU, INFO )
138: *
139: * -- LAPACK computational routine --
140: * -- LAPACK is a software package provided by Univ. of Tennessee, --
141: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
142: *
143: * .. Scalar Arguments ..
144: INTEGER INFO, LDA, M, N
145: * ..
146: * .. Array Arguments ..
147: COMPLEX*16 A( LDA, * ), TAU( * )
148: * ..
149: *
150: * =====================================================================
151: *
152: * .. Parameters ..
153: COMPLEX*16 CONE, CZERO
154: PARAMETER ( CONE = ( 1.0D+0, 0.0D+0 ),
155: $ CZERO = ( 0.0D+0, 0.0D+0 ) )
156: * ..
157: * .. Local Scalars ..
158: INTEGER I, K, M1
159: COMPLEX*16 ALPHA
160: * ..
161: * .. Intrinsic Functions ..
162: INTRINSIC DCONJG, MAX, MIN
163: * ..
164: * .. External Subroutines ..
165: EXTERNAL XERBLA, ZAXPY, ZCOPY, ZGEMV, ZGERC, ZLACGV,
166: $ ZLARFG
167: * ..
168: * .. Executable Statements ..
169: *
170: * Test the input parameters.
171: *
172: INFO = 0
173: IF( M.LT.0 ) THEN
174: INFO = -1
175: ELSE IF( N.LT.M ) THEN
176: INFO = -2
177: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
178: INFO = -4
179: END IF
180: IF( INFO.NE.0 ) THEN
181: CALL XERBLA( 'ZTZRQF', -INFO )
182: RETURN
183: END IF
184: *
185: * Perform the factorization.
186: *
187: IF( M.EQ.0 )
188: $ RETURN
189: IF( M.EQ.N ) THEN
190: DO 10 I = 1, N
191: TAU( I ) = CZERO
192: 10 CONTINUE
193: ELSE
194: M1 = MIN( M+1, N )
195: DO 20 K = M, 1, -1
196: *
197: * Use a Householder reflection to zero the kth row of A.
198: * First set up the reflection.
199: *
200: A( K, K ) = DCONJG( A( K, K ) )
201: CALL ZLACGV( N-M, A( K, M1 ), LDA )
202: ALPHA = A( K, K )
203: CALL ZLARFG( N-M+1, ALPHA, A( K, M1 ), LDA, TAU( K ) )
204: A( K, K ) = ALPHA
205: TAU( K ) = DCONJG( TAU( K ) )
206: *
207: IF( TAU( K ).NE.CZERO .AND. K.GT.1 ) THEN
208: *
209: * We now perform the operation A := A*P( k )**H.
210: *
211: * Use the first ( k - 1 ) elements of TAU to store a( k ),
212: * where a( k ) consists of the first ( k - 1 ) elements of
213: * the kth column of A. Also let B denote the first
214: * ( k - 1 ) rows of the last ( n - m ) columns of A.
215: *
216: CALL ZCOPY( K-1, A( 1, K ), 1, TAU, 1 )
217: *
218: * Form w = a( k ) + B*z( k ) in TAU.
219: *
220: CALL ZGEMV( 'No transpose', K-1, N-M, CONE, A( 1, M1 ),
221: $ LDA, A( K, M1 ), LDA, CONE, TAU, 1 )
222: *
223: * Now form a( k ) := a( k ) - conjg(tau)*w
224: * and B := B - conjg(tau)*w*z( k )**H.
225: *
226: CALL ZAXPY( K-1, -DCONJG( TAU( K ) ), TAU, 1, A( 1, K ),
227: $ 1 )
228: CALL ZGERC( K-1, N-M, -DCONJG( TAU( K ) ), TAU, 1,
229: $ A( K, M1 ), LDA, A( 1, M1 ), LDA )
230: END IF
231: 20 CONTINUE
232: END IF
233: *
234: RETURN
235: *
236: * End of ZTZRQF
237: *
238: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to ztzrqf.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack