1: *> \brief \b ZLARFGP
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLARFGP + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlarfgp.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlarfgp.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlarfgp.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLARFGP( N, ALPHA, X, INCX, TAU )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INCX, N
25: * COMPLEX*16 ALPHA, TAU
26: * ..
27: * .. Array Arguments ..
28: * COMPLEX*16 X( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZLARFGP generates a complex elementary reflector H of order n, such
38: *> that
39: *>
40: *> H**H * ( alpha ) = ( beta ), H**H * H = I.
41: *> ( x ) ( 0 )
42: *>
43: *> where alpha and beta are scalars, beta is real and non-negative, and
44: *> x is an (n-1)-element complex vector. H is represented in the form
45: *>
46: *> H = I - tau * ( 1 ) * ( 1 v**H ) ,
47: *> ( v )
48: *>
49: *> where tau is a complex scalar and v is a complex (n-1)-element
50: *> vector. Note that H is not hermitian.
51: *>
52: *> If the elements of x are all zero and alpha is real, then tau = 0
53: *> and H is taken to be the unit matrix.
54: *> \endverbatim
55: *
56: * Arguments:
57: * ==========
58: *
59: *> \param[in] N
60: *> \verbatim
61: *> N is INTEGER
62: *> The order of the elementary reflector.
63: *> \endverbatim
64: *>
65: *> \param[in,out] ALPHA
66: *> \verbatim
67: *> ALPHA is COMPLEX*16
68: *> On entry, the value alpha.
69: *> On exit, it is overwritten with the value beta.
70: *> \endverbatim
71: *>
72: *> \param[in,out] X
73: *> \verbatim
74: *> X is COMPLEX*16 array, dimension
75: *> (1+(N-2)*abs(INCX))
76: *> On entry, the vector x.
77: *> On exit, it is overwritten with the vector v.
78: *> \endverbatim
79: *>
80: *> \param[in] INCX
81: *> \verbatim
82: *> INCX is INTEGER
83: *> The increment between elements of X. INCX > 0.
84: *> \endverbatim
85: *>
86: *> \param[out] TAU
87: *> \verbatim
88: *> TAU is COMPLEX*16
89: *> The value tau.
90: *> \endverbatim
91: *
92: * Authors:
93: * ========
94: *
95: *> \author Univ. of Tennessee
96: *> \author Univ. of California Berkeley
97: *> \author Univ. of Colorado Denver
98: *> \author NAG Ltd.
99: *
100: *> \date November 2011
101: *
102: *> \ingroup complex16OTHERauxiliary
103: *
104: * =====================================================================
105: SUBROUTINE ZLARFGP( N, ALPHA, X, INCX, TAU )
106: *
107: * -- LAPACK auxiliary routine (version 3.4.0) --
108: * -- LAPACK is a software package provided by Univ. of Tennessee, --
109: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
110: * November 2011
111: *
112: * .. Scalar Arguments ..
113: INTEGER INCX, N
114: COMPLEX*16 ALPHA, TAU
115: * ..
116: * .. Array Arguments ..
117: COMPLEX*16 X( * )
118: * ..
119: *
120: * =====================================================================
121: *
122: * .. Parameters ..
123: DOUBLE PRECISION TWO, ONE, ZERO
124: PARAMETER ( TWO = 2.0D+0, ONE = 1.0D+0, ZERO = 0.0D+0 )
125: * ..
126: * .. Local Scalars ..
127: INTEGER J, KNT
128: DOUBLE PRECISION ALPHI, ALPHR, BETA, BIGNUM, SMLNUM, XNORM
129: COMPLEX*16 SAVEALPHA
130: * ..
131: * .. External Functions ..
132: DOUBLE PRECISION DLAMCH, DLAPY3, DLAPY2, DZNRM2
133: COMPLEX*16 ZLADIV
134: EXTERNAL DLAMCH, DLAPY3, DLAPY2, DZNRM2, ZLADIV
135: * ..
136: * .. Intrinsic Functions ..
137: INTRINSIC ABS, DBLE, DCMPLX, DIMAG, SIGN
138: * ..
139: * .. External Subroutines ..
140: EXTERNAL ZDSCAL, ZSCAL
141: * ..
142: * .. Executable Statements ..
143: *
144: IF( N.LE.0 ) THEN
145: TAU = ZERO
146: RETURN
147: END IF
148: *
149: XNORM = DZNRM2( N-1, X, INCX )
150: ALPHR = DBLE( ALPHA )
151: ALPHI = DIMAG( ALPHA )
152: *
153: IF( XNORM.EQ.ZERO ) THEN
154: *
155: * H = [1-alpha/abs(alpha) 0; 0 I], sign chosen so ALPHA >= 0.
156: *
157: IF( ALPHI.EQ.ZERO ) THEN
158: IF( ALPHR.GE.ZERO ) THEN
159: * When TAU.eq.ZERO, the vector is special-cased to be
160: * all zeros in the application routines. We do not need
161: * to clear it.
162: TAU = ZERO
163: ELSE
164: * However, the application routines rely on explicit
165: * zero checks when TAU.ne.ZERO, and we must clear X.
166: TAU = TWO
167: DO J = 1, N-1
168: X( 1 + (J-1)*INCX ) = ZERO
169: END DO
170: ALPHA = -ALPHA
171: END IF
172: ELSE
173: * Only "reflecting" the diagonal entry to be real and non-negative.
174: XNORM = DLAPY2( ALPHR, ALPHI )
175: TAU = DCMPLX( ONE - ALPHR / XNORM, -ALPHI / XNORM )
176: DO J = 1, N-1
177: X( 1 + (J-1)*INCX ) = ZERO
178: END DO
179: ALPHA = XNORM
180: END IF
181: ELSE
182: *
183: * general case
184: *
185: BETA = SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
186: SMLNUM = DLAMCH( 'S' ) / DLAMCH( 'E' )
187: BIGNUM = ONE / SMLNUM
188: *
189: KNT = 0
190: IF( ABS( BETA ).LT.SMLNUM ) THEN
191: *
192: * XNORM, BETA may be inaccurate; scale X and recompute them
193: *
194: 10 CONTINUE
195: KNT = KNT + 1
196: CALL ZDSCAL( N-1, BIGNUM, X, INCX )
197: BETA = BETA*BIGNUM
198: ALPHI = ALPHI*BIGNUM
199: ALPHR = ALPHR*BIGNUM
200: IF( ABS( BETA ).LT.SMLNUM )
201: $ GO TO 10
202: *
203: * New BETA is at most 1, at least SMLNUM
204: *
205: XNORM = DZNRM2( N-1, X, INCX )
206: ALPHA = DCMPLX( ALPHR, ALPHI )
207: BETA = SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
208: END IF
209: SAVEALPHA = ALPHA
210: ALPHA = ALPHA + BETA
211: IF( BETA.LT.ZERO ) THEN
212: BETA = -BETA
213: TAU = -ALPHA / BETA
214: ELSE
215: ALPHR = ALPHI * (ALPHI/DBLE( ALPHA ))
216: ALPHR = ALPHR + XNORM * (XNORM/DBLE( ALPHA ))
217: TAU = DCMPLX( ALPHR/BETA, -ALPHI/BETA )
218: ALPHA = DCMPLX( -ALPHR, ALPHI )
219: END IF
220: ALPHA = ZLADIV( DCMPLX( ONE ), ALPHA )
221: *
222: IF ( ABS(TAU).LE.SMLNUM ) THEN
223: *
224: * In the case where the computed TAU ends up being a denormalized number,
225: * it loses relative accuracy. This is a BIG problem. Solution: flush TAU
226: * to ZERO (or TWO or whatever makes a nonnegative real number for BETA).
227: *
228: * (Bug report provided by Pat Quillen from MathWorks on Jul 29, 2009.)
229: * (Thanks Pat. Thanks MathWorks.)
230: *
231: ALPHR = DBLE( SAVEALPHA )
232: ALPHI = DIMAG( SAVEALPHA )
233: IF( ALPHI.EQ.ZERO ) THEN
234: IF( ALPHR.GE.ZERO ) THEN
235: TAU = ZERO
236: ELSE
237: TAU = TWO
238: DO J = 1, N-1
239: X( 1 + (J-1)*INCX ) = ZERO
240: END DO
241: BETA = -SAVEALPHA
242: END IF
243: ELSE
244: XNORM = DLAPY2( ALPHR, ALPHI )
245: TAU = DCMPLX( ONE - ALPHR / XNORM, -ALPHI / XNORM )
246: DO J = 1, N-1
247: X( 1 + (J-1)*INCX ) = ZERO
248: END DO
249: BETA = XNORM
250: END IF
251: *
252: ELSE
253: *
254: * This is the general case.
255: *
256: CALL ZSCAL( N-1, ALPHA, X, INCX )
257: *
258: END IF
259: *
260: * If BETA is subnormal, it may lose relative accuracy
261: *
262: DO 20 J = 1, KNT
263: BETA = BETA*SMLNUM
264: 20 CONTINUE
265: ALPHA = BETA
266: END IF
267: *
268: RETURN
269: *
270: * End of ZLARFGP
271: *
272: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlarfgp.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack