1: *> \brief \b ZTPTRI
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZTPTRI + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztptri.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztptri.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztptri.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZTPTRI( UPLO, DIAG, N, AP, INFO )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER DIAG, UPLO
25: * INTEGER INFO, N
26: * ..
27: * .. Array Arguments ..
28: * COMPLEX*16 AP( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZTPTRI computes the inverse of a complex upper or lower triangular
38: *> matrix A stored in packed format.
39: *> \endverbatim
40: *
41: * Arguments:
42: * ==========
43: *
44: *> \param[in] UPLO
45: *> \verbatim
46: *> UPLO is CHARACTER*1
47: *> = 'U': A is upper triangular;
48: *> = 'L': A is lower triangular.
49: *> \endverbatim
50: *>
51: *> \param[in] DIAG
52: *> \verbatim
53: *> DIAG is CHARACTER*1
54: *> = 'N': A is non-unit triangular;
55: *> = 'U': A is unit triangular.
56: *> \endverbatim
57: *>
58: *> \param[in] N
59: *> \verbatim
60: *> N is INTEGER
61: *> The order of the matrix A. N >= 0.
62: *> \endverbatim
63: *>
64: *> \param[in,out] AP
65: *> \verbatim
66: *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
67: *> On entry, the upper or lower triangular matrix A, stored
68: *> columnwise in a linear array. The j-th column of A is stored
69: *> in the array AP as follows:
70: *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
71: *> if UPLO = 'L', AP(i + (j-1)*((2*n-j)/2) = A(i,j) for j<=i<=n.
72: *> See below for further details.
73: *> On exit, the (triangular) inverse of the original matrix, in
74: *> the same packed storage format.
75: *> \endverbatim
76: *>
77: *> \param[out] INFO
78: *> \verbatim
79: *> INFO is INTEGER
80: *> = 0: successful exit
81: *> < 0: if INFO = -i, the i-th argument had an illegal value
82: *> > 0: if INFO = i, A(i,i) is exactly zero. The triangular
83: *> matrix is singular and its inverse can not be computed.
84: *> \endverbatim
85: *
86: * Authors:
87: * ========
88: *
89: *> \author Univ. of Tennessee
90: *> \author Univ. of California Berkeley
91: *> \author Univ. of Colorado Denver
92: *> \author NAG Ltd.
93: *
94: *> \ingroup complex16OTHERcomputational
95: *
96: *> \par Further Details:
97: * =====================
98: *>
99: *> \verbatim
100: *>
101: *> A triangular matrix A can be transferred to packed storage using one
102: *> of the following program segments:
103: *>
104: *> UPLO = 'U': UPLO = 'L':
105: *>
106: *> JC = 1 JC = 1
107: *> DO 2 J = 1, N DO 2 J = 1, N
108: *> DO 1 I = 1, J DO 1 I = J, N
109: *> AP(JC+I-1) = A(I,J) AP(JC+I-J) = A(I,J)
110: *> 1 CONTINUE 1 CONTINUE
111: *> JC = JC + J JC = JC + N - J + 1
112: *> 2 CONTINUE 2 CONTINUE
113: *> \endverbatim
114: *>
115: * =====================================================================
116: SUBROUTINE ZTPTRI( UPLO, DIAG, N, AP, INFO )
117: *
118: * -- LAPACK computational routine --
119: * -- LAPACK is a software package provided by Univ. of Tennessee, --
120: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121: *
122: * .. Scalar Arguments ..
123: CHARACTER DIAG, UPLO
124: INTEGER INFO, N
125: * ..
126: * .. Array Arguments ..
127: COMPLEX*16 AP( * )
128: * ..
129: *
130: * =====================================================================
131: *
132: * .. Parameters ..
133: COMPLEX*16 ONE, ZERO
134: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ),
135: $ ZERO = ( 0.0D+0, 0.0D+0 ) )
136: * ..
137: * .. Local Scalars ..
138: LOGICAL NOUNIT, UPPER
139: INTEGER J, JC, JCLAST, JJ
140: COMPLEX*16 AJJ
141: * ..
142: * .. External Functions ..
143: LOGICAL LSAME
144: EXTERNAL LSAME
145: * ..
146: * .. External Subroutines ..
147: EXTERNAL XERBLA, ZSCAL, ZTPMV
148: * ..
149: * .. Executable Statements ..
150: *
151: * Test the input parameters.
152: *
153: INFO = 0
154: UPPER = LSAME( UPLO, 'U' )
155: NOUNIT = LSAME( DIAG, 'N' )
156: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
157: INFO = -1
158: ELSE IF( .NOT.NOUNIT .AND. .NOT.LSAME( DIAG, 'U' ) ) THEN
159: INFO = -2
160: ELSE IF( N.LT.0 ) THEN
161: INFO = -3
162: END IF
163: IF( INFO.NE.0 ) THEN
164: CALL XERBLA( 'ZTPTRI', -INFO )
165: RETURN
166: END IF
167: *
168: * Check for singularity if non-unit.
169: *
170: IF( NOUNIT ) THEN
171: IF( UPPER ) THEN
172: JJ = 0
173: DO 10 INFO = 1, N
174: JJ = JJ + INFO
175: IF( AP( JJ ).EQ.ZERO )
176: $ RETURN
177: 10 CONTINUE
178: ELSE
179: JJ = 1
180: DO 20 INFO = 1, N
181: IF( AP( JJ ).EQ.ZERO )
182: $ RETURN
183: JJ = JJ + N - INFO + 1
184: 20 CONTINUE
185: END IF
186: INFO = 0
187: END IF
188: *
189: IF( UPPER ) THEN
190: *
191: * Compute inverse of upper triangular matrix.
192: *
193: JC = 1
194: DO 30 J = 1, N
195: IF( NOUNIT ) THEN
196: AP( JC+J-1 ) = ONE / AP( JC+J-1 )
197: AJJ = -AP( JC+J-1 )
198: ELSE
199: AJJ = -ONE
200: END IF
201: *
202: * Compute elements 1:j-1 of j-th column.
203: *
204: CALL ZTPMV( 'Upper', 'No transpose', DIAG, J-1, AP,
205: $ AP( JC ), 1 )
206: CALL ZSCAL( J-1, AJJ, AP( JC ), 1 )
207: JC = JC + J
208: 30 CONTINUE
209: *
210: ELSE
211: *
212: * Compute inverse of lower triangular matrix.
213: *
214: JC = N*( N+1 ) / 2
215: DO 40 J = N, 1, -1
216: IF( NOUNIT ) THEN
217: AP( JC ) = ONE / AP( JC )
218: AJJ = -AP( JC )
219: ELSE
220: AJJ = -ONE
221: END IF
222: IF( J.LT.N ) THEN
223: *
224: * Compute elements j+1:n of j-th column.
225: *
226: CALL ZTPMV( 'Lower', 'No transpose', DIAG, N-J,
227: $ AP( JCLAST ), AP( JC+1 ), 1 )
228: CALL ZSCAL( N-J, AJJ, AP( JC+1 ), 1 )
229: END IF
230: JCLAST = JC
231: JC = JC - N + J - 2
232: 40 CONTINUE
233: END IF
234: *
235: RETURN
236: *
237: * End of ZTPTRI
238: *
239: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to ztptri.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack