Annotation of rpl/lapack/lapack/zunbdb.f, revision 1.5
1.4 bertrand 1: *> \brief \b ZUNBDB
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZUNBDB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zunbdb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zunbdb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zunbdb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZUNBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
22: * X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
23: * TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER SIGNS, TRANS
27: * INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
28: * $ Q
29: * ..
30: * .. Array Arguments ..
31: * DOUBLE PRECISION PHI( * ), THETA( * )
32: * COMPLEX*16 TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
33: * $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
34: * $ X21( LDX21, * ), X22( LDX22, * )
35: * ..
36: *
37: *
38: *> \par Purpose:
39: * =============
40: *>
41: *> \verbatim
42: *>
43: *> ZUNBDB simultaneously bidiagonalizes the blocks of an M-by-M
44: *> partitioned unitary matrix X:
45: *>
46: *> [ B11 | B12 0 0 ]
47: *> [ X11 | X12 ] [ P1 | ] [ 0 | 0 -I 0 ] [ Q1 | ]**H
48: *> X = [-----------] = [---------] [----------------] [---------] .
49: *> [ X21 | X22 ] [ | P2 ] [ B21 | B22 0 0 ] [ | Q2 ]
50: *> [ 0 | 0 0 I ]
51: *>
52: *> X11 is P-by-Q. Q must be no larger than P, M-P, or M-Q. (If this is
53: *> not the case, then X must be transposed and/or permuted. This can be
54: *> done in constant time using the TRANS and SIGNS options. See ZUNCSD
55: *> for details.)
56: *>
57: *> The unitary matrices P1, P2, Q1, and Q2 are P-by-P, (M-P)-by-
58: *> (M-P), Q-by-Q, and (M-Q)-by-(M-Q), respectively. They are
59: *> represented implicitly by Householder vectors.
60: *>
61: *> B11, B12, B21, and B22 are Q-by-Q bidiagonal matrices represented
62: *> implicitly by angles THETA, PHI.
63: *> \endverbatim
64: *
65: * Arguments:
66: * ==========
67: *
68: *> \param[in] TRANS
69: *> \verbatim
70: *> TRANS is CHARACTER
71: *> = 'T': X, U1, U2, V1T, and V2T are stored in row-major
72: *> order;
73: *> otherwise: X, U1, U2, V1T, and V2T are stored in column-
74: *> major order.
75: *> \endverbatim
76: *>
77: *> \param[in] SIGNS
78: *> \verbatim
79: *> SIGNS is CHARACTER
80: *> = 'O': The lower-left block is made nonpositive (the
81: *> "other" convention);
82: *> otherwise: The upper-right block is made nonpositive (the
83: *> "default" convention).
84: *> \endverbatim
85: *>
86: *> \param[in] M
87: *> \verbatim
88: *> M is INTEGER
89: *> The number of rows and columns in X.
90: *> \endverbatim
91: *>
92: *> \param[in] P
93: *> \verbatim
94: *> P is INTEGER
95: *> The number of rows in X11 and X12. 0 <= P <= M.
96: *> \endverbatim
97: *>
98: *> \param[in] Q
99: *> \verbatim
100: *> Q is INTEGER
101: *> The number of columns in X11 and X21. 0 <= Q <=
102: *> MIN(P,M-P,M-Q).
103: *> \endverbatim
104: *>
105: *> \param[in,out] X11
106: *> \verbatim
107: *> X11 is COMPLEX*16 array, dimension (LDX11,Q)
108: *> On entry, the top-left block of the unitary matrix to be
109: *> reduced. On exit, the form depends on TRANS:
110: *> If TRANS = 'N', then
111: *> the columns of tril(X11) specify reflectors for P1,
112: *> the rows of triu(X11,1) specify reflectors for Q1;
113: *> else TRANS = 'T', and
114: *> the rows of triu(X11) specify reflectors for P1,
115: *> the columns of tril(X11,-1) specify reflectors for Q1.
116: *> \endverbatim
117: *>
118: *> \param[in] LDX11
119: *> \verbatim
120: *> LDX11 is INTEGER
121: *> The leading dimension of X11. If TRANS = 'N', then LDX11 >=
122: *> P; else LDX11 >= Q.
123: *> \endverbatim
124: *>
125: *> \param[in,out] X12
126: *> \verbatim
127: *> X12 is COMPLEX*16 array, dimension (LDX12,M-Q)
128: *> On entry, the top-right block of the unitary matrix to
129: *> be reduced. On exit, the form depends on TRANS:
130: *> If TRANS = 'N', then
131: *> the rows of triu(X12) specify the first P reflectors for
132: *> Q2;
133: *> else TRANS = 'T', and
134: *> the columns of tril(X12) specify the first P reflectors
135: *> for Q2.
136: *> \endverbatim
137: *>
138: *> \param[in] LDX12
139: *> \verbatim
140: *> LDX12 is INTEGER
141: *> The leading dimension of X12. If TRANS = 'N', then LDX12 >=
142: *> P; else LDX11 >= M-Q.
143: *> \endverbatim
144: *>
145: *> \param[in,out] X21
146: *> \verbatim
147: *> X21 is COMPLEX*16 array, dimension (LDX21,Q)
148: *> On entry, the bottom-left block of the unitary matrix to
149: *> be reduced. On exit, the form depends on TRANS:
150: *> If TRANS = 'N', then
151: *> the columns of tril(X21) specify reflectors for P2;
152: *> else TRANS = 'T', and
153: *> the rows of triu(X21) specify reflectors for P2.
154: *> \endverbatim
155: *>
156: *> \param[in] LDX21
157: *> \verbatim
158: *> LDX21 is INTEGER
159: *> The leading dimension of X21. If TRANS = 'N', then LDX21 >=
160: *> M-P; else LDX21 >= Q.
161: *> \endverbatim
162: *>
163: *> \param[in,out] X22
164: *> \verbatim
165: *> X22 is COMPLEX*16 array, dimension (LDX22,M-Q)
166: *> On entry, the bottom-right block of the unitary matrix to
167: *> be reduced. On exit, the form depends on TRANS:
168: *> If TRANS = 'N', then
169: *> the rows of triu(X22(Q+1:M-P,P+1:M-Q)) specify the last
170: *> M-P-Q reflectors for Q2,
171: *> else TRANS = 'T', and
172: *> the columns of tril(X22(P+1:M-Q,Q+1:M-P)) specify the last
173: *> M-P-Q reflectors for P2.
174: *> \endverbatim
175: *>
176: *> \param[in] LDX22
177: *> \verbatim
178: *> LDX22 is INTEGER
179: *> The leading dimension of X22. If TRANS = 'N', then LDX22 >=
180: *> M-P; else LDX22 >= M-Q.
181: *> \endverbatim
182: *>
183: *> \param[out] THETA
184: *> \verbatim
185: *> THETA is DOUBLE PRECISION array, dimension (Q)
186: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
187: *> be computed from the angles THETA and PHI. See Further
188: *> Details.
189: *> \endverbatim
190: *>
191: *> \param[out] PHI
192: *> \verbatim
193: *> PHI is DOUBLE PRECISION array, dimension (Q-1)
194: *> The entries of the bidiagonal blocks B11, B12, B21, B22 can
195: *> be computed from the angles THETA and PHI. See Further
196: *> Details.
197: *> \endverbatim
198: *>
199: *> \param[out] TAUP1
200: *> \verbatim
201: *> TAUP1 is COMPLEX*16 array, dimension (P)
202: *> The scalar factors of the elementary reflectors that define
203: *> P1.
204: *> \endverbatim
205: *>
206: *> \param[out] TAUP2
207: *> \verbatim
208: *> TAUP2 is COMPLEX*16 array, dimension (M-P)
209: *> The scalar factors of the elementary reflectors that define
210: *> P2.
211: *> \endverbatim
212: *>
213: *> \param[out] TAUQ1
214: *> \verbatim
215: *> TAUQ1 is COMPLEX*16 array, dimension (Q)
216: *> The scalar factors of the elementary reflectors that define
217: *> Q1.
218: *> \endverbatim
219: *>
220: *> \param[out] TAUQ2
221: *> \verbatim
222: *> TAUQ2 is COMPLEX*16 array, dimension (M-Q)
223: *> The scalar factors of the elementary reflectors that define
224: *> Q2.
225: *> \endverbatim
226: *>
227: *> \param[out] WORK
228: *> \verbatim
229: *> WORK is COMPLEX*16 array, dimension (LWORK)
230: *> \endverbatim
231: *>
232: *> \param[in] LWORK
233: *> \verbatim
234: *> LWORK is INTEGER
235: *> The dimension of the array WORK. LWORK >= M-Q.
236: *>
237: *> If LWORK = -1, then a workspace query is assumed; the routine
238: *> only calculates the optimal size of the WORK array, returns
239: *> this value as the first entry of the WORK array, and no error
240: *> message related to LWORK is issued by XERBLA.
241: *> \endverbatim
242: *>
243: *> \param[out] INFO
244: *> \verbatim
245: *> INFO is INTEGER
246: *> = 0: successful exit.
247: *> < 0: if INFO = -i, the i-th argument had an illegal value.
248: *> \endverbatim
249: *
250: * Authors:
251: * ========
252: *
253: *> \author Univ. of Tennessee
254: *> \author Univ. of California Berkeley
255: *> \author Univ. of Colorado Denver
256: *> \author NAG Ltd.
257: *
258: *> \date November 2011
259: *
260: *> \ingroup complex16OTHERcomputational
261: *
262: *> \par Further Details:
263: * =====================
264: *>
265: *> \verbatim
266: *>
267: *> The bidiagonal blocks B11, B12, B21, and B22 are represented
268: *> implicitly by angles THETA(1), ..., THETA(Q) and PHI(1), ...,
269: *> PHI(Q-1). B11 and B21 are upper bidiagonal, while B21 and B22 are
270: *> lower bidiagonal. Every entry in each bidiagonal band is a product
271: *> of a sine or cosine of a THETA with a sine or cosine of a PHI. See
272: *> [1] or ZUNCSD for details.
273: *>
274: *> P1, P2, Q1, and Q2 are represented as products of elementary
275: *> reflectors. See ZUNCSD for details on generating P1, P2, Q1, and Q2
276: *> using ZUNGQR and ZUNGLQ.
277: *> \endverbatim
278: *
279: *> \par References:
280: * ================
281: *>
282: *> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
283: *> Algorithms, 50(1):33-65, 2009.
284: *>
285: * =====================================================================
1.1 bertrand 286: SUBROUTINE ZUNBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
287: $ X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
288: $ TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
289: *
1.4 bertrand 290: * -- LAPACK computational routine (version 3.4.0) --
1.1 bertrand 291: * -- LAPACK is a software package provided by Univ. of Tennessee, --
1.4 bertrand 292: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
293: * November 2011
1.1 bertrand 294: *
295: * .. Scalar Arguments ..
296: CHARACTER SIGNS, TRANS
297: INTEGER INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
298: $ Q
299: * ..
300: * .. Array Arguments ..
301: DOUBLE PRECISION PHI( * ), THETA( * )
302: COMPLEX*16 TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
303: $ WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
304: $ X21( LDX21, * ), X22( LDX22, * )
305: * ..
306: *
307: * ====================================================================
308: *
309: * .. Parameters ..
310: DOUBLE PRECISION REALONE
311: PARAMETER ( REALONE = 1.0D0 )
312: COMPLEX*16 NEGONE, ONE
313: PARAMETER ( NEGONE = (-1.0D0,0.0D0),
314: $ ONE = (1.0D0,0.0D0) )
315: * ..
316: * .. Local Scalars ..
317: LOGICAL COLMAJOR, LQUERY
318: INTEGER I, LWORKMIN, LWORKOPT
319: DOUBLE PRECISION Z1, Z2, Z3, Z4
320: * ..
321: * .. External Subroutines ..
322: EXTERNAL ZAXPY, ZLARF, ZLARFGP, ZSCAL, XERBLA
323: EXTERNAL ZLACGV
324: *
325: * ..
326: * .. External Functions ..
327: DOUBLE PRECISION DZNRM2
328: LOGICAL LSAME
329: EXTERNAL DZNRM2, LSAME
330: * ..
331: * .. Intrinsic Functions
332: INTRINSIC ATAN2, COS, MAX, MIN, SIN
333: INTRINSIC DCMPLX, DCONJG
334: * ..
335: * .. Executable Statements ..
336: *
337: * Test input arguments
338: *
339: INFO = 0
340: COLMAJOR = .NOT. LSAME( TRANS, 'T' )
341: IF( .NOT. LSAME( SIGNS, 'O' ) ) THEN
342: Z1 = REALONE
343: Z2 = REALONE
344: Z3 = REALONE
345: Z4 = REALONE
346: ELSE
347: Z1 = REALONE
348: Z2 = -REALONE
349: Z3 = REALONE
350: Z4 = -REALONE
351: END IF
352: LQUERY = LWORK .EQ. -1
353: *
354: IF( M .LT. 0 ) THEN
355: INFO = -3
356: ELSE IF( P .LT. 0 .OR. P .GT. M ) THEN
357: INFO = -4
358: ELSE IF( Q .LT. 0 .OR. Q .GT. P .OR. Q .GT. M-P .OR.
359: $ Q .GT. M-Q ) THEN
360: INFO = -5
361: ELSE IF( COLMAJOR .AND. LDX11 .LT. MAX( 1, P ) ) THEN
362: INFO = -7
363: ELSE IF( .NOT.COLMAJOR .AND. LDX11 .LT. MAX( 1, Q ) ) THEN
364: INFO = -7
365: ELSE IF( COLMAJOR .AND. LDX12 .LT. MAX( 1, P ) ) THEN
366: INFO = -9
367: ELSE IF( .NOT.COLMAJOR .AND. LDX12 .LT. MAX( 1, M-Q ) ) THEN
368: INFO = -9
369: ELSE IF( COLMAJOR .AND. LDX21 .LT. MAX( 1, M-P ) ) THEN
370: INFO = -11
371: ELSE IF( .NOT.COLMAJOR .AND. LDX21 .LT. MAX( 1, Q ) ) THEN
372: INFO = -11
373: ELSE IF( COLMAJOR .AND. LDX22 .LT. MAX( 1, M-P ) ) THEN
374: INFO = -13
375: ELSE IF( .NOT.COLMAJOR .AND. LDX22 .LT. MAX( 1, M-Q ) ) THEN
376: INFO = -13
377: END IF
378: *
379: * Compute workspace
380: *
381: IF( INFO .EQ. 0 ) THEN
382: LWORKOPT = M - Q
383: LWORKMIN = M - Q
384: WORK(1) = LWORKOPT
385: IF( LWORK .LT. LWORKMIN .AND. .NOT. LQUERY ) THEN
386: INFO = -21
387: END IF
388: END IF
389: IF( INFO .NE. 0 ) THEN
390: CALL XERBLA( 'xORBDB', -INFO )
391: RETURN
392: ELSE IF( LQUERY ) THEN
393: RETURN
394: END IF
395: *
396: * Handle column-major and row-major separately
397: *
398: IF( COLMAJOR ) THEN
399: *
400: * Reduce columns 1, ..., Q of X11, X12, X21, and X22
401: *
402: DO I = 1, Q
403: *
404: IF( I .EQ. 1 ) THEN
405: CALL ZSCAL( P-I+1, DCMPLX( Z1, 0.0D0 ), X11(I,I), 1 )
406: ELSE
407: CALL ZSCAL( P-I+1, DCMPLX( Z1*COS(PHI(I-1)), 0.0D0 ),
408: $ X11(I,I), 1 )
409: CALL ZAXPY( P-I+1, DCMPLX( -Z1*Z3*Z4*SIN(PHI(I-1)),
410: $ 0.0D0 ), X12(I,I-1), 1, X11(I,I), 1 )
411: END IF
412: IF( I .EQ. 1 ) THEN
413: CALL ZSCAL( M-P-I+1, DCMPLX( Z2, 0.0D0 ), X21(I,I), 1 )
414: ELSE
415: CALL ZSCAL( M-P-I+1, DCMPLX( Z2*COS(PHI(I-1)), 0.0D0 ),
416: $ X21(I,I), 1 )
417: CALL ZAXPY( M-P-I+1, DCMPLX( -Z2*Z3*Z4*SIN(PHI(I-1)),
418: $ 0.0D0 ), X22(I,I-1), 1, X21(I,I), 1 )
419: END IF
420: *
421: THETA(I) = ATAN2( DZNRM2( M-P-I+1, X21(I,I), 1 ),
422: $ DZNRM2( P-I+1, X11(I,I), 1 ) )
423: *
424: CALL ZLARFGP( P-I+1, X11(I,I), X11(I+1,I), 1, TAUP1(I) )
425: X11(I,I) = ONE
426: CALL ZLARFGP( M-P-I+1, X21(I,I), X21(I+1,I), 1, TAUP2(I) )
427: X21(I,I) = ONE
428: *
429: CALL ZLARF( 'L', P-I+1, Q-I, X11(I,I), 1, DCONJG(TAUP1(I)),
430: $ X11(I,I+1), LDX11, WORK )
431: CALL ZLARF( 'L', P-I+1, M-Q-I+1, X11(I,I), 1,
432: $ DCONJG(TAUP1(I)), X12(I,I), LDX12, WORK )
433: CALL ZLARF( 'L', M-P-I+1, Q-I, X21(I,I), 1,
434: $ DCONJG(TAUP2(I)), X21(I,I+1), LDX21, WORK )
435: CALL ZLARF( 'L', M-P-I+1, M-Q-I+1, X21(I,I), 1,
436: $ DCONJG(TAUP2(I)), X22(I,I), LDX22, WORK )
437: *
438: IF( I .LT. Q ) THEN
439: CALL ZSCAL( Q-I, DCMPLX( -Z1*Z3*SIN(THETA(I)), 0.0D0 ),
440: $ X11(I,I+1), LDX11 )
441: CALL ZAXPY( Q-I, DCMPLX( Z2*Z3*COS(THETA(I)), 0.0D0 ),
442: $ X21(I,I+1), LDX21, X11(I,I+1), LDX11 )
443: END IF
444: CALL ZSCAL( M-Q-I+1, DCMPLX( -Z1*Z4*SIN(THETA(I)), 0.0D0 ),
445: $ X12(I,I), LDX12 )
446: CALL ZAXPY( M-Q-I+1, DCMPLX( Z2*Z4*COS(THETA(I)), 0.0D0 ),
447: $ X22(I,I), LDX22, X12(I,I), LDX12 )
448: *
449: IF( I .LT. Q )
450: $ PHI(I) = ATAN2( DZNRM2( Q-I, X11(I,I+1), LDX11 ),
451: $ DZNRM2( M-Q-I+1, X12(I,I), LDX12 ) )
452: *
453: IF( I .LT. Q ) THEN
454: CALL ZLACGV( Q-I, X11(I,I+1), LDX11 )
455: CALL ZLARFGP( Q-I, X11(I,I+1), X11(I,I+2), LDX11,
456: $ TAUQ1(I) )
457: X11(I,I+1) = ONE
458: END IF
459: CALL ZLACGV( M-Q-I+1, X12(I,I), LDX12 )
460: CALL ZLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
461: $ TAUQ2(I) )
462: X12(I,I) = ONE
463: *
464: IF( I .LT. Q ) THEN
465: CALL ZLARF( 'R', P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
466: $ X11(I+1,I+1), LDX11, WORK )
467: CALL ZLARF( 'R', M-P-I, Q-I, X11(I,I+1), LDX11, TAUQ1(I),
468: $ X21(I+1,I+1), LDX21, WORK )
469: END IF
470: CALL ZLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
471: $ X12(I+1,I), LDX12, WORK )
472: CALL ZLARF( 'R', M-P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
473: $ X22(I+1,I), LDX22, WORK )
474: *
475: IF( I .LT. Q )
476: $ CALL ZLACGV( Q-I, X11(I,I+1), LDX11 )
477: CALL ZLACGV( M-Q-I+1, X12(I,I), LDX12 )
478: *
479: END DO
480: *
481: * Reduce columns Q + 1, ..., P of X12, X22
482: *
483: DO I = Q + 1, P
484: *
485: CALL ZSCAL( M-Q-I+1, DCMPLX( -Z1*Z4, 0.0D0 ), X12(I,I),
486: $ LDX12 )
487: CALL ZLACGV( M-Q-I+1, X12(I,I), LDX12 )
488: CALL ZLARFGP( M-Q-I+1, X12(I,I), X12(I,I+1), LDX12,
489: $ TAUQ2(I) )
490: X12(I,I) = ONE
491: *
492: CALL ZLARF( 'R', P-I, M-Q-I+1, X12(I,I), LDX12, TAUQ2(I),
493: $ X12(I+1,I), LDX12, WORK )
494: IF( M-P-Q .GE. 1 )
495: $ CALL ZLARF( 'R', M-P-Q, M-Q-I+1, X12(I,I), LDX12,
496: $ TAUQ2(I), X22(Q+1,I), LDX22, WORK )
497: *
498: CALL ZLACGV( M-Q-I+1, X12(I,I), LDX12 )
499: *
500: END DO
501: *
502: * Reduce columns P + 1, ..., M - Q of X12, X22
503: *
504: DO I = 1, M - P - Q
505: *
506: CALL ZSCAL( M-P-Q-I+1, DCMPLX( Z2*Z4, 0.0D0 ),
507: $ X22(Q+I,P+I), LDX22 )
508: CALL ZLACGV( M-P-Q-I+1, X22(Q+I,P+I), LDX22 )
509: CALL ZLARFGP( M-P-Q-I+1, X22(Q+I,P+I), X22(Q+I,P+I+1),
510: $ LDX22, TAUQ2(P+I) )
511: X22(Q+I,P+I) = ONE
512: CALL ZLARF( 'R', M-P-Q-I, M-P-Q-I+1, X22(Q+I,P+I), LDX22,
513: $ TAUQ2(P+I), X22(Q+I+1,P+I), LDX22, WORK )
514: *
515: CALL ZLACGV( M-P-Q-I+1, X22(Q+I,P+I), LDX22 )
516: *
517: END DO
518: *
519: ELSE
520: *
521: * Reduce columns 1, ..., Q of X11, X12, X21, X22
522: *
523: DO I = 1, Q
524: *
525: IF( I .EQ. 1 ) THEN
526: CALL ZSCAL( P-I+1, DCMPLX( Z1, 0.0D0 ), X11(I,I),
527: $ LDX11 )
528: ELSE
529: CALL ZSCAL( P-I+1, DCMPLX( Z1*COS(PHI(I-1)), 0.0D0 ),
530: $ X11(I,I), LDX11 )
531: CALL ZAXPY( P-I+1, DCMPLX( -Z1*Z3*Z4*SIN(PHI(I-1)),
532: $ 0.0D0 ), X12(I-1,I), LDX12, X11(I,I), LDX11 )
533: END IF
534: IF( I .EQ. 1 ) THEN
535: CALL ZSCAL( M-P-I+1, DCMPLX( Z2, 0.0D0 ), X21(I,I),
536: $ LDX21 )
537: ELSE
538: CALL ZSCAL( M-P-I+1, DCMPLX( Z2*COS(PHI(I-1)), 0.0D0 ),
539: $ X21(I,I), LDX21 )
540: CALL ZAXPY( M-P-I+1, DCMPLX( -Z2*Z3*Z4*SIN(PHI(I-1)),
541: $ 0.0D0 ), X22(I-1,I), LDX22, X21(I,I), LDX21 )
542: END IF
543: *
544: THETA(I) = ATAN2( DZNRM2( M-P-I+1, X21(I,I), LDX21 ),
545: $ DZNRM2( P-I+1, X11(I,I), LDX11 ) )
546: *
547: CALL ZLACGV( P-I+1, X11(I,I), LDX11 )
548: CALL ZLACGV( M-P-I+1, X21(I,I), LDX21 )
549: *
550: CALL ZLARFGP( P-I+1, X11(I,I), X11(I,I+1), LDX11, TAUP1(I) )
551: X11(I,I) = ONE
552: CALL ZLARFGP( M-P-I+1, X21(I,I), X21(I,I+1), LDX21,
553: $ TAUP2(I) )
554: X21(I,I) = ONE
555: *
556: CALL ZLARF( 'R', Q-I, P-I+1, X11(I,I), LDX11, TAUP1(I),
557: $ X11(I+1,I), LDX11, WORK )
558: CALL ZLARF( 'R', M-Q-I+1, P-I+1, X11(I,I), LDX11, TAUP1(I),
559: $ X12(I,I), LDX12, WORK )
560: CALL ZLARF( 'R', Q-I, M-P-I+1, X21(I,I), LDX21, TAUP2(I),
561: $ X21(I+1,I), LDX21, WORK )
562: CALL ZLARF( 'R', M-Q-I+1, M-P-I+1, X21(I,I), LDX21,
563: $ TAUP2(I), X22(I,I), LDX22, WORK )
564: *
565: CALL ZLACGV( P-I+1, X11(I,I), LDX11 )
566: CALL ZLACGV( M-P-I+1, X21(I,I), LDX21 )
567: *
568: IF( I .LT. Q ) THEN
569: CALL ZSCAL( Q-I, DCMPLX( -Z1*Z3*SIN(THETA(I)), 0.0D0 ),
570: $ X11(I+1,I), 1 )
571: CALL ZAXPY( Q-I, DCMPLX( Z2*Z3*COS(THETA(I)), 0.0D0 ),
572: $ X21(I+1,I), 1, X11(I+1,I), 1 )
573: END IF
574: CALL ZSCAL( M-Q-I+1, DCMPLX( -Z1*Z4*SIN(THETA(I)), 0.0D0 ),
575: $ X12(I,I), 1 )
576: CALL ZAXPY( M-Q-I+1, DCMPLX( Z2*Z4*COS(THETA(I)), 0.0D0 ),
577: $ X22(I,I), 1, X12(I,I), 1 )
578: *
579: IF( I .LT. Q )
580: $ PHI(I) = ATAN2( DZNRM2( Q-I, X11(I+1,I), 1 ),
581: $ DZNRM2( M-Q-I+1, X12(I,I), 1 ) )
582: *
583: IF( I .LT. Q ) THEN
584: CALL ZLARFGP( Q-I, X11(I+1,I), X11(I+2,I), 1, TAUQ1(I) )
585: X11(I+1,I) = ONE
586: END IF
587: CALL ZLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1, TAUQ2(I) )
588: X12(I,I) = ONE
589: *
590: IF( I .LT. Q ) THEN
591: CALL ZLARF( 'L', Q-I, P-I, X11(I+1,I), 1,
592: $ DCONJG(TAUQ1(I)), X11(I+1,I+1), LDX11, WORK )
593: CALL ZLARF( 'L', Q-I, M-P-I, X11(I+1,I), 1,
594: $ DCONJG(TAUQ1(I)), X21(I+1,I+1), LDX21, WORK )
595: END IF
596: CALL ZLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1,
597: $ DCONJG(TAUQ2(I)), X12(I,I+1), LDX12, WORK )
598: CALL ZLARF( 'L', M-Q-I+1, M-P-I, X12(I,I), 1,
599: $ DCONJG(TAUQ2(I)), X22(I,I+1), LDX22, WORK )
600: *
601: END DO
602: *
603: * Reduce columns Q + 1, ..., P of X12, X22
604: *
605: DO I = Q + 1, P
606: *
607: CALL ZSCAL( M-Q-I+1, DCMPLX( -Z1*Z4, 0.0D0 ), X12(I,I), 1 )
608: CALL ZLARFGP( M-Q-I+1, X12(I,I), X12(I+1,I), 1, TAUQ2(I) )
609: X12(I,I) = ONE
610: *
611: CALL ZLARF( 'L', M-Q-I+1, P-I, X12(I,I), 1,
612: $ DCONJG(TAUQ2(I)), X12(I,I+1), LDX12, WORK )
613: IF( M-P-Q .GE. 1 )
614: $ CALL ZLARF( 'L', M-Q-I+1, M-P-Q, X12(I,I), 1,
615: $ DCONJG(TAUQ2(I)), X22(I,Q+1), LDX22, WORK )
616: *
617: END DO
618: *
619: * Reduce columns P + 1, ..., M - Q of X12, X22
620: *
621: DO I = 1, M - P - Q
622: *
623: CALL ZSCAL( M-P-Q-I+1, DCMPLX( Z2*Z4, 0.0D0 ),
624: $ X22(P+I,Q+I), 1 )
625: CALL ZLARFGP( M-P-Q-I+1, X22(P+I,Q+I), X22(P+I+1,Q+I), 1,
626: $ TAUQ2(P+I) )
627: X22(P+I,Q+I) = ONE
628: *
629: CALL ZLARF( 'L', M-P-Q-I+1, M-P-Q-I, X22(P+I,Q+I), 1,
630: $ DCONJG(TAUQ2(P+I)), X22(P+I,Q+I+1), LDX22,
631: $ WORK )
632: *
633: END DO
634: *
635: END IF
636: *
637: RETURN
638: *
639: * End of ZUNBDB
640: *
641: END
642:
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zunbdb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack