1: *> \brief \b ZUNMRQ
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZUNMRQ + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunmrq.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunmrq.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunmrq.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22: * WORK, LWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER SIDE, TRANS
26: * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27: * ..
28: * .. Array Arguments ..
29: * COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZUNMRQ overwrites the general complex M-by-N matrix C with
39: *>
40: *> SIDE = 'L' SIDE = 'R'
41: *> TRANS = 'N': Q * C C * Q
42: *> TRANS = 'C': Q**H * C C * Q**H
43: *>
44: *> where Q is a complex unitary matrix defined as the product of k
45: *> elementary reflectors
46: *>
47: *> Q = H(1)**H H(2)**H . . . H(k)**H
48: *>
49: *> as returned by ZGERQF. Q is of order M if SIDE = 'L' and of order N
50: *> if SIDE = 'R'.
51: *> \endverbatim
52: *
53: * Arguments:
54: * ==========
55: *
56: *> \param[in] SIDE
57: *> \verbatim
58: *> SIDE is CHARACTER*1
59: *> = 'L': apply Q or Q**H from the Left;
60: *> = 'R': apply Q or Q**H from the Right.
61: *> \endverbatim
62: *>
63: *> \param[in] TRANS
64: *> \verbatim
65: *> TRANS is CHARACTER*1
66: *> = 'N': No transpose, apply Q;
67: *> = 'C': Transpose, apply Q**H.
68: *> \endverbatim
69: *>
70: *> \param[in] M
71: *> \verbatim
72: *> M is INTEGER
73: *> The number of rows of the matrix C. M >= 0.
74: *> \endverbatim
75: *>
76: *> \param[in] N
77: *> \verbatim
78: *> N is INTEGER
79: *> The number of columns of the matrix C. N >= 0.
80: *> \endverbatim
81: *>
82: *> \param[in] K
83: *> \verbatim
84: *> K is INTEGER
85: *> The number of elementary reflectors whose product defines
86: *> the matrix Q.
87: *> If SIDE = 'L', M >= K >= 0;
88: *> if SIDE = 'R', N >= K >= 0.
89: *> \endverbatim
90: *>
91: *> \param[in] A
92: *> \verbatim
93: *> A is COMPLEX*16 array, dimension
94: *> (LDA,M) if SIDE = 'L',
95: *> (LDA,N) if SIDE = 'R'
96: *> The i-th row must contain the vector which defines the
97: *> elementary reflector H(i), for i = 1,2,...,k, as returned by
98: *> ZGERQF in the last k rows of its array argument A.
99: *> \endverbatim
100: *>
101: *> \param[in] LDA
102: *> \verbatim
103: *> LDA is INTEGER
104: *> The leading dimension of the array A. LDA >= max(1,K).
105: *> \endverbatim
106: *>
107: *> \param[in] TAU
108: *> \verbatim
109: *> TAU is COMPLEX*16 array, dimension (K)
110: *> TAU(i) must contain the scalar factor of the elementary
111: *> reflector H(i), as returned by ZGERQF.
112: *> \endverbatim
113: *>
114: *> \param[in,out] C
115: *> \verbatim
116: *> C is COMPLEX*16 array, dimension (LDC,N)
117: *> On entry, the M-by-N matrix C.
118: *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
119: *> \endverbatim
120: *>
121: *> \param[in] LDC
122: *> \verbatim
123: *> LDC is INTEGER
124: *> The leading dimension of the array C. LDC >= max(1,M).
125: *> \endverbatim
126: *>
127: *> \param[out] WORK
128: *> \verbatim
129: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
130: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
131: *> \endverbatim
132: *>
133: *> \param[in] LWORK
134: *> \verbatim
135: *> LWORK is INTEGER
136: *> The dimension of the array WORK.
137: *> If SIDE = 'L', LWORK >= max(1,N);
138: *> if SIDE = 'R', LWORK >= max(1,M).
139: *> For good performance, LWORK should generally be larger.
140: *>
141: *> If LWORK = -1, then a workspace query is assumed; the routine
142: *> only calculates the optimal size of the WORK array, returns
143: *> this value as the first entry of the WORK array, and no error
144: *> message related to LWORK is issued by XERBLA.
145: *> \endverbatim
146: *>
147: *> \param[out] INFO
148: *> \verbatim
149: *> INFO is INTEGER
150: *> = 0: successful exit
151: *> < 0: if INFO = -i, the i-th argument had an illegal value
152: *> \endverbatim
153: *
154: * Authors:
155: * ========
156: *
157: *> \author Univ. of Tennessee
158: *> \author Univ. of California Berkeley
159: *> \author Univ. of Colorado Denver
160: *> \author NAG Ltd.
161: *
162: *> \date December 2016
163: *
164: *> \ingroup complex16OTHERcomputational
165: *
166: * =====================================================================
167: SUBROUTINE ZUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
168: $ WORK, LWORK, INFO )
169: *
170: * -- LAPACK computational routine (version 3.7.0) --
171: * -- LAPACK is a software package provided by Univ. of Tennessee, --
172: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
173: * December 2016
174: *
175: * .. Scalar Arguments ..
176: CHARACTER SIDE, TRANS
177: INTEGER INFO, K, LDA, LDC, LWORK, M, N
178: * ..
179: * .. Array Arguments ..
180: COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
181: * ..
182: *
183: * =====================================================================
184: *
185: * .. Parameters ..
186: INTEGER NBMAX, LDT, TSIZE
187: PARAMETER ( NBMAX = 64, LDT = NBMAX+1,
188: $ TSIZE = LDT*NBMAX )
189: * ..
190: * .. Local Scalars ..
191: LOGICAL LEFT, LQUERY, NOTRAN
192: CHARACTER TRANST
193: INTEGER I, I1, I2, I3, IB, IINFO, IWT, LDWORK, LWKOPT,
194: $ MI, NB, NBMIN, NI, NQ, NW
195: * ..
196: * .. External Functions ..
197: LOGICAL LSAME
198: INTEGER ILAENV
199: EXTERNAL LSAME, ILAENV
200: * ..
201: * .. External Subroutines ..
202: EXTERNAL XERBLA, ZLARFB, ZLARFT, ZUNMR2
203: * ..
204: * .. Intrinsic Functions ..
205: INTRINSIC MAX, MIN
206: * ..
207: * .. Executable Statements ..
208: *
209: * Test the input arguments
210: *
211: INFO = 0
212: LEFT = LSAME( SIDE, 'L' )
213: NOTRAN = LSAME( TRANS, 'N' )
214: LQUERY = ( LWORK.EQ.-1 )
215: *
216: * NQ is the order of Q and NW is the minimum dimension of WORK
217: *
218: IF( LEFT ) THEN
219: NQ = M
220: NW = MAX( 1, N )
221: ELSE
222: NQ = N
223: NW = MAX( 1, M )
224: END IF
225: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
226: INFO = -1
227: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
228: INFO = -2
229: ELSE IF( M.LT.0 ) THEN
230: INFO = -3
231: ELSE IF( N.LT.0 ) THEN
232: INFO = -4
233: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
234: INFO = -5
235: ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
236: INFO = -7
237: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
238: INFO = -10
239: ELSE IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
240: INFO = -12
241: END IF
242: *
243: IF( INFO.EQ.0 ) THEN
244: *
245: * Compute the workspace requirements
246: *
247: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
248: LWKOPT = 1
249: ELSE
250: NB = MIN( NBMAX, ILAENV( 1, 'ZUNMRQ', SIDE // TRANS, M, N,
251: $ K, -1 ) )
252: LWKOPT = NW*NB + TSIZE
253: END IF
254: WORK( 1 ) = LWKOPT
255: END IF
256: *
257: IF( INFO.NE.0 ) THEN
258: CALL XERBLA( 'ZUNMRQ', -INFO )
259: RETURN
260: ELSE IF( LQUERY ) THEN
261: RETURN
262: END IF
263: *
264: * Quick return if possible
265: *
266: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
267: RETURN
268: END IF
269: *
270: NBMIN = 2
271: LDWORK = NW
272: IF( NB.GT.1 .AND. NB.LT.K ) THEN
273: IF( LWORK.LT.NW*NB+TSIZE ) THEN
274: NB = (LWORK-TSIZE) / LDWORK
275: NBMIN = MAX( 2, ILAENV( 2, 'ZUNMRQ', SIDE // TRANS, M, N, K,
276: $ -1 ) )
277: END IF
278: END IF
279: *
280: IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
281: *
282: * Use unblocked code
283: *
284: CALL ZUNMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
285: $ IINFO )
286: ELSE
287: *
288: * Use blocked code
289: *
290: IWT = 1 + NW*NB
291: IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
292: $ ( .NOT.LEFT .AND. NOTRAN ) ) THEN
293: I1 = 1
294: I2 = K
295: I3 = NB
296: ELSE
297: I1 = ( ( K-1 ) / NB )*NB + 1
298: I2 = 1
299: I3 = -NB
300: END IF
301: *
302: IF( LEFT ) THEN
303: NI = N
304: ELSE
305: MI = M
306: END IF
307: *
308: IF( NOTRAN ) THEN
309: TRANST = 'C'
310: ELSE
311: TRANST = 'N'
312: END IF
313: *
314: DO 10 I = I1, I2, I3
315: IB = MIN( NB, K-I+1 )
316: *
317: * Form the triangular factor of the block reflector
318: * H = H(i+ib-1) . . . H(i+1) H(i)
319: *
320: CALL ZLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
321: $ A( I, 1 ), LDA, TAU( I ), WORK( IWT ), LDT )
322: IF( LEFT ) THEN
323: *
324: * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
325: *
326: MI = M - K + I + IB - 1
327: ELSE
328: *
329: * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
330: *
331: NI = N - K + I + IB - 1
332: END IF
333: *
334: * Apply H or H**H
335: *
336: CALL ZLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
337: $ IB, A( I, 1 ), LDA, WORK( IWT ), LDT, C, LDC,
338: $ WORK, LDWORK )
339: 10 CONTINUE
340: END IF
341: WORK( 1 ) = LWKOPT
342: RETURN
343: *
344: * End of ZUNMRQ
345: *
346: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zunmrq.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack