1: *> \brief \b ZLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhs.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhs.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhs.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHS( NORM, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHS returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> Hessenberg matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANHS
44: *> \verbatim
45: *>
46: *> ZLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHS as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] N
71: *> \verbatim
72: *> N is INTEGER
73: *> The order of the matrix A. N >= 0. When N = 0, ZLANHS is
74: *> set to zero.
75: *> \endverbatim
76: *>
77: *> \param[in] A
78: *> \verbatim
79: *> A is COMPLEX*16 array, dimension (LDA,N)
80: *> The n by n upper Hessenberg matrix A; the part of A below the
81: *> first sub-diagonal is not referenced.
82: *> \endverbatim
83: *>
84: *> \param[in] LDA
85: *> \verbatim
86: *> LDA is INTEGER
87: *> The leading dimension of the array A. LDA >= max(N,1).
88: *> \endverbatim
89: *>
90: *> \param[out] WORK
91: *> \verbatim
92: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
93: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
94: *> referenced.
95: *> \endverbatim
96: *
97: * Authors:
98: * ========
99: *
100: *> \author Univ. of Tennessee
101: *> \author Univ. of California Berkeley
102: *> \author Univ. of Colorado Denver
103: *> \author NAG Ltd.
104: *
105: *> \date December 2016
106: *
107: *> \ingroup complex16OTHERauxiliary
108: *
109: * =====================================================================
110: DOUBLE PRECISION FUNCTION ZLANHS( NORM, N, A, LDA, WORK )
111: *
112: * -- LAPACK auxiliary routine (version 3.7.0) --
113: * -- LAPACK is a software package provided by Univ. of Tennessee, --
114: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
115: * December 2016
116: *
117: IMPLICIT NONE
118: * .. Scalar Arguments ..
119: CHARACTER NORM
120: INTEGER LDA, N
121: * ..
122: * .. Array Arguments ..
123: DOUBLE PRECISION WORK( * )
124: COMPLEX*16 A( LDA, * )
125: * ..
126: *
127: * =====================================================================
128: *
129: * .. Parameters ..
130: DOUBLE PRECISION ONE, ZERO
131: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
132: * ..
133: * .. Local Scalars ..
134: INTEGER I, J
135: DOUBLE PRECISION SUM, VALUE
136: * ..
137: * .. Local Arrays ..
138: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
139: * ..
140: * .. External Functions ..
141: LOGICAL LSAME, DISNAN
142: EXTERNAL LSAME, DISNAN
143: * ..
144: * .. External Subroutines ..
145: EXTERNAL ZLASSQ, DCOMBSSQ
146: * ..
147: * .. Intrinsic Functions ..
148: INTRINSIC ABS, MIN, SQRT
149: * ..
150: * .. Executable Statements ..
151: *
152: IF( N.EQ.0 ) THEN
153: VALUE = ZERO
154: ELSE IF( LSAME( NORM, 'M' ) ) THEN
155: *
156: * Find max(abs(A(i,j))).
157: *
158: VALUE = ZERO
159: DO 20 J = 1, N
160: DO 10 I = 1, MIN( N, J+1 )
161: SUM = ABS( A( I, J ) )
162: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
163: 10 CONTINUE
164: 20 CONTINUE
165: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
166: *
167: * Find norm1(A).
168: *
169: VALUE = ZERO
170: DO 40 J = 1, N
171: SUM = ZERO
172: DO 30 I = 1, MIN( N, J+1 )
173: SUM = SUM + ABS( A( I, J ) )
174: 30 CONTINUE
175: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
176: 40 CONTINUE
177: ELSE IF( LSAME( NORM, 'I' ) ) THEN
178: *
179: * Find normI(A).
180: *
181: DO 50 I = 1, N
182: WORK( I ) = ZERO
183: 50 CONTINUE
184: DO 70 J = 1, N
185: DO 60 I = 1, MIN( N, J+1 )
186: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
187: 60 CONTINUE
188: 70 CONTINUE
189: VALUE = ZERO
190: DO 80 I = 1, N
191: SUM = WORK( I )
192: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
193: 80 CONTINUE
194: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
195: *
196: * Find normF(A).
197: * SSQ(1) is scale
198: * SSQ(2) is sum-of-squares
199: * For better accuracy, sum each column separately.
200: *
201: SSQ( 1 ) = ZERO
202: SSQ( 2 ) = ONE
203: DO 90 J = 1, N
204: COLSSQ( 1 ) = ZERO
205: COLSSQ( 2 ) = ONE
206: CALL ZLASSQ( MIN( N, J+1 ), A( 1, J ), 1,
207: $ COLSSQ( 1 ), COLSSQ( 2 ) )
208: CALL DCOMBSSQ( SSQ, COLSSQ )
209: 90 CONTINUE
210: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
211: END IF
212: *
213: ZLANHS = VALUE
214: RETURN
215: *
216: * End of ZLANHS
217: *
218: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlanhs.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack