1: *> \brief \b ZLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhs.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHS( NORM, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHS returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> Hessenberg matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANHS
44: *> \verbatim
45: *>
46: *> ZLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHS as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] N
71: *> \verbatim
72: *> N is INTEGER
73: *> The order of the matrix A. N >= 0. When N = 0, ZLANHS is
74: *> set to zero.
75: *> \endverbatim
76: *>
77: *> \param[in] A
78: *> \verbatim
79: *> A is COMPLEX*16 array, dimension (LDA,N)
80: *> The n by n upper Hessenberg matrix A; the part of A below the
81: *> first sub-diagonal is not referenced.
82: *> \endverbatim
83: *>
84: *> \param[in] LDA
85: *> \verbatim
86: *> LDA is INTEGER
87: *> The leading dimension of the array A. LDA >= max(N,1).
88: *> \endverbatim
89: *>
90: *> \param[out] WORK
91: *> \verbatim
92: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
93: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
94: *> referenced.
95: *> \endverbatim
96: *
97: * Authors:
98: * ========
99: *
100: *> \author Univ. of Tennessee
101: *> \author Univ. of California Berkeley
102: *> \author Univ. of Colorado Denver
103: *> \author NAG Ltd.
104: *
105: *> \ingroup complex16OTHERauxiliary
106: *
107: * =====================================================================
108: DOUBLE PRECISION FUNCTION ZLANHS( NORM, N, A, LDA, WORK )
109: *
110: * -- LAPACK auxiliary routine --
111: * -- LAPACK is a software package provided by Univ. of Tennessee, --
112: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
113: *
114: * .. Scalar Arguments ..
115: CHARACTER NORM
116: INTEGER LDA, N
117: * ..
118: * .. Array Arguments ..
119: DOUBLE PRECISION WORK( * )
120: COMPLEX*16 A( LDA, * )
121: * ..
122: *
123: * =====================================================================
124: *
125: * .. Parameters ..
126: DOUBLE PRECISION ONE, ZERO
127: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
128: * ..
129: * .. Local Scalars ..
130: INTEGER I, J
131: DOUBLE PRECISION SCALE, SUM, VALUE
132: * ..
133: * .. External Functions ..
134: LOGICAL LSAME, DISNAN
135: EXTERNAL LSAME, DISNAN
136: * ..
137: * .. External Subroutines ..
138: EXTERNAL ZLASSQ
139: * ..
140: * .. Intrinsic Functions ..
141: INTRINSIC ABS, MIN, SQRT
142: * ..
143: * .. Executable Statements ..
144: *
145: IF( N.EQ.0 ) THEN
146: VALUE = ZERO
147: ELSE IF( LSAME( NORM, 'M' ) ) THEN
148: *
149: * Find max(abs(A(i,j))).
150: *
151: VALUE = ZERO
152: DO 20 J = 1, N
153: DO 10 I = 1, MIN( N, J+1 )
154: SUM = ABS( A( I, J ) )
155: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
156: 10 CONTINUE
157: 20 CONTINUE
158: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
159: *
160: * Find norm1(A).
161: *
162: VALUE = ZERO
163: DO 40 J = 1, N
164: SUM = ZERO
165: DO 30 I = 1, MIN( N, J+1 )
166: SUM = SUM + ABS( A( I, J ) )
167: 30 CONTINUE
168: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
169: 40 CONTINUE
170: ELSE IF( LSAME( NORM, 'I' ) ) THEN
171: *
172: * Find normI(A).
173: *
174: DO 50 I = 1, N
175: WORK( I ) = ZERO
176: 50 CONTINUE
177: DO 70 J = 1, N
178: DO 60 I = 1, MIN( N, J+1 )
179: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
180: 60 CONTINUE
181: 70 CONTINUE
182: VALUE = ZERO
183: DO 80 I = 1, N
184: SUM = WORK( I )
185: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
186: 80 CONTINUE
187: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
188: *
189: * Find normF(A).
190: *
191: SCALE = ZERO
192: SUM = ONE
193: DO 90 J = 1, N
194: CALL ZLASSQ( MIN( N, J+1 ), A( 1, J ), 1, SCALE, SUM )
195: 90 CONTINUE
196: VALUE = SCALE*SQRT( SUM )
197: END IF
198: *
199: ZLANHS = VALUE
200: RETURN
201: *
202: * End of ZLANHS
203: *
204: END
CVSweb interface <joel.bertrand@systella.fr>