1: *> \brief \b ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhe.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhe.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhe.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM, UPLO
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHE returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex hermitian matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANHE
44: *> \verbatim
45: *>
46: *> ZLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHE as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the upper or lower triangular part of the
74: *> hermitian matrix A is to be referenced.
75: *> = 'U': Upper triangular part of A is referenced
76: *> = 'L': Lower triangular part of A is referenced
77: *> \endverbatim
78: *>
79: *> \param[in] N
80: *> \verbatim
81: *> N is INTEGER
82: *> The order of the matrix A. N >= 0. When N = 0, ZLANHE is
83: *> set to zero.
84: *> \endverbatim
85: *>
86: *> \param[in] A
87: *> \verbatim
88: *> A is COMPLEX*16 array, dimension (LDA,N)
89: *> The hermitian matrix A. If UPLO = 'U', the leading n by n
90: *> upper triangular part of A contains the upper triangular part
91: *> of the matrix A, and the strictly lower triangular part of A
92: *> is not referenced. If UPLO = 'L', the leading n by n lower
93: *> triangular part of A contains the lower triangular part of
94: *> the matrix A, and the strictly upper triangular part of A is
95: *> not referenced. Note that the imaginary parts of the diagonal
96: *> elements need not be set and are assumed to be zero.
97: *> \endverbatim
98: *>
99: *> \param[in] LDA
100: *> \verbatim
101: *> LDA is INTEGER
102: *> The leading dimension of the array A. LDA >= max(N,1).
103: *> \endverbatim
104: *>
105: *> \param[out] WORK
106: *> \verbatim
107: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
108: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
109: *> WORK is not referenced.
110: *> \endverbatim
111: *
112: * Authors:
113: * ========
114: *
115: *> \author Univ. of Tennessee
116: *> \author Univ. of California Berkeley
117: *> \author Univ. of Colorado Denver
118: *> \author NAG Ltd.
119: *
120: *> \ingroup complex16HEauxiliary
121: *
122: * =====================================================================
123: DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
124: *
125: * -- LAPACK auxiliary routine --
126: * -- LAPACK is a software package provided by Univ. of Tennessee, --
127: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
128: *
129: * .. Scalar Arguments ..
130: CHARACTER NORM, UPLO
131: INTEGER LDA, N
132: * ..
133: * .. Array Arguments ..
134: DOUBLE PRECISION WORK( * )
135: COMPLEX*16 A( LDA, * )
136: * ..
137: *
138: * =====================================================================
139: *
140: * .. Parameters ..
141: DOUBLE PRECISION ONE, ZERO
142: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
143: * ..
144: * .. Local Scalars ..
145: INTEGER I, J
146: DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
147: * ..
148: * .. External Functions ..
149: LOGICAL LSAME, DISNAN
150: EXTERNAL LSAME, DISNAN
151: * ..
152: * .. External Subroutines ..
153: EXTERNAL ZLASSQ
154: * ..
155: * .. Intrinsic Functions ..
156: INTRINSIC ABS, DBLE, SQRT
157: * ..
158: * .. Executable Statements ..
159: *
160: IF( N.EQ.0 ) THEN
161: VALUE = ZERO
162: ELSE IF( LSAME( NORM, 'M' ) ) THEN
163: *
164: * Find max(abs(A(i,j))).
165: *
166: VALUE = ZERO
167: IF( LSAME( UPLO, 'U' ) ) THEN
168: DO 20 J = 1, N
169: DO 10 I = 1, J - 1
170: SUM = ABS( A( I, J ) )
171: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
172: 10 CONTINUE
173: SUM = ABS( DBLE( A( J, J ) ) )
174: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
175: 20 CONTINUE
176: ELSE
177: DO 40 J = 1, N
178: SUM = ABS( DBLE( A( J, J ) ) )
179: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
180: DO 30 I = J + 1, N
181: SUM = ABS( A( I, J ) )
182: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
183: 30 CONTINUE
184: 40 CONTINUE
185: END IF
186: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
187: $ ( NORM.EQ.'1' ) ) THEN
188: *
189: * Find normI(A) ( = norm1(A), since A is hermitian).
190: *
191: VALUE = ZERO
192: IF( LSAME( UPLO, 'U' ) ) THEN
193: DO 60 J = 1, N
194: SUM = ZERO
195: DO 50 I = 1, J - 1
196: ABSA = ABS( A( I, J ) )
197: SUM = SUM + ABSA
198: WORK( I ) = WORK( I ) + ABSA
199: 50 CONTINUE
200: WORK( J ) = SUM + ABS( DBLE( A( J, J ) ) )
201: 60 CONTINUE
202: DO 70 I = 1, N
203: SUM = WORK( I )
204: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
205: 70 CONTINUE
206: ELSE
207: DO 80 I = 1, N
208: WORK( I ) = ZERO
209: 80 CONTINUE
210: DO 100 J = 1, N
211: SUM = WORK( J ) + ABS( DBLE( A( J, J ) ) )
212: DO 90 I = J + 1, N
213: ABSA = ABS( A( I, J ) )
214: SUM = SUM + ABSA
215: WORK( I ) = WORK( I ) + ABSA
216: 90 CONTINUE
217: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
218: 100 CONTINUE
219: END IF
220: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
221: *
222: * Find normF(A).
223: *
224: SCALE = ZERO
225: SUM = ONE
226: IF( LSAME( UPLO, 'U' ) ) THEN
227: DO 110 J = 2, N
228: CALL ZLASSQ( J-1, A( 1, J ), 1, SCALE, SUM )
229: 110 CONTINUE
230: ELSE
231: DO 120 J = 1, N - 1
232: CALL ZLASSQ( N-J, A( J+1, J ), 1, SCALE, SUM )
233: 120 CONTINUE
234: END IF
235: SUM = 2*SUM
236: DO 130 I = 1, N
237: IF( DBLE( A( I, I ) ).NE.ZERO ) THEN
238: ABSA = ABS( DBLE( A( I, I ) ) )
239: IF( SCALE.LT.ABSA ) THEN
240: SUM = ONE + SUM*( SCALE / ABSA )**2
241: SCALE = ABSA
242: ELSE
243: SUM = SUM + ( ABSA / SCALE )**2
244: END IF
245: END IF
246: 130 CONTINUE
247: VALUE = SCALE*SQRT( SUM )
248: END IF
249: *
250: ZLANHE = VALUE
251: RETURN
252: *
253: * End of ZLANHE
254: *
255: END
CVSweb interface <joel.bertrand@systella.fr>