1: SUBROUTINE ZUNMRQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
2: $ WORK, LWORK, INFO )
3: *
4: * -- LAPACK routine (version 3.3.1) --
5: * -- LAPACK is a software package provided by Univ. of Tennessee, --
6: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
7: * -- April 2011 --
8: *
9: * .. Scalar Arguments ..
10: CHARACTER SIDE, TRANS
11: INTEGER INFO, K, LDA, LDC, LWORK, M, N
12: * ..
13: * .. Array Arguments ..
14: COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
15: * ..
16: *
17: * Purpose
18: * =======
19: *
20: * ZUNMRQ overwrites the general complex M-by-N matrix C with
21: *
22: * SIDE = 'L' SIDE = 'R'
23: * TRANS = 'N': Q * C C * Q
24: * TRANS = 'C': Q**H * C C * Q**H
25: *
26: * where Q is a complex unitary matrix defined as the product of k
27: * elementary reflectors
28: *
29: * Q = H(1)**H H(2)**H . . . H(k)**H
30: *
31: * as returned by ZGERQF. Q is of order M if SIDE = 'L' and of order N
32: * if SIDE = 'R'.
33: *
34: * Arguments
35: * =========
36: *
37: * SIDE (input) CHARACTER*1
38: * = 'L': apply Q or Q**H from the Left;
39: * = 'R': apply Q or Q**H from the Right.
40: *
41: * TRANS (input) CHARACTER*1
42: * = 'N': No transpose, apply Q;
43: * = 'C': Transpose, apply Q**H.
44: *
45: * M (input) INTEGER
46: * The number of rows of the matrix C. M >= 0.
47: *
48: * N (input) INTEGER
49: * The number of columns of the matrix C. N >= 0.
50: *
51: * K (input) INTEGER
52: * The number of elementary reflectors whose product defines
53: * the matrix Q.
54: * If SIDE = 'L', M >= K >= 0;
55: * if SIDE = 'R', N >= K >= 0.
56: *
57: * A (input) COMPLEX*16 array, dimension
58: * (LDA,M) if SIDE = 'L',
59: * (LDA,N) if SIDE = 'R'
60: * The i-th row must contain the vector which defines the
61: * elementary reflector H(i), for i = 1,2,...,k, as returned by
62: * ZGERQF in the last k rows of its array argument A.
63: * A is modified by the routine but restored on exit.
64: *
65: * LDA (input) INTEGER
66: * The leading dimension of the array A. LDA >= max(1,K).
67: *
68: * TAU (input) COMPLEX*16 array, dimension (K)
69: * TAU(i) must contain the scalar factor of the elementary
70: * reflector H(i), as returned by ZGERQF.
71: *
72: * C (input/output) COMPLEX*16 array, dimension (LDC,N)
73: * On entry, the M-by-N matrix C.
74: * On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
75: *
76: * LDC (input) INTEGER
77: * The leading dimension of the array C. LDC >= max(1,M).
78: *
79: * WORK (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
80: * On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
81: *
82: * LWORK (input) INTEGER
83: * The dimension of the array WORK.
84: * If SIDE = 'L', LWORK >= max(1,N);
85: * if SIDE = 'R', LWORK >= max(1,M).
86: * For optimum performance LWORK >= N*NB if SIDE = 'L', and
87: * LWORK >= M*NB if SIDE = 'R', where NB is the optimal
88: * blocksize.
89: *
90: * If LWORK = -1, then a workspace query is assumed; the routine
91: * only calculates the optimal size of the WORK array, returns
92: * this value as the first entry of the WORK array, and no error
93: * message related to LWORK is issued by XERBLA.
94: *
95: * INFO (output) INTEGER
96: * = 0: successful exit
97: * < 0: if INFO = -i, the i-th argument had an illegal value
98: *
99: * =====================================================================
100: *
101: * .. Parameters ..
102: INTEGER NBMAX, LDT
103: PARAMETER ( NBMAX = 64, LDT = NBMAX+1 )
104: * ..
105: * .. Local Scalars ..
106: LOGICAL LEFT, LQUERY, NOTRAN
107: CHARACTER TRANST
108: INTEGER I, I1, I2, I3, IB, IINFO, IWS, LDWORK, LWKOPT,
109: $ MI, NB, NBMIN, NI, NQ, NW
110: * ..
111: * .. Local Arrays ..
112: COMPLEX*16 T( LDT, NBMAX )
113: * ..
114: * .. External Functions ..
115: LOGICAL LSAME
116: INTEGER ILAENV
117: EXTERNAL LSAME, ILAENV
118: * ..
119: * .. External Subroutines ..
120: EXTERNAL XERBLA, ZLARFB, ZLARFT, ZUNMR2
121: * ..
122: * .. Intrinsic Functions ..
123: INTRINSIC MAX, MIN
124: * ..
125: * .. Executable Statements ..
126: *
127: * Test the input arguments
128: *
129: INFO = 0
130: LEFT = LSAME( SIDE, 'L' )
131: NOTRAN = LSAME( TRANS, 'N' )
132: LQUERY = ( LWORK.EQ.-1 )
133: *
134: * NQ is the order of Q and NW is the minimum dimension of WORK
135: *
136: IF( LEFT ) THEN
137: NQ = M
138: NW = MAX( 1, N )
139: ELSE
140: NQ = N
141: NW = MAX( 1, M )
142: END IF
143: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
144: INFO = -1
145: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
146: INFO = -2
147: ELSE IF( M.LT.0 ) THEN
148: INFO = -3
149: ELSE IF( N.LT.0 ) THEN
150: INFO = -4
151: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
152: INFO = -5
153: ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
154: INFO = -7
155: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
156: INFO = -10
157: END IF
158: *
159: IF( INFO.EQ.0 ) THEN
160: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
161: LWKOPT = 1
162: ELSE
163: *
164: * Determine the block size. NB may be at most NBMAX, where
165: * NBMAX is used to define the local array T.
166: *
167: NB = MIN( NBMAX, ILAENV( 1, 'ZUNMRQ', SIDE // TRANS, M, N,
168: $ K, -1 ) )
169: LWKOPT = NW*NB
170: END IF
171: WORK( 1 ) = LWKOPT
172: *
173: IF( LWORK.LT.NW .AND. .NOT.LQUERY ) THEN
174: INFO = -12
175: END IF
176: END IF
177: *
178: IF( INFO.NE.0 ) THEN
179: CALL XERBLA( 'ZUNMRQ', -INFO )
180: RETURN
181: ELSE IF( LQUERY ) THEN
182: RETURN
183: END IF
184: *
185: * Quick return if possible
186: *
187: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
188: RETURN
189: END IF
190: *
191: NBMIN = 2
192: LDWORK = NW
193: IF( NB.GT.1 .AND. NB.LT.K ) THEN
194: IWS = NW*NB
195: IF( LWORK.LT.IWS ) THEN
196: NB = LWORK / LDWORK
197: NBMIN = MAX( 2, ILAENV( 2, 'ZUNMRQ', SIDE // TRANS, M, N, K,
198: $ -1 ) )
199: END IF
200: ELSE
201: IWS = NW
202: END IF
203: *
204: IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
205: *
206: * Use unblocked code
207: *
208: CALL ZUNMR2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
209: $ IINFO )
210: ELSE
211: *
212: * Use blocked code
213: *
214: IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
215: $ ( .NOT.LEFT .AND. NOTRAN ) ) THEN
216: I1 = 1
217: I2 = K
218: I3 = NB
219: ELSE
220: I1 = ( ( K-1 ) / NB )*NB + 1
221: I2 = 1
222: I3 = -NB
223: END IF
224: *
225: IF( LEFT ) THEN
226: NI = N
227: ELSE
228: MI = M
229: END IF
230: *
231: IF( NOTRAN ) THEN
232: TRANST = 'C'
233: ELSE
234: TRANST = 'N'
235: END IF
236: *
237: DO 10 I = I1, I2, I3
238: IB = MIN( NB, K-I+1 )
239: *
240: * Form the triangular factor of the block reflector
241: * H = H(i+ib-1) . . . H(i+1) H(i)
242: *
243: CALL ZLARFT( 'Backward', 'Rowwise', NQ-K+I+IB-1, IB,
244: $ A( I, 1 ), LDA, TAU( I ), T, LDT )
245: IF( LEFT ) THEN
246: *
247: * H or H**H is applied to C(1:m-k+i+ib-1,1:n)
248: *
249: MI = M - K + I + IB - 1
250: ELSE
251: *
252: * H or H**H is applied to C(1:m,1:n-k+i+ib-1)
253: *
254: NI = N - K + I + IB - 1
255: END IF
256: *
257: * Apply H or H**H
258: *
259: CALL ZLARFB( SIDE, TRANST, 'Backward', 'Rowwise', MI, NI,
260: $ IB, A( I, 1 ), LDA, T, LDT, C, LDC, WORK,
261: $ LDWORK )
262: 10 CONTINUE
263: END IF
264: WORK( 1 ) = LWKOPT
265: RETURN
266: *
267: * End of ZUNMRQ
268: *
269: END
CVSweb interface <joel.bertrand@systella.fr>