1: *> \brief \b ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANHE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhe.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhe.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhe.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM, UPLO
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHE returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex hermitian matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANHE
44: *> \verbatim
45: *>
46: *> ZLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHE as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the upper or lower triangular part of the
74: *> hermitian matrix A is to be referenced.
75: *> = 'U': Upper triangular part of A is referenced
76: *> = 'L': Lower triangular part of A is referenced
77: *> \endverbatim
78: *>
79: *> \param[in] N
80: *> \verbatim
81: *> N is INTEGER
82: *> The order of the matrix A. N >= 0. When N = 0, ZLANHE is
83: *> set to zero.
84: *> \endverbatim
85: *>
86: *> \param[in] A
87: *> \verbatim
88: *> A is COMPLEX*16 array, dimension (LDA,N)
89: *> The hermitian matrix A. If UPLO = 'U', the leading n by n
90: *> upper triangular part of A contains the upper triangular part
91: *> of the matrix A, and the strictly lower triangular part of A
92: *> is not referenced. If UPLO = 'L', the leading n by n lower
93: *> triangular part of A contains the lower triangular part of
94: *> the matrix A, and the strictly upper triangular part of A is
95: *> not referenced. Note that the imaginary parts of the diagonal
96: *> elements need not be set and are assumed to be zero.
97: *> \endverbatim
98: *>
99: *> \param[in] LDA
100: *> \verbatim
101: *> LDA is INTEGER
102: *> The leading dimension of the array A. LDA >= max(N,1).
103: *> \endverbatim
104: *>
105: *> \param[out] WORK
106: *> \verbatim
107: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
108: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
109: *> WORK is not referenced.
110: *> \endverbatim
111: *
112: * Authors:
113: * ========
114: *
115: *> \author Univ. of Tennessee
116: *> \author Univ. of California Berkeley
117: *> \author Univ. of Colorado Denver
118: *> \author NAG Ltd.
119: *
120: *> \date September 2012
121: *
122: *> \ingroup complex16HEauxiliary
123: *
124: * =====================================================================
125: DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
126: *
127: * -- LAPACK auxiliary routine (version 3.4.2) --
128: * -- LAPACK is a software package provided by Univ. of Tennessee, --
129: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130: * September 2012
131: *
132: * .. Scalar Arguments ..
133: CHARACTER NORM, UPLO
134: INTEGER LDA, N
135: * ..
136: * .. Array Arguments ..
137: DOUBLE PRECISION WORK( * )
138: COMPLEX*16 A( LDA, * )
139: * ..
140: *
141: * =====================================================================
142: *
143: * .. Parameters ..
144: DOUBLE PRECISION ONE, ZERO
145: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
146: * ..
147: * .. Local Scalars ..
148: INTEGER I, J
149: DOUBLE PRECISION ABSA, SCALE, SUM, VALUE
150: * ..
151: * .. External Functions ..
152: LOGICAL LSAME, DISNAN
153: EXTERNAL LSAME, DISNAN
154: * ..
155: * .. External Subroutines ..
156: EXTERNAL ZLASSQ
157: * ..
158: * .. Intrinsic Functions ..
159: INTRINSIC ABS, DBLE, SQRT
160: * ..
161: * .. Executable Statements ..
162: *
163: IF( N.EQ.0 ) THEN
164: VALUE = ZERO
165: ELSE IF( LSAME( NORM, 'M' ) ) THEN
166: *
167: * Find max(abs(A(i,j))).
168: *
169: VALUE = ZERO
170: IF( LSAME( UPLO, 'U' ) ) THEN
171: DO 20 J = 1, N
172: DO 10 I = 1, J - 1
173: SUM = ABS( A( I, J ) )
174: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
175: 10 CONTINUE
176: SUM = ABS( DBLE( A( J, J ) ) )
177: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
178: 20 CONTINUE
179: ELSE
180: DO 40 J = 1, N
181: SUM = ABS( DBLE( A( J, J ) ) )
182: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
183: DO 30 I = J + 1, N
184: SUM = ABS( A( I, J ) )
185: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
186: 30 CONTINUE
187: 40 CONTINUE
188: END IF
189: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
190: $ ( NORM.EQ.'1' ) ) THEN
191: *
192: * Find normI(A) ( = norm1(A), since A is hermitian).
193: *
194: VALUE = ZERO
195: IF( LSAME( UPLO, 'U' ) ) THEN
196: DO 60 J = 1, N
197: SUM = ZERO
198: DO 50 I = 1, J - 1
199: ABSA = ABS( A( I, J ) )
200: SUM = SUM + ABSA
201: WORK( I ) = WORK( I ) + ABSA
202: 50 CONTINUE
203: WORK( J ) = SUM + ABS( DBLE( A( J, J ) ) )
204: 60 CONTINUE
205: DO 70 I = 1, N
206: SUM = WORK( I )
207: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
208: 70 CONTINUE
209: ELSE
210: DO 80 I = 1, N
211: WORK( I ) = ZERO
212: 80 CONTINUE
213: DO 100 J = 1, N
214: SUM = WORK( J ) + ABS( DBLE( A( J, J ) ) )
215: DO 90 I = J + 1, N
216: ABSA = ABS( A( I, J ) )
217: SUM = SUM + ABSA
218: WORK( I ) = WORK( I ) + ABSA
219: 90 CONTINUE
220: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
221: 100 CONTINUE
222: END IF
223: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
224: *
225: * Find normF(A).
226: *
227: SCALE = ZERO
228: SUM = ONE
229: IF( LSAME( UPLO, 'U' ) ) THEN
230: DO 110 J = 2, N
231: CALL ZLASSQ( J-1, A( 1, J ), 1, SCALE, SUM )
232: 110 CONTINUE
233: ELSE
234: DO 120 J = 1, N - 1
235: CALL ZLASSQ( N-J, A( J+1, J ), 1, SCALE, SUM )
236: 120 CONTINUE
237: END IF
238: SUM = 2*SUM
239: DO 130 I = 1, N
240: IF( DBLE( A( I, I ) ).NE.ZERO ) THEN
241: ABSA = ABS( DBLE( A( I, I ) ) )
242: IF( SCALE.LT.ABSA ) THEN
243: SUM = ONE + SUM*( SCALE / ABSA )**2
244: SCALE = ABSA
245: ELSE
246: SUM = SUM + ( ABSA / SCALE )**2
247: END IF
248: END IF
249: 130 CONTINUE
250: VALUE = SCALE*SQRT( SUM )
251: END IF
252: *
253: ZLANHE = VALUE
254: RETURN
255: *
256: * End of ZLANHE
257: *
258: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlanhe.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack