1: *> \brief \b ZUNGL2 generates all or part of the unitary matrix Q from an LQ factorization determined by cgelqf (unblocked algorithm).
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZUNGL2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zungl2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zungl2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zungl2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZUNGL2( M, N, K, A, LDA, TAU, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, K, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> ZUNGL2 generates an m-by-n complex matrix Q with orthonormal rows,
37: *> which is defined as the first m rows of a product of k elementary
38: *> reflectors of order n
39: *>
40: *> Q = H(k)**H . . . H(2)**H H(1)**H
41: *>
42: *> as returned by ZGELQF.
43: *> \endverbatim
44: *
45: * Arguments:
46: * ==========
47: *
48: *> \param[in] M
49: *> \verbatim
50: *> M is INTEGER
51: *> The number of rows of the matrix Q. M >= 0.
52: *> \endverbatim
53: *>
54: *> \param[in] N
55: *> \verbatim
56: *> N is INTEGER
57: *> The number of columns of the matrix Q. N >= M.
58: *> \endverbatim
59: *>
60: *> \param[in] K
61: *> \verbatim
62: *> K is INTEGER
63: *> The number of elementary reflectors whose product defines the
64: *> matrix Q. M >= K >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is COMPLEX*16 array, dimension (LDA,N)
70: *> On entry, the i-th row must contain the vector which defines
71: *> the elementary reflector H(i), for i = 1,2,...,k, as returned
72: *> by ZGELQF in the first k rows of its array argument A.
73: *> On exit, the m by n matrix Q.
74: *> \endverbatim
75: *>
76: *> \param[in] LDA
77: *> \verbatim
78: *> LDA is INTEGER
79: *> The first dimension of the array A. LDA >= max(1,M).
80: *> \endverbatim
81: *>
82: *> \param[in] TAU
83: *> \verbatim
84: *> TAU is COMPLEX*16 array, dimension (K)
85: *> TAU(i) must contain the scalar factor of the elementary
86: *> reflector H(i), as returned by ZGELQF.
87: *> \endverbatim
88: *>
89: *> \param[out] WORK
90: *> \verbatim
91: *> WORK is COMPLEX*16 array, dimension (M)
92: *> \endverbatim
93: *>
94: *> \param[out] INFO
95: *> \verbatim
96: *> INFO is INTEGER
97: *> = 0: successful exit
98: *> < 0: if INFO = -i, the i-th argument has an illegal value
99: *> \endverbatim
100: *
101: * Authors:
102: * ========
103: *
104: *> \author Univ. of Tennessee
105: *> \author Univ. of California Berkeley
106: *> \author Univ. of Colorado Denver
107: *> \author NAG Ltd.
108: *
109: *> \ingroup complex16OTHERcomputational
110: *
111: * =====================================================================
112: SUBROUTINE ZUNGL2( M, N, K, A, LDA, TAU, WORK, INFO )
113: *
114: * -- LAPACK computational routine --
115: * -- LAPACK is a software package provided by Univ. of Tennessee, --
116: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
117: *
118: * .. Scalar Arguments ..
119: INTEGER INFO, K, LDA, M, N
120: * ..
121: * .. Array Arguments ..
122: COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
123: * ..
124: *
125: * =====================================================================
126: *
127: * .. Parameters ..
128: COMPLEX*16 ONE, ZERO
129: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ),
130: $ ZERO = ( 0.0D+0, 0.0D+0 ) )
131: * ..
132: * .. Local Scalars ..
133: INTEGER I, J, L
134: * ..
135: * .. External Subroutines ..
136: EXTERNAL XERBLA, ZLACGV, ZLARF, ZSCAL
137: * ..
138: * .. Intrinsic Functions ..
139: INTRINSIC DCONJG, MAX
140: * ..
141: * .. Executable Statements ..
142: *
143: * Test the input arguments
144: *
145: INFO = 0
146: IF( M.LT.0 ) THEN
147: INFO = -1
148: ELSE IF( N.LT.M ) THEN
149: INFO = -2
150: ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
151: INFO = -3
152: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
153: INFO = -5
154: END IF
155: IF( INFO.NE.0 ) THEN
156: CALL XERBLA( 'ZUNGL2', -INFO )
157: RETURN
158: END IF
159: *
160: * Quick return if possible
161: *
162: IF( M.LE.0 )
163: $ RETURN
164: *
165: IF( K.LT.M ) THEN
166: *
167: * Initialise rows k+1:m to rows of the unit matrix
168: *
169: DO 20 J = 1, N
170: DO 10 L = K + 1, M
171: A( L, J ) = ZERO
172: 10 CONTINUE
173: IF( J.GT.K .AND. J.LE.M )
174: $ A( J, J ) = ONE
175: 20 CONTINUE
176: END IF
177: *
178: DO 40 I = K, 1, -1
179: *
180: * Apply H(i)**H to A(i:m,i:n) from the right
181: *
182: IF( I.LT.N ) THEN
183: CALL ZLACGV( N-I, A( I, I+1 ), LDA )
184: IF( I.LT.M ) THEN
185: A( I, I ) = ONE
186: CALL ZLARF( 'Right', M-I, N-I+1, A( I, I ), LDA,
187: $ DCONJG( TAU( I ) ), A( I+1, I ), LDA, WORK )
188: END IF
189: CALL ZSCAL( N-I, -TAU( I ), A( I, I+1 ), LDA )
190: CALL ZLACGV( N-I, A( I, I+1 ), LDA )
191: END IF
192: A( I, I ) = ONE - DCONJG( TAU( I ) )
193: *
194: * Set A(i,1:i-1) to zero
195: *
196: DO 30 L = 1, I - 1
197: A( I, L ) = ZERO
198: 30 CONTINUE
199: 40 CONTINUE
200: RETURN
201: *
202: * End of ZUNGL2
203: *
204: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zungl2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack