1: *> \brief \b ZLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANGE + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlange.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlange.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlange.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANGE( NORM, M, N, A, LDA, WORK )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER NORM
25: * INTEGER LDA, M, N
26: * ..
27: * .. Array Arguments ..
28: * DOUBLE PRECISION WORK( * )
29: * COMPLEX*16 A( LDA, * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZLANGE returns the value of the one norm, or the Frobenius norm, or
39: *> the infinity norm, or the element of largest absolute value of a
40: *> complex matrix A.
41: *> \endverbatim
42: *>
43: *> \return ZLANGE
44: *> \verbatim
45: *>
46: *> ZLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
47: *> (
48: *> ( norm1(A), NORM = '1', 'O' or 'o'
49: *> (
50: *> ( normI(A), NORM = 'I' or 'i'
51: *> (
52: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
53: *>
54: *> where norm1 denotes the one norm of a matrix (maximum column sum),
55: *> normI denotes the infinity norm of a matrix (maximum row sum) and
56: *> normF denotes the Frobenius norm of a matrix (square root of sum of
57: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
58: *> \endverbatim
59: *
60: * Arguments:
61: * ==========
62: *
63: *> \param[in] NORM
64: *> \verbatim
65: *> NORM is CHARACTER*1
66: *> Specifies the value to be returned in ZLANGE as described
67: *> above.
68: *> \endverbatim
69: *>
70: *> \param[in] M
71: *> \verbatim
72: *> M is INTEGER
73: *> The number of rows of the matrix A. M >= 0. When M = 0,
74: *> ZLANGE is set to zero.
75: *> \endverbatim
76: *>
77: *> \param[in] N
78: *> \verbatim
79: *> N is INTEGER
80: *> The number of columns of the matrix A. N >= 0. When N = 0,
81: *> ZLANGE is set to zero.
82: *> \endverbatim
83: *>
84: *> \param[in] A
85: *> \verbatim
86: *> A is COMPLEX*16 array, dimension (LDA,N)
87: *> The m by n matrix A.
88: *> \endverbatim
89: *>
90: *> \param[in] LDA
91: *> \verbatim
92: *> LDA is INTEGER
93: *> The leading dimension of the array A. LDA >= max(M,1).
94: *> \endverbatim
95: *>
96: *> \param[out] WORK
97: *> \verbatim
98: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
99: *> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
100: *> referenced.
101: *> \endverbatim
102: *
103: * Authors:
104: * ========
105: *
106: *> \author Univ. of Tennessee
107: *> \author Univ. of California Berkeley
108: *> \author Univ. of Colorado Denver
109: *> \author NAG Ltd.
110: *
111: *> \date December 2016
112: *
113: *> \ingroup complex16GEauxiliary
114: *
115: * =====================================================================
116: DOUBLE PRECISION FUNCTION ZLANGE( NORM, M, N, A, LDA, WORK )
117: *
118: * -- LAPACK auxiliary routine (version 3.7.0) --
119: * -- LAPACK is a software package provided by Univ. of Tennessee, --
120: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
121: * December 2016
122: *
123: IMPLICIT NONE
124: * .. Scalar Arguments ..
125: CHARACTER NORM
126: INTEGER LDA, M, N
127: * ..
128: * .. Array Arguments ..
129: DOUBLE PRECISION WORK( * )
130: COMPLEX*16 A( LDA, * )
131: * ..
132: *
133: * =====================================================================
134: *
135: * .. Parameters ..
136: DOUBLE PRECISION ONE, ZERO
137: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
138: * ..
139: * .. Local Scalars ..
140: INTEGER I, J
141: DOUBLE PRECISION SUM, VALUE, TEMP
142: * ..
143: * .. Local Arrays ..
144: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
145: * ..
146: * .. External Functions ..
147: LOGICAL LSAME, DISNAN
148: EXTERNAL LSAME, DISNAN
149: * ..
150: * .. External Subroutines ..
151: EXTERNAL ZLASSQ, DCOMBSSQ
152: * ..
153: * .. Intrinsic Functions ..
154: INTRINSIC ABS, MIN, SQRT
155: * ..
156: * .. Executable Statements ..
157: *
158: IF( MIN( M, N ).EQ.0 ) THEN
159: VALUE = ZERO
160: ELSE IF( LSAME( NORM, 'M' ) ) THEN
161: *
162: * Find max(abs(A(i,j))).
163: *
164: VALUE = ZERO
165: DO 20 J = 1, N
166: DO 10 I = 1, M
167: TEMP = ABS( A( I, J ) )
168: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
169: 10 CONTINUE
170: 20 CONTINUE
171: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
172: *
173: * Find norm1(A).
174: *
175: VALUE = ZERO
176: DO 40 J = 1, N
177: SUM = ZERO
178: DO 30 I = 1, M
179: SUM = SUM + ABS( A( I, J ) )
180: 30 CONTINUE
181: IF( VALUE.LT.SUM .OR. DISNAN( SUM ) ) VALUE = SUM
182: 40 CONTINUE
183: ELSE IF( LSAME( NORM, 'I' ) ) THEN
184: *
185: * Find normI(A).
186: *
187: DO 50 I = 1, M
188: WORK( I ) = ZERO
189: 50 CONTINUE
190: DO 70 J = 1, N
191: DO 60 I = 1, M
192: WORK( I ) = WORK( I ) + ABS( A( I, J ) )
193: 60 CONTINUE
194: 70 CONTINUE
195: VALUE = ZERO
196: DO 80 I = 1, M
197: TEMP = WORK( I )
198: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
199: 80 CONTINUE
200: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
201: *
202: * Find normF(A).
203: * SSQ(1) is scale
204: * SSQ(2) is sum-of-squares
205: * For better accuracy, sum each column separately.
206: *
207: SSQ( 1 ) = ZERO
208: SSQ( 2 ) = ONE
209: DO 90 J = 1, N
210: COLSSQ( 1 ) = ZERO
211: COLSSQ( 2 ) = ONE
212: CALL ZLASSQ( M, A( 1, J ), 1, COLSSQ( 1 ), COLSSQ( 2 ) )
213: CALL DCOMBSSQ( SSQ, COLSSQ )
214: 90 CONTINUE
215: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
216: END IF
217: *
218: ZLANGE = VALUE
219: RETURN
220: *
221: * End of ZLANGE
222: *
223: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlange.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack