1: *> \brief \b ZUNMQR
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZUNMQR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunmqr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunmqr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunmqr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
22: * WORK, LWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER SIDE, TRANS
26: * INTEGER INFO, K, LDA, LDC, LWORK, M, N
27: * ..
28: * .. Array Arguments ..
29: * COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZUNMQR overwrites the general complex M-by-N matrix C with
39: *>
40: *> SIDE = 'L' SIDE = 'R'
41: *> TRANS = 'N': Q * C C * Q
42: *> TRANS = 'C': Q**H * C C * Q**H
43: *>
44: *> where Q is a complex unitary matrix defined as the product of k
45: *> elementary reflectors
46: *>
47: *> Q = H(1) H(2) . . . H(k)
48: *>
49: *> as returned by ZGEQRF. Q is of order M if SIDE = 'L' and of order N
50: *> if SIDE = 'R'.
51: *> \endverbatim
52: *
53: * Arguments:
54: * ==========
55: *
56: *> \param[in] SIDE
57: *> \verbatim
58: *> SIDE is CHARACTER*1
59: *> = 'L': apply Q or Q**H from the Left;
60: *> = 'R': apply Q or Q**H from the Right.
61: *> \endverbatim
62: *>
63: *> \param[in] TRANS
64: *> \verbatim
65: *> TRANS is CHARACTER*1
66: *> = 'N': No transpose, apply Q;
67: *> = 'C': Conjugate transpose, apply Q**H.
68: *> \endverbatim
69: *>
70: *> \param[in] M
71: *> \verbatim
72: *> M is INTEGER
73: *> The number of rows of the matrix C. M >= 0.
74: *> \endverbatim
75: *>
76: *> \param[in] N
77: *> \verbatim
78: *> N is INTEGER
79: *> The number of columns of the matrix C. N >= 0.
80: *> \endverbatim
81: *>
82: *> \param[in] K
83: *> \verbatim
84: *> K is INTEGER
85: *> The number of elementary reflectors whose product defines
86: *> the matrix Q.
87: *> If SIDE = 'L', M >= K >= 0;
88: *> if SIDE = 'R', N >= K >= 0.
89: *> \endverbatim
90: *>
91: *> \param[in] A
92: *> \verbatim
93: *> A is COMPLEX*16 array, dimension (LDA,K)
94: *> The i-th column must contain the vector which defines the
95: *> elementary reflector H(i), for i = 1,2,...,k, as returned by
96: *> ZGEQRF in the first k columns of its array argument A.
97: *> A is modified by the routine but restored on exit.
98: *> \endverbatim
99: *>
100: *> \param[in] LDA
101: *> \verbatim
102: *> LDA is INTEGER
103: *> The leading dimension of the array A.
104: *> If SIDE = 'L', LDA >= max(1,M);
105: *> if SIDE = 'R', LDA >= max(1,N).
106: *> \endverbatim
107: *>
108: *> \param[in] TAU
109: *> \verbatim
110: *> TAU is COMPLEX*16 array, dimension (K)
111: *> TAU(i) must contain the scalar factor of the elementary
112: *> reflector H(i), as returned by ZGEQRF.
113: *> \endverbatim
114: *>
115: *> \param[in,out] C
116: *> \verbatim
117: *> C is COMPLEX*16 array, dimension (LDC,N)
118: *> On entry, the M-by-N matrix C.
119: *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
120: *> \endverbatim
121: *>
122: *> \param[in] LDC
123: *> \verbatim
124: *> LDC is INTEGER
125: *> The leading dimension of the array C. LDC >= max(1,M).
126: *> \endverbatim
127: *>
128: *> \param[out] WORK
129: *> \verbatim
130: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
131: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
132: *> \endverbatim
133: *>
134: *> \param[in] LWORK
135: *> \verbatim
136: *> LWORK is INTEGER
137: *> The dimension of the array WORK.
138: *> If SIDE = 'L', LWORK >= max(1,N);
139: *> if SIDE = 'R', LWORK >= max(1,M).
140: *> For optimum performance LWORK >= N*NB if SIDE = 'L', and
141: *> LWORK >= M*NB if SIDE = 'R', where NB is the optimal
142: *> blocksize.
143: *>
144: *> If LWORK = -1, then a workspace query is assumed; the routine
145: *> only calculates the optimal size of the WORK array, returns
146: *> this value as the first entry of the WORK array, and no error
147: *> message related to LWORK is issued by XERBLA.
148: *> \endverbatim
149: *>
150: *> \param[out] INFO
151: *> \verbatim
152: *> INFO is INTEGER
153: *> = 0: successful exit
154: *> < 0: if INFO = -i, the i-th argument had an illegal value
155: *> \endverbatim
156: *
157: * Authors:
158: * ========
159: *
160: *> \author Univ. of Tennessee
161: *> \author Univ. of California Berkeley
162: *> \author Univ. of Colorado Denver
163: *> \author NAG Ltd.
164: *
165: *> \date November 2011
166: *
167: *> \ingroup complex16OTHERcomputational
168: *
169: * =====================================================================
170: SUBROUTINE ZUNMQR( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
171: $ WORK, LWORK, INFO )
172: *
173: * -- LAPACK computational routine (version 3.4.0) --
174: * -- LAPACK is a software package provided by Univ. of Tennessee, --
175: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
176: * November 2011
177: *
178: * .. Scalar Arguments ..
179: CHARACTER SIDE, TRANS
180: INTEGER INFO, K, LDA, LDC, LWORK, M, N
181: * ..
182: * .. Array Arguments ..
183: COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
184: * ..
185: *
186: * =====================================================================
187: *
188: * .. Parameters ..
189: INTEGER NBMAX, LDT
190: PARAMETER ( NBMAX = 64, LDT = NBMAX+1 )
191: * ..
192: * .. Local Scalars ..
193: LOGICAL LEFT, LQUERY, NOTRAN
194: INTEGER I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK,
195: $ LWKOPT, MI, NB, NBMIN, NI, NQ, NW
196: * ..
197: * .. Local Arrays ..
198: COMPLEX*16 T( LDT, NBMAX )
199: * ..
200: * .. External Functions ..
201: LOGICAL LSAME
202: INTEGER ILAENV
203: EXTERNAL LSAME, ILAENV
204: * ..
205: * .. External Subroutines ..
206: EXTERNAL XERBLA, ZLARFB, ZLARFT, ZUNM2R
207: * ..
208: * .. Intrinsic Functions ..
209: INTRINSIC MAX, MIN
210: * ..
211: * .. Executable Statements ..
212: *
213: * Test the input arguments
214: *
215: INFO = 0
216: LEFT = LSAME( SIDE, 'L' )
217: NOTRAN = LSAME( TRANS, 'N' )
218: LQUERY = ( LWORK.EQ.-1 )
219: *
220: * NQ is the order of Q and NW is the minimum dimension of WORK
221: *
222: IF( LEFT ) THEN
223: NQ = M
224: NW = N
225: ELSE
226: NQ = N
227: NW = M
228: END IF
229: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
230: INFO = -1
231: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
232: INFO = -2
233: ELSE IF( M.LT.0 ) THEN
234: INFO = -3
235: ELSE IF( N.LT.0 ) THEN
236: INFO = -4
237: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
238: INFO = -5
239: ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
240: INFO = -7
241: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
242: INFO = -10
243: ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
244: INFO = -12
245: END IF
246: *
247: IF( INFO.EQ.0 ) THEN
248: *
249: * Determine the block size. NB may be at most NBMAX, where NBMAX
250: * is used to define the local array T.
251: *
252: NB = MIN( NBMAX, ILAENV( 1, 'ZUNMQR', SIDE // TRANS, M, N, K,
253: $ -1 ) )
254: LWKOPT = MAX( 1, NW )*NB
255: WORK( 1 ) = LWKOPT
256: END IF
257: *
258: IF( INFO.NE.0 ) THEN
259: CALL XERBLA( 'ZUNMQR', -INFO )
260: RETURN
261: ELSE IF( LQUERY ) THEN
262: RETURN
263: END IF
264: *
265: * Quick return if possible
266: *
267: IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
268: WORK( 1 ) = 1
269: RETURN
270: END IF
271: *
272: NBMIN = 2
273: LDWORK = NW
274: IF( NB.GT.1 .AND. NB.LT.K ) THEN
275: IWS = NW*NB
276: IF( LWORK.LT.IWS ) THEN
277: NB = LWORK / LDWORK
278: NBMIN = MAX( 2, ILAENV( 2, 'ZUNMQR', SIDE // TRANS, M, N, K,
279: $ -1 ) )
280: END IF
281: ELSE
282: IWS = NW
283: END IF
284: *
285: IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
286: *
287: * Use unblocked code
288: *
289: CALL ZUNM2R( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
290: $ IINFO )
291: ELSE
292: *
293: * Use blocked code
294: *
295: IF( ( LEFT .AND. .NOT.NOTRAN ) .OR.
296: $ ( .NOT.LEFT .AND. NOTRAN ) ) THEN
297: I1 = 1
298: I2 = K
299: I3 = NB
300: ELSE
301: I1 = ( ( K-1 ) / NB )*NB + 1
302: I2 = 1
303: I3 = -NB
304: END IF
305: *
306: IF( LEFT ) THEN
307: NI = N
308: JC = 1
309: ELSE
310: MI = M
311: IC = 1
312: END IF
313: *
314: DO 10 I = I1, I2, I3
315: IB = MIN( NB, K-I+1 )
316: *
317: * Form the triangular factor of the block reflector
318: * H = H(i) H(i+1) . . . H(i+ib-1)
319: *
320: CALL ZLARFT( 'Forward', 'Columnwise', NQ-I+1, IB, A( I, I ),
321: $ LDA, TAU( I ), T, LDT )
322: IF( LEFT ) THEN
323: *
324: * H or H**H is applied to C(i:m,1:n)
325: *
326: MI = M - I + 1
327: IC = I
328: ELSE
329: *
330: * H or H**H is applied to C(1:m,i:n)
331: *
332: NI = N - I + 1
333: JC = I
334: END IF
335: *
336: * Apply H or H**H
337: *
338: CALL ZLARFB( SIDE, TRANS, 'Forward', 'Columnwise', MI, NI,
339: $ IB, A( I, I ), LDA, T, LDT, C( IC, JC ), LDC,
340: $ WORK, LDWORK )
341: 10 CONTINUE
342: END IF
343: WORK( 1 ) = LWKOPT
344: RETURN
345: *
346: * End of ZUNMQR
347: *
348: END
CVSweb interface <joel.bertrand@systella.fr>