1: *> \brief \b ZLANTR returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a trapezoidal or triangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANTR + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlantr.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlantr.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlantr.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER LDA, M, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION WORK( * )
30: * COMPLEX*16 A( LDA, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLANTR returns the value of the one norm, or the Frobenius norm, or
40: *> the infinity norm, or the element of largest absolute value of a
41: *> trapezoidal or triangular matrix A.
42: *> \endverbatim
43: *>
44: *> \return ZLANTR
45: *> \verbatim
46: *>
47: *> ZLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48: *> (
49: *> ( norm1(A), NORM = '1', 'O' or 'o'
50: *> (
51: *> ( normI(A), NORM = 'I' or 'i'
52: *> (
53: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54: *>
55: *> where norm1 denotes the one norm of a matrix (maximum column sum),
56: *> normI denotes the infinity norm of a matrix (maximum row sum) and
57: *> normF denotes the Frobenius norm of a matrix (square root of sum of
58: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59: *> \endverbatim
60: *
61: * Arguments:
62: * ==========
63: *
64: *> \param[in] NORM
65: *> \verbatim
66: *> NORM is CHARACTER*1
67: *> Specifies the value to be returned in ZLANTR as described
68: *> above.
69: *> \endverbatim
70: *>
71: *> \param[in] UPLO
72: *> \verbatim
73: *> UPLO is CHARACTER*1
74: *> Specifies whether the matrix A is upper or lower trapezoidal.
75: *> = 'U': Upper trapezoidal
76: *> = 'L': Lower trapezoidal
77: *> Note that A is triangular instead of trapezoidal if M = N.
78: *> \endverbatim
79: *>
80: *> \param[in] DIAG
81: *> \verbatim
82: *> DIAG is CHARACTER*1
83: *> Specifies whether or not the matrix A has unit diagonal.
84: *> = 'N': Non-unit diagonal
85: *> = 'U': Unit diagonal
86: *> \endverbatim
87: *>
88: *> \param[in] M
89: *> \verbatim
90: *> M is INTEGER
91: *> The number of rows of the matrix A. M >= 0, and if
92: *> UPLO = 'U', M <= N. When M = 0, ZLANTR is set to zero.
93: *> \endverbatim
94: *>
95: *> \param[in] N
96: *> \verbatim
97: *> N is INTEGER
98: *> The number of columns of the matrix A. N >= 0, and if
99: *> UPLO = 'L', N <= M. When N = 0, ZLANTR is set to zero.
100: *> \endverbatim
101: *>
102: *> \param[in] A
103: *> \verbatim
104: *> A is COMPLEX*16 array, dimension (LDA,N)
105: *> The trapezoidal matrix A (A is triangular if M = N).
106: *> If UPLO = 'U', the leading m by n upper trapezoidal part of
107: *> the array A contains the upper trapezoidal matrix, and the
108: *> strictly lower triangular part of A is not referenced.
109: *> If UPLO = 'L', the leading m by n lower trapezoidal part of
110: *> the array A contains the lower trapezoidal matrix, and the
111: *> strictly upper triangular part of A is not referenced. Note
112: *> that when DIAG = 'U', the diagonal elements of A are not
113: *> referenced and are assumed to be one.
114: *> \endverbatim
115: *>
116: *> \param[in] LDA
117: *> \verbatim
118: *> LDA is INTEGER
119: *> The leading dimension of the array A. LDA >= max(M,1).
120: *> \endverbatim
121: *>
122: *> \param[out] WORK
123: *> \verbatim
124: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
125: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
126: *> referenced.
127: *> \endverbatim
128: *
129: * Authors:
130: * ========
131: *
132: *> \author Univ. of Tennessee
133: *> \author Univ. of California Berkeley
134: *> \author Univ. of Colorado Denver
135: *> \author NAG Ltd.
136: *
137: *> \date December 2016
138: *
139: *> \ingroup complex16OTHERauxiliary
140: *
141: * =====================================================================
142: DOUBLE PRECISION FUNCTION ZLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
143: $ WORK )
144: *
145: * -- LAPACK auxiliary routine (version 3.7.0) --
146: * -- LAPACK is a software package provided by Univ. of Tennessee, --
147: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
148: * December 2016
149: *
150: IMPLICIT NONE
151: * .. Scalar Arguments ..
152: CHARACTER DIAG, NORM, UPLO
153: INTEGER LDA, M, N
154: * ..
155: * .. Array Arguments ..
156: DOUBLE PRECISION WORK( * )
157: COMPLEX*16 A( LDA, * )
158: * ..
159: *
160: * =====================================================================
161: *
162: * .. Parameters ..
163: DOUBLE PRECISION ONE, ZERO
164: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
165: * ..
166: * .. Local Scalars ..
167: LOGICAL UDIAG
168: INTEGER I, J
169: DOUBLE PRECISION SUM, VALUE
170: * ..
171: * .. Local Arrays ..
172: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
173: * ..
174: * .. External Functions ..
175: LOGICAL LSAME, DISNAN
176: EXTERNAL LSAME, DISNAN
177: * ..
178: * .. External Subroutines ..
179: EXTERNAL ZLASSQ, DCOMBSSQ
180: * ..
181: * .. Intrinsic Functions ..
182: INTRINSIC ABS, MIN, SQRT
183: * ..
184: * .. Executable Statements ..
185: *
186: IF( MIN( M, N ).EQ.0 ) THEN
187: VALUE = ZERO
188: ELSE IF( LSAME( NORM, 'M' ) ) THEN
189: *
190: * Find max(abs(A(i,j))).
191: *
192: IF( LSAME( DIAG, 'U' ) ) THEN
193: VALUE = ONE
194: IF( LSAME( UPLO, 'U' ) ) THEN
195: DO 20 J = 1, N
196: DO 10 I = 1, MIN( M, J-1 )
197: SUM = ABS( A( I, J ) )
198: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
199: 10 CONTINUE
200: 20 CONTINUE
201: ELSE
202: DO 40 J = 1, N
203: DO 30 I = J + 1, M
204: SUM = ABS( A( I, J ) )
205: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
206: 30 CONTINUE
207: 40 CONTINUE
208: END IF
209: ELSE
210: VALUE = ZERO
211: IF( LSAME( UPLO, 'U' ) ) THEN
212: DO 60 J = 1, N
213: DO 50 I = 1, MIN( M, J )
214: SUM = ABS( A( I, J ) )
215: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
216: 50 CONTINUE
217: 60 CONTINUE
218: ELSE
219: DO 80 J = 1, N
220: DO 70 I = J, M
221: SUM = ABS( A( I, J ) )
222: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
223: 70 CONTINUE
224: 80 CONTINUE
225: END IF
226: END IF
227: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
228: *
229: * Find norm1(A).
230: *
231: VALUE = ZERO
232: UDIAG = LSAME( DIAG, 'U' )
233: IF( LSAME( UPLO, 'U' ) ) THEN
234: DO 110 J = 1, N
235: IF( ( UDIAG ) .AND. ( J.LE.M ) ) THEN
236: SUM = ONE
237: DO 90 I = 1, J - 1
238: SUM = SUM + ABS( A( I, J ) )
239: 90 CONTINUE
240: ELSE
241: SUM = ZERO
242: DO 100 I = 1, MIN( M, J )
243: SUM = SUM + ABS( A( I, J ) )
244: 100 CONTINUE
245: END IF
246: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
247: 110 CONTINUE
248: ELSE
249: DO 140 J = 1, N
250: IF( UDIAG ) THEN
251: SUM = ONE
252: DO 120 I = J + 1, M
253: SUM = SUM + ABS( A( I, J ) )
254: 120 CONTINUE
255: ELSE
256: SUM = ZERO
257: DO 130 I = J, M
258: SUM = SUM + ABS( A( I, J ) )
259: 130 CONTINUE
260: END IF
261: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
262: 140 CONTINUE
263: END IF
264: ELSE IF( LSAME( NORM, 'I' ) ) THEN
265: *
266: * Find normI(A).
267: *
268: IF( LSAME( UPLO, 'U' ) ) THEN
269: IF( LSAME( DIAG, 'U' ) ) THEN
270: DO 150 I = 1, M
271: WORK( I ) = ONE
272: 150 CONTINUE
273: DO 170 J = 1, N
274: DO 160 I = 1, MIN( M, J-1 )
275: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
276: 160 CONTINUE
277: 170 CONTINUE
278: ELSE
279: DO 180 I = 1, M
280: WORK( I ) = ZERO
281: 180 CONTINUE
282: DO 200 J = 1, N
283: DO 190 I = 1, MIN( M, J )
284: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
285: 190 CONTINUE
286: 200 CONTINUE
287: END IF
288: ELSE
289: IF( LSAME( DIAG, 'U' ) ) THEN
290: DO 210 I = 1, N
291: WORK( I ) = ONE
292: 210 CONTINUE
293: DO 220 I = N + 1, M
294: WORK( I ) = ZERO
295: 220 CONTINUE
296: DO 240 J = 1, N
297: DO 230 I = J + 1, M
298: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
299: 230 CONTINUE
300: 240 CONTINUE
301: ELSE
302: DO 250 I = 1, M
303: WORK( I ) = ZERO
304: 250 CONTINUE
305: DO 270 J = 1, N
306: DO 260 I = J, M
307: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
308: 260 CONTINUE
309: 270 CONTINUE
310: END IF
311: END IF
312: VALUE = ZERO
313: DO 280 I = 1, M
314: SUM = WORK( I )
315: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
316: 280 CONTINUE
317: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
318: *
319: * Find normF(A).
320: * SSQ(1) is scale
321: * SSQ(2) is sum-of-squares
322: * For better accuracy, sum each column separately.
323: *
324: IF( LSAME( UPLO, 'U' ) ) THEN
325: IF( LSAME( DIAG, 'U' ) ) THEN
326: SSQ( 1 ) = ONE
327: SSQ( 2 ) = MIN( M, N )
328: DO 290 J = 2, N
329: COLSSQ( 1 ) = ZERO
330: COLSSQ( 2 ) = ONE
331: CALL ZLASSQ( MIN( M, J-1 ), A( 1, J ), 1,
332: $ COLSSQ( 1 ), COLSSQ( 2 ) )
333: CALL DCOMBSSQ( SSQ, COLSSQ )
334: 290 CONTINUE
335: ELSE
336: SSQ( 1 ) = ZERO
337: SSQ( 2 ) = ONE
338: DO 300 J = 1, N
339: COLSSQ( 1 ) = ZERO
340: COLSSQ( 2 ) = ONE
341: CALL ZLASSQ( MIN( M, J ), A( 1, J ), 1,
342: $ COLSSQ( 1 ), COLSSQ( 2 ) )
343: CALL DCOMBSSQ( SSQ, COLSSQ )
344: 300 CONTINUE
345: END IF
346: ELSE
347: IF( LSAME( DIAG, 'U' ) ) THEN
348: SSQ( 1 ) = ONE
349: SSQ( 2 ) = MIN( M, N )
350: DO 310 J = 1, N
351: COLSSQ( 1 ) = ZERO
352: COLSSQ( 2 ) = ONE
353: CALL ZLASSQ( M-J, A( MIN( M, J+1 ), J ), 1,
354: $ COLSSQ( 1 ), COLSSQ( 2 ) )
355: CALL DCOMBSSQ( SSQ, COLSSQ )
356: 310 CONTINUE
357: ELSE
358: SSQ( 1 ) = ZERO
359: SSQ( 2 ) = ONE
360: DO 320 J = 1, N
361: COLSSQ( 1 ) = ZERO
362: COLSSQ( 2 ) = ONE
363: CALL ZLASSQ( M-J+1, A( J, J ), 1,
364: $ COLSSQ( 1 ), COLSSQ( 2 ) )
365: CALL DCOMBSSQ( SSQ, COLSSQ )
366: 320 CONTINUE
367: END IF
368: END IF
369: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
370: END IF
371: *
372: ZLANTR = VALUE
373: RETURN
374: *
375: * End of ZLANTR
376: *
377: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlantr.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack