1: *> \brief \b ZLARFB applies a block reflector or its conjugate-transpose to a general rectangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLARFB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlarfb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlarfb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlarfb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLARFB( SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV,
22: * T, LDT, C, LDC, WORK, LDWORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIRECT, SIDE, STOREV, TRANS
26: * INTEGER K, LDC, LDT, LDV, LDWORK, M, N
27: * ..
28: * .. Array Arguments ..
29: * COMPLEX*16 C( LDC, * ), T( LDT, * ), V( LDV, * ),
30: * $ WORK( LDWORK, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLARFB applies a complex block reflector H or its transpose H**H to a
40: *> complex M-by-N matrix C, from either the left or the right.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] SIDE
47: *> \verbatim
48: *> SIDE is CHARACTER*1
49: *> = 'L': apply H or H**H from the Left
50: *> = 'R': apply H or H**H from the Right
51: *> \endverbatim
52: *>
53: *> \param[in] TRANS
54: *> \verbatim
55: *> TRANS is CHARACTER*1
56: *> = 'N': apply H (No transpose)
57: *> = 'C': apply H**H (Conjugate transpose)
58: *> \endverbatim
59: *>
60: *> \param[in] DIRECT
61: *> \verbatim
62: *> DIRECT is CHARACTER*1
63: *> Indicates how H is formed from a product of elementary
64: *> reflectors
65: *> = 'F': H = H(1) H(2) . . . H(k) (Forward)
66: *> = 'B': H = H(k) . . . H(2) H(1) (Backward)
67: *> \endverbatim
68: *>
69: *> \param[in] STOREV
70: *> \verbatim
71: *> STOREV is CHARACTER*1
72: *> Indicates how the vectors which define the elementary
73: *> reflectors are stored:
74: *> = 'C': Columnwise
75: *> = 'R': Rowwise
76: *> \endverbatim
77: *>
78: *> \param[in] M
79: *> \verbatim
80: *> M is INTEGER
81: *> The number of rows of the matrix C.
82: *> \endverbatim
83: *>
84: *> \param[in] N
85: *> \verbatim
86: *> N is INTEGER
87: *> The number of columns of the matrix C.
88: *> \endverbatim
89: *>
90: *> \param[in] K
91: *> \verbatim
92: *> K is INTEGER
93: *> The order of the matrix T (= the number of elementary
94: *> reflectors whose product defines the block reflector).
95: *> \endverbatim
96: *>
97: *> \param[in] V
98: *> \verbatim
99: *> V is COMPLEX*16 array, dimension
100: *> (LDV,K) if STOREV = 'C'
101: *> (LDV,M) if STOREV = 'R' and SIDE = 'L'
102: *> (LDV,N) if STOREV = 'R' and SIDE = 'R'
103: *> See Further Details.
104: *> \endverbatim
105: *>
106: *> \param[in] LDV
107: *> \verbatim
108: *> LDV is INTEGER
109: *> The leading dimension of the array V.
110: *> If STOREV = 'C' and SIDE = 'L', LDV >= max(1,M);
111: *> if STOREV = 'C' and SIDE = 'R', LDV >= max(1,N);
112: *> if STOREV = 'R', LDV >= K.
113: *> \endverbatim
114: *>
115: *> \param[in] T
116: *> \verbatim
117: *> T is COMPLEX*16 array, dimension (LDT,K)
118: *> The triangular K-by-K matrix T in the representation of the
119: *> block reflector.
120: *> \endverbatim
121: *>
122: *> \param[in] LDT
123: *> \verbatim
124: *> LDT is INTEGER
125: *> The leading dimension of the array T. LDT >= K.
126: *> \endverbatim
127: *>
128: *> \param[in,out] C
129: *> \verbatim
130: *> C is COMPLEX*16 array, dimension (LDC,N)
131: *> On entry, the M-by-N matrix C.
132: *> On exit, C is overwritten by H*C or H**H*C or C*H or C*H**H.
133: *> \endverbatim
134: *>
135: *> \param[in] LDC
136: *> \verbatim
137: *> LDC is INTEGER
138: *> The leading dimension of the array C. LDC >= max(1,M).
139: *> \endverbatim
140: *>
141: *> \param[out] WORK
142: *> \verbatim
143: *> WORK is COMPLEX*16 array, dimension (LDWORK,K)
144: *> \endverbatim
145: *>
146: *> \param[in] LDWORK
147: *> \verbatim
148: *> LDWORK is INTEGER
149: *> The leading dimension of the array WORK.
150: *> If SIDE = 'L', LDWORK >= max(1,N);
151: *> if SIDE = 'R', LDWORK >= max(1,M).
152: *> \endverbatim
153: *
154: * Authors:
155: * ========
156: *
157: *> \author Univ. of Tennessee
158: *> \author Univ. of California Berkeley
159: *> \author Univ. of Colorado Denver
160: *> \author NAG Ltd.
161: *
162: *> \date September 2012
163: *
164: *> \ingroup complex16OTHERauxiliary
165: *
166: *> \par Further Details:
167: * =====================
168: *>
169: *> \verbatim
170: *>
171: *> The shape of the matrix V and the storage of the vectors which define
172: *> the H(i) is best illustrated by the following example with n = 5 and
173: *> k = 3. The elements equal to 1 are not stored; the corresponding
174: *> array elements are modified but restored on exit. The rest of the
175: *> array is not used.
176: *>
177: *> DIRECT = 'F' and STOREV = 'C': DIRECT = 'F' and STOREV = 'R':
178: *>
179: *> V = ( 1 ) V = ( 1 v1 v1 v1 v1 )
180: *> ( v1 1 ) ( 1 v2 v2 v2 )
181: *> ( v1 v2 1 ) ( 1 v3 v3 )
182: *> ( v1 v2 v3 )
183: *> ( v1 v2 v3 )
184: *>
185: *> DIRECT = 'B' and STOREV = 'C': DIRECT = 'B' and STOREV = 'R':
186: *>
187: *> V = ( v1 v2 v3 ) V = ( v1 v1 1 )
188: *> ( v1 v2 v3 ) ( v2 v2 v2 1 )
189: *> ( 1 v2 v3 ) ( v3 v3 v3 v3 1 )
190: *> ( 1 v3 )
191: *> ( 1 )
192: *> \endverbatim
193: *>
194: * =====================================================================
195: SUBROUTINE ZLARFB( SIDE, TRANS, DIRECT, STOREV, M, N, K, V, LDV,
196: $ T, LDT, C, LDC, WORK, LDWORK )
197: *
198: * -- LAPACK auxiliary routine (version 3.4.2) --
199: * -- LAPACK is a software package provided by Univ. of Tennessee, --
200: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
201: * September 2012
202: *
203: * .. Scalar Arguments ..
204: CHARACTER DIRECT, SIDE, STOREV, TRANS
205: INTEGER K, LDC, LDT, LDV, LDWORK, M, N
206: * ..
207: * .. Array Arguments ..
208: COMPLEX*16 C( LDC, * ), T( LDT, * ), V( LDV, * ),
209: $ WORK( LDWORK, * )
210: * ..
211: *
212: * =====================================================================
213: *
214: * .. Parameters ..
215: COMPLEX*16 ONE
216: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
217: * ..
218: * .. Local Scalars ..
219: CHARACTER TRANST
220: INTEGER I, J, LASTV, LASTC
221: * ..
222: * .. External Functions ..
223: LOGICAL LSAME
224: INTEGER ILAZLR, ILAZLC
225: EXTERNAL LSAME, ILAZLR, ILAZLC
226: * ..
227: * .. External Subroutines ..
228: EXTERNAL ZCOPY, ZGEMM, ZLACGV, ZTRMM
229: * ..
230: * .. Intrinsic Functions ..
231: INTRINSIC DCONJG
232: * ..
233: * .. Executable Statements ..
234: *
235: * Quick return if possible
236: *
237: IF( M.LE.0 .OR. N.LE.0 )
238: $ RETURN
239: *
240: IF( LSAME( TRANS, 'N' ) ) THEN
241: TRANST = 'C'
242: ELSE
243: TRANST = 'N'
244: END IF
245: *
246: IF( LSAME( STOREV, 'C' ) ) THEN
247: *
248: IF( LSAME( DIRECT, 'F' ) ) THEN
249: *
250: * Let V = ( V1 ) (first K rows)
251: * ( V2 )
252: * where V1 is unit lower triangular.
253: *
254: IF( LSAME( SIDE, 'L' ) ) THEN
255: *
256: * Form H * C or H**H * C where C = ( C1 )
257: * ( C2 )
258: *
259: LASTV = MAX( K, ILAZLR( M, K, V, LDV ) )
260: LASTC = ILAZLC( LASTV, N, C, LDC )
261: *
262: * W := C**H * V = (C1**H * V1 + C2**H * V2) (stored in WORK)
263: *
264: * W := C1**H
265: *
266: DO 10 J = 1, K
267: CALL ZCOPY( LASTC, C( J, 1 ), LDC, WORK( 1, J ), 1 )
268: CALL ZLACGV( LASTC, WORK( 1, J ), 1 )
269: 10 CONTINUE
270: *
271: * W := W * V1
272: *
273: CALL ZTRMM( 'Right', 'Lower', 'No transpose', 'Unit',
274: $ LASTC, K, ONE, V, LDV, WORK, LDWORK )
275: IF( LASTV.GT.K ) THEN
276: *
277: * W := W + C2**H *V2
278: *
279: CALL ZGEMM( 'Conjugate transpose', 'No transpose',
280: $ LASTC, K, LASTV-K, ONE, C( K+1, 1 ), LDC,
281: $ V( K+1, 1 ), LDV, ONE, WORK, LDWORK )
282: END IF
283: *
284: * W := W * T**H or W * T
285: *
286: CALL ZTRMM( 'Right', 'Upper', TRANST, 'Non-unit',
287: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
288: *
289: * C := C - V * W**H
290: *
291: IF( M.GT.K ) THEN
292: *
293: * C2 := C2 - V2 * W**H
294: *
295: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
296: $ LASTV-K, LASTC, K,
297: $ -ONE, V( K+1, 1 ), LDV, WORK, LDWORK,
298: $ ONE, C( K+1, 1 ), LDC )
299: END IF
300: *
301: * W := W * V1**H
302: *
303: CALL ZTRMM( 'Right', 'Lower', 'Conjugate transpose',
304: $ 'Unit', LASTC, K, ONE, V, LDV, WORK, LDWORK )
305: *
306: * C1 := C1 - W**H
307: *
308: DO 30 J = 1, K
309: DO 20 I = 1, LASTC
310: C( J, I ) = C( J, I ) - DCONJG( WORK( I, J ) )
311: 20 CONTINUE
312: 30 CONTINUE
313: *
314: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
315: *
316: * Form C * H or C * H**H where C = ( C1 C2 )
317: *
318: LASTV = MAX( K, ILAZLR( N, K, V, LDV ) )
319: LASTC = ILAZLR( M, LASTV, C, LDC )
320: *
321: * W := C * V = (C1*V1 + C2*V2) (stored in WORK)
322: *
323: * W := C1
324: *
325: DO 40 J = 1, K
326: CALL ZCOPY( LASTC, C( 1, J ), 1, WORK( 1, J ), 1 )
327: 40 CONTINUE
328: *
329: * W := W * V1
330: *
331: CALL ZTRMM( 'Right', 'Lower', 'No transpose', 'Unit',
332: $ LASTC, K, ONE, V, LDV, WORK, LDWORK )
333: IF( LASTV.GT.K ) THEN
334: *
335: * W := W + C2 * V2
336: *
337: CALL ZGEMM( 'No transpose', 'No transpose',
338: $ LASTC, K, LASTV-K,
339: $ ONE, C( 1, K+1 ), LDC, V( K+1, 1 ), LDV,
340: $ ONE, WORK, LDWORK )
341: END IF
342: *
343: * W := W * T or W * T**H
344: *
345: CALL ZTRMM( 'Right', 'Upper', TRANS, 'Non-unit',
346: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
347: *
348: * C := C - W * V**H
349: *
350: IF( LASTV.GT.K ) THEN
351: *
352: * C2 := C2 - W * V2**H
353: *
354: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
355: $ LASTC, LASTV-K, K,
356: $ -ONE, WORK, LDWORK, V( K+1, 1 ), LDV,
357: $ ONE, C( 1, K+1 ), LDC )
358: END IF
359: *
360: * W := W * V1**H
361: *
362: CALL ZTRMM( 'Right', 'Lower', 'Conjugate transpose',
363: $ 'Unit', LASTC, K, ONE, V, LDV, WORK, LDWORK )
364: *
365: * C1 := C1 - W
366: *
367: DO 60 J = 1, K
368: DO 50 I = 1, LASTC
369: C( I, J ) = C( I, J ) - WORK( I, J )
370: 50 CONTINUE
371: 60 CONTINUE
372: END IF
373: *
374: ELSE
375: *
376: * Let V = ( V1 )
377: * ( V2 ) (last K rows)
378: * where V2 is unit upper triangular.
379: *
380: IF( LSAME( SIDE, 'L' ) ) THEN
381: *
382: * Form H * C or H**H * C where C = ( C1 )
383: * ( C2 )
384: *
385: LASTC = ILAZLC( M, N, C, LDC )
386: *
387: * W := C**H * V = (C1**H * V1 + C2**H * V2) (stored in WORK)
388: *
389: * W := C2**H
390: *
391: DO 70 J = 1, K
392: CALL ZCOPY( LASTC, C( M-K+J, 1 ), LDC,
393: $ WORK( 1, J ), 1 )
394: CALL ZLACGV( LASTC, WORK( 1, J ), 1 )
395: 70 CONTINUE
396: *
397: * W := W * V2
398: *
399: CALL ZTRMM( 'Right', 'Upper', 'No transpose', 'Unit',
400: $ LASTC, K, ONE, V( M-K+1, 1 ), LDV,
401: $ WORK, LDWORK )
402: IF( M.GT.K ) THEN
403: *
404: * W := W + C1**H*V1
405: *
406: CALL ZGEMM( 'Conjugate transpose', 'No transpose',
407: $ LASTC, K, M-K,
408: $ ONE, C, LDC, V, LDV,
409: $ ONE, WORK, LDWORK )
410: END IF
411: *
412: * W := W * T**H or W * T
413: *
414: CALL ZTRMM( 'Right', 'Lower', TRANST, 'Non-unit',
415: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
416: *
417: * C := C - V * W**H
418: *
419: IF( M.GT.K ) THEN
420: *
421: * C1 := C1 - V1 * W**H
422: *
423: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
424: $ M-K, LASTC, K,
425: $ -ONE, V, LDV, WORK, LDWORK,
426: $ ONE, C, LDC )
427: END IF
428: *
429: * W := W * V2**H
430: *
431: CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
432: $ 'Unit', LASTC, K, ONE, V( M-K+1, 1 ), LDV,
433: $ WORK, LDWORK )
434: *
435: * C2 := C2 - W**H
436: *
437: DO 90 J = 1, K
438: DO 80 I = 1, LASTC
439: C( M-K+J, I ) = C( M-K+J, I ) -
440: $ DCONJG( WORK( I, J ) )
441: 80 CONTINUE
442: 90 CONTINUE
443: *
444: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
445: *
446: * Form C * H or C * H**H where C = ( C1 C2 )
447: *
448: LASTC = ILAZLR( M, N, C, LDC )
449: *
450: * W := C * V = (C1*V1 + C2*V2) (stored in WORK)
451: *
452: * W := C2
453: *
454: DO 100 J = 1, K
455: CALL ZCOPY( LASTC, C( 1, N-K+J ), 1,
456: $ WORK( 1, J ), 1 )
457: 100 CONTINUE
458: *
459: * W := W * V2
460: *
461: CALL ZTRMM( 'Right', 'Upper', 'No transpose', 'Unit',
462: $ LASTC, K, ONE, V( N-K+1, 1 ), LDV,
463: $ WORK, LDWORK )
464: IF( N.GT.K ) THEN
465: *
466: * W := W + C1 * V1
467: *
468: CALL ZGEMM( 'No transpose', 'No transpose',
469: $ LASTC, K, N-K,
470: $ ONE, C, LDC, V, LDV, ONE, WORK, LDWORK )
471: END IF
472: *
473: * W := W * T or W * T**H
474: *
475: CALL ZTRMM( 'Right', 'Lower', TRANS, 'Non-unit',
476: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
477: *
478: * C := C - W * V**H
479: *
480: IF( N.GT.K ) THEN
481: *
482: * C1 := C1 - W * V1**H
483: *
484: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
485: $ LASTC, N-K, K, -ONE, WORK, LDWORK, V, LDV,
486: $ ONE, C, LDC )
487: END IF
488: *
489: * W := W * V2**H
490: *
491: CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
492: $ 'Unit', LASTC, K, ONE, V( N-K+1, 1 ), LDV,
493: $ WORK, LDWORK )
494: *
495: * C2 := C2 - W
496: *
497: DO 120 J = 1, K
498: DO 110 I = 1, LASTC
499: C( I, N-K+J ) = C( I, N-K+J )
500: $ - WORK( I, J )
501: 110 CONTINUE
502: 120 CONTINUE
503: END IF
504: END IF
505: *
506: ELSE IF( LSAME( STOREV, 'R' ) ) THEN
507: *
508: IF( LSAME( DIRECT, 'F' ) ) THEN
509: *
510: * Let V = ( V1 V2 ) (V1: first K columns)
511: * where V1 is unit upper triangular.
512: *
513: IF( LSAME( SIDE, 'L' ) ) THEN
514: *
515: * Form H * C or H**H * C where C = ( C1 )
516: * ( C2 )
517: *
518: LASTV = MAX( K, ILAZLC( K, M, V, LDV ) )
519: LASTC = ILAZLC( LASTV, N, C, LDC )
520: *
521: * W := C**H * V**H = (C1**H * V1**H + C2**H * V2**H) (stored in WORK)
522: *
523: * W := C1**H
524: *
525: DO 130 J = 1, K
526: CALL ZCOPY( LASTC, C( J, 1 ), LDC, WORK( 1, J ), 1 )
527: CALL ZLACGV( LASTC, WORK( 1, J ), 1 )
528: 130 CONTINUE
529: *
530: * W := W * V1**H
531: *
532: CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
533: $ 'Unit', LASTC, K, ONE, V, LDV, WORK, LDWORK )
534: IF( LASTV.GT.K ) THEN
535: *
536: * W := W + C2**H*V2**H
537: *
538: CALL ZGEMM( 'Conjugate transpose',
539: $ 'Conjugate transpose', LASTC, K, LASTV-K,
540: $ ONE, C( K+1, 1 ), LDC, V( 1, K+1 ), LDV,
541: $ ONE, WORK, LDWORK )
542: END IF
543: *
544: * W := W * T**H or W * T
545: *
546: CALL ZTRMM( 'Right', 'Upper', TRANST, 'Non-unit',
547: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
548: *
549: * C := C - V**H * W**H
550: *
551: IF( LASTV.GT.K ) THEN
552: *
553: * C2 := C2 - V2**H * W**H
554: *
555: CALL ZGEMM( 'Conjugate transpose',
556: $ 'Conjugate transpose', LASTV-K, LASTC, K,
557: $ -ONE, V( 1, K+1 ), LDV, WORK, LDWORK,
558: $ ONE, C( K+1, 1 ), LDC )
559: END IF
560: *
561: * W := W * V1
562: *
563: CALL ZTRMM( 'Right', 'Upper', 'No transpose', 'Unit',
564: $ LASTC, K, ONE, V, LDV, WORK, LDWORK )
565: *
566: * C1 := C1 - W**H
567: *
568: DO 150 J = 1, K
569: DO 140 I = 1, LASTC
570: C( J, I ) = C( J, I ) - DCONJG( WORK( I, J ) )
571: 140 CONTINUE
572: 150 CONTINUE
573: *
574: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
575: *
576: * Form C * H or C * H**H where C = ( C1 C2 )
577: *
578: LASTV = MAX( K, ILAZLC( K, N, V, LDV ) )
579: LASTC = ILAZLR( M, LASTV, C, LDC )
580: *
581: * W := C * V**H = (C1*V1**H + C2*V2**H) (stored in WORK)
582: *
583: * W := C1
584: *
585: DO 160 J = 1, K
586: CALL ZCOPY( LASTC, C( 1, J ), 1, WORK( 1, J ), 1 )
587: 160 CONTINUE
588: *
589: * W := W * V1**H
590: *
591: CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
592: $ 'Unit', LASTC, K, ONE, V, LDV, WORK, LDWORK )
593: IF( LASTV.GT.K ) THEN
594: *
595: * W := W + C2 * V2**H
596: *
597: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
598: $ LASTC, K, LASTV-K, ONE, C( 1, K+1 ), LDC,
599: $ V( 1, K+1 ), LDV, ONE, WORK, LDWORK )
600: END IF
601: *
602: * W := W * T or W * T**H
603: *
604: CALL ZTRMM( 'Right', 'Upper', TRANS, 'Non-unit',
605: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
606: *
607: * C := C - W * V
608: *
609: IF( LASTV.GT.K ) THEN
610: *
611: * C2 := C2 - W * V2
612: *
613: CALL ZGEMM( 'No transpose', 'No transpose',
614: $ LASTC, LASTV-K, K,
615: $ -ONE, WORK, LDWORK, V( 1, K+1 ), LDV,
616: $ ONE, C( 1, K+1 ), LDC )
617: END IF
618: *
619: * W := W * V1
620: *
621: CALL ZTRMM( 'Right', 'Upper', 'No transpose', 'Unit',
622: $ LASTC, K, ONE, V, LDV, WORK, LDWORK )
623: *
624: * C1 := C1 - W
625: *
626: DO 180 J = 1, K
627: DO 170 I = 1, LASTC
628: C( I, J ) = C( I, J ) - WORK( I, J )
629: 170 CONTINUE
630: 180 CONTINUE
631: *
632: END IF
633: *
634: ELSE
635: *
636: * Let V = ( V1 V2 ) (V2: last K columns)
637: * where V2 is unit lower triangular.
638: *
639: IF( LSAME( SIDE, 'L' ) ) THEN
640: *
641: * Form H * C or H**H * C where C = ( C1 )
642: * ( C2 )
643: *
644: LASTC = ILAZLC( M, N, C, LDC )
645: *
646: * W := C**H * V**H = (C1**H * V1**H + C2**H * V2**H) (stored in WORK)
647: *
648: * W := C2**H
649: *
650: DO 190 J = 1, K
651: CALL ZCOPY( LASTC, C( M-K+J, 1 ), LDC,
652: $ WORK( 1, J ), 1 )
653: CALL ZLACGV( LASTC, WORK( 1, J ), 1 )
654: 190 CONTINUE
655: *
656: * W := W * V2**H
657: *
658: CALL ZTRMM( 'Right', 'Lower', 'Conjugate transpose',
659: $ 'Unit', LASTC, K, ONE, V( 1, M-K+1 ), LDV,
660: $ WORK, LDWORK )
661: IF( M.GT.K ) THEN
662: *
663: * W := W + C1**H * V1**H
664: *
665: CALL ZGEMM( 'Conjugate transpose',
666: $ 'Conjugate transpose', LASTC, K, M-K,
667: $ ONE, C, LDC, V, LDV, ONE, WORK, LDWORK )
668: END IF
669: *
670: * W := W * T**H or W * T
671: *
672: CALL ZTRMM( 'Right', 'Lower', TRANST, 'Non-unit',
673: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
674: *
675: * C := C - V**H * W**H
676: *
677: IF( M.GT.K ) THEN
678: *
679: * C1 := C1 - V1**H * W**H
680: *
681: CALL ZGEMM( 'Conjugate transpose',
682: $ 'Conjugate transpose', M-K, LASTC, K,
683: $ -ONE, V, LDV, WORK, LDWORK, ONE, C, LDC )
684: END IF
685: *
686: * W := W * V2
687: *
688: CALL ZTRMM( 'Right', 'Lower', 'No transpose', 'Unit',
689: $ LASTC, K, ONE, V( 1, M-K+1 ), LDV,
690: $ WORK, LDWORK )
691: *
692: * C2 := C2 - W**H
693: *
694: DO 210 J = 1, K
695: DO 200 I = 1, LASTC
696: C( M-K+J, I ) = C( M-K+J, I ) -
697: $ DCONJG( WORK( I, J ) )
698: 200 CONTINUE
699: 210 CONTINUE
700: *
701: ELSE IF( LSAME( SIDE, 'R' ) ) THEN
702: *
703: * Form C * H or C * H**H where C = ( C1 C2 )
704: *
705: LASTC = ILAZLR( M, N, C, LDC )
706: *
707: * W := C * V**H = (C1*V1**H + C2*V2**H) (stored in WORK)
708: *
709: * W := C2
710: *
711: DO 220 J = 1, K
712: CALL ZCOPY( LASTC, C( 1, N-K+J ), 1,
713: $ WORK( 1, J ), 1 )
714: 220 CONTINUE
715: *
716: * W := W * V2**H
717: *
718: CALL ZTRMM( 'Right', 'Lower', 'Conjugate transpose',
719: $ 'Unit', LASTC, K, ONE, V( 1, N-K+1 ), LDV,
720: $ WORK, LDWORK )
721: IF( N.GT.K ) THEN
722: *
723: * W := W + C1 * V1**H
724: *
725: CALL ZGEMM( 'No transpose', 'Conjugate transpose',
726: $ LASTC, K, N-K, ONE, C, LDC, V, LDV, ONE,
727: $ WORK, LDWORK )
728: END IF
729: *
730: * W := W * T or W * T**H
731: *
732: CALL ZTRMM( 'Right', 'Lower', TRANS, 'Non-unit',
733: $ LASTC, K, ONE, T, LDT, WORK, LDWORK )
734: *
735: * C := C - W * V
736: *
737: IF( N.GT.K ) THEN
738: *
739: * C1 := C1 - W * V1
740: *
741: CALL ZGEMM( 'No transpose', 'No transpose',
742: $ LASTC, N-K, K, -ONE, WORK, LDWORK, V, LDV,
743: $ ONE, C, LDC )
744: END IF
745: *
746: * W := W * V2
747: *
748: CALL ZTRMM( 'Right', 'Lower', 'No transpose', 'Unit',
749: $ LASTC, K, ONE, V( 1, N-K+1 ), LDV,
750: $ WORK, LDWORK )
751: *
752: * C1 := C1 - W
753: *
754: DO 240 J = 1, K
755: DO 230 I = 1, LASTC
756: C( I, N-K+J ) = C( I, N-K+J ) - WORK( I, J )
757: 230 CONTINUE
758: 240 CONTINUE
759: *
760: END IF
761: *
762: END IF
763: END IF
764: *
765: RETURN
766: *
767: * End of ZLARFB
768: *
769: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlarfb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack