1: *> \brief \b ZLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHP + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhp.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhp.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhp.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM, UPLO
25: * INTEGER N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 AP( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHP returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex hermitian matrix A, supplied in packed form.
41: *> \endverbatim
42: *>
43: *> \return ZLANHP
44: *> \verbatim
45: *>
46: *> ZLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHP as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the upper or lower triangular part of the
74: *> hermitian matrix A is supplied.
75: *> = 'U': Upper triangular part of A is supplied
76: *> = 'L': Lower triangular part of A is supplied
77: *> \endverbatim
78: *>
79: *> \param[in] N
80: *> \verbatim
81: *> N is INTEGER
82: *> The order of the matrix A. N >= 0. When N = 0, ZLANHP is
83: *> set to zero.
84: *> \endverbatim
85: *>
86: *> \param[in] AP
87: *> \verbatim
88: *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
89: *> The upper or lower triangle of the hermitian matrix A, packed
90: *> columnwise in a linear array. The j-th column of A is stored
91: *> in the array AP as follows:
92: *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93: *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94: *> Note that the imaginary parts of the diagonal elements need
95: *> not be set and are assumed to be zero.
96: *> \endverbatim
97: *>
98: *> \param[out] WORK
99: *> \verbatim
100: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
101: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
102: *> WORK is not referenced.
103: *> \endverbatim
104: *
105: * Authors:
106: * ========
107: *
108: *> \author Univ. of Tennessee
109: *> \author Univ. of California Berkeley
110: *> \author Univ. of Colorado Denver
111: *> \author NAG Ltd.
112: *
113: *> \date December 2016
114: *
115: *> \ingroup complex16OTHERauxiliary
116: *
117: * =====================================================================
118: DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
119: *
120: * -- LAPACK auxiliary routine (version 3.7.0) --
121: * -- LAPACK is a software package provided by Univ. of Tennessee, --
122: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
123: * December 2016
124: *
125: IMPLICIT NONE
126: * .. Scalar Arguments ..
127: CHARACTER NORM, UPLO
128: INTEGER N
129: * ..
130: * .. Array Arguments ..
131: DOUBLE PRECISION WORK( * )
132: COMPLEX*16 AP( * )
133: * ..
134: *
135: * =====================================================================
136: *
137: * .. Parameters ..
138: DOUBLE PRECISION ONE, ZERO
139: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
140: * ..
141: * .. Local Scalars ..
142: INTEGER I, J, K
143: DOUBLE PRECISION ABSA, SUM, VALUE
144: * ..
145: * .. Local Arrays ..
146: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
147: * ..
148: * .. External Functions ..
149: LOGICAL LSAME, DISNAN
150: EXTERNAL LSAME, DISNAN
151: * ..
152: * .. External Subroutines ..
153: EXTERNAL ZLASSQ, DCOMBSSQ
154: * ..
155: * .. Intrinsic Functions ..
156: INTRINSIC ABS, DBLE, SQRT
157: * ..
158: * .. Executable Statements ..
159: *
160: IF( N.EQ.0 ) THEN
161: VALUE = ZERO
162: ELSE IF( LSAME( NORM, 'M' ) ) THEN
163: *
164: * Find max(abs(A(i,j))).
165: *
166: VALUE = ZERO
167: IF( LSAME( UPLO, 'U' ) ) THEN
168: K = 0
169: DO 20 J = 1, N
170: DO 10 I = K + 1, K + J - 1
171: SUM = ABS( AP( I ) )
172: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
173: 10 CONTINUE
174: K = K + J
175: SUM = ABS( DBLE( AP( K ) ) )
176: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
177: 20 CONTINUE
178: ELSE
179: K = 1
180: DO 40 J = 1, N
181: SUM = ABS( DBLE( AP( K ) ) )
182: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
183: DO 30 I = K + 1, K + N - J
184: SUM = ABS( AP( I ) )
185: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
186: 30 CONTINUE
187: K = K + N - J + 1
188: 40 CONTINUE
189: END IF
190: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
191: $ ( NORM.EQ.'1' ) ) THEN
192: *
193: * Find normI(A) ( = norm1(A), since A is hermitian).
194: *
195: VALUE = ZERO
196: K = 1
197: IF( LSAME( UPLO, 'U' ) ) THEN
198: DO 60 J = 1, N
199: SUM = ZERO
200: DO 50 I = 1, J - 1
201: ABSA = ABS( AP( K ) )
202: SUM = SUM + ABSA
203: WORK( I ) = WORK( I ) + ABSA
204: K = K + 1
205: 50 CONTINUE
206: WORK( J ) = SUM + ABS( DBLE( AP( K ) ) )
207: K = K + 1
208: 60 CONTINUE
209: DO 70 I = 1, N
210: SUM = WORK( I )
211: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
212: 70 CONTINUE
213: ELSE
214: DO 80 I = 1, N
215: WORK( I ) = ZERO
216: 80 CONTINUE
217: DO 100 J = 1, N
218: SUM = WORK( J ) + ABS( DBLE( AP( K ) ) )
219: K = K + 1
220: DO 90 I = J + 1, N
221: ABSA = ABS( AP( K ) )
222: SUM = SUM + ABSA
223: WORK( I ) = WORK( I ) + ABSA
224: K = K + 1
225: 90 CONTINUE
226: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
227: 100 CONTINUE
228: END IF
229: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
230: *
231: * Find normF(A).
232: * SSQ(1) is scale
233: * SSQ(2) is sum-of-squares
234: * For better accuracy, sum each column separately.
235: *
236: SSQ( 1 ) = ZERO
237: SSQ( 2 ) = ONE
238: *
239: * Sum off-diagonals
240: *
241: K = 2
242: IF( LSAME( UPLO, 'U' ) ) THEN
243: DO 110 J = 2, N
244: COLSSQ( 1 ) = ZERO
245: COLSSQ( 2 ) = ONE
246: CALL ZLASSQ( J-1, AP( K ), 1, COLSSQ( 1 ), COLSSQ( 2 ) )
247: CALL DCOMBSSQ( SSQ, COLSSQ )
248: K = K + J
249: 110 CONTINUE
250: ELSE
251: DO 120 J = 1, N - 1
252: COLSSQ( 1 ) = ZERO
253: COLSSQ( 2 ) = ONE
254: CALL ZLASSQ( N-J, AP( K ), 1, COLSSQ( 1 ), COLSSQ( 2 ) )
255: CALL DCOMBSSQ( SSQ, COLSSQ )
256: K = K + N - J + 1
257: 120 CONTINUE
258: END IF
259: SSQ( 2 ) = 2*SSQ( 2 )
260: *
261: * Sum diagonal
262: *
263: K = 1
264: COLSSQ( 1 ) = ZERO
265: COLSSQ( 2 ) = ONE
266: DO 130 I = 1, N
267: IF( DBLE( AP( K ) ).NE.ZERO ) THEN
268: ABSA = ABS( DBLE( AP( K ) ) )
269: IF( COLSSQ( 1 ).LT.ABSA ) THEN
270: COLSSQ( 2 ) = ONE + COLSSQ(2)*( COLSSQ(1) / ABSA )**2
271: COLSSQ( 1 ) = ABSA
272: ELSE
273: COLSSQ( 2 ) = COLSSQ( 2 ) + ( ABSA / COLSSQ( 1 ) )**2
274: END IF
275: END IF
276: IF( LSAME( UPLO, 'U' ) ) THEN
277: K = K + I + 1
278: ELSE
279: K = K + N - I + 1
280: END IF
281: 130 CONTINUE
282: CALL DCOMBSSQ( SSQ, COLSSQ )
283: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
284: END IF
285: *
286: ZLANHP = VALUE
287: RETURN
288: *
289: * End of ZLANHP
290: *
291: END
CVSweb interface <joel.bertrand@systella.fr>