Annotation of rpl/lapack/lapack/zuncsd.f, revision 1.2
1.1 bertrand 1: RECURSIVE SUBROUTINE ZUNCSD( JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS,
2: $ SIGNS, M, P, Q, X11, LDX11, X12,
3: $ LDX12, X21, LDX21, X22, LDX22, THETA,
4: $ U1, LDU1, U2, LDU2, V1T, LDV1T, V2T,
5: $ LDV2T, WORK, LWORK, RWORK, LRWORK,
6: $ IWORK, INFO )
7: IMPLICIT NONE
8: *
9: * -- LAPACK routine (version 3.3.0) --
10: *
11: * -- Contributed by Brian Sutton of the Randolph-Macon College --
12: * -- November 2010
13: *
14: * -- LAPACK is a software package provided by Univ. of Tennessee, --
15: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
16: *
17: * .. Scalar Arguments ..
18: CHARACTER JOBU1, JOBU2, JOBV1T, JOBV2T, SIGNS, TRANS
19: INTEGER INFO, LDU1, LDU2, LDV1T, LDV2T, LDX11, LDX12,
20: $ LDX21, LDX22, LRWORK, LWORK, M, P, Q
21: * ..
22: * .. Array Arguments ..
23: INTEGER IWORK( * )
24: DOUBLE PRECISION THETA( * )
25: DOUBLE PRECISION RWORK( * )
26: COMPLEX*16 U1( LDU1, * ), U2( LDU2, * ), V1T( LDV1T, * ),
27: $ V2T( LDV2T, * ), WORK( * ), X11( LDX11, * ),
28: $ X12( LDX12, * ), X21( LDX21, * ), X22( LDX22,
29: $ * )
30: * ..
31: *
32: * Purpose
33: * =======
34: *
35: * ZUNCSD computes the CS decomposition of an M-by-M partitioned
36: * unitary matrix X:
37: *
38: * [ I 0 0 | 0 0 0 ]
39: * [ 0 C 0 | 0 -S 0 ]
40: * [ X11 | X12 ] [ U1 | ] [ 0 0 0 | 0 0 -I ] [ V1 | ]**H
41: * X = [-----------] = [---------] [---------------------] [---------] .
42: * [ X21 | X22 ] [ | U2 ] [ 0 0 0 | I 0 0 ] [ | V2 ]
43: * [ 0 S 0 | 0 C 0 ]
44: * [ 0 0 I | 0 0 0 ]
45: *
46: * X11 is P-by-Q. The unitary matrices U1, U2, V1, and V2 are P-by-P,
47: * (M-P)-by-(M-P), Q-by-Q, and (M-Q)-by-(M-Q), respectively. C and S are
48: * R-by-R nonnegative diagonal matrices satisfying C^2 + S^2 = I, in
49: * which R = MIN(P,M-P,Q,M-Q).
50: *
51: * Arguments
52: * =========
53: *
54: * JOBU1 (input) CHARACTER
55: * = 'Y': U1 is computed;
56: * otherwise: U1 is not computed.
57: *
58: * JOBU2 (input) CHARACTER
59: * = 'Y': U2 is computed;
60: * otherwise: U2 is not computed.
61: *
62: * JOBV1T (input) CHARACTER
63: * = 'Y': V1T is computed;
64: * otherwise: V1T is not computed.
65: *
66: * JOBV2T (input) CHARACTER
67: * = 'Y': V2T is computed;
68: * otherwise: V2T is not computed.
69: *
70: * TRANS (input) CHARACTER
71: * = 'T': X, U1, U2, V1T, and V2T are stored in row-major
72: * order;
73: * otherwise: X, U1, U2, V1T, and V2T are stored in column-
74: * major order.
75: *
76: * SIGNS (input) CHARACTER
77: * = 'O': The lower-left block is made nonpositive (the
78: * "other" convention);
79: * otherwise: The upper-right block is made nonpositive (the
80: * "default" convention).
81: *
82: * M (input) INTEGER
83: * The number of rows and columns in X.
84: *
85: * P (input) INTEGER
86: * The number of rows in X11 and X12. 0 <= P <= M.
87: *
88: * Q (input) INTEGER
89: * The number of columns in X11 and X21. 0 <= Q <= M.
90: *
91: * X (input/workspace) COMPLEX*16 array, dimension (LDX,M)
92: * On entry, the unitary matrix whose CSD is desired.
93: *
94: * LDX (input) INTEGER
95: * The leading dimension of X. LDX >= MAX(1,M).
96: *
97: * THETA (output) DOUBLE PRECISION array, dimension (R), in which R =
98: * MIN(P,M-P,Q,M-Q).
99: * C = DIAG( COS(THETA(1)), ... , COS(THETA(R)) ) and
100: * S = DIAG( SIN(THETA(1)), ... , SIN(THETA(R)) ).
101: *
102: * U1 (output) COMPLEX*16 array, dimension (P)
103: * If JOBU1 = 'Y', U1 contains the P-by-P unitary matrix U1.
104: *
105: * LDU1 (input) INTEGER
106: * The leading dimension of U1. If JOBU1 = 'Y', LDU1 >=
107: * MAX(1,P).
108: *
109: * U2 (output) COMPLEX*16 array, dimension (M-P)
110: * If JOBU2 = 'Y', U2 contains the (M-P)-by-(M-P) unitary
111: * matrix U2.
112: *
113: * LDU2 (input) INTEGER
114: * The leading dimension of U2. If JOBU2 = 'Y', LDU2 >=
115: * MAX(1,M-P).
116: *
117: * V1T (output) COMPLEX*16 array, dimension (Q)
118: * If JOBV1T = 'Y', V1T contains the Q-by-Q matrix unitary
119: * matrix V1**H.
120: *
121: * LDV1T (input) INTEGER
122: * The leading dimension of V1T. If JOBV1T = 'Y', LDV1T >=
123: * MAX(1,Q).
124: *
125: * V2T (output) COMPLEX*16 array, dimension (M-Q)
126: * If JOBV2T = 'Y', V2T contains the (M-Q)-by-(M-Q) unitary
127: * matrix V2**H.
128: *
129: * LDV2T (input) INTEGER
130: * The leading dimension of V2T. If JOBV2T = 'Y', LDV2T >=
131: * MAX(1,M-Q).
132: *
133: * WORK (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
134: * On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
135: *
136: * LWORK (input) INTEGER
137: * The dimension of the array WORK.
138: *
139: * If LWORK = -1, then a workspace query is assumed; the routine
140: * only calculates the optimal size of the WORK array, returns
141: * this value as the first entry of the work array, and no error
142: * message related to LWORK is issued by XERBLA.
143: *
144: * RWORK (workspace) DOUBLE PRECISION array, dimension MAX(1,LRWORK)
145: * On exit, if INFO = 0, RWORK(1) returns the optimal LRWORK.
146: * If INFO > 0 on exit, RWORK(2:R) contains the values PHI(1),
147: * ..., PHI(R-1) that, together with THETA(1), ..., THETA(R),
148: * define the matrix in intermediate bidiagonal-block form
149: * remaining after nonconvergence. INFO specifies the number
150: * of nonzero PHI's.
151: *
152: * LRWORK (input) INTEGER
153: * The dimension of the array RWORK.
154: *
155: * If LRWORK = -1, then a workspace query is assumed; the routine
156: * only calculates the optimal size of the RWORK array, returns
157: * this value as the first entry of the work array, and no error
158: * message related to LRWORK is issued by XERBLA.
159: *
160: * IWORK (workspace) INTEGER array, dimension (M-Q)
161: *
162: * INFO (output) INTEGER
163: * = 0: successful exit.
164: * < 0: if INFO = -i, the i-th argument had an illegal value.
165: * > 0: ZBBCSD did not converge. See the description of RWORK
166: * above for details.
167: *
168: * Reference
169: * =========
170: *
171: * [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
172: * Algorithms, 50(1):33-65, 2009.
173: *
174: * ===================================================================
175: *
176: * .. Parameters ..
177: DOUBLE PRECISION REALONE
178: PARAMETER ( REALONE = 1.0D0 )
179: COMPLEX*16 NEGONE, ONE, PIOVER2, ZERO
180: PARAMETER ( NEGONE = (-1.0D0,0.0D0), ONE = (1.0D0,0.0D0),
181: $ PIOVER2 = 1.57079632679489662D0,
182: $ ZERO = (0.0D0,0.0D0) )
183: * ..
184: * .. Local Scalars ..
185: CHARACTER TRANST, SIGNST
186: INTEGER CHILDINFO, I, IB11D, IB11E, IB12D, IB12E,
187: $ IB21D, IB21E, IB22D, IB22E, IBBCSD, IORBDB,
188: $ IORGLQ, IORGQR, IPHI, ITAUP1, ITAUP2, ITAUQ1,
189: $ ITAUQ2, J, LBBCSDWORK, LBBCSDWORKMIN,
190: $ LBBCSDWORKOPT, LORBDBWORK, LORBDBWORKMIN,
191: $ LORBDBWORKOPT, LORGLQWORK, LORGLQWORKMIN,
192: $ LORGLQWORKOPT, LORGQRWORK, LORGQRWORKMIN,
193: $ LORGQRWORKOPT, LWORKMIN, LWORKOPT
194: LOGICAL COLMAJOR, DEFAULTSIGNS, LQUERY, WANTU1, WANTU2,
195: $ WANTV1T, WANTV2T
196: INTEGER LRWORKMIN, LRWORKOPT
197: LOGICAL LRQUERY
198: * ..
199: * .. External Subroutines ..
200: EXTERNAL XERBLA, ZBBCSD, ZLACPY, ZLAPMR, ZLAPMT, ZLASCL,
201: $ ZLASET, ZUNBDB, ZUNGLQ, ZUNGQR
202: * ..
203: * .. External Functions ..
204: LOGICAL LSAME
205: EXTERNAL LSAME
206: * ..
207: * .. Intrinsic Functions
208: INTRINSIC COS, INT, MAX, MIN, SIN
209: * ..
210: * .. Executable Statements ..
211: *
212: * Test input arguments
213: *
214: INFO = 0
215: WANTU1 = LSAME( JOBU1, 'Y' )
216: WANTU2 = LSAME( JOBU2, 'Y' )
217: WANTV1T = LSAME( JOBV1T, 'Y' )
218: WANTV2T = LSAME( JOBV2T, 'Y' )
219: COLMAJOR = .NOT. LSAME( TRANS, 'T' )
220: DEFAULTSIGNS = .NOT. LSAME( SIGNS, 'O' )
221: LQUERY = LWORK .EQ. -1
222: LRQUERY = LRWORK .EQ. -1
223: IF( M .LT. 0 ) THEN
224: INFO = -7
225: ELSE IF( P .LT. 0 .OR. P .GT. M ) THEN
226: INFO = -8
227: ELSE IF( Q .LT. 0 .OR. Q .GT. M ) THEN
228: INFO = -9
229: ELSE IF( ( COLMAJOR .AND. LDX11 .LT. MAX(1,P) ) .OR.
230: $ ( .NOT.COLMAJOR .AND. LDX11 .LT. MAX(1,Q) ) ) THEN
231: INFO = -11
232: ELSE IF( WANTU1 .AND. LDU1 .LT. P ) THEN
233: INFO = -14
234: ELSE IF( WANTU2 .AND. LDU2 .LT. M-P ) THEN
235: INFO = -16
236: ELSE IF( WANTV1T .AND. LDV1T .LT. Q ) THEN
237: INFO = -18
238: ELSE IF( WANTV2T .AND. LDV2T .LT. M-Q ) THEN
239: INFO = -20
240: END IF
241: *
242: * Work with transpose if convenient
243: *
244: IF( INFO .EQ. 0 .AND. MIN( P, M-P ) .LT. MIN( Q, M-Q ) ) THEN
245: IF( COLMAJOR ) THEN
246: TRANST = 'T'
247: ELSE
248: TRANST = 'N'
249: END IF
250: IF( DEFAULTSIGNS ) THEN
251: SIGNST = 'O'
252: ELSE
253: SIGNST = 'D'
254: END IF
255: CALL ZUNCSD( JOBV1T, JOBV2T, JOBU1, JOBU2, TRANST, SIGNST, M,
256: $ Q, P, X11, LDX11, X21, LDX21, X12, LDX12, X22,
257: $ LDX22, THETA, V1T, LDV1T, V2T, LDV2T, U1, LDU1,
258: $ U2, LDU2, WORK, LWORK, RWORK, LRWORK, IWORK,
259: $ INFO )
260: RETURN
261: END IF
262: *
263: * Work with permutation [ 0 I; I 0 ] * X * [ 0 I; I 0 ] if
264: * convenient
265: *
266: IF( INFO .EQ. 0 .AND. M-Q .LT. Q ) THEN
267: IF( DEFAULTSIGNS ) THEN
268: SIGNST = 'O'
269: ELSE
270: SIGNST = 'D'
271: END IF
272: CALL ZUNCSD( JOBU2, JOBU1, JOBV2T, JOBV1T, TRANS, SIGNST, M,
273: $ M-P, M-Q, X22, LDX22, X21, LDX21, X12, LDX12, X11,
274: $ LDX11, THETA, U2, LDU2, U1, LDU1, V2T, LDV2T, V1T,
275: $ LDV1T, WORK, LWORK, RWORK, LRWORK, IWORK, INFO )
276: RETURN
277: END IF
278: *
279: * Compute workspace
280: *
281: IF( INFO .EQ. 0 ) THEN
282: *
283: * Real workspace
284: *
285: IPHI = 2
286: IB11D = IPHI + MAX( 1, Q - 1 )
287: IB11E = IB11D + MAX( 1, Q )
288: IB12D = IB11E + MAX( 1, Q - 1 )
289: IB12E = IB12D + MAX( 1, Q )
290: IB21D = IB12E + MAX( 1, Q - 1 )
291: IB21E = IB21D + MAX( 1, Q )
292: IB22D = IB21E + MAX( 1, Q - 1 )
293: IB22E = IB22D + MAX( 1, Q )
294: IBBCSD = IB22E + MAX( 1, Q - 1 )
295: CALL ZBBCSD( JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS, M, P, Q, 0,
296: $ 0, U1, LDU1, U2, LDU2, V1T, LDV1T, V2T, LDV2T, 0,
297: $ 0, 0, 0, 0, 0, 0, 0, RWORK, -1, CHILDINFO )
298: LBBCSDWORKOPT = INT( RWORK(1) )
299: LBBCSDWORKMIN = LBBCSDWORKOPT
300: LRWORKOPT = IBBCSD + LBBCSDWORKOPT - 1
301: LRWORKMIN = IBBCSD + LBBCSDWORKMIN - 1
302: RWORK(1) = LRWORKOPT
303: *
304: * Complex workspace
305: *
306: ITAUP1 = 2
307: ITAUP2 = ITAUP1 + MAX( 1, P )
308: ITAUQ1 = ITAUP2 + MAX( 1, M - P )
309: ITAUQ2 = ITAUQ1 + MAX( 1, Q )
310: IORGQR = ITAUQ2 + MAX( 1, M - Q )
311: CALL ZUNGQR( M-Q, M-Q, M-Q, 0, MAX(1,M-Q), 0, WORK, -1,
312: $ CHILDINFO )
313: LORGQRWORKOPT = INT( WORK(1) )
314: LORGQRWORKMIN = MAX( 1, M - Q )
315: IORGLQ = ITAUQ2 + MAX( 1, M - Q )
316: CALL ZUNGLQ( M-Q, M-Q, M-Q, 0, MAX(1,M-Q), 0, WORK, -1,
317: $ CHILDINFO )
318: LORGLQWORKOPT = INT( WORK(1) )
319: LORGLQWORKMIN = MAX( 1, M - Q )
320: IORBDB = ITAUQ2 + MAX( 1, M - Q )
321: CALL ZUNBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
322: $ X21, LDX21, X22, LDX22, 0, 0, 0, 0, 0, 0, WORK,
323: $ -1, CHILDINFO )
324: LORBDBWORKOPT = INT( WORK(1) )
325: LORBDBWORKMIN = LORBDBWORKOPT
326: LWORKOPT = MAX( IORGQR + LORGQRWORKOPT, IORGLQ + LORGLQWORKOPT,
327: $ IORBDB + LORBDBWORKOPT ) - 1
328: LWORKMIN = MAX( IORGQR + LORGQRWORKMIN, IORGLQ + LORGLQWORKMIN,
329: $ IORBDB + LORBDBWORKMIN ) - 1
330: WORK(1) = LWORKOPT
331: *
332: IF( LWORK .LT. LWORKMIN
333: $ .AND. .NOT. ( LQUERY .OR. LRQUERY ) ) THEN
334: INFO = -22
335: ELSE IF( LRWORK .LT. LRWORKMIN
336: $ .AND. .NOT. ( LQUERY .OR. LRQUERY ) ) THEN
337: INFO = -24
338: ELSE
339: LORGQRWORK = LWORK - IORGQR + 1
340: LORGLQWORK = LWORK - IORGLQ + 1
341: LORBDBWORK = LWORK - IORBDB + 1
342: LBBCSDWORK = LRWORK - IBBCSD + 1
343: END IF
344: END IF
345: *
346: * Abort if any illegal arguments
347: *
348: IF( INFO .NE. 0 ) THEN
349: CALL XERBLA( 'ZUNCSD', -INFO )
350: RETURN
351: ELSE IF( LQUERY .OR. LRQUERY ) THEN
352: RETURN
353: END IF
354: *
355: * Transform to bidiagonal block form
356: *
357: CALL ZUNBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12, X21,
358: $ LDX21, X22, LDX22, THETA, RWORK(IPHI), WORK(ITAUP1),
359: $ WORK(ITAUP2), WORK(ITAUQ1), WORK(ITAUQ2),
360: $ WORK(IORBDB), LORBDBWORK, CHILDINFO )
361: *
362: * Accumulate Householder reflectors
363: *
364: IF( COLMAJOR ) THEN
365: IF( WANTU1 .AND. P .GT. 0 ) THEN
366: CALL ZLACPY( 'L', P, Q, X11, LDX11, U1, LDU1 )
367: CALL ZUNGQR( P, P, Q, U1, LDU1, WORK(ITAUP1), WORK(IORGQR),
368: $ LORGQRWORK, INFO)
369: END IF
370: IF( WANTU2 .AND. M-P .GT. 0 ) THEN
371: CALL ZLACPY( 'L', M-P, Q, X21, LDX21, U2, LDU2 )
372: CALL ZUNGQR( M-P, M-P, Q, U2, LDU2, WORK(ITAUP2),
373: $ WORK(IORGQR), LORGQRWORK, INFO )
374: END IF
375: IF( WANTV1T .AND. Q .GT. 0 ) THEN
376: CALL ZLACPY( 'U', Q-1, Q-1, X11(1,2), LDX11, V1T(2,2),
377: $ LDV1T )
378: V1T(1, 1) = ONE
379: DO J = 2, Q
380: V1T(1,J) = ZERO
381: V1T(J,1) = ZERO
382: END DO
383: CALL ZUNGLQ( Q-1, Q-1, Q-1, V1T(2,2), LDV1T, WORK(ITAUQ1),
384: $ WORK(IORGLQ), LORGLQWORK, INFO )
385: END IF
386: IF( WANTV2T .AND. M-Q .GT. 0 ) THEN
387: CALL ZLACPY( 'U', P, M-Q, X12, LDX12, V2T, LDV2T )
388: CALL ZLACPY( 'U', M-P-Q, M-P-Q, X22(Q+1,P+1), LDX22,
389: $ V2T(P+1,P+1), LDV2T )
390: CALL ZUNGLQ( M-Q, M-Q, M-Q, V2T, LDV2T, WORK(ITAUQ2),
391: $ WORK(IORGLQ), LORGLQWORK, INFO )
392: END IF
393: ELSE
394: IF( WANTU1 .AND. P .GT. 0 ) THEN
395: CALL ZLACPY( 'U', Q, P, X11, LDX11, U1, LDU1 )
396: CALL ZUNGLQ( P, P, Q, U1, LDU1, WORK(ITAUP1), WORK(IORGLQ),
397: $ LORGLQWORK, INFO)
398: END IF
399: IF( WANTU2 .AND. M-P .GT. 0 ) THEN
400: CALL ZLACPY( 'U', Q, M-P, X21, LDX21, U2, LDU2 )
401: CALL ZUNGLQ( M-P, M-P, Q, U2, LDU2, WORK(ITAUP2),
402: $ WORK(IORGLQ), LORGLQWORK, INFO )
403: END IF
404: IF( WANTV1T .AND. Q .GT. 0 ) THEN
405: CALL ZLACPY( 'L', Q-1, Q-1, X11(2,1), LDX11, V1T(2,2),
406: $ LDV1T )
407: V1T(1, 1) = ONE
408: DO J = 2, Q
409: V1T(1,J) = ZERO
410: V1T(J,1) = ZERO
411: END DO
412: CALL ZUNGQR( Q-1, Q-1, Q-1, V1T(2,2), LDV1T, WORK(ITAUQ1),
413: $ WORK(IORGQR), LORGQRWORK, INFO )
414: END IF
415: IF( WANTV2T .AND. M-Q .GT. 0 ) THEN
416: CALL ZLACPY( 'L', M-Q, P, X12, LDX12, V2T, LDV2T )
417: CALL ZLACPY( 'L', M-P-Q, M-P-Q, X22(P+1,Q+1), LDX22,
418: $ V2T(P+1,P+1), LDV2T )
419: CALL ZUNGQR( M-Q, M-Q, M-Q, V2T, LDV2T, WORK(ITAUQ2),
420: $ WORK(IORGQR), LORGQRWORK, INFO )
421: END IF
422: END IF
423: *
424: * Compute the CSD of the matrix in bidiagonal-block form
425: *
426: CALL ZBBCSD( JOBU1, JOBU2, JOBV1T, JOBV2T, TRANS, M, P, Q, THETA,
427: $ RWORK(IPHI), U1, LDU1, U2, LDU2, V1T, LDV1T, V2T,
428: $ LDV2T, RWORK(IB11D), RWORK(IB11E), RWORK(IB12D),
429: $ RWORK(IB12E), RWORK(IB21D), RWORK(IB21E),
430: $ RWORK(IB22D), RWORK(IB22E), RWORK(IBBCSD),
431: $ LBBCSDWORK, INFO )
432: *
433: * Permute rows and columns to place identity submatrices in top-
434: * left corner of (1,1)-block and/or bottom-right corner of (1,2)-
435: * block and/or bottom-right corner of (2,1)-block and/or top-left
436: * corner of (2,2)-block
437: *
438: IF( Q .GT. 0 .AND. WANTU2 ) THEN
439: DO I = 1, Q
440: IWORK(I) = M - P - Q + I
441: END DO
442: DO I = Q + 1, M - P
443: IWORK(I) = I - Q
444: END DO
445: IF( COLMAJOR ) THEN
446: CALL ZLAPMT( .FALSE., M-P, M-P, U2, LDU2, IWORK )
447: ELSE
448: CALL ZLAPMR( .FALSE., M-P, M-P, U2, LDU2, IWORK )
449: END IF
450: END IF
451: IF( M .GT. 0 .AND. WANTV2T ) THEN
452: DO I = 1, P
453: IWORK(I) = M - P - Q + I
454: END DO
455: DO I = P + 1, M - Q
456: IWORK(I) = I - P
457: END DO
458: IF( .NOT. COLMAJOR ) THEN
459: CALL ZLAPMT( .FALSE., M-Q, M-Q, V2T, LDV2T, IWORK )
460: ELSE
461: CALL ZLAPMR( .FALSE., M-Q, M-Q, V2T, LDV2T, IWORK )
462: END IF
463: END IF
464: *
465: RETURN
466: *
467: * End ZUNCSD
468: *
469: END
470:
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zuncsd.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack