Annotation of rpl/lapack/lapack/zlauum.f, revision 1.19
1.12 bertrand 1: *> \brief \b ZLAUUM computes the product UUH or LHL, where U and L are upper or lower triangular matrices (blocked algorithm).
1.9 bertrand 2: *
3: * =========== DOCUMENTATION ===========
4: *
1.16 bertrand 5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
1.9 bertrand 7: *
8: *> \htmlonly
1.16 bertrand 9: *> Download ZLAUUM + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlauum.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlauum.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlauum.f">
1.9 bertrand 15: *> [TXT]</a>
1.16 bertrand 16: *> \endhtmlonly
1.9 bertrand 17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLAUUM( UPLO, N, A, LDA, INFO )
1.16 bertrand 22: *
1.9 bertrand 23: * .. Scalar Arguments ..
24: * CHARACTER UPLO
25: * INTEGER INFO, LDA, N
26: * ..
27: * .. Array Arguments ..
28: * COMPLEX*16 A( LDA, * )
29: * ..
1.16 bertrand 30: *
1.9 bertrand 31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZLAUUM computes the product U * U**H or L**H * L, where the triangular
38: *> factor U or L is stored in the upper or lower triangular part of
39: *> the array A.
40: *>
41: *> If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
42: *> overwriting the factor U in A.
43: *> If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
44: *> overwriting the factor L in A.
45: *>
46: *> This is the blocked form of the algorithm, calling Level 3 BLAS.
47: *> \endverbatim
48: *
49: * Arguments:
50: * ==========
51: *
52: *> \param[in] UPLO
53: *> \verbatim
54: *> UPLO is CHARACTER*1
55: *> Specifies whether the triangular factor stored in the array A
56: *> is upper or lower triangular:
57: *> = 'U': Upper triangular
58: *> = 'L': Lower triangular
59: *> \endverbatim
60: *>
61: *> \param[in] N
62: *> \verbatim
63: *> N is INTEGER
64: *> The order of the triangular factor U or L. N >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is COMPLEX*16 array, dimension (LDA,N)
70: *> On entry, the triangular factor U or L.
71: *> On exit, if UPLO = 'U', the upper triangle of A is
72: *> overwritten with the upper triangle of the product U * U**H;
73: *> if UPLO = 'L', the lower triangle of A is overwritten with
74: *> the lower triangle of the product L**H * L.
75: *> \endverbatim
76: *>
77: *> \param[in] LDA
78: *> \verbatim
79: *> LDA is INTEGER
80: *> The leading dimension of the array A. LDA >= max(1,N).
81: *> \endverbatim
82: *>
83: *> \param[out] INFO
84: *> \verbatim
85: *> INFO is INTEGER
86: *> = 0: successful exit
87: *> < 0: if INFO = -k, the k-th argument had an illegal value
88: *> \endverbatim
89: *
90: * Authors:
91: * ========
92: *
1.16 bertrand 93: *> \author Univ. of Tennessee
94: *> \author Univ. of California Berkeley
95: *> \author Univ. of Colorado Denver
96: *> \author NAG Ltd.
1.9 bertrand 97: *
98: *> \ingroup complex16OTHERauxiliary
99: *
100: * =====================================================================
1.1 bertrand 101: SUBROUTINE ZLAUUM( UPLO, N, A, LDA, INFO )
102: *
1.19 ! bertrand 103: * -- LAPACK auxiliary routine --
1.1 bertrand 104: * -- LAPACK is a software package provided by Univ. of Tennessee, --
105: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
106: *
107: * .. Scalar Arguments ..
108: CHARACTER UPLO
109: INTEGER INFO, LDA, N
110: * ..
111: * .. Array Arguments ..
112: COMPLEX*16 A( LDA, * )
113: * ..
114: *
115: * =====================================================================
116: *
117: * .. Parameters ..
118: DOUBLE PRECISION ONE
119: PARAMETER ( ONE = 1.0D+0 )
120: COMPLEX*16 CONE
121: PARAMETER ( CONE = ( 1.0D+0, 0.0D+0 ) )
122: * ..
123: * .. Local Scalars ..
124: LOGICAL UPPER
125: INTEGER I, IB, NB
126: * ..
127: * .. External Functions ..
128: LOGICAL LSAME
129: INTEGER ILAENV
130: EXTERNAL LSAME, ILAENV
131: * ..
132: * .. External Subroutines ..
133: EXTERNAL XERBLA, ZGEMM, ZHERK, ZLAUU2, ZTRMM
134: * ..
135: * .. Intrinsic Functions ..
136: INTRINSIC MAX, MIN
137: * ..
138: * .. Executable Statements ..
139: *
140: * Test the input parameters.
141: *
142: INFO = 0
143: UPPER = LSAME( UPLO, 'U' )
144: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
145: INFO = -1
146: ELSE IF( N.LT.0 ) THEN
147: INFO = -2
148: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
149: INFO = -4
150: END IF
151: IF( INFO.NE.0 ) THEN
152: CALL XERBLA( 'ZLAUUM', -INFO )
153: RETURN
154: END IF
155: *
156: * Quick return if possible
157: *
158: IF( N.EQ.0 )
159: $ RETURN
160: *
161: * Determine the block size for this environment.
162: *
163: NB = ILAENV( 1, 'ZLAUUM', UPLO, N, -1, -1, -1 )
164: *
165: IF( NB.LE.1 .OR. NB.GE.N ) THEN
166: *
167: * Use unblocked code
168: *
169: CALL ZLAUU2( UPLO, N, A, LDA, INFO )
170: ELSE
171: *
172: * Use blocked code
173: *
174: IF( UPPER ) THEN
175: *
1.8 bertrand 176: * Compute the product U * U**H.
1.1 bertrand 177: *
178: DO 10 I = 1, N, NB
179: IB = MIN( NB, N-I+1 )
180: CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
181: $ 'Non-unit', I-1, IB, CONE, A( I, I ), LDA,
182: $ A( 1, I ), LDA )
183: CALL ZLAUU2( 'Upper', IB, A( I, I ), LDA, INFO )
184: IF( I+IB.LE.N ) THEN
185: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
186: $ I-1, IB, N-I-IB+1, CONE, A( 1, I+IB ),
187: $ LDA, A( I, I+IB ), LDA, CONE, A( 1, I ),
188: $ LDA )
189: CALL ZHERK( 'Upper', 'No transpose', IB, N-I-IB+1,
190: $ ONE, A( I, I+IB ), LDA, ONE, A( I, I ),
191: $ LDA )
192: END IF
193: 10 CONTINUE
194: ELSE
195: *
1.8 bertrand 196: * Compute the product L**H * L.
1.1 bertrand 197: *
198: DO 20 I = 1, N, NB
199: IB = MIN( NB, N-I+1 )
200: CALL ZTRMM( 'Left', 'Lower', 'Conjugate transpose',
201: $ 'Non-unit', IB, I-1, CONE, A( I, I ), LDA,
202: $ A( I, 1 ), LDA )
203: CALL ZLAUU2( 'Lower', IB, A( I, I ), LDA, INFO )
204: IF( I+IB.LE.N ) THEN
205: CALL ZGEMM( 'Conjugate transpose', 'No transpose', IB,
206: $ I-1, N-I-IB+1, CONE, A( I+IB, I ), LDA,
207: $ A( I+IB, 1 ), LDA, CONE, A( I, 1 ), LDA )
208: CALL ZHERK( 'Lower', 'Conjugate transpose', IB,
209: $ N-I-IB+1, ONE, A( I+IB, I ), LDA, ONE,
210: $ A( I, I ), LDA )
211: END IF
212: 20 CONTINUE
213: END IF
214: END IF
215: *
216: RETURN
217: *
218: * End of ZLAUUM
219: *
220: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlauum.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack