Return to dlauum.f CVS log

Up to [local] / rpl / lapack / lapack

Mise à jour de lapack vers la version 3.3.0.

    1:       SUBROUTINE DLAUUM( UPLO, N, A, LDA, INFO )
    2: *
    3: *  -- LAPACK auxiliary routine (version 3.2) --
    4: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
    5: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
    6: *     November 2006
    7: *
    8: *     .. Scalar Arguments ..
    9:       CHARACTER          UPLO
   10:       INTEGER            INFO, LDA, N
   11: *     ..
   12: *     .. Array Arguments ..
   13:       DOUBLE PRECISION   A( LDA, * )
   14: *     ..
   15: *
   16: *  Purpose
   17: *  =======
   18: *
   19: *  DLAUUM computes the product U * U' or L' * L, where the triangular
   20: *  factor U or L is stored in the upper or lower triangular part of
   21: *  the array A.
   22: *
   23: *  If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
   24: *  overwriting the factor U in A.
   25: *  If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
   26: *  overwriting the factor L in A.
   27: *
   28: *  This is the blocked form of the algorithm, calling Level 3 BLAS.
   29: *
   30: *  Arguments
   31: *  =========
   32: *
   33: *  UPLO    (input) CHARACTER*1
   34: *          Specifies whether the triangular factor stored in the array A
   35: *          is upper or lower triangular:
   36: *          = 'U':  Upper triangular
   37: *          = 'L':  Lower triangular
   38: *
   39: *  N       (input) INTEGER
   40: *          The order of the triangular factor U or L.  N >= 0.
   41: *
   42: *  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
   43: *          On entry, the triangular factor U or L.
   44: *          On exit, if UPLO = 'U', the upper triangle of A is
   45: *          overwritten with the upper triangle of the product U * U';
   46: *          if UPLO = 'L', the lower triangle of A is overwritten with
   47: *          the lower triangle of the product L' * L.
   48: *
   49: *  LDA     (input) INTEGER
   50: *          The leading dimension of the array A.  LDA >= max(1,N).
   51: *
   52: *  INFO    (output) INTEGER
   53: *          = 0: successful exit
   54: *          < 0: if INFO = -k, the k-th argument had an illegal value
   55: *
   56: *  =====================================================================
   57: *
   58: *     .. Parameters ..
   59:       DOUBLE PRECISION   ONE
   60:       PARAMETER          ( ONE = 1.0D+0 )
   61: *     ..
   62: *     .. Local Scalars ..
   63:       LOGICAL            UPPER
   64:       INTEGER            I, IB, NB
   65: *     ..
   66: *     .. External Functions ..
   67:       LOGICAL            LSAME
   68:       INTEGER            ILAENV
   69:       EXTERNAL           LSAME, ILAENV
   70: *     ..
   71: *     .. External Subroutines ..
   72:       EXTERNAL           DGEMM, DLAUU2, DSYRK, DTRMM, XERBLA
   73: *     ..
   74: *     .. Intrinsic Functions ..
   75:       INTRINSIC          MAX, MIN
   76: *     ..
   77: *     .. Executable Statements ..
   78: *
   79: *     Test the input parameters.
   80: *
   81:       INFO = 0
   82:       UPPER = LSAME( UPLO, 'U' )
   83:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
   84:          INFO = -1
   85:       ELSE IF( N.LT.0 ) THEN
   86:          INFO = -2
   87:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
   88:          INFO = -4
   89:       END IF
   90:       IF( INFO.NE.0 ) THEN
   91:          CALL XERBLA( 'DLAUUM', -INFO )
   92:          RETURN
   93:       END IF
   94: *
   95: *     Quick return if possible
   96: *
   97:       IF( N.EQ.0 )
   98:      $   RETURN
   99: *
  100: *     Determine the block size for this environment.
  101: *
  102:       NB = ILAENV( 1, 'DLAUUM', UPLO, N, -1, -1, -1 )
  103: *
  104:       IF( NB.LE.1 .OR. NB.GE.N ) THEN
  105: *
  106: *        Use unblocked code
  107: *
  108:          CALL DLAUU2( UPLO, N, A, LDA, INFO )
  109:       ELSE
  110: *
  111: *        Use blocked code
  112: *
  113:          IF( UPPER ) THEN
  114: *
  115: *           Compute the product U * U'.
  116: *
  117:             DO 10 I = 1, N, NB
  118:                IB = MIN( NB, N-I+1 )
  119:                CALL DTRMM( 'Right', 'Upper', 'Transpose', 'Non-unit',
  120:      $                     I-1, IB, ONE, A( I, I ), LDA, A( 1, I ),
  121:      $                     LDA )
  122:                CALL DLAUU2( 'Upper', IB, A( I, I ), LDA, INFO )
  123:                IF( I+IB.LE.N ) THEN
  124:                   CALL DGEMM( 'No transpose', 'Transpose', I-1, IB,
  125:      $                        N-I-IB+1, ONE, A( 1, I+IB ), LDA,
  126:      $                        A( I, I+IB ), LDA, ONE, A( 1, I ), LDA )
  127:                   CALL DSYRK( 'Upper', 'No transpose', IB, N-I-IB+1,
  128:      $                        ONE, A( I, I+IB ), LDA, ONE, A( I, I ),
  129:      $                        LDA )
  130:                END IF
  131:    10       CONTINUE
  132:          ELSE
  133: *
  134: *           Compute the product L' * L.
  135: *
  136:             DO 20 I = 1, N, NB
  137:                IB = MIN( NB, N-I+1 )
  138:                CALL DTRMM( 'Left', 'Lower', 'Transpose', 'Non-unit', IB,
  139:      $                     I-1, ONE, A( I, I ), LDA, A( I, 1 ), LDA )
  140:                CALL DLAUU2( 'Lower', IB, A( I, I ), LDA, INFO )
  141:                IF( I+IB.LE.N ) THEN
  142:                   CALL DGEMM( 'Transpose', 'No transpose', IB, I-1,
  143:      $                        N-I-IB+1, ONE, A( I+IB, I ), LDA,
  144:      $                        A( I+IB, 1 ), LDA, ONE, A( I, 1 ), LDA )
  145:                   CALL DSYRK( 'Lower', 'Transpose', IB, N-I-IB+1, ONE,
  146:      $                        A( I+IB, I ), LDA, ONE, A( I, I ), LDA )
  147:                END IF
  148:    20       CONTINUE
  149:          END IF
  150:       END IF
  151: *
  152:       RETURN
  153: *
  154: *     End of DLAUUM
  155: *
  156:       END