1: *
2: * Definition:
3: * ===========
4: *
5: * SUBROUTINE ZLAMSWLQ( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
6: * $ LDT, C, LDC, WORK, LWORK, INFO )
7: *
8: *
9: * .. Scalar Arguments ..
10: * CHARACTER SIDE, TRANS
11: * INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
12: * ..
13: * .. Array Arguments ..
14: * COMPLEX*16 A( LDA, * ), WORK( * ), C(LDC, * ),
15: * $ T( LDT, * )
16: *> \par Purpose:
17: * =============
18: *>
19: *> \verbatim
20: *>
21: *> ZLAMQRTS overwrites the general real M-by-N matrix C with
22: *>
23: *>
24: *> SIDE = 'L' SIDE = 'R'
25: *> TRANS = 'N': Q * C C * Q
26: *> TRANS = 'C': Q**H * C C * Q**H
27: *> where Q is a real orthogonal matrix defined as the product of blocked
28: *> elementary reflectors computed by short wide LQ
29: *> factorization (ZLASWLQ)
30: *> \endverbatim
31: *
32: * Arguments:
33: * ==========
34: *
35: *> \param[in] SIDE
36: *> \verbatim
37: *> SIDE is CHARACTER*1
38: *> = 'L': apply Q or Q**H from the Left;
39: *> = 'R': apply Q or Q**H from the Right.
40: *> \endverbatim
41: *>
42: *> \param[in] TRANS
43: *> \verbatim
44: *> TRANS is CHARACTER*1
45: *> = 'N': No transpose, apply Q;
46: *> = 'C': Conjugate Transpose, apply Q**H.
47: *> \endverbatim
48: *>
49: *> \param[in] M
50: *> \verbatim
51: *> M is INTEGER
52: *> The number of rows of the matrix C. M >=0.
53: *> \endverbatim
54: *>
55: *> \param[in] N
56: *> \verbatim
57: *> N is INTEGER
58: *> The number of columns of the matrix C. N >= M.
59: *> \endverbatim
60: *>
61: *> \param[in] K
62: *> \verbatim
63: *> K is INTEGER
64: *> The number of elementary reflectors whose product defines
65: *> the matrix Q.
66: *> M >= K >= 0;
67: *>
68: *> \endverbatim
69: *> \param[in] MB
70: *> \verbatim
71: *> MB is INTEGER
72: *> The row block size to be used in the blocked QR.
73: *> M >= MB >= 1
74: *> \endverbatim
75: *>
76: *> \param[in] NB
77: *> \verbatim
78: *> NB is INTEGER
79: *> The column block size to be used in the blocked QR.
80: *> NB > M.
81: *> \endverbatim
82: *>
83: *> \param[in] NB
84: *> \verbatim
85: *> NB is INTEGER
86: *> The block size to be used in the blocked QR.
87: *> MB > M.
88: *>
89: *> \endverbatim
90: *>
91: *> \param[in] A
92: *> \verbatim
93: *> A is COMPLEX*16 array, dimension
94: *> (LDA,M) if SIDE = 'L',
95: *> (LDA,N) if SIDE = 'R'
96: *> The i-th row must contain the vector which defines the blocked
97: *> elementary reflector H(i), for i = 1,2,...,k, as returned by
98: *> ZLASWLQ in the first k rows of its array argument A.
99: *> \endverbatim
100: *>
101: *> \param[in] LDA
102: *> \verbatim
103: *> LDA is INTEGER
104: *> The leading dimension of the array A.
105: *> If SIDE = 'L', LDA >= max(1,M);
106: *> if SIDE = 'R', LDA >= max(1,N).
107: *> \endverbatim
108: *>
109: *> \param[in] T
110: *> \verbatim
111: *> T is COMPLEX*16 array, dimension
112: *> ( M * Number of blocks(CEIL(N-K/NB-K)),
113: *> The blocked upper triangular block reflectors stored in compact form
114: *> as a sequence of upper triangular blocks. See below
115: *> for further details.
116: *> \endverbatim
117: *>
118: *> \param[in] LDT
119: *> \verbatim
120: *> LDT is INTEGER
121: *> The leading dimension of the array T. LDT >= MB.
122: *> \endverbatim
123: *>
124: *> \param[in,out] C
125: *> \verbatim
126: *> C is COMPLEX*16 array, dimension (LDC,N)
127: *> On entry, the M-by-N matrix C.
128: *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
129: *> \endverbatim
130: *>
131: *> \param[in] LDC
132: *> \verbatim
133: *> LDC is INTEGER
134: *> The leading dimension of the array C. LDC >= max(1,M).
135: *> \endverbatim
136: *>
137: *> \param[out] WORK
138: *> \verbatim
139: *> (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
140: *> \endverbatim
141: *>
142: *> \param[in] LWORK
143: *> \verbatim
144: *> LWORK is INTEGER
145: *> The dimension of the array WORK.
146: *> If SIDE = 'L', LWORK >= max(1,NB) * MB;
147: *> if SIDE = 'R', LWORK >= max(1,M) * MB.
148: *> If LWORK = -1, then a workspace query is assumed; the routine
149: *> only calculates the optimal size of the WORK array, returns
150: *> this value as the first entry of the WORK array, and no error
151: *> message related to LWORK is issued by XERBLA.
152: *> \endverbatim
153: *>
154: *> \param[out] INFO
155: *> \verbatim
156: *> INFO is INTEGER
157: *> = 0: successful exit
158: *> < 0: if INFO = -i, the i-th argument had an illegal value
159: *> \endverbatim
160: *
161: * Authors:
162: * ========
163: *
164: *> \author Univ. of Tennessee
165: *> \author Univ. of California Berkeley
166: *> \author Univ. of Colorado Denver
167: *> \author NAG Ltd.
168: *
169: *> \par Further Details:
170: * =====================
171: *>
172: *> \verbatim
173: *> Short-Wide LQ (SWLQ) performs LQ by a sequence of orthogonal transformations,
174: *> representing Q as a product of other orthogonal matrices
175: *> Q = Q(1) * Q(2) * . . . * Q(k)
176: *> where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
177: *> Q(1) zeros out the upper diagonal entries of rows 1:NB of A
178: *> Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
179: *> Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
180: *> . . .
181: *>
182: *> Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
183: *> stored under the diagonal of rows 1:MB of A, and by upper triangular
184: *> block reflectors, stored in array T(1:LDT,1:N).
185: *> For more information see Further Details in GELQT.
186: *>
187: *> Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
188: *> stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
189: *> block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
190: *> The last Q(k) may use fewer rows.
191: *> For more information see Further Details in TPQRT.
192: *>
193: *> For more details of the overall algorithm, see the description of
194: *> Sequential TSQR in Section 2.2 of [1].
195: *>
196: *> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
197: *> J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
198: *> SIAM J. Sci. Comput, vol. 34, no. 1, 2012
199: *> \endverbatim
200: *>
201: * =====================================================================
202: SUBROUTINE ZLAMSWLQ( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
203: $ LDT, C, LDC, WORK, LWORK, INFO )
204: *
205: * -- LAPACK computational routine (version 3.7.1) --
206: * -- LAPACK is a software package provided by Univ. of Tennessee, --
207: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
208: * June 2017
209: *
210: * .. Scalar Arguments ..
211: CHARACTER SIDE, TRANS
212: INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
213: * ..
214: * .. Array Arguments ..
215: COMPLEX*16 A( LDA, * ), WORK( * ), C(LDC, * ),
216: $ T( LDT, * )
217: * ..
218: *
219: * =====================================================================
220: *
221: * ..
222: * .. Local Scalars ..
223: LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
224: INTEGER I, II, KK, LW, CTR
225: * ..
226: * .. External Functions ..
227: LOGICAL LSAME
228: EXTERNAL LSAME
229: * .. External Subroutines ..
230: EXTERNAL ZTPMLQT, ZGEMLQT, XERBLA
231: * ..
232: * .. Executable Statements ..
233: *
234: * Test the input arguments
235: *
236: LQUERY = LWORK.LT.0
237: NOTRAN = LSAME( TRANS, 'N' )
238: TRAN = LSAME( TRANS, 'C' )
239: LEFT = LSAME( SIDE, 'L' )
240: RIGHT = LSAME( SIDE, 'R' )
241: IF (LEFT) THEN
242: LW = N * MB
243: ELSE
244: LW = M * MB
245: END IF
246: *
247: INFO = 0
248: IF( .NOT.LEFT .AND. .NOT.RIGHT ) THEN
249: INFO = -1
250: ELSE IF( .NOT.TRAN .AND. .NOT.NOTRAN ) THEN
251: INFO = -2
252: ELSE IF( M.LT.0 ) THEN
253: INFO = -3
254: ELSE IF( N.LT.0 ) THEN
255: INFO = -4
256: ELSE IF( K.LT.0 ) THEN
257: INFO = -5
258: ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
259: INFO = -9
260: ELSE IF( LDT.LT.MAX( 1, MB) ) THEN
261: INFO = -11
262: ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
263: INFO = -13
264: ELSE IF(( LWORK.LT.MAX(1,LW)).AND.(.NOT.LQUERY)) THEN
265: INFO = -15
266: END IF
267: *
268: IF( INFO.NE.0 ) THEN
269: CALL XERBLA( 'ZLAMSWLQ', -INFO )
270: WORK(1) = LW
271: RETURN
272: ELSE IF (LQUERY) THEN
273: WORK(1) = LW
274: RETURN
275: END IF
276: *
277: * Quick return if possible
278: *
279: IF( MIN(M,N,K).EQ.0 ) THEN
280: RETURN
281: END IF
282: *
283: IF((NB.LE.K).OR.(NB.GE.MAX(M,N,K))) THEN
284: CALL ZGEMLQT( SIDE, TRANS, M, N, K, MB, A, LDA,
285: $ T, LDT, C, LDC, WORK, INFO)
286: RETURN
287: END IF
288: *
289: IF(LEFT.AND.TRAN) THEN
290: *
291: * Multiply Q to the last block of C
292: *
293: KK = MOD((M-K),(NB-K))
294: CTR = (M-K)/(NB-K)
295: *
296: IF (KK.GT.0) THEN
297: II=M-KK+1
298: CALL ZTPMLQT('L','C',KK , N, K, 0, MB, A(1,II), LDA,
299: $ T(1,CTR*K+1), LDT, C(1,1), LDC,
300: $ C(II,1), LDC, WORK, INFO )
301: ELSE
302: II=M+1
303: END IF
304: *
305: DO I=II-(NB-K),NB+1,-(NB-K)
306: *
307: * Multiply Q to the current block of C (1:M,I:I+NB)
308: *
309: CTR = CTR - 1
310: CALL ZTPMLQT('L','C',NB-K , N, K, 0,MB, A(1,I), LDA,
311: $ T(1,CTR*K+1),LDT, C(1,1), LDC,
312: $ C(I,1), LDC, WORK, INFO )
313:
314: END DO
315: *
316: * Multiply Q to the first block of C (1:M,1:NB)
317: *
318: CALL ZGEMLQT('L','C',NB , N, K, MB, A(1,1), LDA, T
319: $ ,LDT ,C(1,1), LDC, WORK, INFO )
320: *
321: ELSE IF (LEFT.AND.NOTRAN) THEN
322: *
323: * Multiply Q to the first block of C
324: *
325: KK = MOD((M-K),(NB-K))
326: II=M-KK+1
327: CTR = 1
328: CALL ZGEMLQT('L','N',NB , N, K, MB, A(1,1), LDA, T
329: $ ,LDT ,C(1,1), LDC, WORK, INFO )
330: *
331: DO I=NB+1,II-NB+K,(NB-K)
332: *
333: * Multiply Q to the current block of C (I:I+NB,1:N)
334: *
335: CALL ZTPMLQT('L','N',NB-K , N, K, 0,MB, A(1,I), LDA,
336: $ T(1, CTR * K + 1), LDT, C(1,1), LDC,
337: $ C(I,1), LDC, WORK, INFO )
338: CTR = CTR + 1
339: *
340: END DO
341: IF(II.LE.M) THEN
342: *
343: * Multiply Q to the last block of C
344: *
345: CALL ZTPMLQT('L','N',KK , N, K, 0, MB, A(1,II), LDA,
346: $ T(1, CTR * K + 1), LDT, C(1,1), LDC,
347: $ C(II,1), LDC, WORK, INFO )
348: *
349: END IF
350: *
351: ELSE IF(RIGHT.AND.NOTRAN) THEN
352: *
353: * Multiply Q to the last block of C
354: *
355: KK = MOD((N-K),(NB-K))
356: CTR = (N-K)/(NB-K)
357: IF (KK.GT.0) THEN
358: II=N-KK+1
359: CALL ZTPMLQT('R','N',M , KK, K, 0, MB, A(1, II), LDA,
360: $ T(1, CTR * K + 1), LDT, C(1,1), LDC,
361: $ C(1,II), LDC, WORK, INFO )
362: ELSE
363: II=N+1
364: END IF
365: *
366: DO I=II-(NB-K),NB+1,-(NB-K)
367: *
368: * Multiply Q to the current block of C (1:M,I:I+MB)
369: *
370: CTR = CTR - 1
371: CALL ZTPMLQT('R','N', M, NB-K, K, 0, MB, A(1, I), LDA,
372: $ T(1, CTR * K + 1), LDT, C(1,1), LDC,
373: $ C(1,I), LDC, WORK, INFO )
374:
375: END DO
376: *
377: * Multiply Q to the first block of C (1:M,1:MB)
378: *
379: CALL ZGEMLQT('R','N',M , NB, K, MB, A(1,1), LDA, T
380: $ ,LDT ,C(1,1), LDC, WORK, INFO )
381: *
382: ELSE IF (RIGHT.AND.TRAN) THEN
383: *
384: * Multiply Q to the first block of C
385: *
386: KK = MOD((N-K),(NB-K))
387: II=N-KK+1
388: CALL ZGEMLQT('R','C',M , NB, K, MB, A(1,1), LDA, T
389: $ ,LDT ,C(1,1), LDC, WORK, INFO )
390: CTR = 1
391: *
392: DO I=NB+1,II-NB+K,(NB-K)
393: *
394: * Multiply Q to the current block of C (1:M,I:I+MB)
395: *
396: CALL ZTPMLQT('R','C',M , NB-K, K, 0,MB, A(1,I), LDA,
397: $ T(1,CTR *K+1), LDT, C(1,1), LDC,
398: $ C(1,I), LDC, WORK, INFO )
399: CTR = CTR + 1
400: *
401: END DO
402: IF(II.LE.N) THEN
403: *
404: * Multiply Q to the last block of C
405: *
406: CALL ZTPMLQT('R','C',M , KK, K, 0,MB, A(1,II), LDA,
407: $ T(1, CTR * K + 1),LDT, C(1,1), LDC,
408: $ C(1,II), LDC, WORK, INFO )
409: *
410: END IF
411: *
412: END IF
413: *
414: WORK(1) = LW
415: RETURN
416: *
417: * End of ZLAMSWLQ
418: *
419: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zlamswlq.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack