1: *> \brief \b ZUNGRQ
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZUNGRQ + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zungrq.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zungrq.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zungrq.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZUNGRQ( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, K, LDA, LWORK, M, N
25: * ..
26: * .. Array Arguments ..
27: * COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> ZUNGRQ generates an M-by-N complex matrix Q with orthonormal rows,
37: *> which is defined as the last M rows of a product of K elementary
38: *> reflectors of order N
39: *>
40: *> Q = H(1)**H H(2)**H . . . H(k)**H
41: *>
42: *> as returned by ZGERQF.
43: *> \endverbatim
44: *
45: * Arguments:
46: * ==========
47: *
48: *> \param[in] M
49: *> \verbatim
50: *> M is INTEGER
51: *> The number of rows of the matrix Q. M >= 0.
52: *> \endverbatim
53: *>
54: *> \param[in] N
55: *> \verbatim
56: *> N is INTEGER
57: *> The number of columns of the matrix Q. N >= M.
58: *> \endverbatim
59: *>
60: *> \param[in] K
61: *> \verbatim
62: *> K is INTEGER
63: *> The number of elementary reflectors whose product defines the
64: *> matrix Q. M >= K >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is COMPLEX*16 array, dimension (LDA,N)
70: *> On entry, the (m-k+i)-th row must contain the vector which
71: *> defines the elementary reflector H(i), for i = 1,2,...,k, as
72: *> returned by ZGERQF in the last k rows of its array argument
73: *> A.
74: *> On exit, the M-by-N matrix Q.
75: *> \endverbatim
76: *>
77: *> \param[in] LDA
78: *> \verbatim
79: *> LDA is INTEGER
80: *> The first dimension of the array A. LDA >= max(1,M).
81: *> \endverbatim
82: *>
83: *> \param[in] TAU
84: *> \verbatim
85: *> TAU is COMPLEX*16 array, dimension (K)
86: *> TAU(i) must contain the scalar factor of the elementary
87: *> reflector H(i), as returned by ZGERQF.
88: *> \endverbatim
89: *>
90: *> \param[out] WORK
91: *> \verbatim
92: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
93: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
94: *> \endverbatim
95: *>
96: *> \param[in] LWORK
97: *> \verbatim
98: *> LWORK is INTEGER
99: *> The dimension of the array WORK. LWORK >= max(1,M).
100: *> For optimum performance LWORK >= M*NB, where NB is the
101: *> optimal blocksize.
102: *>
103: *> If LWORK = -1, then a workspace query is assumed; the routine
104: *> only calculates the optimal size of the WORK array, returns
105: *> this value as the first entry of the WORK array, and no error
106: *> message related to LWORK is issued by XERBLA.
107: *> \endverbatim
108: *>
109: *> \param[out] INFO
110: *> \verbatim
111: *> INFO is INTEGER
112: *> = 0: successful exit
113: *> < 0: if INFO = -i, the i-th argument has an illegal value
114: *> \endverbatim
115: *
116: * Authors:
117: * ========
118: *
119: *> \author Univ. of Tennessee
120: *> \author Univ. of California Berkeley
121: *> \author Univ. of Colorado Denver
122: *> \author NAG Ltd.
123: *
124: *> \ingroup complex16OTHERcomputational
125: *
126: * =====================================================================
127: SUBROUTINE ZUNGRQ( M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
128: *
129: * -- LAPACK computational routine --
130: * -- LAPACK is a software package provided by Univ. of Tennessee, --
131: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
132: *
133: * .. Scalar Arguments ..
134: INTEGER INFO, K, LDA, LWORK, M, N
135: * ..
136: * .. Array Arguments ..
137: COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
138: * ..
139: *
140: * =====================================================================
141: *
142: * .. Parameters ..
143: COMPLEX*16 ZERO
144: PARAMETER ( ZERO = ( 0.0D+0, 0.0D+0 ) )
145: * ..
146: * .. Local Scalars ..
147: LOGICAL LQUERY
148: INTEGER I, IB, II, IINFO, IWS, J, KK, L, LDWORK,
149: $ LWKOPT, NB, NBMIN, NX
150: * ..
151: * .. External Subroutines ..
152: EXTERNAL XERBLA, ZLARFB, ZLARFT, ZUNGR2
153: * ..
154: * .. Intrinsic Functions ..
155: INTRINSIC MAX, MIN
156: * ..
157: * .. External Functions ..
158: INTEGER ILAENV
159: EXTERNAL ILAENV
160: * ..
161: * .. Executable Statements ..
162: *
163: * Test the input arguments
164: *
165: INFO = 0
166: LQUERY = ( LWORK.EQ.-1 )
167: IF( M.LT.0 ) THEN
168: INFO = -1
169: ELSE IF( N.LT.M ) THEN
170: INFO = -2
171: ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
172: INFO = -3
173: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
174: INFO = -5
175: END IF
176: *
177: IF( INFO.EQ.0 ) THEN
178: IF( M.LE.0 ) THEN
179: LWKOPT = 1
180: ELSE
181: NB = ILAENV( 1, 'ZUNGRQ', ' ', M, N, K, -1 )
182: LWKOPT = M*NB
183: END IF
184: WORK( 1 ) = LWKOPT
185: *
186: IF( LWORK.LT.MAX( 1, M ) .AND. .NOT.LQUERY ) THEN
187: INFO = -8
188: END IF
189: END IF
190: *
191: IF( INFO.NE.0 ) THEN
192: CALL XERBLA( 'ZUNGRQ', -INFO )
193: RETURN
194: ELSE IF( LQUERY ) THEN
195: RETURN
196: END IF
197: *
198: * Quick return if possible
199: *
200: IF( M.LE.0 ) THEN
201: RETURN
202: END IF
203: *
204: NBMIN = 2
205: NX = 0
206: IWS = M
207: IF( NB.GT.1 .AND. NB.LT.K ) THEN
208: *
209: * Determine when to cross over from blocked to unblocked code.
210: *
211: NX = MAX( 0, ILAENV( 3, 'ZUNGRQ', ' ', M, N, K, -1 ) )
212: IF( NX.LT.K ) THEN
213: *
214: * Determine if workspace is large enough for blocked code.
215: *
216: LDWORK = M
217: IWS = LDWORK*NB
218: IF( LWORK.LT.IWS ) THEN
219: *
220: * Not enough workspace to use optimal NB: reduce NB and
221: * determine the minimum value of NB.
222: *
223: NB = LWORK / LDWORK
224: NBMIN = MAX( 2, ILAENV( 2, 'ZUNGRQ', ' ', M, N, K, -1 ) )
225: END IF
226: END IF
227: END IF
228: *
229: IF( NB.GE.NBMIN .AND. NB.LT.K .AND. NX.LT.K ) THEN
230: *
231: * Use blocked code after the first block.
232: * The last kk rows are handled by the block method.
233: *
234: KK = MIN( K, ( ( K-NX+NB-1 ) / NB )*NB )
235: *
236: * Set A(1:m-kk,n-kk+1:n) to zero.
237: *
238: DO 20 J = N - KK + 1, N
239: DO 10 I = 1, M - KK
240: A( I, J ) = ZERO
241: 10 CONTINUE
242: 20 CONTINUE
243: ELSE
244: KK = 0
245: END IF
246: *
247: * Use unblocked code for the first or only block.
248: *
249: CALL ZUNGR2( M-KK, N-KK, K-KK, A, LDA, TAU, WORK, IINFO )
250: *
251: IF( KK.GT.0 ) THEN
252: *
253: * Use blocked code
254: *
255: DO 50 I = K - KK + 1, K, NB
256: IB = MIN( NB, K-I+1 )
257: II = M - K + I
258: IF( II.GT.1 ) THEN
259: *
260: * Form the triangular factor of the block reflector
261: * H = H(i+ib-1) . . . H(i+1) H(i)
262: *
263: CALL ZLARFT( 'Backward', 'Rowwise', N-K+I+IB-1, IB,
264: $ A( II, 1 ), LDA, TAU( I ), WORK, LDWORK )
265: *
266: * Apply H**H to A(1:m-k+i-1,1:n-k+i+ib-1) from the right
267: *
268: CALL ZLARFB( 'Right', 'Conjugate transpose', 'Backward',
269: $ 'Rowwise', II-1, N-K+I+IB-1, IB, A( II, 1 ),
270: $ LDA, WORK, LDWORK, A, LDA, WORK( IB+1 ),
271: $ LDWORK )
272: END IF
273: *
274: * Apply H**H to columns 1:n-k+i+ib-1 of current block
275: *
276: CALL ZUNGR2( IB, N-K+I+IB-1, IB, A( II, 1 ), LDA, TAU( I ),
277: $ WORK, IINFO )
278: *
279: * Set columns n-k+i+ib:n of current block to zero
280: *
281: DO 40 L = N - K + I + IB, N
282: DO 30 J = II, II + IB - 1
283: A( J, L ) = ZERO
284: 30 CONTINUE
285: 40 CONTINUE
286: 50 CONTINUE
287: END IF
288: *
289: WORK( 1 ) = IWS
290: RETURN
291: *
292: * End of ZUNGRQ
293: *
294: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zungrq.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack