Annotation of rpl/lapack/lapack/zlanhe.f, revision 1.18
1.11 bertrand 1: *> \brief \b ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
1.8 bertrand 2: *
3: * =========== DOCUMENTATION ===========
4: *
1.15 bertrand 5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
1.8 bertrand 7: *
8: *> \htmlonly
1.15 bertrand 9: *> Download ZLANHE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhe.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhe.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhe.f">
1.8 bertrand 15: *> [TXT]</a>
1.15 bertrand 16: *> \endhtmlonly
1.8 bertrand 17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
1.15 bertrand 22: *
1.8 bertrand 23: * .. Scalar Arguments ..
24: * CHARACTER NORM, UPLO
25: * INTEGER LDA, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
1.15 bertrand 31: *
1.8 bertrand 32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANHE returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex hermitian matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANHE
44: *> \verbatim
45: *>
46: *> ZLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANHE as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] UPLO
71: *> \verbatim
72: *> UPLO is CHARACTER*1
73: *> Specifies whether the upper or lower triangular part of the
74: *> hermitian matrix A is to be referenced.
75: *> = 'U': Upper triangular part of A is referenced
76: *> = 'L': Lower triangular part of A is referenced
77: *> \endverbatim
78: *>
79: *> \param[in] N
80: *> \verbatim
81: *> N is INTEGER
82: *> The order of the matrix A. N >= 0. When N = 0, ZLANHE is
83: *> set to zero.
84: *> \endverbatim
85: *>
86: *> \param[in] A
87: *> \verbatim
88: *> A is COMPLEX*16 array, dimension (LDA,N)
89: *> The hermitian matrix A. If UPLO = 'U', the leading n by n
90: *> upper triangular part of A contains the upper triangular part
91: *> of the matrix A, and the strictly lower triangular part of A
92: *> is not referenced. If UPLO = 'L', the leading n by n lower
93: *> triangular part of A contains the lower triangular part of
94: *> the matrix A, and the strictly upper triangular part of A is
95: *> not referenced. Note that the imaginary parts of the diagonal
96: *> elements need not be set and are assumed to be zero.
97: *> \endverbatim
98: *>
99: *> \param[in] LDA
100: *> \verbatim
101: *> LDA is INTEGER
102: *> The leading dimension of the array A. LDA >= max(N,1).
103: *> \endverbatim
104: *>
105: *> \param[out] WORK
106: *> \verbatim
107: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
108: *> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
109: *> WORK is not referenced.
110: *> \endverbatim
111: *
112: * Authors:
113: * ========
114: *
1.15 bertrand 115: *> \author Univ. of Tennessee
116: *> \author Univ. of California Berkeley
117: *> \author Univ. of Colorado Denver
118: *> \author NAG Ltd.
1.8 bertrand 119: *
1.15 bertrand 120: *> \date December 2016
1.8 bertrand 121: *
122: *> \ingroup complex16HEauxiliary
123: *
124: * =====================================================================
1.1 bertrand 125: DOUBLE PRECISION FUNCTION ZLANHE( NORM, UPLO, N, A, LDA, WORK )
126: *
1.15 bertrand 127: * -- LAPACK auxiliary routine (version 3.7.0) --
1.1 bertrand 128: * -- LAPACK is a software package provided by Univ. of Tennessee, --
129: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.15 bertrand 130: * December 2016
1.1 bertrand 131: *
1.18 ! bertrand 132: IMPLICIT NONE
1.1 bertrand 133: * .. Scalar Arguments ..
134: CHARACTER NORM, UPLO
135: INTEGER LDA, N
136: * ..
137: * .. Array Arguments ..
138: DOUBLE PRECISION WORK( * )
139: COMPLEX*16 A( LDA, * )
140: * ..
141: *
142: * =====================================================================
143: *
144: * .. Parameters ..
145: DOUBLE PRECISION ONE, ZERO
146: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
147: * ..
148: * .. Local Scalars ..
149: INTEGER I, J
1.18 ! bertrand 150: DOUBLE PRECISION ABSA, SUM, VALUE
! 151: * ..
! 152: * .. Local Arrays ..
! 153: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
1.1 bertrand 154: * ..
155: * .. External Functions ..
1.11 bertrand 156: LOGICAL LSAME, DISNAN
157: EXTERNAL LSAME, DISNAN
1.1 bertrand 158: * ..
159: * .. External Subroutines ..
1.18 ! bertrand 160: EXTERNAL ZLASSQ, DCOMBSSQ
1.1 bertrand 161: * ..
162: * .. Intrinsic Functions ..
1.11 bertrand 163: INTRINSIC ABS, DBLE, SQRT
1.1 bertrand 164: * ..
165: * .. Executable Statements ..
166: *
167: IF( N.EQ.0 ) THEN
168: VALUE = ZERO
169: ELSE IF( LSAME( NORM, 'M' ) ) THEN
170: *
171: * Find max(abs(A(i,j))).
172: *
173: VALUE = ZERO
174: IF( LSAME( UPLO, 'U' ) ) THEN
175: DO 20 J = 1, N
176: DO 10 I = 1, J - 1
1.11 bertrand 177: SUM = ABS( A( I, J ) )
178: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 179: 10 CONTINUE
1.11 bertrand 180: SUM = ABS( DBLE( A( J, J ) ) )
181: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 182: 20 CONTINUE
183: ELSE
184: DO 40 J = 1, N
1.11 bertrand 185: SUM = ABS( DBLE( A( J, J ) ) )
186: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 187: DO 30 I = J + 1, N
1.11 bertrand 188: SUM = ABS( A( I, J ) )
189: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 190: 30 CONTINUE
191: 40 CONTINUE
192: END IF
193: ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
194: $ ( NORM.EQ.'1' ) ) THEN
195: *
196: * Find normI(A) ( = norm1(A), since A is hermitian).
197: *
198: VALUE = ZERO
199: IF( LSAME( UPLO, 'U' ) ) THEN
200: DO 60 J = 1, N
201: SUM = ZERO
202: DO 50 I = 1, J - 1
203: ABSA = ABS( A( I, J ) )
204: SUM = SUM + ABSA
205: WORK( I ) = WORK( I ) + ABSA
206: 50 CONTINUE
207: WORK( J ) = SUM + ABS( DBLE( A( J, J ) ) )
208: 60 CONTINUE
209: DO 70 I = 1, N
1.11 bertrand 210: SUM = WORK( I )
211: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 212: 70 CONTINUE
213: ELSE
214: DO 80 I = 1, N
215: WORK( I ) = ZERO
216: 80 CONTINUE
217: DO 100 J = 1, N
218: SUM = WORK( J ) + ABS( DBLE( A( J, J ) ) )
219: DO 90 I = J + 1, N
220: ABSA = ABS( A( I, J ) )
221: SUM = SUM + ABSA
222: WORK( I ) = WORK( I ) + ABSA
223: 90 CONTINUE
1.11 bertrand 224: IF( VALUE .LT. SUM .OR. DISNAN( SUM ) ) VALUE = SUM
1.1 bertrand 225: 100 CONTINUE
226: END IF
227: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
228: *
229: * Find normF(A).
1.18 ! bertrand 230: * SSQ(1) is scale
! 231: * SSQ(2) is sum-of-squares
! 232: * For better accuracy, sum each column separately.
! 233: *
! 234: SSQ( 1 ) = ZERO
! 235: SSQ( 2 ) = ONE
! 236: *
! 237: * Sum off-diagonals
1.1 bertrand 238: *
239: IF( LSAME( UPLO, 'U' ) ) THEN
240: DO 110 J = 2, N
1.18 ! bertrand 241: COLSSQ( 1 ) = ZERO
! 242: COLSSQ( 2 ) = ONE
! 243: CALL ZLASSQ( J-1, A( 1, J ), 1,
! 244: $ COLSSQ( 1 ), COLSSQ( 2 ) )
! 245: CALL DCOMBSSQ( SSQ, COLSSQ )
1.1 bertrand 246: 110 CONTINUE
247: ELSE
248: DO 120 J = 1, N - 1
1.18 ! bertrand 249: COLSSQ( 1 ) = ZERO
! 250: COLSSQ( 2 ) = ONE
! 251: CALL ZLASSQ( N-J, A( J+1, J ), 1,
! 252: $ COLSSQ( 1 ), COLSSQ( 2 ) )
! 253: CALL DCOMBSSQ( SSQ, COLSSQ )
1.1 bertrand 254: 120 CONTINUE
255: END IF
1.18 ! bertrand 256: SSQ( 2 ) = 2*SSQ( 2 )
! 257: *
! 258: * Sum diagonal
! 259: *
1.1 bertrand 260: DO 130 I = 1, N
261: IF( DBLE( A( I, I ) ).NE.ZERO ) THEN
262: ABSA = ABS( DBLE( A( I, I ) ) )
1.18 ! bertrand 263: IF( SSQ( 1 ).LT.ABSA ) THEN
! 264: SSQ( 2 ) = ONE + SSQ( 2 )*( SSQ( 1 ) / ABSA )**2
! 265: SSQ( 1 ) = ABSA
1.1 bertrand 266: ELSE
1.18 ! bertrand 267: SSQ( 2 ) = SSQ( 2 ) + ( ABSA / SSQ( 1 ) )**2
1.1 bertrand 268: END IF
269: END IF
270: 130 CONTINUE
1.18 ! bertrand 271: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
1.1 bertrand 272: END IF
273: *
274: ZLANHE = VALUE
275: RETURN
276: *
277: * End of ZLANHE
278: *
279: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlanhe.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack