1: *> \brief \b ZPPTRI
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZPPTRI + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zpptri.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zpptri.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zpptri.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZPPTRI( UPLO, N, AP, INFO )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER UPLO
25: * INTEGER INFO, N
26: * ..
27: * .. Array Arguments ..
28: * COMPLEX*16 AP( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZPPTRI computes the inverse of a complex Hermitian positive definite
38: *> matrix A using the Cholesky factorization A = U**H*U or A = L*L**H
39: *> computed by ZPPTRF.
40: *> \endverbatim
41: *
42: * Arguments:
43: * ==========
44: *
45: *> \param[in] UPLO
46: *> \verbatim
47: *> UPLO is CHARACTER*1
48: *> = 'U': Upper triangular factor is stored in AP;
49: *> = 'L': Lower triangular factor is stored in AP.
50: *> \endverbatim
51: *>
52: *> \param[in] N
53: *> \verbatim
54: *> N is INTEGER
55: *> The order of the matrix A. N >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in,out] AP
59: *> \verbatim
60: *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
61: *> On entry, the triangular factor U or L from the Cholesky
62: *> factorization A = U**H*U or A = L*L**H, packed columnwise as
63: *> a linear array. The j-th column of U or L is stored in the
64: *> array AP as follows:
65: *> if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
66: *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
67: *>
68: *> On exit, the upper or lower triangle of the (Hermitian)
69: *> inverse of A, overwriting the input factor U or L.
70: *> \endverbatim
71: *>
72: *> \param[out] INFO
73: *> \verbatim
74: *> INFO is INTEGER
75: *> = 0: successful exit
76: *> < 0: if INFO = -i, the i-th argument had an illegal value
77: *> > 0: if INFO = i, the (i,i) element of the factor U or L is
78: *> zero, and the inverse could not be computed.
79: *> \endverbatim
80: *
81: * Authors:
82: * ========
83: *
84: *> \author Univ. of Tennessee
85: *> \author Univ. of California Berkeley
86: *> \author Univ. of Colorado Denver
87: *> \author NAG Ltd.
88: *
89: *> \ingroup complex16OTHERcomputational
90: *
91: * =====================================================================
92: SUBROUTINE ZPPTRI( UPLO, N, AP, INFO )
93: *
94: * -- LAPACK computational routine --
95: * -- LAPACK is a software package provided by Univ. of Tennessee, --
96: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
97: *
98: * .. Scalar Arguments ..
99: CHARACTER UPLO
100: INTEGER INFO, N
101: * ..
102: * .. Array Arguments ..
103: COMPLEX*16 AP( * )
104: * ..
105: *
106: * =====================================================================
107: *
108: * .. Parameters ..
109: DOUBLE PRECISION ONE
110: PARAMETER ( ONE = 1.0D+0 )
111: * ..
112: * .. Local Scalars ..
113: LOGICAL UPPER
114: INTEGER J, JC, JJ, JJN
115: DOUBLE PRECISION AJJ
116: * ..
117: * .. External Functions ..
118: LOGICAL LSAME
119: COMPLEX*16 ZDOTC
120: EXTERNAL LSAME, ZDOTC
121: * ..
122: * .. External Subroutines ..
123: EXTERNAL XERBLA, ZDSCAL, ZHPR, ZTPMV, ZTPTRI
124: * ..
125: * .. Intrinsic Functions ..
126: INTRINSIC DBLE
127: * ..
128: * .. Executable Statements ..
129: *
130: * Test the input parameters.
131: *
132: INFO = 0
133: UPPER = LSAME( UPLO, 'U' )
134: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
135: INFO = -1
136: ELSE IF( N.LT.0 ) THEN
137: INFO = -2
138: END IF
139: IF( INFO.NE.0 ) THEN
140: CALL XERBLA( 'ZPPTRI', -INFO )
141: RETURN
142: END IF
143: *
144: * Quick return if possible
145: *
146: IF( N.EQ.0 )
147: $ RETURN
148: *
149: * Invert the triangular Cholesky factor U or L.
150: *
151: CALL ZTPTRI( UPLO, 'Non-unit', N, AP, INFO )
152: IF( INFO.GT.0 )
153: $ RETURN
154: IF( UPPER ) THEN
155: *
156: * Compute the product inv(U) * inv(U)**H.
157: *
158: JJ = 0
159: DO 10 J = 1, N
160: JC = JJ + 1
161: JJ = JJ + J
162: IF( J.GT.1 )
163: $ CALL ZHPR( 'Upper', J-1, ONE, AP( JC ), 1, AP )
164: AJJ = DBLE( AP( JJ ) )
165: CALL ZDSCAL( J, AJJ, AP( JC ), 1 )
166: 10 CONTINUE
167: *
168: ELSE
169: *
170: * Compute the product inv(L)**H * inv(L).
171: *
172: JJ = 1
173: DO 20 J = 1, N
174: JJN = JJ + N - J + 1
175: AP( JJ ) = DBLE( ZDOTC( N-J+1, AP( JJ ), 1, AP( JJ ), 1 ) )
176: IF( J.LT.N )
177: $ CALL ZTPMV( 'Lower', 'Conjugate transpose', 'Non-unit',
178: $ N-J, AP( JJN ), AP( JJ+1 ), 1 )
179: JJ = JJN
180: 20 CONTINUE
181: END IF
182: *
183: RETURN
184: *
185: * End of ZPPTRI
186: *
187: END
CVSweb interface <joel.bertrand@systella.fr>