Return to zsytrf.f CVS log

Up to [local] / rpl / lapack / lapack

Première mise à jour de lapack et blas.

    1: *> \brief \b ZSYTRF
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at
    6: *            http://www.netlib.org/lapack/explore-html/
    7: *
    8: *> \htmlonly
    9: *> Download ZSYTRF + dependencies
   10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zsytrf.f">
   11: *> [TGZ]</a>
   12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zsytrf.f">
   13: *> [ZIP]</a>
   14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zsytrf.f">
   15: *> [TXT]</a>
   16: *> \endhtmlonly
   17: *
   18: *  Definition:
   19: *  ===========
   20: *
   21: *       SUBROUTINE ZSYTRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
   22: *
   23: *       .. Scalar Arguments ..
   24: *       CHARACTER          UPLO
   25: *       INTEGER            INFO, LDA, LWORK, N
   26: *       ..
   27: *       .. Array Arguments ..
   28: *       INTEGER            IPIV( * )
   29: *       COMPLEX*16         A( LDA, * ), WORK( * )
   30: *       ..
   31: *
   32: *
   33: *> \par Purpose:
   34: *  =============
   35: *>
   36: *> \verbatim
   37: *>
   38: *> ZSYTRF computes the factorization of a complex symmetric matrix A
   39: *> using the Bunch-Kaufman diagonal pivoting method.  The form of the
   40: *> factorization is
   41: *>
   42: *>    A = U*D*U**T  or  A = L*D*L**T
   43: *>
   44: *> where U (or L) is a product of permutation and unit upper (lower)
   45: *> triangular matrices, and D is symmetric and block diagonal with
   46: *> 1-by-1 and 2-by-2 diagonal blocks.
   47: *>
   48: *> This is the blocked version of the algorithm, calling Level 3 BLAS.
   49: *> \endverbatim
   50: *
   51: *  Arguments:
   52: *  ==========
   53: *
   54: *> \param[in] UPLO
   55: *> \verbatim
   56: *>          UPLO is CHARACTER*1
   57: *>          = 'U':  Upper triangle of A is stored;
   58: *>          = 'L':  Lower triangle of A is stored.
   59: *> \endverbatim
   60: *>
   61: *> \param[in] N
   62: *> \verbatim
   63: *>          N is INTEGER
   64: *>          The order of the matrix A.  N >= 0.
   65: *> \endverbatim
   66: *>
   67: *> \param[in,out] A
   68: *> \verbatim
   69: *>          A is COMPLEX*16 array, dimension (LDA,N)
   70: *>          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
   71: *>          N-by-N upper triangular part of A contains the upper
   72: *>          triangular part of the matrix A, and the strictly lower
   73: *>          triangular part of A is not referenced.  If UPLO = 'L', the
   74: *>          leading N-by-N lower triangular part of A contains the lower
   75: *>          triangular part of the matrix A, and the strictly upper
   76: *>          triangular part of A is not referenced.
   77: *>
   78: *>          On exit, the block diagonal matrix D and the multipliers used
   79: *>          to obtain the factor U or L (see below for further details).
   80: *> \endverbatim
   81: *>
   82: *> \param[in] LDA
   83: *> \verbatim
   84: *>          LDA is INTEGER
   85: *>          The leading dimension of the array A.  LDA >= max(1,N).
   86: *> \endverbatim
   87: *>
   88: *> \param[out] IPIV
   89: *> \verbatim
   90: *>          IPIV is INTEGER array, dimension (N)
   91: *>          Details of the interchanges and the block structure of D.
   92: *>          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
   93: *>          interchanged and D(k,k) is a 1-by-1 diagonal block.
   94: *>          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
   95: *>          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
   96: *>          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
   97: *>          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
   98: *>          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
   99: *> \endverbatim
  100: *>
  101: *> \param[out] WORK
  102: *> \verbatim
  103: *>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
  104: *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  105: *> \endverbatim
  106: *>
  107: *> \param[in] LWORK
  108: *> \verbatim
  109: *>          LWORK is INTEGER
  110: *>          The length of WORK.  LWORK >=1.  For best performance
  111: *>          LWORK >= N*NB, where NB is the block size returned by ILAENV.
  112: *>
  113: *>          If LWORK = -1, then a workspace query is assumed; the routine
  114: *>          only calculates the optimal size of the WORK array, returns
  115: *>          this value as the first entry of the WORK array, and no error
  116: *>          message related to LWORK is issued by XERBLA.
  117: *> \endverbatim
  118: *>
  119: *> \param[out] INFO
  120: *> \verbatim
  121: *>          INFO is INTEGER
  122: *>          = 0:  successful exit
  123: *>          < 0:  if INFO = -i, the i-th argument had an illegal value
  124: *>          > 0:  if INFO = i, D(i,i) is exactly zero.  The factorization
  125: *>                has been completed, but the block diagonal matrix D is
  126: *>                exactly singular, and division by zero will occur if it
  127: *>                is used to solve a system of equations.
  128: *> \endverbatim
  129: *
  130: *  Authors:
  131: *  ========
  132: *
  133: *> \author Univ. of Tennessee
  134: *> \author Univ. of California Berkeley
  135: *> \author Univ. of Colorado Denver
  136: *> \author NAG Ltd.
  137: *
  138: *> \ingroup complex16SYcomputational
  139: *
  140: *> \par Further Details:
  141: *  =====================
  142: *>
  143: *> \verbatim
  144: *>
  145: *>  If UPLO = 'U', then A = U*D*U**T, where
  146: *>     U = P(n)*U(n)* ... *P(k)U(k)* ...,
  147: *>  i.e., U is a product of terms P(k)*U(k), where k decreases from n to
  148: *>  1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  149: *>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  150: *>  defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
  151: *>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
  152: *>
  153: *>             (   I    v    0   )   k-s
  154: *>     U(k) =  (   0    I    0   )   s
  155: *>             (   0    0    I   )   n-k
  156: *>                k-s   s   n-k
  157: *>
  158: *>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
  159: *>  If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
  160: *>  and A(k,k), and v overwrites A(1:k-2,k-1:k).
  161: *>
  162: *>  If UPLO = 'L', then A = L*D*L**T, where
  163: *>     L = P(1)*L(1)* ... *P(k)*L(k)* ...,
  164: *>  i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
  165: *>  n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  166: *>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  167: *>  defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
  168: *>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
  169: *>
  170: *>             (   I    0     0   )  k-1
  171: *>     L(k) =  (   0    I     0   )  s
  172: *>             (   0    v     I   )  n-k-s+1
  173: *>                k-1   s  n-k-s+1
  174: *>
  175: *>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
  176: *>  If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
  177: *>  and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
  178: *> \endverbatim
  179: *>
  180: *  =====================================================================
  181:       SUBROUTINE ZSYTRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
  182: *
  183: *  -- LAPACK computational routine --
  184: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
  185: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
  186: *
  187: *     .. Scalar Arguments ..
  188:       CHARACTER          UPLO
  189:       INTEGER            INFO, LDA, LWORK, N
  190: *     ..
  191: *     .. Array Arguments ..
  192:       INTEGER            IPIV( * )
  193:       COMPLEX*16         A( LDA, * ), WORK( * )
  194: *     ..
  195: *
  196: *  =====================================================================
  197: *
  198: *     .. Local Scalars ..
  199:       LOGICAL            LQUERY, UPPER
  200:       INTEGER            IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
  201: *     ..
  202: *     .. External Functions ..
  203:       LOGICAL            LSAME
  204:       INTEGER            ILAENV
  205:       EXTERNAL           LSAME, ILAENV
  206: *     ..
  207: *     .. External Subroutines ..
  208:       EXTERNAL           XERBLA, ZLASYF, ZSYTF2
  209: *     ..
  210: *     .. Intrinsic Functions ..
  211:       INTRINSIC          MAX
  212: *     ..
  213: *     .. Executable Statements ..
  214: *
  215: *     Test the input parameters.
  216: *
  217:       INFO = 0
  218:       UPPER = LSAME( UPLO, 'U' )
  219:       LQUERY = ( LWORK.EQ.-1 )
  220:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
  221:          INFO = -1
  222:       ELSE IF( N.LT.0 ) THEN
  223:          INFO = -2
  224:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  225:          INFO = -4
  226:       ELSE IF( LWORK.LT.1 .AND. .NOT.LQUERY ) THEN
  227:          INFO = -7
  228:       END IF
  229: *
  230:       IF( INFO.EQ.0 ) THEN
  231: *
  232: *        Determine the block size
  233: *
  234:          NB = ILAENV( 1, 'ZSYTRF', UPLO, N, -1, -1, -1 )
  235:          LWKOPT = N*NB
  236:          WORK( 1 ) = LWKOPT
  237:       END IF
  238: *
  239:       IF( INFO.NE.0 ) THEN
  240:          CALL XERBLA( 'ZSYTRF', -INFO )
  241:          RETURN
  242:       ELSE IF( LQUERY ) THEN
  243:          RETURN
  244:       END IF
  245: *
  246:       NBMIN = 2
  247:       LDWORK = N
  248:       IF( NB.GT.1 .AND. NB.LT.N ) THEN
  249:          IWS = LDWORK*NB
  250:          IF( LWORK.LT.IWS ) THEN
  251:             NB = MAX( LWORK / LDWORK, 1 )
  252:             NBMIN = MAX( 2, ILAENV( 2, 'ZSYTRF', UPLO, N, -1, -1, -1 ) )
  253:          END IF
  254:       ELSE
  255:          IWS = 1
  256:       END IF
  257:       IF( NB.LT.NBMIN )
  258:      $   NB = N
  259: *
  260:       IF( UPPER ) THEN
  261: *
  262: *        Factorize A as U*D*U**T using the upper triangle of A
  263: *
  264: *        K is the main loop index, decreasing from N to 1 in steps of
  265: *        KB, where KB is the number of columns factorized by ZLASYF;
  266: *        KB is either NB or NB-1, or K for the last block
  267: *
  268:          K = N
  269:    10    CONTINUE
  270: *
  271: *        If K < 1, exit from loop
  272: *
  273:          IF( K.LT.1 )
  274:      $      GO TO 40
  275: *
  276:          IF( K.GT.NB ) THEN
  277: *
  278: *           Factorize columns k-kb+1:k of A and use blocked code to
  279: *           update columns 1:k-kb
  280: *
  281:             CALL ZLASYF( UPLO, K, NB, KB, A, LDA, IPIV, WORK, N, IINFO )
  282:          ELSE
  283: *
  284: *           Use unblocked code to factorize columns 1:k of A
  285: *
  286:             CALL ZSYTF2( UPLO, K, A, LDA, IPIV, IINFO )
  287:             KB = K
  288:          END IF
  289: *
  290: *        Set INFO on the first occurrence of a zero pivot
  291: *
  292:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
  293:      $      INFO = IINFO
  294: *
  295: *        Decrease K and return to the start of the main loop
  296: *
  297:          K = K - KB
  298:          GO TO 10
  299: *
  300:       ELSE
  301: *
  302: *        Factorize A as L*D*L**T using the lower triangle of A
  303: *
  304: *        K is the main loop index, increasing from 1 to N in steps of
  305: *        KB, where KB is the number of columns factorized by ZLASYF;
  306: *        KB is either NB or NB-1, or N-K+1 for the last block
  307: *
  308:          K = 1
  309:    20    CONTINUE
  310: *
  311: *        If K > N, exit from loop
  312: *
  313:          IF( K.GT.N )
  314:      $      GO TO 40
  315: *
  316:          IF( K.LE.N-NB ) THEN
  317: *
  318: *           Factorize columns k:k+kb-1 of A and use blocked code to
  319: *           update columns k+kb:n
  320: *
  321:             CALL ZLASYF( UPLO, N-K+1, NB, KB, A( K, K ), LDA, IPIV( K ),
  322:      $                   WORK, N, IINFO )
  323:          ELSE
  324: *
  325: *           Use unblocked code to factorize columns k:n of A
  326: *
  327:             CALL ZSYTF2( UPLO, N-K+1, A( K, K ), LDA, IPIV( K ), IINFO )
  328:             KB = N - K + 1
  329:          END IF
  330: *
  331: *        Set INFO on the first occurrence of a zero pivot
  332: *
  333:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
  334:      $      INFO = IINFO + K - 1
  335: *
  336: *        Adjust IPIV
  337: *
  338:          DO 30 J = K, K + KB - 1
  339:             IF( IPIV( J ).GT.0 ) THEN
  340:                IPIV( J ) = IPIV( J ) + K - 1
  341:             ELSE
  342:                IPIV( J ) = IPIV( J ) - K + 1
  343:             END IF
  344:    30    CONTINUE
  345: *
  346: *        Increase K and return to the start of the main loop
  347: *
  348:          K = K + KB
  349:          GO TO 20
  350: *
  351:       END IF
  352: *
  353:    40 CONTINUE
  354:       WORK( 1 ) = LWKOPT
  355:       RETURN
  356: *
  357: *     End of ZSYTRF
  358: *
  359:       END