1: *> \brief \b DPOCON
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DPOCON + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dpocon.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dpocon.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dpocon.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DPOCON( UPLO, N, A, LDA, ANORM, RCOND, WORK, IWORK,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER UPLO
26: * INTEGER INFO, LDA, N
27: * DOUBLE PRECISION ANORM, RCOND
28: * ..
29: * .. Array Arguments ..
30: * INTEGER IWORK( * )
31: * DOUBLE PRECISION A( LDA, * ), WORK( * )
32: * ..
33: *
34: *
35: *> \par Purpose:
36: * =============
37: *>
38: *> \verbatim
39: *>
40: *> DPOCON estimates the reciprocal of the condition number (in the
41: *> 1-norm) of a real symmetric positive definite matrix using the
42: *> Cholesky factorization A = U**T*U or A = L*L**T computed by DPOTRF.
43: *>
44: *> An estimate is obtained for norm(inv(A)), and the reciprocal of the
45: *> condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
46: *> \endverbatim
47: *
48: * Arguments:
49: * ==========
50: *
51: *> \param[in] UPLO
52: *> \verbatim
53: *> UPLO is CHARACTER*1
54: *> = 'U': Upper triangle of A is stored;
55: *> = 'L': Lower triangle of A is stored.
56: *> \endverbatim
57: *>
58: *> \param[in] N
59: *> \verbatim
60: *> N is INTEGER
61: *> The order of the matrix A. N >= 0.
62: *> \endverbatim
63: *>
64: *> \param[in] A
65: *> \verbatim
66: *> A is DOUBLE PRECISION array, dimension (LDA,N)
67: *> The triangular factor U or L from the Cholesky factorization
68: *> A = U**T*U or A = L*L**T, as computed by DPOTRF.
69: *> \endverbatim
70: *>
71: *> \param[in] LDA
72: *> \verbatim
73: *> LDA is INTEGER
74: *> The leading dimension of the array A. LDA >= max(1,N).
75: *> \endverbatim
76: *>
77: *> \param[in] ANORM
78: *> \verbatim
79: *> ANORM is DOUBLE PRECISION
80: *> The 1-norm (or infinity-norm) of the symmetric matrix A.
81: *> \endverbatim
82: *>
83: *> \param[out] RCOND
84: *> \verbatim
85: *> RCOND is DOUBLE PRECISION
86: *> The reciprocal of the condition number of the matrix A,
87: *> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
88: *> estimate of the 1-norm of inv(A) computed in this routine.
89: *> \endverbatim
90: *>
91: *> \param[out] WORK
92: *> \verbatim
93: *> WORK is DOUBLE PRECISION array, dimension (3*N)
94: *> \endverbatim
95: *>
96: *> \param[out] IWORK
97: *> \verbatim
98: *> IWORK is INTEGER array, dimension (N)
99: *> \endverbatim
100: *>
101: *> \param[out] INFO
102: *> \verbatim
103: *> INFO is INTEGER
104: *> = 0: successful exit
105: *> < 0: if INFO = -i, the i-th argument had an illegal value
106: *> \endverbatim
107: *
108: * Authors:
109: * ========
110: *
111: *> \author Univ. of Tennessee
112: *> \author Univ. of California Berkeley
113: *> \author Univ. of Colorado Denver
114: *> \author NAG Ltd.
115: *
116: *> \ingroup doublePOcomputational
117: *
118: * =====================================================================
119: SUBROUTINE DPOCON( UPLO, N, A, LDA, ANORM, RCOND, WORK, IWORK,
120: $ INFO )
121: *
122: * -- LAPACK computational routine --
123: * -- LAPACK is a software package provided by Univ. of Tennessee, --
124: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
125: *
126: * .. Scalar Arguments ..
127: CHARACTER UPLO
128: INTEGER INFO, LDA, N
129: DOUBLE PRECISION ANORM, RCOND
130: * ..
131: * .. Array Arguments ..
132: INTEGER IWORK( * )
133: DOUBLE PRECISION A( LDA, * ), WORK( * )
134: * ..
135: *
136: * =====================================================================
137: *
138: * .. Parameters ..
139: DOUBLE PRECISION ONE, ZERO
140: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
141: * ..
142: * .. Local Scalars ..
143: LOGICAL UPPER
144: CHARACTER NORMIN
145: INTEGER IX, KASE
146: DOUBLE PRECISION AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
147: * ..
148: * .. Local Arrays ..
149: INTEGER ISAVE( 3 )
150: * ..
151: * .. External Functions ..
152: LOGICAL LSAME
153: INTEGER IDAMAX
154: DOUBLE PRECISION DLAMCH
155: EXTERNAL LSAME, IDAMAX, DLAMCH
156: * ..
157: * .. External Subroutines ..
158: EXTERNAL DLACN2, DLATRS, DRSCL, XERBLA
159: * ..
160: * .. Intrinsic Functions ..
161: INTRINSIC ABS, MAX
162: * ..
163: * .. Executable Statements ..
164: *
165: * Test the input parameters.
166: *
167: INFO = 0
168: UPPER = LSAME( UPLO, 'U' )
169: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
170: INFO = -1
171: ELSE IF( N.LT.0 ) THEN
172: INFO = -2
173: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
174: INFO = -4
175: ELSE IF( ANORM.LT.ZERO ) THEN
176: INFO = -5
177: END IF
178: IF( INFO.NE.0 ) THEN
179: CALL XERBLA( 'DPOCON', -INFO )
180: RETURN
181: END IF
182: *
183: * Quick return if possible
184: *
185: RCOND = ZERO
186: IF( N.EQ.0 ) THEN
187: RCOND = ONE
188: RETURN
189: ELSE IF( ANORM.EQ.ZERO ) THEN
190: RETURN
191: END IF
192: *
193: SMLNUM = DLAMCH( 'Safe minimum' )
194: *
195: * Estimate the 1-norm of inv(A).
196: *
197: KASE = 0
198: NORMIN = 'N'
199: 10 CONTINUE
200: CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
201: IF( KASE.NE.0 ) THEN
202: IF( UPPER ) THEN
203: *
204: * Multiply by inv(U**T).
205: *
206: CALL DLATRS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N, A,
207: $ LDA, WORK, SCALEL, WORK( 2*N+1 ), INFO )
208: NORMIN = 'Y'
209: *
210: * Multiply by inv(U).
211: *
212: CALL DLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
213: $ A, LDA, WORK, SCALEU, WORK( 2*N+1 ), INFO )
214: ELSE
215: *
216: * Multiply by inv(L).
217: *
218: CALL DLATRS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
219: $ A, LDA, WORK, SCALEL, WORK( 2*N+1 ), INFO )
220: NORMIN = 'Y'
221: *
222: * Multiply by inv(L**T).
223: *
224: CALL DLATRS( 'Lower', 'Transpose', 'Non-unit', NORMIN, N, A,
225: $ LDA, WORK, SCALEU, WORK( 2*N+1 ), INFO )
226: END IF
227: *
228: * Multiply by 1/SCALE if doing so will not cause overflow.
229: *
230: SCALE = SCALEL*SCALEU
231: IF( SCALE.NE.ONE ) THEN
232: IX = IDAMAX( N, WORK, 1 )
233: IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
234: $ GO TO 20
235: CALL DRSCL( N, SCALE, WORK, 1 )
236: END IF
237: GO TO 10
238: END IF
239: *
240: * Compute the estimate of the reciprocal condition number.
241: *
242: IF( AINVNM.NE.ZERO )
243: $ RCOND = ( ONE / AINVNM ) / ANORM
244: *
245: 20 CONTINUE
246: RETURN
247: *
248: * End of DPOCON
249: *
250: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dpocon.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack