1: *> \brief \b ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANGE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlange.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlange.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlange.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANGE( NORM, M, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, M, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANGE returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANGE
44: *> \verbatim
45: *>
46: *> ZLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANGE as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] M
71: *> \verbatim
72: *> M is INTEGER
73: *> The number of rows of the matrix A. M >= 0. When M = 0,
74: *> ZLANGE is set to zero.
75: *> \endverbatim
76: *>
77: *> \param[in] N
78: *> \verbatim
79: *> N is INTEGER
80: *> The number of columns of the matrix A. N >= 0. When N = 0,
81: *> ZLANGE is set to zero.
82: *> \endverbatim
83: *>
84: *> \param[in] A
85: *> \verbatim
86: *> A is COMPLEX*16 array, dimension (LDA,N)
87: *> The m by n matrix A.
88: *> \endverbatim
89: *>
90: *> \param[in] LDA
91: *> \verbatim
92: *> LDA is INTEGER
93: *> The leading dimension of the array A. LDA >= max(M,1).
94: *> \endverbatim
95: *>
96: *> \param[out] WORK
97: *> \verbatim
98: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
99: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
100: *> referenced.
101: *> \endverbatim
102: *
103: * Authors:
104: * ========
105: *
106: *> \author Univ. of Tennessee
107: *> \author Univ. of California Berkeley
108: *> \author Univ. of Colorado Denver
109: *> \author NAG Ltd.
110: *
111: *> \ingroup complex16GEauxiliary
112: *
113: * =====================================================================
114: DOUBLE PRECISION FUNCTION ZLANGE( NORM, M, N, A, LDA, WORK )
115: *
116: * -- LAPACK auxiliary routine --
117: * -- LAPACK is a software package provided by Univ. of Tennessee, --
118: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119: *
120: * .. Scalar Arguments ..
121: CHARACTER NORM
122: INTEGER LDA, M, N
123: * ..
124: * .. Array Arguments ..
125: DOUBLE PRECISION WORK( * )
126: COMPLEX*16 A( LDA, * )
127: * ..
128: *
129: * =====================================================================
130: *
131: * .. Parameters ..
132: DOUBLE PRECISION ONE, ZERO
133: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
134: * ..
135: * .. Local Scalars ..
136: INTEGER I, J
137: DOUBLE PRECISION SCALE, SUM, VALUE, TEMP
138: * ..
139: * .. External Functions ..
140: LOGICAL LSAME, DISNAN
141: EXTERNAL LSAME, DISNAN
142: * ..
143: * .. External Subroutines ..
144: EXTERNAL ZLASSQ
145: * ..
146: * .. Intrinsic Functions ..
147: INTRINSIC ABS, MIN, SQRT
148: * ..
149: * .. Executable Statements ..
150: *
151: IF( MIN( M, N ).EQ.0 ) THEN
152: VALUE = ZERO
153: ELSE IF( LSAME( NORM, 'M' ) ) THEN
154: *
155: * Find max(abs(A(i,j))).
156: *
157: VALUE = ZERO
158: DO 20 J = 1, N
159: DO 10 I = 1, M
160: TEMP = ABS( A( I, J ) )
161: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
162: 10 CONTINUE
163: 20 CONTINUE
164: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
165: *
166: * Find norm1(A).
167: *
168: VALUE = ZERO
169: DO 40 J = 1, N
170: SUM = ZERO
171: DO 30 I = 1, M
172: SUM = SUM + ABS( A( I, J ) )
173: 30 CONTINUE
174: IF( VALUE.LT.SUM .OR. DISNAN( SUM ) ) VALUE = SUM
175: 40 CONTINUE
176: ELSE IF( LSAME( NORM, 'I' ) ) THEN
177: *
178: * Find normI(A).
179: *
180: DO 50 I = 1, M
181: WORK( I ) = ZERO
182: 50 CONTINUE
183: DO 70 J = 1, N
184: DO 60 I = 1, M
185: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
186: 60 CONTINUE
187: 70 CONTINUE
188: VALUE = ZERO
189: DO 80 I = 1, M
190: TEMP = WORK( I )
191: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
192: 80 CONTINUE
193: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
194: *
195: * Find normF(A).
196: *
197: SCALE = ZERO
198: SUM = ONE
199: DO 90 J = 1, N
200: CALL ZLASSQ( M, A( 1, J ), 1, SCALE, SUM )
201: 90 CONTINUE
202: VALUE = SCALE*SQRT( SUM )
203: END IF
204: *
205: ZLANGE = VALUE
206: RETURN
207: *
208: * End of ZLANGE
209: *
210: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlange.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack