1: *> \brief \b ZLASYF_RK computes a partial factorization of a complex symmetric indefinite matrix using bounded Bunch-Kaufman (rook) diagonal pivoting method.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLASYF_RK + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlasyf_rk.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlasyf_rk.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlasyf_rk.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLASYF_RK( UPLO, N, NB, KB, A, LDA, E, IPIV, W, LDW,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER UPLO
26: * INTEGER INFO, KB, LDA, LDW, N, NB
27: * ..
28: * .. Array Arguments ..
29: * INTEGER IPIV( * )
30: * COMPLEX*16 A( LDA, * ), E( * ), W( LDW, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *> ZLASYF_RK computes a partial factorization of a complex symmetric
39: *> matrix A using the bounded Bunch-Kaufman (rook) diagonal
40: *> pivoting method. The partial factorization has the form:
41: *>
42: *> A = ( I U12 ) ( A11 0 ) ( I 0 ) if UPLO = 'U', or:
43: *> ( 0 U22 ) ( 0 D ) ( U12**T U22**T )
44: *>
45: *> A = ( L11 0 ) ( D 0 ) ( L11**T L21**T ) if UPLO = 'L',
46: *> ( L21 I ) ( 0 A22 ) ( 0 I )
47: *>
48: *> where the order of D is at most NB. The actual order is returned in
49: *> the argument KB, and is either NB or NB-1, or N if N <= NB.
50: *>
51: *> ZLASYF_RK is an auxiliary routine called by ZSYTRF_RK. It uses
52: *> blocked code (calling Level 3 BLAS) to update the submatrix
53: *> A11 (if UPLO = 'U') or A22 (if UPLO = 'L').
54: *> \endverbatim
55: *
56: * Arguments:
57: * ==========
58: *
59: *> \param[in] UPLO
60: *> \verbatim
61: *> UPLO is CHARACTER*1
62: *> Specifies whether the upper or lower triangular part of the
63: *> symmetric matrix A is stored:
64: *> = 'U': Upper triangular
65: *> = 'L': Lower triangular
66: *> \endverbatim
67: *>
68: *> \param[in] N
69: *> \verbatim
70: *> N is INTEGER
71: *> The order of the matrix A. N >= 0.
72: *> \endverbatim
73: *>
74: *> \param[in] NB
75: *> \verbatim
76: *> NB is INTEGER
77: *> The maximum number of columns of the matrix A that should be
78: *> factored. NB should be at least 2 to allow for 2-by-2 pivot
79: *> blocks.
80: *> \endverbatim
81: *>
82: *> \param[out] KB
83: *> \verbatim
84: *> KB is INTEGER
85: *> The number of columns of A that were actually factored.
86: *> KB is either NB-1 or NB, or N if N <= NB.
87: *> \endverbatim
88: *>
89: *> \param[in,out] A
90: *> \verbatim
91: *> A is COMPLEX*16 array, dimension (LDA,N)
92: *> On entry, the symmetric matrix A.
93: *> If UPLO = 'U': the leading N-by-N upper triangular part
94: *> of A contains the upper triangular part of the matrix A,
95: *> and the strictly lower triangular part of A is not
96: *> referenced.
97: *>
98: *> If UPLO = 'L': the leading N-by-N lower triangular part
99: *> of A contains the lower triangular part of the matrix A,
100: *> and the strictly upper triangular part of A is not
101: *> referenced.
102: *>
103: *> On exit, contains:
104: *> a) ONLY diagonal elements of the symmetric block diagonal
105: *> matrix D on the diagonal of A, i.e. D(k,k) = A(k,k);
106: *> (superdiagonal (or subdiagonal) elements of D
107: *> are stored on exit in array E), and
108: *> b) If UPLO = 'U': factor U in the superdiagonal part of A.
109: *> If UPLO = 'L': factor L in the subdiagonal part of A.
110: *> \endverbatim
111: *>
112: *> \param[in] LDA
113: *> \verbatim
114: *> LDA is INTEGER
115: *> The leading dimension of the array A. LDA >= max(1,N).
116: *> \endverbatim
117: *>
118: *> \param[out] E
119: *> \verbatim
120: *> E is COMPLEX*16 array, dimension (N)
121: *> On exit, contains the superdiagonal (or subdiagonal)
122: *> elements of the symmetric block diagonal matrix D
123: *> with 1-by-1 or 2-by-2 diagonal blocks, where
124: *> If UPLO = 'U': E(i) = D(i-1,i), i=2:N, E(1) is set to 0;
125: *> If UPLO = 'L': E(i) = D(i+1,i), i=1:N-1, E(N) is set to 0.
126: *>
127: *> NOTE: For 1-by-1 diagonal block D(k), where
128: *> 1 <= k <= N, the element E(k) is set to 0 in both
129: *> UPLO = 'U' or UPLO = 'L' cases.
130: *> \endverbatim
131: *>
132: *> \param[out] IPIV
133: *> \verbatim
134: *> IPIV is INTEGER array, dimension (N)
135: *> IPIV describes the permutation matrix P in the factorization
136: *> of matrix A as follows. The absolute value of IPIV(k)
137: *> represents the index of row and column that were
138: *> interchanged with the k-th row and column. The value of UPLO
139: *> describes the order in which the interchanges were applied.
140: *> Also, the sign of IPIV represents the block structure of
141: *> the symmetric block diagonal matrix D with 1-by-1 or 2-by-2
142: *> diagonal blocks which correspond to 1 or 2 interchanges
143: *> at each factorization step.
144: *>
145: *> If UPLO = 'U',
146: *> ( in factorization order, k decreases from N to 1 ):
147: *> a) A single positive entry IPIV(k) > 0 means:
148: *> D(k,k) is a 1-by-1 diagonal block.
149: *> If IPIV(k) != k, rows and columns k and IPIV(k) were
150: *> interchanged in the submatrix A(1:N,N-KB+1:N);
151: *> If IPIV(k) = k, no interchange occurred.
152: *>
153: *>
154: *> b) A pair of consecutive negative entries
155: *> IPIV(k) < 0 and IPIV(k-1) < 0 means:
156: *> D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
157: *> (NOTE: negative entries in IPIV appear ONLY in pairs).
158: *> 1) If -IPIV(k) != k, rows and columns
159: *> k and -IPIV(k) were interchanged
160: *> in the matrix A(1:N,N-KB+1:N).
161: *> If -IPIV(k) = k, no interchange occurred.
162: *> 2) If -IPIV(k-1) != k-1, rows and columns
163: *> k-1 and -IPIV(k-1) were interchanged
164: *> in the submatrix A(1:N,N-KB+1:N).
165: *> If -IPIV(k-1) = k-1, no interchange occurred.
166: *>
167: *> c) In both cases a) and b) is always ABS( IPIV(k) ) <= k.
168: *>
169: *> d) NOTE: Any entry IPIV(k) is always NONZERO on output.
170: *>
171: *> If UPLO = 'L',
172: *> ( in factorization order, k increases from 1 to N ):
173: *> a) A single positive entry IPIV(k) > 0 means:
174: *> D(k,k) is a 1-by-1 diagonal block.
175: *> If IPIV(k) != k, rows and columns k and IPIV(k) were
176: *> interchanged in the submatrix A(1:N,1:KB).
177: *> If IPIV(k) = k, no interchange occurred.
178: *>
179: *> b) A pair of consecutive negative entries
180: *> IPIV(k) < 0 and IPIV(k+1) < 0 means:
181: *> D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
182: *> (NOTE: negative entries in IPIV appear ONLY in pairs).
183: *> 1) If -IPIV(k) != k, rows and columns
184: *> k and -IPIV(k) were interchanged
185: *> in the submatrix A(1:N,1:KB).
186: *> If -IPIV(k) = k, no interchange occurred.
187: *> 2) If -IPIV(k+1) != k+1, rows and columns
188: *> k-1 and -IPIV(k-1) were interchanged
189: *> in the submatrix A(1:N,1:KB).
190: *> If -IPIV(k+1) = k+1, no interchange occurred.
191: *>
192: *> c) In both cases a) and b) is always ABS( IPIV(k) ) >= k.
193: *>
194: *> d) NOTE: Any entry IPIV(k) is always NONZERO on output.
195: *> \endverbatim
196: *>
197: *> \param[out] W
198: *> \verbatim
199: *> W is COMPLEX*16 array, dimension (LDW,NB)
200: *> \endverbatim
201: *>
202: *> \param[in] LDW
203: *> \verbatim
204: *> LDW is INTEGER
205: *> The leading dimension of the array W. LDW >= max(1,N).
206: *> \endverbatim
207: *>
208: *> \param[out] INFO
209: *> \verbatim
210: *> INFO is INTEGER
211: *> = 0: successful exit
212: *>
213: *> < 0: If INFO = -k, the k-th argument had an illegal value
214: *>
215: *> > 0: If INFO = k, the matrix A is singular, because:
216: *> If UPLO = 'U': column k in the upper
217: *> triangular part of A contains all zeros.
218: *> If UPLO = 'L': column k in the lower
219: *> triangular part of A contains all zeros.
220: *>
221: *> Therefore D(k,k) is exactly zero, and superdiagonal
222: *> elements of column k of U (or subdiagonal elements of
223: *> column k of L ) are all zeros. The factorization has
224: *> been completed, but the block diagonal matrix D is
225: *> exactly singular, and division by zero will occur if
226: *> it is used to solve a system of equations.
227: *>
228: *> NOTE: INFO only stores the first occurrence of
229: *> a singularity, any subsequent occurrence of singularity
230: *> is not stored in INFO even though the factorization
231: *> always completes.
232: *> \endverbatim
233: *
234: * Authors:
235: * ========
236: *
237: *> \author Univ. of Tennessee
238: *> \author Univ. of California Berkeley
239: *> \author Univ. of Colorado Denver
240: *> \author NAG Ltd.
241: *
242: *> \ingroup complex16SYcomputational
243: *
244: *> \par Contributors:
245: * ==================
246: *>
247: *> \verbatim
248: *>
249: *> December 2016, Igor Kozachenko,
250: *> Computer Science Division,
251: *> University of California, Berkeley
252: *>
253: *> September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
254: *> School of Mathematics,
255: *> University of Manchester
256: *>
257: *> \endverbatim
258: *
259: * =====================================================================
260: SUBROUTINE ZLASYF_RK( UPLO, N, NB, KB, A, LDA, E, IPIV, W, LDW,
261: $ INFO )
262: *
263: * -- LAPACK computational routine --
264: * -- LAPACK is a software package provided by Univ. of Tennessee, --
265: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
266: *
267: * .. Scalar Arguments ..
268: CHARACTER UPLO
269: INTEGER INFO, KB, LDA, LDW, N, NB
270: * ..
271: * .. Array Arguments ..
272: INTEGER IPIV( * )
273: COMPLEX*16 A( LDA, * ), E( * ), W( LDW, * )
274: * ..
275: *
276: * =====================================================================
277: *
278: * .. Parameters ..
279: DOUBLE PRECISION ZERO, ONE
280: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
281: DOUBLE PRECISION EIGHT, SEVTEN
282: PARAMETER ( EIGHT = 8.0D+0, SEVTEN = 17.0D+0 )
283: COMPLEX*16 CONE, CZERO
284: PARAMETER ( CONE = ( 1.0D+0, 0.0D+0 ),
285: $ CZERO = ( 0.0D+0, 0.0D+0 ) )
286: * ..
287: * .. Local Scalars ..
288: LOGICAL DONE
289: INTEGER IMAX, ITEMP, J, JB, JJ, JMAX, K, KK, KW, KKW,
290: $ KP, KSTEP, P, II
291: DOUBLE PRECISION ABSAKK, ALPHA, COLMAX, ROWMAX, SFMIN, DTEMP
292: COMPLEX*16 D11, D12, D21, D22, R1, T, Z
293: * ..
294: * .. External Functions ..
295: LOGICAL LSAME
296: INTEGER IZAMAX
297: DOUBLE PRECISION DLAMCH
298: EXTERNAL LSAME, IZAMAX, DLAMCH
299: * ..
300: * .. External Subroutines ..
301: EXTERNAL ZCOPY, ZGEMM, ZGEMV, ZSCAL, ZSWAP
302: * ..
303: * .. Intrinsic Functions ..
304: INTRINSIC ABS, DBLE, DIMAG, MAX, MIN, SQRT
305: * ..
306: * .. Statement Functions ..
307: DOUBLE PRECISION CABS1
308: * ..
309: * .. Statement Function definitions ..
310: CABS1( Z ) = ABS( DBLE( Z ) ) + ABS( DIMAG( Z ) )
311: * ..
312: * .. Executable Statements ..
313: *
314: INFO = 0
315: *
316: * Initialize ALPHA for use in choosing pivot block size.
317: *
318: ALPHA = ( ONE+SQRT( SEVTEN ) ) / EIGHT
319: *
320: * Compute machine safe minimum
321: *
322: SFMIN = DLAMCH( 'S' )
323: *
324: IF( LSAME( UPLO, 'U' ) ) THEN
325: *
326: * Factorize the trailing columns of A using the upper triangle
327: * of A and working backwards, and compute the matrix W = U12*D
328: * for use in updating A11
329: *
330: * Initialize the first entry of array E, where superdiagonal
331: * elements of D are stored
332: *
333: E( 1 ) = CZERO
334: *
335: * K is the main loop index, decreasing from N in steps of 1 or 2
336: *
337: K = N
338: 10 CONTINUE
339: *
340: * KW is the column of W which corresponds to column K of A
341: *
342: KW = NB + K - N
343: *
344: * Exit from loop
345: *
346: IF( ( K.LE.N-NB+1 .AND. NB.LT.N ) .OR. K.LT.1 )
347: $ GO TO 30
348: *
349: KSTEP = 1
350: P = K
351: *
352: * Copy column K of A to column KW of W and update it
353: *
354: CALL ZCOPY( K, A( 1, K ), 1, W( 1, KW ), 1 )
355: IF( K.LT.N )
356: $ CALL ZGEMV( 'No transpose', K, N-K, -CONE, A( 1, K+1 ),
357: $ LDA, W( K, KW+1 ), LDW, CONE, W( 1, KW ), 1 )
358: *
359: * Determine rows and columns to be interchanged and whether
360: * a 1-by-1 or 2-by-2 pivot block will be used
361: *
362: ABSAKK = CABS1( W( K, KW ) )
363: *
364: * IMAX is the row-index of the largest off-diagonal element in
365: * column K, and COLMAX is its absolute value.
366: * Determine both COLMAX and IMAX.
367: *
368: IF( K.GT.1 ) THEN
369: IMAX = IZAMAX( K-1, W( 1, KW ), 1 )
370: COLMAX = CABS1( W( IMAX, KW ) )
371: ELSE
372: COLMAX = ZERO
373: END IF
374: *
375: IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
376: *
377: * Column K is zero or underflow: set INFO and continue
378: *
379: IF( INFO.EQ.0 )
380: $ INFO = K
381: KP = K
382: CALL ZCOPY( K, W( 1, KW ), 1, A( 1, K ), 1 )
383: *
384: * Set E( K ) to zero
385: *
386: IF( K.GT.1 )
387: $ E( K ) = CZERO
388: *
389: ELSE
390: *
391: * ============================================================
392: *
393: * Test for interchange
394: *
395: * Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
396: * (used to handle NaN and Inf)
397: *
398: IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
399: *
400: * no interchange, use 1-by-1 pivot block
401: *
402: KP = K
403: *
404: ELSE
405: *
406: DONE = .FALSE.
407: *
408: * Loop until pivot found
409: *
410: 12 CONTINUE
411: *
412: * Begin pivot search loop body
413: *
414: *
415: * Copy column IMAX to column KW-1 of W and update it
416: *
417: CALL ZCOPY( IMAX, A( 1, IMAX ), 1, W( 1, KW-1 ), 1 )
418: CALL ZCOPY( K-IMAX, A( IMAX, IMAX+1 ), LDA,
419: $ W( IMAX+1, KW-1 ), 1 )
420: *
421: IF( K.LT.N )
422: $ CALL ZGEMV( 'No transpose', K, N-K, -CONE,
423: $ A( 1, K+1 ), LDA, W( IMAX, KW+1 ), LDW,
424: $ CONE, W( 1, KW-1 ), 1 )
425: *
426: * JMAX is the column-index of the largest off-diagonal
427: * element in row IMAX, and ROWMAX is its absolute value.
428: * Determine both ROWMAX and JMAX.
429: *
430: IF( IMAX.NE.K ) THEN
431: JMAX = IMAX + IZAMAX( K-IMAX, W( IMAX+1, KW-1 ),
432: $ 1 )
433: ROWMAX = CABS1( W( JMAX, KW-1 ) )
434: ELSE
435: ROWMAX = ZERO
436: END IF
437: *
438: IF( IMAX.GT.1 ) THEN
439: ITEMP = IZAMAX( IMAX-1, W( 1, KW-1 ), 1 )
440: DTEMP = CABS1( W( ITEMP, KW-1 ) )
441: IF( DTEMP.GT.ROWMAX ) THEN
442: ROWMAX = DTEMP
443: JMAX = ITEMP
444: END IF
445: END IF
446: *
447: * Equivalent to testing for
448: * CABS1( W( IMAX, KW-1 ) ).GE.ALPHA*ROWMAX
449: * (used to handle NaN and Inf)
450: *
451: IF( .NOT.(CABS1( W( IMAX, KW-1 ) ).LT.ALPHA*ROWMAX ) )
452: $ THEN
453: *
454: * interchange rows and columns K and IMAX,
455: * use 1-by-1 pivot block
456: *
457: KP = IMAX
458: *
459: * copy column KW-1 of W to column KW of W
460: *
461: CALL ZCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
462: *
463: DONE = .TRUE.
464: *
465: * Equivalent to testing for ROWMAX.EQ.COLMAX,
466: * (used to handle NaN and Inf)
467: *
468: ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
469: $ THEN
470: *
471: * interchange rows and columns K-1 and IMAX,
472: * use 2-by-2 pivot block
473: *
474: KP = IMAX
475: KSTEP = 2
476: DONE = .TRUE.
477: ELSE
478: *
479: * Pivot not found: set params and repeat
480: *
481: P = IMAX
482: COLMAX = ROWMAX
483: IMAX = JMAX
484: *
485: * Copy updated JMAXth (next IMAXth) column to Kth of W
486: *
487: CALL ZCOPY( K, W( 1, KW-1 ), 1, W( 1, KW ), 1 )
488: *
489: END IF
490: *
491: * End pivot search loop body
492: *
493: IF( .NOT. DONE ) GOTO 12
494: *
495: END IF
496: *
497: * ============================================================
498: *
499: KK = K - KSTEP + 1
500: *
501: * KKW is the column of W which corresponds to column KK of A
502: *
503: KKW = NB + KK - N
504: *
505: IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
506: *
507: * Copy non-updated column K to column P
508: *
509: CALL ZCOPY( K-P, A( P+1, K ), 1, A( P, P+1 ), LDA )
510: CALL ZCOPY( P, A( 1, K ), 1, A( 1, P ), 1 )
511: *
512: * Interchange rows K and P in last N-K+1 columns of A
513: * and last N-K+2 columns of W
514: *
515: CALL ZSWAP( N-K+1, A( K, K ), LDA, A( P, K ), LDA )
516: CALL ZSWAP( N-KK+1, W( K, KKW ), LDW, W( P, KKW ), LDW )
517: END IF
518: *
519: * Updated column KP is already stored in column KKW of W
520: *
521: IF( KP.NE.KK ) THEN
522: *
523: * Copy non-updated column KK to column KP
524: *
525: A( KP, K ) = A( KK, K )
526: CALL ZCOPY( K-1-KP, A( KP+1, KK ), 1, A( KP, KP+1 ),
527: $ LDA )
528: CALL ZCOPY( KP, A( 1, KK ), 1, A( 1, KP ), 1 )
529: *
530: * Interchange rows KK and KP in last N-KK+1 columns
531: * of A and W
532: *
533: CALL ZSWAP( N-KK+1, A( KK, KK ), LDA, A( KP, KK ), LDA )
534: CALL ZSWAP( N-KK+1, W( KK, KKW ), LDW, W( KP, KKW ),
535: $ LDW )
536: END IF
537: *
538: IF( KSTEP.EQ.1 ) THEN
539: *
540: * 1-by-1 pivot block D(k): column KW of W now holds
541: *
542: * W(k) = U(k)*D(k)
543: *
544: * where U(k) is the k-th column of U
545: *
546: * Store U(k) in column k of A
547: *
548: CALL ZCOPY( K, W( 1, KW ), 1, A( 1, K ), 1 )
549: IF( K.GT.1 ) THEN
550: IF( CABS1( A( K, K ) ).GE.SFMIN ) THEN
551: R1 = CONE / A( K, K )
552: CALL ZSCAL( K-1, R1, A( 1, K ), 1 )
553: ELSE IF( A( K, K ).NE.CZERO ) THEN
554: DO 14 II = 1, K - 1
555: A( II, K ) = A( II, K ) / A( K, K )
556: 14 CONTINUE
557: END IF
558: *
559: * Store the superdiagonal element of D in array E
560: *
561: E( K ) = CZERO
562: *
563: END IF
564: *
565: ELSE
566: *
567: * 2-by-2 pivot block D(k): columns KW and KW-1 of W now
568: * hold
569: *
570: * ( W(k-1) W(k) ) = ( U(k-1) U(k) )*D(k)
571: *
572: * where U(k) and U(k-1) are the k-th and (k-1)-th columns
573: * of U
574: *
575: IF( K.GT.2 ) THEN
576: *
577: * Store U(k) and U(k-1) in columns k and k-1 of A
578: *
579: D12 = W( K-1, KW )
580: D11 = W( K, KW ) / D12
581: D22 = W( K-1, KW-1 ) / D12
582: T = CONE / ( D11*D22-CONE )
583: DO 20 J = 1, K - 2
584: A( J, K-1 ) = T*( (D11*W( J, KW-1 )-W( J, KW ) ) /
585: $ D12 )
586: A( J, K ) = T*( ( D22*W( J, KW )-W( J, KW-1 ) ) /
587: $ D12 )
588: 20 CONTINUE
589: END IF
590: *
591: * Copy diagonal elements of D(K) to A,
592: * copy superdiagonal element of D(K) to E(K) and
593: * ZERO out superdiagonal entry of A
594: *
595: A( K-1, K-1 ) = W( K-1, KW-1 )
596: A( K-1, K ) = CZERO
597: A( K, K ) = W( K, KW )
598: E( K ) = W( K-1, KW )
599: E( K-1 ) = CZERO
600: *
601: END IF
602: *
603: * End column K is nonsingular
604: *
605: END IF
606: *
607: * Store details of the interchanges in IPIV
608: *
609: IF( KSTEP.EQ.1 ) THEN
610: IPIV( K ) = KP
611: ELSE
612: IPIV( K ) = -P
613: IPIV( K-1 ) = -KP
614: END IF
615: *
616: * Decrease K and return to the start of the main loop
617: *
618: K = K - KSTEP
619: GO TO 10
620: *
621: 30 CONTINUE
622: *
623: * Update the upper triangle of A11 (= A(1:k,1:k)) as
624: *
625: * A11 := A11 - U12*D*U12**T = A11 - U12*W**T
626: *
627: * computing blocks of NB columns at a time
628: *
629: DO 50 J = ( ( K-1 ) / NB )*NB + 1, 1, -NB
630: JB = MIN( NB, K-J+1 )
631: *
632: * Update the upper triangle of the diagonal block
633: *
634: DO 40 JJ = J, J + JB - 1
635: CALL ZGEMV( 'No transpose', JJ-J+1, N-K, -CONE,
636: $ A( J, K+1 ), LDA, W( JJ, KW+1 ), LDW, CONE,
637: $ A( J, JJ ), 1 )
638: 40 CONTINUE
639: *
640: * Update the rectangular superdiagonal block
641: *
642: IF( J.GE.2 )
643: $ CALL ZGEMM( 'No transpose', 'Transpose', J-1, JB,
644: $ N-K, -CONE, A( 1, K+1 ), LDA, W( J, KW+1 ),
645: $ LDW, CONE, A( 1, J ), LDA )
646: 50 CONTINUE
647: *
648: * Set KB to the number of columns factorized
649: *
650: KB = N - K
651: *
652: ELSE
653: *
654: * Factorize the leading columns of A using the lower triangle
655: * of A and working forwards, and compute the matrix W = L21*D
656: * for use in updating A22
657: *
658: * Initialize the unused last entry of the subdiagonal array E.
659: *
660: E( N ) = CZERO
661: *
662: * K is the main loop index, increasing from 1 in steps of 1 or 2
663: *
664: K = 1
665: 70 CONTINUE
666: *
667: * Exit from loop
668: *
669: IF( ( K.GE.NB .AND. NB.LT.N ) .OR. K.GT.N )
670: $ GO TO 90
671: *
672: KSTEP = 1
673: P = K
674: *
675: * Copy column K of A to column K of W and update it
676: *
677: CALL ZCOPY( N-K+1, A( K, K ), 1, W( K, K ), 1 )
678: IF( K.GT.1 )
679: $ CALL ZGEMV( 'No transpose', N-K+1, K-1, -CONE, A( K, 1 ),
680: $ LDA, W( K, 1 ), LDW, CONE, W( K, K ), 1 )
681: *
682: * Determine rows and columns to be interchanged and whether
683: * a 1-by-1 or 2-by-2 pivot block will be used
684: *
685: ABSAKK = CABS1( W( K, K ) )
686: *
687: * IMAX is the row-index of the largest off-diagonal element in
688: * column K, and COLMAX is its absolute value.
689: * Determine both COLMAX and IMAX.
690: *
691: IF( K.LT.N ) THEN
692: IMAX = K + IZAMAX( N-K, W( K+1, K ), 1 )
693: COLMAX = CABS1( W( IMAX, K ) )
694: ELSE
695: COLMAX = ZERO
696: END IF
697: *
698: IF( MAX( ABSAKK, COLMAX ).EQ.ZERO ) THEN
699: *
700: * Column K is zero or underflow: set INFO and continue
701: *
702: IF( INFO.EQ.0 )
703: $ INFO = K
704: KP = K
705: CALL ZCOPY( N-K+1, W( K, K ), 1, A( K, K ), 1 )
706: *
707: * Set E( K ) to zero
708: *
709: IF( K.LT.N )
710: $ E( K ) = CZERO
711: *
712: ELSE
713: *
714: * ============================================================
715: *
716: * Test for interchange
717: *
718: * Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
719: * (used to handle NaN and Inf)
720: *
721: IF( .NOT.( ABSAKK.LT.ALPHA*COLMAX ) ) THEN
722: *
723: * no interchange, use 1-by-1 pivot block
724: *
725: KP = K
726: *
727: ELSE
728: *
729: DONE = .FALSE.
730: *
731: * Loop until pivot found
732: *
733: 72 CONTINUE
734: *
735: * Begin pivot search loop body
736: *
737: *
738: * Copy column IMAX to column K+1 of W and update it
739: *
740: CALL ZCOPY( IMAX-K, A( IMAX, K ), LDA, W( K, K+1 ), 1)
741: CALL ZCOPY( N-IMAX+1, A( IMAX, IMAX ), 1,
742: $ W( IMAX, K+1 ), 1 )
743: IF( K.GT.1 )
744: $ CALL ZGEMV( 'No transpose', N-K+1, K-1, -CONE,
745: $ A( K, 1 ), LDA, W( IMAX, 1 ), LDW,
746: $ CONE, W( K, K+1 ), 1 )
747: *
748: * JMAX is the column-index of the largest off-diagonal
749: * element in row IMAX, and ROWMAX is its absolute value.
750: * Determine both ROWMAX and JMAX.
751: *
752: IF( IMAX.NE.K ) THEN
753: JMAX = K - 1 + IZAMAX( IMAX-K, W( K, K+1 ), 1 )
754: ROWMAX = CABS1( W( JMAX, K+1 ) )
755: ELSE
756: ROWMAX = ZERO
757: END IF
758: *
759: IF( IMAX.LT.N ) THEN
760: ITEMP = IMAX + IZAMAX( N-IMAX, W( IMAX+1, K+1 ), 1)
761: DTEMP = CABS1( W( ITEMP, K+1 ) )
762: IF( DTEMP.GT.ROWMAX ) THEN
763: ROWMAX = DTEMP
764: JMAX = ITEMP
765: END IF
766: END IF
767: *
768: * Equivalent to testing for
769: * CABS1( W( IMAX, K+1 ) ).GE.ALPHA*ROWMAX
770: * (used to handle NaN and Inf)
771: *
772: IF( .NOT.( CABS1( W( IMAX, K+1 ) ).LT.ALPHA*ROWMAX ) )
773: $ THEN
774: *
775: * interchange rows and columns K and IMAX,
776: * use 1-by-1 pivot block
777: *
778: KP = IMAX
779: *
780: * copy column K+1 of W to column K of W
781: *
782: CALL ZCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
783: *
784: DONE = .TRUE.
785: *
786: * Equivalent to testing for ROWMAX.EQ.COLMAX,
787: * (used to handle NaN and Inf)
788: *
789: ELSE IF( ( P.EQ.JMAX ) .OR. ( ROWMAX.LE.COLMAX ) )
790: $ THEN
791: *
792: * interchange rows and columns K+1 and IMAX,
793: * use 2-by-2 pivot block
794: *
795: KP = IMAX
796: KSTEP = 2
797: DONE = .TRUE.
798: ELSE
799: *
800: * Pivot not found: set params and repeat
801: *
802: P = IMAX
803: COLMAX = ROWMAX
804: IMAX = JMAX
805: *
806: * Copy updated JMAXth (next IMAXth) column to Kth of W
807: *
808: CALL ZCOPY( N-K+1, W( K, K+1 ), 1, W( K, K ), 1 )
809: *
810: END IF
811: *
812: * End pivot search loop body
813: *
814: IF( .NOT. DONE ) GOTO 72
815: *
816: END IF
817: *
818: * ============================================================
819: *
820: KK = K + KSTEP - 1
821: *
822: IF( ( KSTEP.EQ.2 ) .AND. ( P.NE.K ) ) THEN
823: *
824: * Copy non-updated column K to column P
825: *
826: CALL ZCOPY( P-K, A( K, K ), 1, A( P, K ), LDA )
827: CALL ZCOPY( N-P+1, A( P, K ), 1, A( P, P ), 1 )
828: *
829: * Interchange rows K and P in first K columns of A
830: * and first K+1 columns of W
831: *
832: CALL ZSWAP( K, A( K, 1 ), LDA, A( P, 1 ), LDA )
833: CALL ZSWAP( KK, W( K, 1 ), LDW, W( P, 1 ), LDW )
834: END IF
835: *
836: * Updated column KP is already stored in column KK of W
837: *
838: IF( KP.NE.KK ) THEN
839: *
840: * Copy non-updated column KK to column KP
841: *
842: A( KP, K ) = A( KK, K )
843: CALL ZCOPY( KP-K-1, A( K+1, KK ), 1, A( KP, K+1 ), LDA )
844: CALL ZCOPY( N-KP+1, A( KP, KK ), 1, A( KP, KP ), 1 )
845: *
846: * Interchange rows KK and KP in first KK columns of A and W
847: *
848: CALL ZSWAP( KK, A( KK, 1 ), LDA, A( KP, 1 ), LDA )
849: CALL ZSWAP( KK, W( KK, 1 ), LDW, W( KP, 1 ), LDW )
850: END IF
851: *
852: IF( KSTEP.EQ.1 ) THEN
853: *
854: * 1-by-1 pivot block D(k): column k of W now holds
855: *
856: * W(k) = L(k)*D(k)
857: *
858: * where L(k) is the k-th column of L
859: *
860: * Store L(k) in column k of A
861: *
862: CALL ZCOPY( N-K+1, W( K, K ), 1, A( K, K ), 1 )
863: IF( K.LT.N ) THEN
864: IF( CABS1( A( K, K ) ).GE.SFMIN ) THEN
865: R1 = CONE / A( K, K )
866: CALL ZSCAL( N-K, R1, A( K+1, K ), 1 )
867: ELSE IF( A( K, K ).NE.CZERO ) THEN
868: DO 74 II = K + 1, N
869: A( II, K ) = A( II, K ) / A( K, K )
870: 74 CONTINUE
871: END IF
872: *
873: * Store the subdiagonal element of D in array E
874: *
875: E( K ) = CZERO
876: *
877: END IF
878: *
879: ELSE
880: *
881: * 2-by-2 pivot block D(k): columns k and k+1 of W now hold
882: *
883: * ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
884: *
885: * where L(k) and L(k+1) are the k-th and (k+1)-th columns
886: * of L
887: *
888: IF( K.LT.N-1 ) THEN
889: *
890: * Store L(k) and L(k+1) in columns k and k+1 of A
891: *
892: D21 = W( K+1, K )
893: D11 = W( K+1, K+1 ) / D21
894: D22 = W( K, K ) / D21
895: T = CONE / ( D11*D22-CONE )
896: DO 80 J = K + 2, N
897: A( J, K ) = T*( ( D11*W( J, K )-W( J, K+1 ) ) /
898: $ D21 )
899: A( J, K+1 ) = T*( ( D22*W( J, K+1 )-W( J, K ) ) /
900: $ D21 )
901: 80 CONTINUE
902: END IF
903: *
904: * Copy diagonal elements of D(K) to A,
905: * copy subdiagonal element of D(K) to E(K) and
906: * ZERO out subdiagonal entry of A
907: *
908: A( K, K ) = W( K, K )
909: A( K+1, K ) = CZERO
910: A( K+1, K+1 ) = W( K+1, K+1 )
911: E( K ) = W( K+1, K )
912: E( K+1 ) = CZERO
913: *
914: END IF
915: *
916: * End column K is nonsingular
917: *
918: END IF
919: *
920: * Store details of the interchanges in IPIV
921: *
922: IF( KSTEP.EQ.1 ) THEN
923: IPIV( K ) = KP
924: ELSE
925: IPIV( K ) = -P
926: IPIV( K+1 ) = -KP
927: END IF
928: *
929: * Increase K and return to the start of the main loop
930: *
931: K = K + KSTEP
932: GO TO 70
933: *
934: 90 CONTINUE
935: *
936: * Update the lower triangle of A22 (= A(k:n,k:n)) as
937: *
938: * A22 := A22 - L21*D*L21**T = A22 - L21*W**T
939: *
940: * computing blocks of NB columns at a time
941: *
942: DO 110 J = K, N, NB
943: JB = MIN( NB, N-J+1 )
944: *
945: * Update the lower triangle of the diagonal block
946: *
947: DO 100 JJ = J, J + JB - 1
948: CALL ZGEMV( 'No transpose', J+JB-JJ, K-1, -CONE,
949: $ A( JJ, 1 ), LDA, W( JJ, 1 ), LDW, CONE,
950: $ A( JJ, JJ ), 1 )
951: 100 CONTINUE
952: *
953: * Update the rectangular subdiagonal block
954: *
955: IF( J+JB.LE.N )
956: $ CALL ZGEMM( 'No transpose', 'Transpose', N-J-JB+1, JB,
957: $ K-1, -CONE, A( J+JB, 1 ), LDA, W( J, 1 ),
958: $ LDW, CONE, A( J+JB, J ), LDA )
959: 110 CONTINUE
960: *
961: * Set KB to the number of columns factorized
962: *
963: KB = K - 1
964: *
965: END IF
966: *
967: RETURN
968: *
969: * End of ZLASYF_RK
970: *
971: END
CVSweb interface <joel.bertrand@systella.fr>