1: *> \brief \b ZLANTR
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANTR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlantr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlantr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlantr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER LDA, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION WORK( * )
30: * COMPLEX*16 A( LDA, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLANTR returns the value of the one norm, or the Frobenius norm, or
40: *> the infinity norm, or the element of largest absolute value of a
41: *> trapezoidal or triangular matrix A.
42: *> \endverbatim
43: *>
44: *> \return ZLANTR
45: *> \verbatim
46: *>
47: *> ZLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48: *> (
49: *> ( norm1(A), NORM = '1', 'O' or 'o'
50: *> (
51: *> ( normI(A), NORM = 'I' or 'i'
52: *> (
53: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54: *>
55: *> where norm1 denotes the one norm of a matrix (maximum column sum),
56: *> normI denotes the infinity norm of a matrix (maximum row sum) and
57: *> normF denotes the Frobenius norm of a matrix (square root of sum of
58: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59: *> \endverbatim
60: *
61: * Arguments:
62: * ==========
63: *
64: *> \param[in] NORM
65: *> \verbatim
66: *> NORM is CHARACTER*1
67: *> Specifies the value to be returned in ZLANTR as described
68: *> above.
69: *> \endverbatim
70: *>
71: *> \param[in] UPLO
72: *> \verbatim
73: *> UPLO is CHARACTER*1
74: *> Specifies whether the matrix A is upper or lower trapezoidal.
75: *> = 'U': Upper trapezoidal
76: *> = 'L': Lower trapezoidal
77: *> Note that A is triangular instead of trapezoidal if M = N.
78: *> \endverbatim
79: *>
80: *> \param[in] DIAG
81: *> \verbatim
82: *> DIAG is CHARACTER*1
83: *> Specifies whether or not the matrix A has unit diagonal.
84: *> = 'N': Non-unit diagonal
85: *> = 'U': Unit diagonal
86: *> \endverbatim
87: *>
88: *> \param[in] M
89: *> \verbatim
90: *> M is INTEGER
91: *> The number of rows of the matrix A. M >= 0, and if
92: *> UPLO = 'U', M <= N. When M = 0, ZLANTR is set to zero.
93: *> \endverbatim
94: *>
95: *> \param[in] N
96: *> \verbatim
97: *> N is INTEGER
98: *> The number of columns of the matrix A. N >= 0, and if
99: *> UPLO = 'L', N <= M. When N = 0, ZLANTR is set to zero.
100: *> \endverbatim
101: *>
102: *> \param[in] A
103: *> \verbatim
104: *> A is COMPLEX*16 array, dimension (LDA,N)
105: *> The trapezoidal matrix A (A is triangular if M = N).
106: *> If UPLO = 'U', the leading m by n upper trapezoidal part of
107: *> the array A contains the upper trapezoidal matrix, and the
108: *> strictly lower triangular part of A is not referenced.
109: *> If UPLO = 'L', the leading m by n lower trapezoidal part of
110: *> the array A contains the lower trapezoidal matrix, and the
111: *> strictly upper triangular part of A is not referenced. Note
112: *> that when DIAG = 'U', the diagonal elements of A are not
113: *> referenced and are assumed to be one.
114: *> \endverbatim
115: *>
116: *> \param[in] LDA
117: *> \verbatim
118: *> LDA is INTEGER
119: *> The leading dimension of the array A. LDA >= max(M,1).
120: *> \endverbatim
121: *>
122: *> \param[out] WORK
123: *> \verbatim
124: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
125: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
126: *> referenced.
127: *> \endverbatim
128: *
129: * Authors:
130: * ========
131: *
132: *> \author Univ. of Tennessee
133: *> \author Univ. of California Berkeley
134: *> \author Univ. of Colorado Denver
135: *> \author NAG Ltd.
136: *
137: *> \date November 2011
138: *
139: *> \ingroup complex16OTHERauxiliary
140: *
141: * =====================================================================
142: DOUBLE PRECISION FUNCTION ZLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
143: $ WORK )
144: *
145: * -- LAPACK auxiliary routine (version 3.4.0) --
146: * -- LAPACK is a software package provided by Univ. of Tennessee, --
147: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
148: * November 2011
149: *
150: * .. Scalar Arguments ..
151: CHARACTER DIAG, NORM, UPLO
152: INTEGER LDA, M, N
153: * ..
154: * .. Array Arguments ..
155: DOUBLE PRECISION WORK( * )
156: COMPLEX*16 A( LDA, * )
157: * ..
158: *
159: * =====================================================================
160: *
161: * .. Parameters ..
162: DOUBLE PRECISION ONE, ZERO
163: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
164: * ..
165: * .. Local Scalars ..
166: LOGICAL UDIAG
167: INTEGER I, J
168: DOUBLE PRECISION SCALE, SUM, VALUE
169: * ..
170: * .. External Functions ..
171: LOGICAL LSAME
172: EXTERNAL LSAME
173: * ..
174: * .. External Subroutines ..
175: EXTERNAL ZLASSQ
176: * ..
177: * .. Intrinsic Functions ..
178: INTRINSIC ABS, MAX, MIN, SQRT
179: * ..
180: * .. Executable Statements ..
181: *
182: IF( MIN( M, N ).EQ.0 ) THEN
183: VALUE = ZERO
184: ELSE IF( LSAME( NORM, 'M' ) ) THEN
185: *
186: * Find max(abs(A(i,j))).
187: *
188: IF( LSAME( DIAG, 'U' ) ) THEN
189: VALUE = ONE
190: IF( LSAME( UPLO, 'U' ) ) THEN
191: DO 20 J = 1, N
192: DO 10 I = 1, MIN( M, J-1 )
193: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
194: 10 CONTINUE
195: 20 CONTINUE
196: ELSE
197: DO 40 J = 1, N
198: DO 30 I = J + 1, M
199: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
200: 30 CONTINUE
201: 40 CONTINUE
202: END IF
203: ELSE
204: VALUE = ZERO
205: IF( LSAME( UPLO, 'U' ) ) THEN
206: DO 60 J = 1, N
207: DO 50 I = 1, MIN( M, J )
208: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
209: 50 CONTINUE
210: 60 CONTINUE
211: ELSE
212: DO 80 J = 1, N
213: DO 70 I = J, M
214: VALUE = MAX( VALUE, ABS( A( I, J ) ) )
215: 70 CONTINUE
216: 80 CONTINUE
217: END IF
218: END IF
219: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
220: *
221: * Find norm1(A).
222: *
223: VALUE = ZERO
224: UDIAG = LSAME( DIAG, 'U' )
225: IF( LSAME( UPLO, 'U' ) ) THEN
226: DO 110 J = 1, N
227: IF( ( UDIAG ) .AND. ( J.LE.M ) ) THEN
228: SUM = ONE
229: DO 90 I = 1, J - 1
230: SUM = SUM + ABS( A( I, J ) )
231: 90 CONTINUE
232: ELSE
233: SUM = ZERO
234: DO 100 I = 1, MIN( M, J )
235: SUM = SUM + ABS( A( I, J ) )
236: 100 CONTINUE
237: END IF
238: VALUE = MAX( VALUE, SUM )
239: 110 CONTINUE
240: ELSE
241: DO 140 J = 1, N
242: IF( UDIAG ) THEN
243: SUM = ONE
244: DO 120 I = J + 1, M
245: SUM = SUM + ABS( A( I, J ) )
246: 120 CONTINUE
247: ELSE
248: SUM = ZERO
249: DO 130 I = J, M
250: SUM = SUM + ABS( A( I, J ) )
251: 130 CONTINUE
252: END IF
253: VALUE = MAX( VALUE, SUM )
254: 140 CONTINUE
255: END IF
256: ELSE IF( LSAME( NORM, 'I' ) ) THEN
257: *
258: * Find normI(A).
259: *
260: IF( LSAME( UPLO, 'U' ) ) THEN
261: IF( LSAME( DIAG, 'U' ) ) THEN
262: DO 150 I = 1, M
263: WORK( I ) = ONE
264: 150 CONTINUE
265: DO 170 J = 1, N
266: DO 160 I = 1, MIN( M, J-1 )
267: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
268: 160 CONTINUE
269: 170 CONTINUE
270: ELSE
271: DO 180 I = 1, M
272: WORK( I ) = ZERO
273: 180 CONTINUE
274: DO 200 J = 1, N
275: DO 190 I = 1, MIN( M, J )
276: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
277: 190 CONTINUE
278: 200 CONTINUE
279: END IF
280: ELSE
281: IF( LSAME( DIAG, 'U' ) ) THEN
282: DO 210 I = 1, N
283: WORK( I ) = ONE
284: 210 CONTINUE
285: DO 220 I = N + 1, M
286: WORK( I ) = ZERO
287: 220 CONTINUE
288: DO 240 J = 1, N
289: DO 230 I = J + 1, M
290: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
291: 230 CONTINUE
292: 240 CONTINUE
293: ELSE
294: DO 250 I = 1, M
295: WORK( I ) = ZERO
296: 250 CONTINUE
297: DO 270 J = 1, N
298: DO 260 I = J, M
299: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
300: 260 CONTINUE
301: 270 CONTINUE
302: END IF
303: END IF
304: VALUE = ZERO
305: DO 280 I = 1, M
306: VALUE = MAX( VALUE, WORK( I ) )
307: 280 CONTINUE
308: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
309: *
310: * Find normF(A).
311: *
312: IF( LSAME( UPLO, 'U' ) ) THEN
313: IF( LSAME( DIAG, 'U' ) ) THEN
314: SCALE = ONE
315: SUM = MIN( M, N )
316: DO 290 J = 2, N
317: CALL ZLASSQ( MIN( M, J-1 ), A( 1, J ), 1, SCALE, SUM )
318: 290 CONTINUE
319: ELSE
320: SCALE = ZERO
321: SUM = ONE
322: DO 300 J = 1, N
323: CALL ZLASSQ( MIN( M, J ), A( 1, J ), 1, SCALE, SUM )
324: 300 CONTINUE
325: END IF
326: ELSE
327: IF( LSAME( DIAG, 'U' ) ) THEN
328: SCALE = ONE
329: SUM = MIN( M, N )
330: DO 310 J = 1, N
331: CALL ZLASSQ( M-J, A( MIN( M, J+1 ), J ), 1, SCALE,
332: $ SUM )
333: 310 CONTINUE
334: ELSE
335: SCALE = ZERO
336: SUM = ONE
337: DO 320 J = 1, N
338: CALL ZLASSQ( M-J+1, A( J, J ), 1, SCALE, SUM )
339: 320 CONTINUE
340: END IF
341: END IF
342: VALUE = SCALE*SQRT( SUM )
343: END IF
344: *
345: ZLANTR = VALUE
346: RETURN
347: *
348: * End of ZLANTR
349: *
350: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlantr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack