1: *> \brief <b> DGGES computes the eigenvalues, the Schur form, and, optionally, the matrix of Schur vectors for GE matrices</b>
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download DGGES + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dgges.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dgges.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dgges.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE DGGES( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB,
22: * SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL, VSR,
23: * LDVSR, WORK, LWORK, BWORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER JOBVSL, JOBVSR, SORT
27: * INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
28: * ..
29: * .. Array Arguments ..
30: * LOGICAL BWORK( * )
31: * DOUBLE PRECISION A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
32: * $ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
33: * $ VSR( LDVSR, * ), WORK( * )
34: * ..
35: * .. Function Arguments ..
36: * LOGICAL SELCTG
37: * EXTERNAL SELCTG
38: * ..
39: *
40: *
41: *> \par Purpose:
42: * =============
43: *>
44: *> \verbatim
45: *>
46: *> DGGES computes for a pair of N-by-N real nonsymmetric matrices (A,B),
47: *> the generalized eigenvalues, the generalized real Schur form (S,T),
48: *> optionally, the left and/or right matrices of Schur vectors (VSL and
49: *> VSR). This gives the generalized Schur factorization
50: *>
51: *> (A,B) = ( (VSL)*S*(VSR)**T, (VSL)*T*(VSR)**T )
52: *>
53: *> Optionally, it also orders the eigenvalues so that a selected cluster
54: *> of eigenvalues appears in the leading diagonal blocks of the upper
55: *> quasi-triangular matrix S and the upper triangular matrix T.The
56: *> leading columns of VSL and VSR then form an orthonormal basis for the
57: *> corresponding left and right eigenspaces (deflating subspaces).
58: *>
59: *> (If only the generalized eigenvalues are needed, use the driver
60: *> DGGEV instead, which is faster.)
61: *>
62: *> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
63: *> or a ratio alpha/beta = w, such that A - w*B is singular. It is
64: *> usually represented as the pair (alpha,beta), as there is a
65: *> reasonable interpretation for beta=0 or both being zero.
66: *>
67: *> A pair of matrices (S,T) is in generalized real Schur form if T is
68: *> upper triangular with non-negative diagonal and S is block upper
69: *> triangular with 1-by-1 and 2-by-2 blocks. 1-by-1 blocks correspond
70: *> to real generalized eigenvalues, while 2-by-2 blocks of S will be
71: *> "standardized" by making the corresponding elements of T have the
72: *> form:
73: *> [ a 0 ]
74: *> [ 0 b ]
75: *>
76: *> and the pair of corresponding 2-by-2 blocks in S and T will have a
77: *> complex conjugate pair of generalized eigenvalues.
78: *>
79: *> \endverbatim
80: *
81: * Arguments:
82: * ==========
83: *
84: *> \param[in] JOBVSL
85: *> \verbatim
86: *> JOBVSL is CHARACTER*1
87: *> = 'N': do not compute the left Schur vectors;
88: *> = 'V': compute the left Schur vectors.
89: *> \endverbatim
90: *>
91: *> \param[in] JOBVSR
92: *> \verbatim
93: *> JOBVSR is CHARACTER*1
94: *> = 'N': do not compute the right Schur vectors;
95: *> = 'V': compute the right Schur vectors.
96: *> \endverbatim
97: *>
98: *> \param[in] SORT
99: *> \verbatim
100: *> SORT is CHARACTER*1
101: *> Specifies whether or not to order the eigenvalues on the
102: *> diagonal of the generalized Schur form.
103: *> = 'N': Eigenvalues are not ordered;
104: *> = 'S': Eigenvalues are ordered (see SELCTG);
105: *> \endverbatim
106: *>
107: *> \param[in] SELCTG
108: *> \verbatim
109: *> SELCTG is a LOGICAL FUNCTION of three DOUBLE PRECISION arguments
110: *> SELCTG must be declared EXTERNAL in the calling subroutine.
111: *> If SORT = 'N', SELCTG is not referenced.
112: *> If SORT = 'S', SELCTG is used to select eigenvalues to sort
113: *> to the top left of the Schur form.
114: *> An eigenvalue (ALPHAR(j)+ALPHAI(j))/BETA(j) is selected if
115: *> SELCTG(ALPHAR(j),ALPHAI(j),BETA(j)) is true; i.e. if either
116: *> one of a complex conjugate pair of eigenvalues is selected,
117: *> then both complex eigenvalues are selected.
118: *>
119: *> Note that in the ill-conditioned case, a selected complex
120: *> eigenvalue may no longer satisfy SELCTG(ALPHAR(j),ALPHAI(j),
121: *> BETA(j)) = .TRUE. after ordering. INFO is to be set to N+2
122: *> in this case.
123: *> \endverbatim
124: *>
125: *> \param[in] N
126: *> \verbatim
127: *> N is INTEGER
128: *> The order of the matrices A, B, VSL, and VSR. N >= 0.
129: *> \endverbatim
130: *>
131: *> \param[in,out] A
132: *> \verbatim
133: *> A is DOUBLE PRECISION array, dimension (LDA, N)
134: *> On entry, the first of the pair of matrices.
135: *> On exit, A has been overwritten by its generalized Schur
136: *> form S.
137: *> \endverbatim
138: *>
139: *> \param[in] LDA
140: *> \verbatim
141: *> LDA is INTEGER
142: *> The leading dimension of A. LDA >= max(1,N).
143: *> \endverbatim
144: *>
145: *> \param[in,out] B
146: *> \verbatim
147: *> B is DOUBLE PRECISION array, dimension (LDB, N)
148: *> On entry, the second of the pair of matrices.
149: *> On exit, B has been overwritten by its generalized Schur
150: *> form T.
151: *> \endverbatim
152: *>
153: *> \param[in] LDB
154: *> \verbatim
155: *> LDB is INTEGER
156: *> The leading dimension of B. LDB >= max(1,N).
157: *> \endverbatim
158: *>
159: *> \param[out] SDIM
160: *> \verbatim
161: *> SDIM is INTEGER
162: *> If SORT = 'N', SDIM = 0.
163: *> If SORT = 'S', SDIM = number of eigenvalues (after sorting)
164: *> for which SELCTG is true. (Complex conjugate pairs for which
165: *> SELCTG is true for either eigenvalue count as 2.)
166: *> \endverbatim
167: *>
168: *> \param[out] ALPHAR
169: *> \verbatim
170: *> ALPHAR is DOUBLE PRECISION array, dimension (N)
171: *> \endverbatim
172: *>
173: *> \param[out] ALPHAI
174: *> \verbatim
175: *> ALPHAI is DOUBLE PRECISION array, dimension (N)
176: *> \endverbatim
177: *>
178: *> \param[out] BETA
179: *> \verbatim
180: *> BETA is DOUBLE PRECISION array, dimension (N)
181: *> On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will
182: *> be the generalized eigenvalues. ALPHAR(j) + ALPHAI(j)*i,
183: *> and BETA(j),j=1,...,N are the diagonals of the complex Schur
184: *> form (S,T) that would result if the 2-by-2 diagonal blocks of
185: *> the real Schur form of (A,B) were further reduced to
186: *> triangular form using 2-by-2 complex unitary transformations.
187: *> If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
188: *> positive, then the j-th and (j+1)-st eigenvalues are a
189: *> complex conjugate pair, with ALPHAI(j+1) negative.
190: *>
191: *> Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j)
192: *> may easily over- or underflow, and BETA(j) may even be zero.
193: *> Thus, the user should avoid naively computing the ratio.
194: *> However, ALPHAR and ALPHAI will be always less than and
195: *> usually comparable with norm(A) in magnitude, and BETA always
196: *> less than and usually comparable with norm(B).
197: *> \endverbatim
198: *>
199: *> \param[out] VSL
200: *> \verbatim
201: *> VSL is DOUBLE PRECISION array, dimension (LDVSL,N)
202: *> If JOBVSL = 'V', VSL will contain the left Schur vectors.
203: *> Not referenced if JOBVSL = 'N'.
204: *> \endverbatim
205: *>
206: *> \param[in] LDVSL
207: *> \verbatim
208: *> LDVSL is INTEGER
209: *> The leading dimension of the matrix VSL. LDVSL >=1, and
210: *> if JOBVSL = 'V', LDVSL >= N.
211: *> \endverbatim
212: *>
213: *> \param[out] VSR
214: *> \verbatim
215: *> VSR is DOUBLE PRECISION array, dimension (LDVSR,N)
216: *> If JOBVSR = 'V', VSR will contain the right Schur vectors.
217: *> Not referenced if JOBVSR = 'N'.
218: *> \endverbatim
219: *>
220: *> \param[in] LDVSR
221: *> \verbatim
222: *> LDVSR is INTEGER
223: *> The leading dimension of the matrix VSR. LDVSR >= 1, and
224: *> if JOBVSR = 'V', LDVSR >= N.
225: *> \endverbatim
226: *>
227: *> \param[out] WORK
228: *> \verbatim
229: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
230: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
231: *> \endverbatim
232: *>
233: *> \param[in] LWORK
234: *> \verbatim
235: *> LWORK is INTEGER
236: *> The dimension of the array WORK.
237: *> If N = 0, LWORK >= 1, else LWORK >= 8*N+16.
238: *> For good performance , LWORK must generally be larger.
239: *>
240: *> If LWORK = -1, then a workspace query is assumed; the routine
241: *> only calculates the optimal size of the WORK array, returns
242: *> this value as the first entry of the WORK array, and no error
243: *> message related to LWORK is issued by XERBLA.
244: *> \endverbatim
245: *>
246: *> \param[out] BWORK
247: *> \verbatim
248: *> BWORK is LOGICAL array, dimension (N)
249: *> Not referenced if SORT = 'N'.
250: *> \endverbatim
251: *>
252: *> \param[out] INFO
253: *> \verbatim
254: *> INFO is INTEGER
255: *> = 0: successful exit
256: *> < 0: if INFO = -i, the i-th argument had an illegal value.
257: *> = 1,...,N:
258: *> The QZ iteration failed. (A,B) are not in Schur
259: *> form, but ALPHAR(j), ALPHAI(j), and BETA(j) should
260: *> be correct for j=INFO+1,...,N.
261: *> > N: =N+1: other than QZ iteration failed in DHGEQZ.
262: *> =N+2: after reordering, roundoff changed values of
263: *> some complex eigenvalues so that leading
264: *> eigenvalues in the Generalized Schur form no
265: *> longer satisfy SELCTG=.TRUE. This could also
266: *> be caused due to scaling.
267: *> =N+3: reordering failed in DTGSEN.
268: *> \endverbatim
269: *
270: * Authors:
271: * ========
272: *
273: *> \author Univ. of Tennessee
274: *> \author Univ. of California Berkeley
275: *> \author Univ. of Colorado Denver
276: *> \author NAG Ltd.
277: *
278: *> \ingroup doubleGEeigen
279: *
280: * =====================================================================
281: SUBROUTINE DGGES( JOBVSL, JOBVSR, SORT, SELCTG, N, A, LDA, B, LDB,
282: $ SDIM, ALPHAR, ALPHAI, BETA, VSL, LDVSL, VSR,
283: $ LDVSR, WORK, LWORK, BWORK, INFO )
284: *
285: * -- LAPACK driver routine --
286: * -- LAPACK is a software package provided by Univ. of Tennessee, --
287: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
288: *
289: * .. Scalar Arguments ..
290: CHARACTER JOBVSL, JOBVSR, SORT
291: INTEGER INFO, LDA, LDB, LDVSL, LDVSR, LWORK, N, SDIM
292: * ..
293: * .. Array Arguments ..
294: LOGICAL BWORK( * )
295: DOUBLE PRECISION A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
296: $ B( LDB, * ), BETA( * ), VSL( LDVSL, * ),
297: $ VSR( LDVSR, * ), WORK( * )
298: * ..
299: * .. Function Arguments ..
300: LOGICAL SELCTG
301: EXTERNAL SELCTG
302: * ..
303: *
304: * =====================================================================
305: *
306: * .. Parameters ..
307: DOUBLE PRECISION ZERO, ONE
308: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
309: * ..
310: * .. Local Scalars ..
311: LOGICAL CURSL, ILASCL, ILBSCL, ILVSL, ILVSR, LASTSL,
312: $ LQUERY, LST2SL, WANTST
313: INTEGER I, ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT,
314: $ ILO, IP, IRIGHT, IROWS, ITAU, IWRK, MAXWRK,
315: $ MINWRK
316: DOUBLE PRECISION ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS, PVSL,
317: $ PVSR, SAFMAX, SAFMIN, SMLNUM
318: * ..
319: * .. Local Arrays ..
320: INTEGER IDUM( 1 )
321: DOUBLE PRECISION DIF( 2 )
322: * ..
323: * .. External Subroutines ..
324: EXTERNAL DGEQRF, DGGBAK, DGGBAL, DGGHRD, DHGEQZ, DLABAD,
325: $ DLACPY, DLASCL, DLASET, DORGQR, DORMQR, DTGSEN,
326: $ XERBLA
327: * ..
328: * .. External Functions ..
329: LOGICAL LSAME
330: INTEGER ILAENV
331: DOUBLE PRECISION DLAMCH, DLANGE
332: EXTERNAL LSAME, ILAENV, DLAMCH, DLANGE
333: * ..
334: * .. Intrinsic Functions ..
335: INTRINSIC ABS, MAX, SQRT
336: * ..
337: * .. Executable Statements ..
338: *
339: * Decode the input arguments
340: *
341: IF( LSAME( JOBVSL, 'N' ) ) THEN
342: IJOBVL = 1
343: ILVSL = .FALSE.
344: ELSE IF( LSAME( JOBVSL, 'V' ) ) THEN
345: IJOBVL = 2
346: ILVSL = .TRUE.
347: ELSE
348: IJOBVL = -1
349: ILVSL = .FALSE.
350: END IF
351: *
352: IF( LSAME( JOBVSR, 'N' ) ) THEN
353: IJOBVR = 1
354: ILVSR = .FALSE.
355: ELSE IF( LSAME( JOBVSR, 'V' ) ) THEN
356: IJOBVR = 2
357: ILVSR = .TRUE.
358: ELSE
359: IJOBVR = -1
360: ILVSR = .FALSE.
361: END IF
362: *
363: WANTST = LSAME( SORT, 'S' )
364: *
365: * Test the input arguments
366: *
367: INFO = 0
368: LQUERY = ( LWORK.EQ.-1 )
369: IF( IJOBVL.LE.0 ) THEN
370: INFO = -1
371: ELSE IF( IJOBVR.LE.0 ) THEN
372: INFO = -2
373: ELSE IF( ( .NOT.WANTST ) .AND. ( .NOT.LSAME( SORT, 'N' ) ) ) THEN
374: INFO = -3
375: ELSE IF( N.LT.0 ) THEN
376: INFO = -5
377: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
378: INFO = -7
379: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
380: INFO = -9
381: ELSE IF( LDVSL.LT.1 .OR. ( ILVSL .AND. LDVSL.LT.N ) ) THEN
382: INFO = -15
383: ELSE IF( LDVSR.LT.1 .OR. ( ILVSR .AND. LDVSR.LT.N ) ) THEN
384: INFO = -17
385: END IF
386: *
387: * Compute workspace
388: * (Note: Comments in the code beginning "Workspace:" describe the
389: * minimal amount of workspace needed at that point in the code,
390: * as well as the preferred amount for good performance.
391: * NB refers to the optimal block size for the immediately
392: * following subroutine, as returned by ILAENV.)
393: *
394: IF( INFO.EQ.0 ) THEN
395: IF( N.GT.0 )THEN
396: MINWRK = MAX( 8*N, 6*N + 16 )
397: MAXWRK = MINWRK - N +
398: $ N*ILAENV( 1, 'DGEQRF', ' ', N, 1, N, 0 )
399: MAXWRK = MAX( MAXWRK, MINWRK - N +
400: $ N*ILAENV( 1, 'DORMQR', ' ', N, 1, N, -1 ) )
401: IF( ILVSL ) THEN
402: MAXWRK = MAX( MAXWRK, MINWRK - N +
403: $ N*ILAENV( 1, 'DORGQR', ' ', N, 1, N, -1 ) )
404: END IF
405: ELSE
406: MINWRK = 1
407: MAXWRK = 1
408: END IF
409: WORK( 1 ) = MAXWRK
410: *
411: IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY )
412: $ INFO = -19
413: END IF
414: *
415: IF( INFO.NE.0 ) THEN
416: CALL XERBLA( 'DGGES ', -INFO )
417: RETURN
418: ELSE IF( LQUERY ) THEN
419: RETURN
420: END IF
421: *
422: * Quick return if possible
423: *
424: IF( N.EQ.0 ) THEN
425: SDIM = 0
426: RETURN
427: END IF
428: *
429: * Get machine constants
430: *
431: EPS = DLAMCH( 'P' )
432: SAFMIN = DLAMCH( 'S' )
433: SAFMAX = ONE / SAFMIN
434: CALL DLABAD( SAFMIN, SAFMAX )
435: SMLNUM = SQRT( SAFMIN ) / EPS
436: BIGNUM = ONE / SMLNUM
437: *
438: * Scale A if max element outside range [SMLNUM,BIGNUM]
439: *
440: ANRM = DLANGE( 'M', N, N, A, LDA, WORK )
441: ILASCL = .FALSE.
442: IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
443: ANRMTO = SMLNUM
444: ILASCL = .TRUE.
445: ELSE IF( ANRM.GT.BIGNUM ) THEN
446: ANRMTO = BIGNUM
447: ILASCL = .TRUE.
448: END IF
449: IF( ILASCL )
450: $ CALL DLASCL( 'G', 0, 0, ANRM, ANRMTO, N, N, A, LDA, IERR )
451: *
452: * Scale B if max element outside range [SMLNUM,BIGNUM]
453: *
454: BNRM = DLANGE( 'M', N, N, B, LDB, WORK )
455: ILBSCL = .FALSE.
456: IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
457: BNRMTO = SMLNUM
458: ILBSCL = .TRUE.
459: ELSE IF( BNRM.GT.BIGNUM ) THEN
460: BNRMTO = BIGNUM
461: ILBSCL = .TRUE.
462: END IF
463: IF( ILBSCL )
464: $ CALL DLASCL( 'G', 0, 0, BNRM, BNRMTO, N, N, B, LDB, IERR )
465: *
466: * Permute the matrix to make it more nearly triangular
467: * (Workspace: need 6*N + 2*N space for storing balancing factors)
468: *
469: ILEFT = 1
470: IRIGHT = N + 1
471: IWRK = IRIGHT + N
472: CALL DGGBAL( 'P', N, A, LDA, B, LDB, ILO, IHI, WORK( ILEFT ),
473: $ WORK( IRIGHT ), WORK( IWRK ), IERR )
474: *
475: * Reduce B to triangular form (QR decomposition of B)
476: * (Workspace: need N, prefer N*NB)
477: *
478: IROWS = IHI + 1 - ILO
479: ICOLS = N + 1 - ILO
480: ITAU = IWRK
481: IWRK = ITAU + IROWS
482: CALL DGEQRF( IROWS, ICOLS, B( ILO, ILO ), LDB, WORK( ITAU ),
483: $ WORK( IWRK ), LWORK+1-IWRK, IERR )
484: *
485: * Apply the orthogonal transformation to matrix A
486: * (Workspace: need N, prefer N*NB)
487: *
488: CALL DORMQR( 'L', 'T', IROWS, ICOLS, IROWS, B( ILO, ILO ), LDB,
489: $ WORK( ITAU ), A( ILO, ILO ), LDA, WORK( IWRK ),
490: $ LWORK+1-IWRK, IERR )
491: *
492: * Initialize VSL
493: * (Workspace: need N, prefer N*NB)
494: *
495: IF( ILVSL ) THEN
496: CALL DLASET( 'Full', N, N, ZERO, ONE, VSL, LDVSL )
497: IF( IROWS.GT.1 ) THEN
498: CALL DLACPY( 'L', IROWS-1, IROWS-1, B( ILO+1, ILO ), LDB,
499: $ VSL( ILO+1, ILO ), LDVSL )
500: END IF
501: CALL DORGQR( IROWS, IROWS, IROWS, VSL( ILO, ILO ), LDVSL,
502: $ WORK( ITAU ), WORK( IWRK ), LWORK+1-IWRK, IERR )
503: END IF
504: *
505: * Initialize VSR
506: *
507: IF( ILVSR )
508: $ CALL DLASET( 'Full', N, N, ZERO, ONE, VSR, LDVSR )
509: *
510: * Reduce to generalized Hessenberg form
511: * (Workspace: none needed)
512: *
513: CALL DGGHRD( JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB, VSL,
514: $ LDVSL, VSR, LDVSR, IERR )
515: *
516: * Perform QZ algorithm, computing Schur vectors if desired
517: * (Workspace: need N)
518: *
519: IWRK = ITAU
520: CALL DHGEQZ( 'S', JOBVSL, JOBVSR, N, ILO, IHI, A, LDA, B, LDB,
521: $ ALPHAR, ALPHAI, BETA, VSL, LDVSL, VSR, LDVSR,
522: $ WORK( IWRK ), LWORK+1-IWRK, IERR )
523: IF( IERR.NE.0 ) THEN
524: IF( IERR.GT.0 .AND. IERR.LE.N ) THEN
525: INFO = IERR
526: ELSE IF( IERR.GT.N .AND. IERR.LE.2*N ) THEN
527: INFO = IERR - N
528: ELSE
529: INFO = N + 1
530: END IF
531: GO TO 50
532: END IF
533: *
534: * Sort eigenvalues ALPHA/BETA if desired
535: * (Workspace: need 4*N+16 )
536: *
537: SDIM = 0
538: IF( WANTST ) THEN
539: *
540: * Undo scaling on eigenvalues before SELCTGing
541: *
542: IF( ILASCL ) THEN
543: CALL DLASCL( 'G', 0, 0, ANRMTO, ANRM, N, 1, ALPHAR, N,
544: $ IERR )
545: CALL DLASCL( 'G', 0, 0, ANRMTO, ANRM, N, 1, ALPHAI, N,
546: $ IERR )
547: END IF
548: IF( ILBSCL )
549: $ CALL DLASCL( 'G', 0, 0, BNRMTO, BNRM, N, 1, BETA, N, IERR )
550: *
551: * Select eigenvalues
552: *
553: DO 10 I = 1, N
554: BWORK( I ) = SELCTG( ALPHAR( I ), ALPHAI( I ), BETA( I ) )
555: 10 CONTINUE
556: *
557: CALL DTGSEN( 0, ILVSL, ILVSR, BWORK, N, A, LDA, B, LDB, ALPHAR,
558: $ ALPHAI, BETA, VSL, LDVSL, VSR, LDVSR, SDIM, PVSL,
559: $ PVSR, DIF, WORK( IWRK ), LWORK-IWRK+1, IDUM, 1,
560: $ IERR )
561: IF( IERR.EQ.1 )
562: $ INFO = N + 3
563: *
564: END IF
565: *
566: * Apply back-permutation to VSL and VSR
567: * (Workspace: none needed)
568: *
569: IF( ILVSL )
570: $ CALL DGGBAK( 'P', 'L', N, ILO, IHI, WORK( ILEFT ),
571: $ WORK( IRIGHT ), N, VSL, LDVSL, IERR )
572: *
573: IF( ILVSR )
574: $ CALL DGGBAK( 'P', 'R', N, ILO, IHI, WORK( ILEFT ),
575: $ WORK( IRIGHT ), N, VSR, LDVSR, IERR )
576: *
577: * Check if unscaling would cause over/underflow, if so, rescale
578: * (ALPHAR(I),ALPHAI(I),BETA(I)) so BETA(I) is on the order of
579: * B(I,I) and ALPHAR(I) and ALPHAI(I) are on the order of A(I,I)
580: *
581: IF( ILASCL ) THEN
582: DO 20 I = 1, N
583: IF( ALPHAI( I ).NE.ZERO ) THEN
584: IF( ( ALPHAR( I ) / SAFMAX ).GT.( ANRMTO / ANRM ) .OR.
585: $ ( SAFMIN / ALPHAR( I ) ).GT.( ANRM / ANRMTO ) ) THEN
586: WORK( 1 ) = ABS( A( I, I ) / ALPHAR( I ) )
587: BETA( I ) = BETA( I )*WORK( 1 )
588: ALPHAR( I ) = ALPHAR( I )*WORK( 1 )
589: ALPHAI( I ) = ALPHAI( I )*WORK( 1 )
590: ELSE IF( ( ALPHAI( I ) / SAFMAX ).GT.
591: $ ( ANRMTO / ANRM ) .OR.
592: $ ( SAFMIN / ALPHAI( I ) ).GT.( ANRM / ANRMTO ) )
593: $ THEN
594: WORK( 1 ) = ABS( A( I, I+1 ) / ALPHAI( I ) )
595: BETA( I ) = BETA( I )*WORK( 1 )
596: ALPHAR( I ) = ALPHAR( I )*WORK( 1 )
597: ALPHAI( I ) = ALPHAI( I )*WORK( 1 )
598: END IF
599: END IF
600: 20 CONTINUE
601: END IF
602: *
603: IF( ILBSCL ) THEN
604: DO 30 I = 1, N
605: IF( ALPHAI( I ).NE.ZERO ) THEN
606: IF( ( BETA( I ) / SAFMAX ).GT.( BNRMTO / BNRM ) .OR.
607: $ ( SAFMIN / BETA( I ) ).GT.( BNRM / BNRMTO ) ) THEN
608: WORK( 1 ) = ABS( B( I, I ) / BETA( I ) )
609: BETA( I ) = BETA( I )*WORK( 1 )
610: ALPHAR( I ) = ALPHAR( I )*WORK( 1 )
611: ALPHAI( I ) = ALPHAI( I )*WORK( 1 )
612: END IF
613: END IF
614: 30 CONTINUE
615: END IF
616: *
617: * Undo scaling
618: *
619: IF( ILASCL ) THEN
620: CALL DLASCL( 'H', 0, 0, ANRMTO, ANRM, N, N, A, LDA, IERR )
621: CALL DLASCL( 'G', 0, 0, ANRMTO, ANRM, N, 1, ALPHAR, N, IERR )
622: CALL DLASCL( 'G', 0, 0, ANRMTO, ANRM, N, 1, ALPHAI, N, IERR )
623: END IF
624: *
625: IF( ILBSCL ) THEN
626: CALL DLASCL( 'U', 0, 0, BNRMTO, BNRM, N, N, B, LDB, IERR )
627: CALL DLASCL( 'G', 0, 0, BNRMTO, BNRM, N, 1, BETA, N, IERR )
628: END IF
629: *
630: IF( WANTST ) THEN
631: *
632: * Check if reordering is correct
633: *
634: LASTSL = .TRUE.
635: LST2SL = .TRUE.
636: SDIM = 0
637: IP = 0
638: DO 40 I = 1, N
639: CURSL = SELCTG( ALPHAR( I ), ALPHAI( I ), BETA( I ) )
640: IF( ALPHAI( I ).EQ.ZERO ) THEN
641: IF( CURSL )
642: $ SDIM = SDIM + 1
643: IP = 0
644: IF( CURSL .AND. .NOT.LASTSL )
645: $ INFO = N + 2
646: ELSE
647: IF( IP.EQ.1 ) THEN
648: *
649: * Last eigenvalue of conjugate pair
650: *
651: CURSL = CURSL .OR. LASTSL
652: LASTSL = CURSL
653: IF( CURSL )
654: $ SDIM = SDIM + 2
655: IP = -1
656: IF( CURSL .AND. .NOT.LST2SL )
657: $ INFO = N + 2
658: ELSE
659: *
660: * First eigenvalue of conjugate pair
661: *
662: IP = 1
663: END IF
664: END IF
665: LST2SL = LASTSL
666: LASTSL = CURSL
667: 40 CONTINUE
668: *
669: END IF
670: *
671: 50 CONTINUE
672: *
673: WORK( 1 ) = MAXWRK
674: *
675: RETURN
676: *
677: * End of DGGES
678: *
679: END
CVSweb interface <joel.bertrand@systella.fr>