Annotation of rpl/lapack/lapack/zunml2.f, revision 1.9
1.9 ! bertrand 1: *> \brief \b ZUNML2
! 2: *
! 3: * =========== DOCUMENTATION ===========
! 4: *
! 5: * Online html documentation available at
! 6: * http://www.netlib.org/lapack/explore-html/
! 7: *
! 8: *> \htmlonly
! 9: *> Download ZUNML2 + dependencies
! 10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunml2.f">
! 11: *> [TGZ]</a>
! 12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunml2.f">
! 13: *> [ZIP]</a>
! 14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunml2.f">
! 15: *> [TXT]</a>
! 16: *> \endhtmlonly
! 17: *
! 18: * Definition:
! 19: * ===========
! 20: *
! 21: * SUBROUTINE ZUNML2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
! 22: * WORK, INFO )
! 23: *
! 24: * .. Scalar Arguments ..
! 25: * CHARACTER SIDE, TRANS
! 26: * INTEGER INFO, K, LDA, LDC, M, N
! 27: * ..
! 28: * .. Array Arguments ..
! 29: * COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
! 30: * ..
! 31: *
! 32: *
! 33: *> \par Purpose:
! 34: * =============
! 35: *>
! 36: *> \verbatim
! 37: *>
! 38: *> ZUNML2 overwrites the general complex m-by-n matrix C with
! 39: *>
! 40: *> Q * C if SIDE = 'L' and TRANS = 'N', or
! 41: *>
! 42: *> Q**H* C if SIDE = 'L' and TRANS = 'C', or
! 43: *>
! 44: *> C * Q if SIDE = 'R' and TRANS = 'N', or
! 45: *>
! 46: *> C * Q**H if SIDE = 'R' and TRANS = 'C',
! 47: *>
! 48: *> where Q is a complex unitary matrix defined as the product of k
! 49: *> elementary reflectors
! 50: *>
! 51: *> Q = H(k)**H . . . H(2)**H H(1)**H
! 52: *>
! 53: *> as returned by ZGELQF. Q is of order m if SIDE = 'L' and of order n
! 54: *> if SIDE = 'R'.
! 55: *> \endverbatim
! 56: *
! 57: * Arguments:
! 58: * ==========
! 59: *
! 60: *> \param[in] SIDE
! 61: *> \verbatim
! 62: *> SIDE is CHARACTER*1
! 63: *> = 'L': apply Q or Q**H from the Left
! 64: *> = 'R': apply Q or Q**H from the Right
! 65: *> \endverbatim
! 66: *>
! 67: *> \param[in] TRANS
! 68: *> \verbatim
! 69: *> TRANS is CHARACTER*1
! 70: *> = 'N': apply Q (No transpose)
! 71: *> = 'C': apply Q**H (Conjugate transpose)
! 72: *> \endverbatim
! 73: *>
! 74: *> \param[in] M
! 75: *> \verbatim
! 76: *> M is INTEGER
! 77: *> The number of rows of the matrix C. M >= 0.
! 78: *> \endverbatim
! 79: *>
! 80: *> \param[in] N
! 81: *> \verbatim
! 82: *> N is INTEGER
! 83: *> The number of columns of the matrix C. N >= 0.
! 84: *> \endverbatim
! 85: *>
! 86: *> \param[in] K
! 87: *> \verbatim
! 88: *> K is INTEGER
! 89: *> The number of elementary reflectors whose product defines
! 90: *> the matrix Q.
! 91: *> If SIDE = 'L', M >= K >= 0;
! 92: *> if SIDE = 'R', N >= K >= 0.
! 93: *> \endverbatim
! 94: *>
! 95: *> \param[in] A
! 96: *> \verbatim
! 97: *> A is COMPLEX*16 array, dimension
! 98: *> (LDA,M) if SIDE = 'L',
! 99: *> (LDA,N) if SIDE = 'R'
! 100: *> The i-th row must contain the vector which defines the
! 101: *> elementary reflector H(i), for i = 1,2,...,k, as returned by
! 102: *> ZGELQF in the first k rows of its array argument A.
! 103: *> A is modified by the routine but restored on exit.
! 104: *> \endverbatim
! 105: *>
! 106: *> \param[in] LDA
! 107: *> \verbatim
! 108: *> LDA is INTEGER
! 109: *> The leading dimension of the array A. LDA >= max(1,K).
! 110: *> \endverbatim
! 111: *>
! 112: *> \param[in] TAU
! 113: *> \verbatim
! 114: *> TAU is COMPLEX*16 array, dimension (K)
! 115: *> TAU(i) must contain the scalar factor of the elementary
! 116: *> reflector H(i), as returned by ZGELQF.
! 117: *> \endverbatim
! 118: *>
! 119: *> \param[in,out] C
! 120: *> \verbatim
! 121: *> C is COMPLEX*16 array, dimension (LDC,N)
! 122: *> On entry, the m-by-n matrix C.
! 123: *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
! 124: *> \endverbatim
! 125: *>
! 126: *> \param[in] LDC
! 127: *> \verbatim
! 128: *> LDC is INTEGER
! 129: *> The leading dimension of the array C. LDC >= max(1,M).
! 130: *> \endverbatim
! 131: *>
! 132: *> \param[out] WORK
! 133: *> \verbatim
! 134: *> WORK is COMPLEX*16 array, dimension
! 135: *> (N) if SIDE = 'L',
! 136: *> (M) if SIDE = 'R'
! 137: *> \endverbatim
! 138: *>
! 139: *> \param[out] INFO
! 140: *> \verbatim
! 141: *> INFO is INTEGER
! 142: *> = 0: successful exit
! 143: *> < 0: if INFO = -i, the i-th argument had an illegal value
! 144: *> \endverbatim
! 145: *
! 146: * Authors:
! 147: * ========
! 148: *
! 149: *> \author Univ. of Tennessee
! 150: *> \author Univ. of California Berkeley
! 151: *> \author Univ. of Colorado Denver
! 152: *> \author NAG Ltd.
! 153: *
! 154: *> \date November 2011
! 155: *
! 156: *> \ingroup complex16OTHERcomputational
! 157: *
! 158: * =====================================================================
1.1 bertrand 159: SUBROUTINE ZUNML2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
160: $ WORK, INFO )
161: *
1.9 ! bertrand 162: * -- LAPACK computational routine (version 3.4.0) --
1.1 bertrand 163: * -- LAPACK is a software package provided by Univ. of Tennessee, --
164: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.9 ! bertrand 165: * November 2011
1.1 bertrand 166: *
167: * .. Scalar Arguments ..
168: CHARACTER SIDE, TRANS
169: INTEGER INFO, K, LDA, LDC, M, N
170: * ..
171: * .. Array Arguments ..
172: COMPLEX*16 A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
173: * ..
174: *
175: * =====================================================================
176: *
177: * .. Parameters ..
178: COMPLEX*16 ONE
179: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
180: * ..
181: * .. Local Scalars ..
182: LOGICAL LEFT, NOTRAN
183: INTEGER I, I1, I2, I3, IC, JC, MI, NI, NQ
184: COMPLEX*16 AII, TAUI
185: * ..
186: * .. External Functions ..
187: LOGICAL LSAME
188: EXTERNAL LSAME
189: * ..
190: * .. External Subroutines ..
191: EXTERNAL XERBLA, ZLACGV, ZLARF
192: * ..
193: * .. Intrinsic Functions ..
194: INTRINSIC DCONJG, MAX
195: * ..
196: * .. Executable Statements ..
197: *
198: * Test the input arguments
199: *
200: INFO = 0
201: LEFT = LSAME( SIDE, 'L' )
202: NOTRAN = LSAME( TRANS, 'N' )
203: *
204: * NQ is the order of Q
205: *
206: IF( LEFT ) THEN
207: NQ = M
208: ELSE
209: NQ = N
210: END IF
211: IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
212: INFO = -1
213: ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'C' ) ) THEN
214: INFO = -2
215: ELSE IF( M.LT.0 ) THEN
216: INFO = -3
217: ELSE IF( N.LT.0 ) THEN
218: INFO = -4
219: ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
220: INFO = -5
221: ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
222: INFO = -7
223: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
224: INFO = -10
225: END IF
226: IF( INFO.NE.0 ) THEN
227: CALL XERBLA( 'ZUNML2', -INFO )
228: RETURN
229: END IF
230: *
231: * Quick return if possible
232: *
233: IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 )
234: $ RETURN
235: *
236: IF( ( LEFT .AND. NOTRAN .OR. .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
237: I1 = 1
238: I2 = K
239: I3 = 1
240: ELSE
241: I1 = K
242: I2 = 1
243: I3 = -1
244: END IF
245: *
246: IF( LEFT ) THEN
247: NI = N
248: JC = 1
249: ELSE
250: MI = M
251: IC = 1
252: END IF
253: *
254: DO 10 I = I1, I2, I3
255: IF( LEFT ) THEN
256: *
1.8 bertrand 257: * H(i) or H(i)**H is applied to C(i:m,1:n)
1.1 bertrand 258: *
259: MI = M - I + 1
260: IC = I
261: ELSE
262: *
1.8 bertrand 263: * H(i) or H(i)**H is applied to C(1:m,i:n)
1.1 bertrand 264: *
265: NI = N - I + 1
266: JC = I
267: END IF
268: *
1.8 bertrand 269: * Apply H(i) or H(i)**H
1.1 bertrand 270: *
271: IF( NOTRAN ) THEN
272: TAUI = DCONJG( TAU( I ) )
273: ELSE
274: TAUI = TAU( I )
275: END IF
276: IF( I.LT.NQ )
277: $ CALL ZLACGV( NQ-I, A( I, I+1 ), LDA )
278: AII = A( I, I )
279: A( I, I ) = ONE
280: CALL ZLARF( SIDE, MI, NI, A( I, I ), LDA, TAUI, C( IC, JC ),
281: $ LDC, WORK )
282: A( I, I ) = AII
283: IF( I.LT.NQ )
284: $ CALL ZLACGV( NQ-I, A( I, I+1 ), LDA )
285: 10 CONTINUE
286: RETURN
287: *
288: * End of ZUNML2
289: *
290: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zunml2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack