1: *> \brief \b ZLANTB
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANTB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlantb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlantb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlantb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANTB( NORM, UPLO, DIAG, N, K, AB,
22: * LDAB, WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER DIAG, NORM, UPLO
26: * INTEGER K, LDAB, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION WORK( * )
30: * COMPLEX*16 AB( LDAB, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLANTB returns the value of the one norm, or the Frobenius norm, or
40: *> the infinity norm, or the element of largest absolute value of an
41: *> n by n triangular band matrix A, with ( k + 1 ) diagonals.
42: *> \endverbatim
43: *>
44: *> \return ZLANTB
45: *> \verbatim
46: *>
47: *> ZLANTB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48: *> (
49: *> ( norm1(A), NORM = '1', 'O' or 'o'
50: *> (
51: *> ( normI(A), NORM = 'I' or 'i'
52: *> (
53: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54: *>
55: *> where norm1 denotes the one norm of a matrix (maximum column sum),
56: *> normI denotes the infinity norm of a matrix (maximum row sum) and
57: *> normF denotes the Frobenius norm of a matrix (square root of sum of
58: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59: *> \endverbatim
60: *
61: * Arguments:
62: * ==========
63: *
64: *> \param[in] NORM
65: *> \verbatim
66: *> NORM is CHARACTER*1
67: *> Specifies the value to be returned in ZLANTB as described
68: *> above.
69: *> \endverbatim
70: *>
71: *> \param[in] UPLO
72: *> \verbatim
73: *> UPLO is CHARACTER*1
74: *> Specifies whether the matrix A is upper or lower triangular.
75: *> = 'U': Upper triangular
76: *> = 'L': Lower triangular
77: *> \endverbatim
78: *>
79: *> \param[in] DIAG
80: *> \verbatim
81: *> DIAG is CHARACTER*1
82: *> Specifies whether or not the matrix A is unit triangular.
83: *> = 'N': Non-unit triangular
84: *> = 'U': Unit triangular
85: *> \endverbatim
86: *>
87: *> \param[in] N
88: *> \verbatim
89: *> N is INTEGER
90: *> The order of the matrix A. N >= 0. When N = 0, ZLANTB is
91: *> set to zero.
92: *> \endverbatim
93: *>
94: *> \param[in] K
95: *> \verbatim
96: *> K is INTEGER
97: *> The number of super-diagonals of the matrix A if UPLO = 'U',
98: *> or the number of sub-diagonals of the matrix A if UPLO = 'L'.
99: *> K >= 0.
100: *> \endverbatim
101: *>
102: *> \param[in] AB
103: *> \verbatim
104: *> AB is COMPLEX*16 array, dimension (LDAB,N)
105: *> The upper or lower triangular band matrix A, stored in the
106: *> first k+1 rows of AB. The j-th column of A is stored
107: *> in the j-th column of the array AB as follows:
108: *> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
109: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
110: *> Note that when DIAG = 'U', the elements of the array AB
111: *> corresponding to the diagonal elements of the matrix A are
112: *> not referenced, but are assumed to be one.
113: *> \endverbatim
114: *>
115: *> \param[in] LDAB
116: *> \verbatim
117: *> LDAB is INTEGER
118: *> The leading dimension of the array AB. LDAB >= K+1.
119: *> \endverbatim
120: *>
121: *> \param[out] WORK
122: *> \verbatim
123: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
124: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
125: *> referenced.
126: *> \endverbatim
127: *
128: * Authors:
129: * ========
130: *
131: *> \author Univ. of Tennessee
132: *> \author Univ. of California Berkeley
133: *> \author Univ. of Colorado Denver
134: *> \author NAG Ltd.
135: *
136: *> \date November 2011
137: *
138: *> \ingroup complex16OTHERauxiliary
139: *
140: * =====================================================================
141: DOUBLE PRECISION FUNCTION ZLANTB( NORM, UPLO, DIAG, N, K, AB,
142: $ LDAB, WORK )
143: *
144: * -- LAPACK auxiliary routine (version 3.4.0) --
145: * -- LAPACK is a software package provided by Univ. of Tennessee, --
146: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
147: * November 2011
148: *
149: * .. Scalar Arguments ..
150: CHARACTER DIAG, NORM, UPLO
151: INTEGER K, LDAB, N
152: * ..
153: * .. Array Arguments ..
154: DOUBLE PRECISION WORK( * )
155: COMPLEX*16 AB( LDAB, * )
156: * ..
157: *
158: * =====================================================================
159: *
160: * .. Parameters ..
161: DOUBLE PRECISION ONE, ZERO
162: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
163: * ..
164: * .. Local Scalars ..
165: LOGICAL UDIAG
166: INTEGER I, J, L
167: DOUBLE PRECISION SCALE, SUM, VALUE
168: * ..
169: * .. External Functions ..
170: LOGICAL LSAME
171: EXTERNAL LSAME
172: * ..
173: * .. External Subroutines ..
174: EXTERNAL ZLASSQ
175: * ..
176: * .. Intrinsic Functions ..
177: INTRINSIC ABS, MAX, MIN, SQRT
178: * ..
179: * .. Executable Statements ..
180: *
181: IF( N.EQ.0 ) THEN
182: VALUE = ZERO
183: ELSE IF( LSAME( NORM, 'M' ) ) THEN
184: *
185: * Find max(abs(A(i,j))).
186: *
187: IF( LSAME( DIAG, 'U' ) ) THEN
188: VALUE = ONE
189: IF( LSAME( UPLO, 'U' ) ) THEN
190: DO 20 J = 1, N
191: DO 10 I = MAX( K+2-J, 1 ), K
192: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
193: 10 CONTINUE
194: 20 CONTINUE
195: ELSE
196: DO 40 J = 1, N
197: DO 30 I = 2, MIN( N+1-J, K+1 )
198: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
199: 30 CONTINUE
200: 40 CONTINUE
201: END IF
202: ELSE
203: VALUE = ZERO
204: IF( LSAME( UPLO, 'U' ) ) THEN
205: DO 60 J = 1, N
206: DO 50 I = MAX( K+2-J, 1 ), K + 1
207: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
208: 50 CONTINUE
209: 60 CONTINUE
210: ELSE
211: DO 80 J = 1, N
212: DO 70 I = 1, MIN( N+1-J, K+1 )
213: VALUE = MAX( VALUE, ABS( AB( I, J ) ) )
214: 70 CONTINUE
215: 80 CONTINUE
216: END IF
217: END IF
218: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
219: *
220: * Find norm1(A).
221: *
222: VALUE = ZERO
223: UDIAG = LSAME( DIAG, 'U' )
224: IF( LSAME( UPLO, 'U' ) ) THEN
225: DO 110 J = 1, N
226: IF( UDIAG ) THEN
227: SUM = ONE
228: DO 90 I = MAX( K+2-J, 1 ), K
229: SUM = SUM + ABS( AB( I, J ) )
230: 90 CONTINUE
231: ELSE
232: SUM = ZERO
233: DO 100 I = MAX( K+2-J, 1 ), K + 1
234: SUM = SUM + ABS( AB( I, J ) )
235: 100 CONTINUE
236: END IF
237: VALUE = MAX( VALUE, SUM )
238: 110 CONTINUE
239: ELSE
240: DO 140 J = 1, N
241: IF( UDIAG ) THEN
242: SUM = ONE
243: DO 120 I = 2, MIN( N+1-J, K+1 )
244: SUM = SUM + ABS( AB( I, J ) )
245: 120 CONTINUE
246: ELSE
247: SUM = ZERO
248: DO 130 I = 1, MIN( N+1-J, K+1 )
249: SUM = SUM + ABS( AB( I, J ) )
250: 130 CONTINUE
251: END IF
252: VALUE = MAX( VALUE, SUM )
253: 140 CONTINUE
254: END IF
255: ELSE IF( LSAME( NORM, 'I' ) ) THEN
256: *
257: * Find normI(A).
258: *
259: VALUE = ZERO
260: IF( LSAME( UPLO, 'U' ) ) THEN
261: IF( LSAME( DIAG, 'U' ) ) THEN
262: DO 150 I = 1, N
263: WORK( I ) = ONE
264: 150 CONTINUE
265: DO 170 J = 1, N
266: L = K + 1 - J
267: DO 160 I = MAX( 1, J-K ), J - 1
268: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
269: 160 CONTINUE
270: 170 CONTINUE
271: ELSE
272: DO 180 I = 1, N
273: WORK( I ) = ZERO
274: 180 CONTINUE
275: DO 200 J = 1, N
276: L = K + 1 - J
277: DO 190 I = MAX( 1, J-K ), J
278: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
279: 190 CONTINUE
280: 200 CONTINUE
281: END IF
282: ELSE
283: IF( LSAME( DIAG, 'U' ) ) THEN
284: DO 210 I = 1, N
285: WORK( I ) = ONE
286: 210 CONTINUE
287: DO 230 J = 1, N
288: L = 1 - J
289: DO 220 I = J + 1, MIN( N, J+K )
290: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
291: 220 CONTINUE
292: 230 CONTINUE
293: ELSE
294: DO 240 I = 1, N
295: WORK( I ) = ZERO
296: 240 CONTINUE
297: DO 260 J = 1, N
298: L = 1 - J
299: DO 250 I = J, MIN( N, J+K )
300: WORK( I ) = WORK( I ) + ABS( AB( L+I, J ) )
301: 250 CONTINUE
302: 260 CONTINUE
303: END IF
304: END IF
305: DO 270 I = 1, N
306: VALUE = MAX( VALUE, WORK( I ) )
307: 270 CONTINUE
308: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
309: *
310: * Find normF(A).
311: *
312: IF( LSAME( UPLO, 'U' ) ) THEN
313: IF( LSAME( DIAG, 'U' ) ) THEN
314: SCALE = ONE
315: SUM = N
316: IF( K.GT.0 ) THEN
317: DO 280 J = 2, N
318: CALL ZLASSQ( MIN( J-1, K ),
319: $ AB( MAX( K+2-J, 1 ), J ), 1, SCALE,
320: $ SUM )
321: 280 CONTINUE
322: END IF
323: ELSE
324: SCALE = ZERO
325: SUM = ONE
326: DO 290 J = 1, N
327: CALL ZLASSQ( MIN( J, K+1 ), AB( MAX( K+2-J, 1 ), J ),
328: $ 1, SCALE, SUM )
329: 290 CONTINUE
330: END IF
331: ELSE
332: IF( LSAME( DIAG, 'U' ) ) THEN
333: SCALE = ONE
334: SUM = N
335: IF( K.GT.0 ) THEN
336: DO 300 J = 1, N - 1
337: CALL ZLASSQ( MIN( N-J, K ), AB( 2, J ), 1, SCALE,
338: $ SUM )
339: 300 CONTINUE
340: END IF
341: ELSE
342: SCALE = ZERO
343: SUM = ONE
344: DO 310 J = 1, N
345: CALL ZLASSQ( MIN( N-J+1, K+1 ), AB( 1, J ), 1, SCALE,
346: $ SUM )
347: 310 CONTINUE
348: END IF
349: END IF
350: VALUE = SCALE*SQRT( SUM )
351: END IF
352: *
353: ZLANTB = VALUE
354: RETURN
355: *
356: * End of ZLANTB
357: *
358: END
CVSweb interface <joel.bertrand@systella.fr>