1: *> \brief \b ZLANHP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix supplied in packed form.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHP + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhp.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhp.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhp.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM, UPLO
25: * INTEGER N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 AP( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHP returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex hermitian matrix A, supplied in packed form.
41: *> \endverbatim
42: *>
43: *> \return ZLANHP
44: *> \verbatim
45: *>
46: *> ZLANHP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHP as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the upper or lower triangular part of the
74: *> hermitian matrix A is supplied.
75: *> = 'U': Upper triangular part of A is supplied
76: *> = 'L': Lower triangular part of A is supplied
77: *> \endverbatim
78: *>
79: *> \param[in] N
80: *> \verbatim
81: *> N is INTEGER
82: *> The order of the matrix A. N >= 0. When N = 0, ZLANHP is
83: *> set to zero.
84: *> \endverbatim
85: *>
86: *> \param[in] AP
87: *> \verbatim
88: *> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
89: *> The upper or lower triangle of the hermitian matrix A, packed
90: *> columnwise in a linear array. The j-th column of A is stored
91: *> in the array AP as follows:
92: *> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
93: *> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
94: *> Note that the imaginary parts of the diagonal elements need
95: *> not be set and are assumed to be zero.
96: *> \endverbatim
97: *>
98: *> \param[out] WORK
99: *> \verbatim
100: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
101: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
102: *> WORK is not referenced.
103: *> \endverbatim
104: *
105: * Authors:
106: * ========
107: *
108: *> \author Univ. of Tennessee
109: *> \author Univ. of California Berkeley
110: *> \author Univ. of Colorado Denver
111: *> \author NAG Ltd.
112: *
113: *> \ingroup complex16OTHERauxiliary
114: *
115: * =====================================================================
116: DOUBLE PRECISION FUNCTION ZLANHP( NORM, UPLO, N, AP, WORK )
117: *
118: * -- LAPACK auxiliary routine --
119: * -- LAPACK is a software package provided by Univ. of Tennessee, --
120: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121: *
122: * .. Scalar Arguments ..
123: CHARACTER NORM, UPLO
124: INTEGER N
125: * ..
126: * .. Array Arguments ..
127: DOUBLE PRECISION WORK( * )
128: COMPLEX*16 AP( * )
129: * ..
130: *
131: * =====================================================================
132: *
133: * .. Parameters ..
134: DOUBLE PRECISION ONE, ZERO
135: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
136: * ..
137: * .. Local Scalars ..
138: INTEGER I, J, K
139: DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
140: * ..
141: * .. External Functions ..
142: LOGICAL LSAME, DISNAN
143: EXTERNAL LSAME, DISNAN
144: * ..
145: * .. External Subroutines ..
146: EXTERNAL ZLASSQ
147: * ..
148: * .. Intrinsic Functions ..
149: INTRINSIC ABS, DBLE, SQRT
150: * ..
151: * .. Executable Statements ..
152: *
153: IF( N.EQ.0 ) THEN
154: VALUE = ZERO
155: ELSE IF( LSAME( NORM, 'M' ) ) THEN
156: *
157: * Find max(abs(A(i,j))).
158: *
159: VALUE = ZERO
160: IF( LSAME( UPLO, 'U' ) ) THEN
161: K = 0
162: DO 20 J = 1, N
163: DO 10 I = K + 1, K + J - 1
164: SUM = ABS( AP( I ) )
165: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
166: 10 CONTINUE
167: K = K + J
168: SUM = ABS( DBLE( AP( K ) ) )
169: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
170: 20 CONTINUE
171: ELSE
172: K = 1
173: DO 40 J = 1, N
174: SUM = ABS( DBLE( AP( K ) ) )
175: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
176: DO 30 I = K + 1, K + N - J
177: SUM = ABS( AP( I ) )
178: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
179: 30 CONTINUE
180: K = K + N - J + 1
181: 40 CONTINUE
182: END IF
183: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
184: $ ( NORM.EQ.'1' ) ) THEN
185: *
186: * Find normI(A) ( = norm1(A), since A is hermitian).
187: *
188: VALUE = ZERO
189: K = 1
190: IF( LSAME( UPLO, 'U' ) ) THEN
191: DO 60 J = 1, N
192: SUM = ZERO
193: DO 50 I = 1, J - 1
194: ABSA = ABS( AP( K ) )
195: SUM = SUM + ABSA
196: WORK( I ) = WORK( I ) + ABSA
197: K = K + 1
198: 50 CONTINUE
199: WORK( J ) = SUM + ABS( DBLE( AP( K ) ) )
200: K = K + 1
201: 60 CONTINUE
202: DO 70 I = 1, N
203: SUM = WORK( I )
204: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
205: 70 CONTINUE
206: ELSE
207: DO 80 I = 1, N
208: WORK( I ) = ZERO
209: 80 CONTINUE
210: DO 100 J = 1, N
211: SUM = WORK( J ) + ABS( DBLE( AP( K ) ) )
212: K = K + 1
213: DO 90 I = J + 1, N
214: ABSA = ABS( AP( K ) )
215: SUM = SUM + ABSA
216: WORK( I ) = WORK( I ) + ABSA
217: K = K + 1
218: 90 CONTINUE
219: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
220: 100 CONTINUE
221: END IF
222: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
223: *
224: * Find normF(A).
225: *
226: SCALE = ZERO
227: SUM = ONE
228: K = 2
229: IF( LSAME( UPLO, 'U' ) ) THEN
230: DO 110 J = 2, N
231: CALL ZLASSQ( J-1, AP( K ), 1, SCALE, SUM )
232: K = K + J
233: 110 CONTINUE
234: ELSE
235: DO 120 J = 1, N - 1
236: CALL ZLASSQ( N-J, AP( K ), 1, SCALE, SUM )
237: K = K + N - J + 1
238: 120 CONTINUE
239: END IF
240: SUM = 2*SUM
241: K = 1
242: DO 130 I = 1, N
243: IF( DBLE( AP( K ) ).NE.ZERO ) THEN
244: ABSA = ABS( DBLE( AP( K ) ) )
245: IF( SCALE.LT.ABSA ) THEN
246: SUM = ONE + SUM*( SCALE / ABSA )**2
247: SCALE = ABSA
248: ELSE
249: SUM = SUM + ( ABSA / SCALE )**2
250: END IF
251: END IF
252: IF( LSAME( UPLO, 'U' ) ) THEN
253: K = K + I + 1
254: ELSE
255: K = K + N - I + 1
256: END IF
257: 130 CONTINUE
258: VALUE = SCALE*SQRT( SUM )
259: END IF
260: *
261: ZLANHP = VALUE
262: RETURN
263: *
264: * End of ZLANHP
265: *
266: END
CVSweb interface <joel.bertrand@systella.fr>