Annotation of rpl/lapack/lapack/zlansp.f, revision 1.8
1.8 ! bertrand 1: *> \brief \b ZLANSP
! 2: *
! 3: * =========== DOCUMENTATION ===========
! 4: *
! 5: * Online html documentation available at
! 6: * http://www.netlib.org/lapack/explore-html/
! 7: *
! 8: *> \htmlonly
! 9: *> Download ZLANSP + dependencies
! 10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlansp.f">
! 11: *> [TGZ]</a>
! 12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlansp.f">
! 13: *> [ZIP]</a>
! 14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlansp.f">
! 15: *> [TXT]</a>
! 16: *> \endhtmlonly
! 17: *
! 18: * Definition:
! 19: * ===========
! 20: *
! 21: * DOUBLE PRECISION FUNCTION ZLANSP( NORM, UPLO, N, AP, WORK )
! 22: *
! 23: * .. Scalar Arguments ..
! 24: * CHARACTER NORM, UPLO
! 25: * INTEGER N
! 26: * ..
! 27: * .. Array Arguments ..
! 28: * DOUBLE PRECISION WORK( * )
! 29: * COMPLEX*16 AP( * )
! 30: * ..
! 31: *
! 32: *
! 33: *> \par Purpose:
! 34: * =============
! 35: *>
! 36: *> \verbatim
! 37: *>
! 38: *> ZLANSP returns the value of the one norm, or the Frobenius norm, or
! 39: *> the infinity norm, or the element of largest absolute value of a
! 40: *> complex symmetric matrix A, supplied in packed form.
! 41: *> \endverbatim
! 42: *>
! 43: *> \return ZLANSP
! 44: *> \verbatim
! 45: *>
! 46: *> ZLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
! 47: *> (
! 48: *> ( norm1(A), NORM = '1', 'O' or 'o'
! 49: *> (
! 50: *> ( normI(A), NORM = 'I' or 'i'
! 51: *> (
! 52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
! 53: *>
! 54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
! 55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
! 56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
! 57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
! 58: *> \endverbatim
! 59: *
! 60: * Arguments:
! 61: * ==========
! 62: *
! 63: *> \param[in] NORM
! 64: *> \verbatim
! 65: *> NORM is CHARACTER*1
! 66: *> Specifies the value to be returned in ZLANSP as described
! 67: *> above.
! 68: *> \endverbatim
! 69: *>
! 70: *> \param[in] UPLO
! 71: *> \verbatim
! 72: *> UPLO is CHARACTER*1
! 73: *> Specifies whether the upper or lower triangular part of the
! 74: *> symmetric matrix A is supplied.
! 75: *> = 'U': Upper triangular part of A is supplied
! 76: *> = 'L': Lower triangular part of A is supplied
! 77: *> \endverbatim
! 78: *>
! 79: *> \param[in] N
! 80: *> \verbatim
! 81: *> N is INTEGER
! 82: *> The order of the matrix A. N >= 0. When N = 0, ZLANSP is
! 83: *> set to zero.
! 84: *> \endverbatim
! 85: *>
! 86: *> \param[in] AP
! 87: *> \verbatim
! 88: *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
! 89: *> The upper or lower triangle of the symmetric matrix A, packed
! 90: *> columnwise in a linear array. The j-th column of A is stored
! 91: *> in the array AP as follows:
! 92: *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
! 93: *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
! 94: *> \endverbatim
! 95: *>
! 96: *> \param[out] WORK
! 97: *> \verbatim
! 98: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
! 99: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
! 100: *> WORK is not referenced.
! 101: *> \endverbatim
! 102: *
! 103: * Authors:
! 104: * ========
! 105: *
! 106: *> \author Univ. of Tennessee
! 107: *> \author Univ. of California Berkeley
! 108: *> \author Univ. of Colorado Denver
! 109: *> \author NAG Ltd.
! 110: *
! 111: *> \date November 2011
! 112: *
! 113: *> \ingroup complex16OTHERauxiliary
! 114: *
! 115: * =====================================================================
1.1 bertrand 116: DOUBLE PRECISION FUNCTION ZLANSP( NORM, UPLO, N, AP, WORK )
117: *
1.8 ! bertrand 118: * -- LAPACK auxiliary routine (version 3.4.0) --
1.1 bertrand 119: * -- LAPACK is a software package provided by Univ. of Tennessee, --
120: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.8 ! bertrand 121: * November 2011
1.1 bertrand 122: *
123: * .. Scalar Arguments ..
124: CHARACTER NORM, UPLO
125: INTEGER N
126: * ..
127: * .. Array Arguments ..
128: DOUBLE PRECISION WORK( * )
129: COMPLEX*16 AP( * )
130: * ..
131: *
132: * =====================================================================
133: *
134: * .. Parameters ..
135: DOUBLE PRECISION ONE, ZERO
136: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
137: * ..
138: * .. Local Scalars ..
139: INTEGER I, J, K
140: DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
141: * ..
142: * .. External Functions ..
143: LOGICAL LSAME
144: EXTERNAL LSAME
145: * ..
146: * .. External Subroutines ..
147: EXTERNAL ZLASSQ
148: * ..
149: * .. Intrinsic Functions ..
150: INTRINSIC ABS, DBLE, DIMAG, MAX, SQRT
151: * ..
152: * .. Executable Statements ..
153: *
154: IF( N.EQ.0 ) THEN
155: VALUE = ZERO
156: ELSE IF( LSAME( NORM, 'M' ) ) THEN
157: *
158: * Find max(abs(A(i,j))).
159: *
160: VALUE = ZERO
161: IF( LSAME( UPLO, 'U' ) ) THEN
162: K = 1
163: DO 20 J = 1, N
164: DO 10 I = K, K + J - 1
165: VALUE = MAX( VALUE, ABS( AP( I ) ) )
166: 10 CONTINUE
167: K = K + J
168: 20 CONTINUE
169: ELSE
170: K = 1
171: DO 40 J = 1, N
172: DO 30 I = K, K + N - J
173: VALUE = MAX( VALUE, ABS( AP( I ) ) )
174: 30 CONTINUE
175: K = K + N - J + 1
176: 40 CONTINUE
177: END IF
178: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
179: $ ( NORM.EQ.'1' ) ) THEN
180: *
181: * Find normI(A) ( = norm1(A), since A is symmetric).
182: *
183: VALUE = ZERO
184: K = 1
185: IF( LSAME( UPLO, 'U' ) ) THEN
186: DO 60 J = 1, N
187: SUM = ZERO
188: DO 50 I = 1, J - 1
189: ABSA = ABS( AP( K ) )
190: SUM = SUM + ABSA
191: WORK( I ) = WORK( I ) + ABSA
192: K = K + 1
193: 50 CONTINUE
194: WORK( J ) = SUM + ABS( AP( K ) )
195: K = K + 1
196: 60 CONTINUE
197: DO 70 I = 1, N
198: VALUE = MAX( VALUE, WORK( I ) )
199: 70 CONTINUE
200: ELSE
201: DO 80 I = 1, N
202: WORK( I ) = ZERO
203: 80 CONTINUE
204: DO 100 J = 1, N
205: SUM = WORK( J ) + ABS( AP( K ) )
206: K = K + 1
207: DO 90 I = J + 1, N
208: ABSA = ABS( AP( K ) )
209: SUM = SUM + ABSA
210: WORK( I ) = WORK( I ) + ABSA
211: K = K + 1
212: 90 CONTINUE
213: VALUE = MAX( VALUE, SUM )
214: 100 CONTINUE
215: END IF
216: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
217: *
218: * Find normF(A).
219: *
220: SCALE = ZERO
221: SUM = ONE
222: K = 2
223: IF( LSAME( UPLO, 'U' ) ) THEN
224: DO 110 J = 2, N
225: CALL ZLASSQ( J-1, AP( K ), 1, SCALE, SUM )
226: K = K + J
227: 110 CONTINUE
228: ELSE
229: DO 120 J = 1, N - 1
230: CALL ZLASSQ( N-J, AP( K ), 1, SCALE, SUM )
231: K = K + N - J + 1
232: 120 CONTINUE
233: END IF
234: SUM = 2*SUM
235: K = 1
236: DO 130 I = 1, N
237: IF( DBLE( AP( K ) ).NE.ZERO ) THEN
238: ABSA = ABS( DBLE( AP( K ) ) )
239: IF( SCALE.LT.ABSA ) THEN
240: SUM = ONE + SUM*( SCALE / ABSA )**2
241: SCALE = ABSA
242: ELSE
243: SUM = SUM + ( ABSA / SCALE )**2
244: END IF
245: END IF
246: IF( DIMAG( AP( K ) ).NE.ZERO ) THEN
247: ABSA = ABS( DIMAG( AP( K ) ) )
248: IF( SCALE.LT.ABSA ) THEN
249: SUM = ONE + SUM*( SCALE / ABSA )**2
250: SCALE = ABSA
251: ELSE
252: SUM = SUM + ( ABSA / SCALE )**2
253: END IF
254: END IF
255: IF( LSAME( UPLO, 'U' ) ) THEN
256: K = K + I + 1
257: ELSE
258: K = K + N - I + 1
259: END IF
260: 130 CONTINUE
261: VALUE = SCALE*SQRT( SUM )
262: END IF
263: *
264: ZLANSP = VALUE
265: RETURN
266: *
267: * End of ZLANSP
268: *
269: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlansp.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack