1: *> \brief \b ZLANGB returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of general band matrix.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLANGB + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlangb.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlangb.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlangb.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * DOUBLE PRECISION FUNCTION ZLANGB( NORM, N, KL, KU, AB, LDAB,
22: * WORK )
23: *
24: * .. Scalar Arguments ..
25: * CHARACTER NORM
26: * INTEGER KL, KU, LDAB, N
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION WORK( * )
30: * COMPLEX*16 AB( LDAB, * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZLANGB returns the value of the one norm, or the Frobenius norm, or
40: *> the infinity norm, or the element of largest absolute value of an
41: *> n by n band matrix A, with kl sub-diagonals and ku super-diagonals.
42: *> \endverbatim
43: *>
44: *> \return ZLANGB
45: *> \verbatim
46: *>
47: *> ZLANGB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48: *> (
49: *> ( norm1(A), NORM = '1', 'O' or 'o'
50: *> (
51: *> ( normI(A), NORM = 'I' or 'i'
52: *> (
53: *> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54: *>
55: *> where norm1 denotes the one norm of a matrix (maximum column sum),
56: *> normI denotes the infinity norm of a matrix (maximum row sum) and
57: *> normF denotes the Frobenius norm of a matrix (square root of sum of
58: *> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59: *> \endverbatim
60: *
61: * Arguments:
62: * ==========
63: *
64: *> \param[in] NORM
65: *> \verbatim
66: *> NORM is CHARACTER*1
67: *> Specifies the value to be returned in ZLANGB as described
68: *> above.
69: *> \endverbatim
70: *>
71: *> \param[in] N
72: *> \verbatim
73: *> N is INTEGER
74: *> The order of the matrix A. N >= 0. When N = 0, ZLANGB is
75: *> set to zero.
76: *> \endverbatim
77: *>
78: *> \param[in] KL
79: *> \verbatim
80: *> KL is INTEGER
81: *> The number of sub-diagonals of the matrix A. KL >= 0.
82: *> \endverbatim
83: *>
84: *> \param[in] KU
85: *> \verbatim
86: *> KU is INTEGER
87: *> The number of super-diagonals of the matrix A. KU >= 0.
88: *> \endverbatim
89: *>
90: *> \param[in] AB
91: *> \verbatim
92: *> AB is COMPLEX*16 array, dimension (LDAB,N)
93: *> The band matrix A, stored in rows 1 to KL+KU+1. The j-th
94: *> column of A is stored in the j-th column of the array AB as
95: *> follows:
96: *> AB(ku+1+i-j,j) = A(i,j) for max(1,j-ku)<=i<=min(n,j+kl).
97: *> \endverbatim
98: *>
99: *> \param[in] LDAB
100: *> \verbatim
101: *> LDAB is INTEGER
102: *> The leading dimension of the array AB. LDAB >= KL+KU+1.
103: *> \endverbatim
104: *>
105: *> \param[out] WORK
106: *> \verbatim
107: *> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
108: *> where LWORK >= N when NORM = 'I'; otherwise, WORK is not
109: *> referenced.
110: *> \endverbatim
111: *
112: * Authors:
113: * ========
114: *
115: *> \author Univ. of Tennessee
116: *> \author Univ. of California Berkeley
117: *> \author Univ. of Colorado Denver
118: *> \author NAG Ltd.
119: *
120: *> \date December 2016
121: *
122: *> \ingroup complex16GBauxiliary
123: *
124: * =====================================================================
125: DOUBLE PRECISION FUNCTION ZLANGB( NORM, N, KL, KU, AB, LDAB,
126: $ WORK )
127: *
128: * -- LAPACK auxiliary routine (version 3.7.0) --
129: * -- LAPACK is a software package provided by Univ. of Tennessee, --
130: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
131: * December 2016
132: *
133: IMPLICIT NONE
134: * .. Scalar Arguments ..
135: CHARACTER NORM
136: INTEGER KL, KU, LDAB, N
137: * ..
138: * .. Array Arguments ..
139: DOUBLE PRECISION WORK( * )
140: COMPLEX*16 AB( LDAB, * )
141: * ..
142: *
143: * =====================================================================
144: *
145: * .. Parameters ..
146: DOUBLE PRECISION ONE, ZERO
147: PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
148: * ..
149: * .. Local Scalars ..
150: INTEGER I, J, K, L
151: DOUBLE PRECISION SUM, VALUE, TEMP
152: * ..
153: * .. Local Arrays ..
154: DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
155: * ..
156: * .. External Functions ..
157: LOGICAL LSAME, DISNAN
158: EXTERNAL LSAME, DISNAN
159: * ..
160: * .. External Subroutines ..
161: EXTERNAL ZLASSQ, DCOMBSSQ
162: * ..
163: * .. Intrinsic Functions ..
164: INTRINSIC ABS, MAX, MIN, SQRT
165: * ..
166: * .. Executable Statements ..
167: *
168: IF( N.EQ.0 ) THEN
169: VALUE = ZERO
170: ELSE IF( LSAME( NORM, 'M' ) ) THEN
171: *
172: * Find max(abs(A(i,j))).
173: *
174: VALUE = ZERO
175: DO 20 J = 1, N
176: DO 10 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
177: TEMP = ABS( AB( I, J ) )
178: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
179: 10 CONTINUE
180: 20 CONTINUE
181: ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
182: *
183: * Find norm1(A).
184: *
185: VALUE = ZERO
186: DO 40 J = 1, N
187: SUM = ZERO
188: DO 30 I = MAX( KU+2-J, 1 ), MIN( N+KU+1-J, KL+KU+1 )
189: SUM = SUM + ABS( AB( I, J ) )
190: 30 CONTINUE
191: IF( VALUE.LT.SUM .OR. DISNAN( SUM ) ) VALUE = SUM
192: 40 CONTINUE
193: ELSE IF( LSAME( NORM, 'I' ) ) THEN
194: *
195: * Find normI(A).
196: *
197: DO 50 I = 1, N
198: WORK( I ) = ZERO
199: 50 CONTINUE
200: DO 70 J = 1, N
201: K = KU + 1 - J
202: DO 60 I = MAX( 1, J-KU ), MIN( N, J+KL )
203: WORK( I ) = WORK( I ) + ABS( AB( K+I, J ) )
204: 60 CONTINUE
205: 70 CONTINUE
206: VALUE = ZERO
207: DO 80 I = 1, N
208: TEMP = WORK( I )
209: IF( VALUE.LT.TEMP .OR. DISNAN( TEMP ) ) VALUE = TEMP
210: 80 CONTINUE
211: ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
212: *
213: * Find normF(A).
214: * SSQ(1) is scale
215: * SSQ(2) is sum-of-squares
216: * For better accuracy, sum each column separately.
217: *
218: SSQ( 1 ) = ZERO
219: SSQ( 2 ) = ONE
220: DO 90 J = 1, N
221: L = MAX( 1, J-KU )
222: K = KU + 1 - J + L
223: COLSSQ( 1 ) = ZERO
224: COLSSQ( 2 ) = ONE
225: CALL ZLASSQ( MIN( N, J+KL )-L+1, AB( K, J ), 1,
226: $ COLSSQ( 1 ), COLSSQ( 2 ) )
227: CALL DCOMBSSQ( SSQ, COLSSQ )
228: 90 CONTINUE
229: VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
230: END IF
231: *
232: ZLANGB = VALUE
233: RETURN
234: *
235: * End of ZLANGB
236: *
237: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlangb.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack