1: *> \brief \b ZLAQHE
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLAQHE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlaqhe.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlaqhe.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlaqhe.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLAQHE( UPLO, N, A, LDA, S, SCOND, AMAX, EQUED )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER EQUED, UPLO
25: * INTEGER LDA, N
26: * DOUBLE PRECISION AMAX, SCOND
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION S( * )
30: * COMPLEX*16 A( LDA, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLAQHE equilibrates a Hermitian matrix A using the scaling factors
40: *> in the vector S.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] UPLO
47: *> \verbatim
48: *> UPLO is CHARACTER*1
49: *> Specifies whether the upper or lower triangular part of the
50: *> Hermitian matrix A is stored.
51: *> = 'U': Upper triangular
52: *> = 'L': Lower triangular
53: *> \endverbatim
54: *>
55: *> \param[in] N
56: *> \verbatim
57: *> N is INTEGER
58: *> The order of the matrix A. N >= 0.
59: *> \endverbatim
60: *>
61: *> \param[in,out] A
62: *> \verbatim
63: *> A is COMPLEX*16 array, dimension (LDA,N)
64: *> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
65: *> n by n upper triangular part of A contains the upper
66: *> triangular part of the matrix A, and the strictly lower
67: *> triangular part of A is not referenced. If UPLO = 'L', the
68: *> leading n by n lower triangular part of A contains the lower
69: *> triangular part of the matrix A, and the strictly upper
70: *> triangular part of A is not referenced.
71: *>
72: *> On exit, if EQUED = 'Y', the equilibrated matrix:
73: *> diag(S) * A * diag(S).
74: *> \endverbatim
75: *>
76: *> \param[in] LDA
77: *> \verbatim
78: *> LDA is INTEGER
79: *> The leading dimension of the array A. LDA >= max(N,1).
80: *> \endverbatim
81: *>
82: *> \param[in] S
83: *> \verbatim
84: *> S is DOUBLE PRECISION array, dimension (N)
85: *> The scale factors for A.
86: *> \endverbatim
87: *>
88: *> \param[in] SCOND
89: *> \verbatim
90: *> SCOND is DOUBLE PRECISION
91: *> Ratio of the smallest S(i) to the largest S(i).
92: *> \endverbatim
93: *>
94: *> \param[in] AMAX
95: *> \verbatim
96: *> AMAX is DOUBLE PRECISION
97: *> Absolute value of largest matrix entry.
98: *> \endverbatim
99: *>
100: *> \param[out] EQUED
101: *> \verbatim
102: *> EQUED is CHARACTER*1
103: *> Specifies whether or not equilibration was done.
104: *> = 'N': No equilibration.
105: *> = 'Y': Equilibration was done, i.e., A has been replaced by
106: *> diag(S) * A * diag(S).
107: *> \endverbatim
108: *
109: *> \par Internal Parameters:
110: * =========================
111: *>
112: *> \verbatim
113: *> THRESH is a threshold value used to decide if scaling should be done
114: *> based on the ratio of the scaling factors. If SCOND < THRESH,
115: *> scaling is done.
116: *>
117: *> LARGE and SMALL are threshold values used to decide if scaling should
118: *> be done based on the absolute size of the largest matrix element.
119: *> If AMAX > LARGE or AMAX < SMALL, scaling is done.
120: *> \endverbatim
121: *
122: * Authors:
123: * ========
124: *
125: *> \author Univ. of Tennessee
126: *> \author Univ. of California Berkeley
127: *> \author Univ. of Colorado Denver
128: *> \author NAG Ltd.
129: *
130: *> \date November 2011
131: *
132: *> \ingroup complex16HEauxiliary
133: *
134: * =====================================================================
135: SUBROUTINE ZLAQHE( UPLO, N, A, LDA, S, SCOND, AMAX, EQUED )
136: *
137: * -- LAPACK auxiliary routine (version 3.4.0) --
138: * -- LAPACK is a software package provided by Univ. of Tennessee, --
139: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
140: * November 2011
141: *
142: * .. Scalar Arguments ..
143: CHARACTER EQUED, UPLO
144: INTEGER LDA, N
145: DOUBLE PRECISION AMAX, SCOND
146: * ..
147: * .. Array Arguments ..
148: DOUBLE PRECISION S( * )
149: COMPLEX*16 A( LDA, * )
150: * ..
151: *
152: * =====================================================================
153: *
154: * .. Parameters ..
155: DOUBLE PRECISION ONE, THRESH
156: PARAMETER ( ONE = 1.0D+0, THRESH = 0.1D+0 )
157: * ..
158: * .. Local Scalars ..
159: INTEGER I, J
160: DOUBLE PRECISION CJ, LARGE, SMALL
161: * ..
162: * .. External Functions ..
163: LOGICAL LSAME
164: DOUBLE PRECISION DLAMCH
165: EXTERNAL LSAME, DLAMCH
166: * ..
167: * .. Intrinsic Functions ..
168: INTRINSIC DBLE
169: * ..
170: * .. Executable Statements ..
171: *
172: * Quick return if possible
173: *
174: IF( N.LE.0 ) THEN
175: EQUED = 'N'
176: RETURN
177: END IF
178: *
179: * Initialize LARGE and SMALL.
180: *
181: SMALL = DLAMCH( 'Safe minimum' ) / DLAMCH( 'Precision' )
182: LARGE = ONE / SMALL
183: *
184: IF( SCOND.GE.THRESH .AND. AMAX.GE.SMALL .AND. AMAX.LE.LARGE ) THEN
185: *
186: * No equilibration
187: *
188: EQUED = 'N'
189: ELSE
190: *
191: * Replace A by diag(S) * A * diag(S).
192: *
193: IF( LSAME( UPLO, 'U' ) ) THEN
194: *
195: * Upper triangle of A is stored.
196: *
197: DO 20 J = 1, N
198: CJ = S( J )
199: DO 10 I = 1, J - 1
200: A( I, J ) = CJ*S( I )*A( I, J )
201: 10 CONTINUE
202: A( J, J ) = CJ*CJ*DBLE( A( J, J ) )
203: 20 CONTINUE
204: ELSE
205: *
206: * Lower triangle of A is stored.
207: *
208: DO 40 J = 1, N
209: CJ = S( J )
210: A( J, J ) = CJ*CJ*DBLE( A( J, J ) )
211: DO 30 I = J + 1, N
212: A( I, J ) = CJ*S( I )*A( I, J )
213: 30 CONTINUE
214: 40 CONTINUE
215: END IF
216: EQUED = 'Y'
217: END IF
218: *
219: RETURN
220: *
221: * End of ZLAQHE
222: *
223: END
CVSweb interface <joel.bertrand@systella.fr>