1: *> \brief \b ZLA_SYRFSX_EXTENDED improves the computed solution to a system of linear equations for symmetric indefinite matrices by performing extra-precise iterative refinement and provides error bounds and backward error estimates for the solution.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLA_SYRFSX_EXTENDED + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
22: * AF, LDAF, IPIV, COLEQU, C, B, LDB,
23: * Y, LDY, BERR_OUT, N_NORMS,
24: * ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
25: * AYB, DY, Y_TAIL, RCOND, ITHRESH,
26: * RTHRESH, DZ_UB, IGNORE_CWISE,
27: * INFO )
28: *
29: * .. Scalar Arguments ..
30: * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
31: * $ N_NORMS, ITHRESH
32: * CHARACTER UPLO
33: * LOGICAL COLEQU, IGNORE_CWISE
34: * DOUBLE PRECISION RTHRESH, DZ_UB
35: * ..
36: * .. Array Arguments ..
37: * INTEGER IPIV( * )
38: * COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
39: * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
40: * DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
41: * $ ERR_BNDS_NORM( NRHS, * ),
42: * $ ERR_BNDS_COMP( NRHS, * )
43: * ..
44: *
45: *
46: *> \par Purpose:
47: * =============
48: *>
49: *> \verbatim
50: *>
51: *> ZLA_SYRFSX_EXTENDED improves the computed solution to a system of
52: *> linear equations by performing extra-precise iterative refinement
53: *> and provides error bounds and backward error estimates for the solution.
54: *> This subroutine is called by ZSYRFSX to perform iterative refinement.
55: *> In addition to normwise error bound, the code provides maximum
56: *> componentwise error bound if possible. See comments for ERR_BNDS_NORM
57: *> and ERR_BNDS_COMP for details of the error bounds. Note that this
58: *> subroutine is only resonsible for setting the second fields of
59: *> ERR_BNDS_NORM and ERR_BNDS_COMP.
60: *> \endverbatim
61: *
62: * Arguments:
63: * ==========
64: *
65: *> \param[in] PREC_TYPE
66: *> \verbatim
67: *> PREC_TYPE is INTEGER
68: *> Specifies the intermediate precision to be used in refinement.
69: *> The value is defined by ILAPREC(P) where P is a CHARACTER and
70: *> P = 'S': Single
71: *> = 'D': Double
72: *> = 'I': Indigenous
73: *> = 'X', 'E': Extra
74: *> \endverbatim
75: *>
76: *> \param[in] UPLO
77: *> \verbatim
78: *> UPLO is CHARACTER*1
79: *> = 'U': Upper triangle of A is stored;
80: *> = 'L': Lower triangle of A is stored.
81: *> \endverbatim
82: *>
83: *> \param[in] N
84: *> \verbatim
85: *> N is INTEGER
86: *> The number of linear equations, i.e., the order of the
87: *> matrix A. N >= 0.
88: *> \endverbatim
89: *>
90: *> \param[in] NRHS
91: *> \verbatim
92: *> NRHS is INTEGER
93: *> The number of right-hand-sides, i.e., the number of columns of the
94: *> matrix B.
95: *> \endverbatim
96: *>
97: *> \param[in] A
98: *> \verbatim
99: *> A is COMPLEX*16 array, dimension (LDA,N)
100: *> On entry, the N-by-N matrix A.
101: *> \endverbatim
102: *>
103: *> \param[in] LDA
104: *> \verbatim
105: *> LDA is INTEGER
106: *> The leading dimension of the array A. LDA >= max(1,N).
107: *> \endverbatim
108: *>
109: *> \param[in] AF
110: *> \verbatim
111: *> AF is COMPLEX*16 array, dimension (LDAF,N)
112: *> The block diagonal matrix D and the multipliers used to
113: *> obtain the factor U or L as computed by ZSYTRF.
114: *> \endverbatim
115: *>
116: *> \param[in] LDAF
117: *> \verbatim
118: *> LDAF is INTEGER
119: *> The leading dimension of the array AF. LDAF >= max(1,N).
120: *> \endverbatim
121: *>
122: *> \param[in] IPIV
123: *> \verbatim
124: *> IPIV is INTEGER array, dimension (N)
125: *> Details of the interchanges and the block structure of D
126: *> as determined by ZSYTRF.
127: *> \endverbatim
128: *>
129: *> \param[in] COLEQU
130: *> \verbatim
131: *> COLEQU is LOGICAL
132: *> If .TRUE. then column equilibration was done to A before calling
133: *> this routine. This is needed to compute the solution and error
134: *> bounds correctly.
135: *> \endverbatim
136: *>
137: *> \param[in] C
138: *> \verbatim
139: *> C is DOUBLE PRECISION array, dimension (N)
140: *> The column scale factors for A. If COLEQU = .FALSE., C
141: *> is not accessed. If C is input, each element of C should be a power
142: *> of the radix to ensure a reliable solution and error estimates.
143: *> Scaling by powers of the radix does not cause rounding errors unless
144: *> the result underflows or overflows. Rounding errors during scaling
145: *> lead to refining with a matrix that is not equivalent to the
146: *> input matrix, producing error estimates that may not be
147: *> reliable.
148: *> \endverbatim
149: *>
150: *> \param[in] B
151: *> \verbatim
152: *> B is COMPLEX*16 array, dimension (LDB,NRHS)
153: *> The right-hand-side matrix B.
154: *> \endverbatim
155: *>
156: *> \param[in] LDB
157: *> \verbatim
158: *> LDB is INTEGER
159: *> The leading dimension of the array B. LDB >= max(1,N).
160: *> \endverbatim
161: *>
162: *> \param[in,out] Y
163: *> \verbatim
164: *> Y is COMPLEX*16 array, dimension (LDY,NRHS)
165: *> On entry, the solution matrix X, as computed by ZSYTRS.
166: *> On exit, the improved solution matrix Y.
167: *> \endverbatim
168: *>
169: *> \param[in] LDY
170: *> \verbatim
171: *> LDY is INTEGER
172: *> The leading dimension of the array Y. LDY >= max(1,N).
173: *> \endverbatim
174: *>
175: *> \param[out] BERR_OUT
176: *> \verbatim
177: *> BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
178: *> On exit, BERR_OUT(j) contains the componentwise relative backward
179: *> error for right-hand-side j from the formula
180: *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
181: *> where abs(Z) is the componentwise absolute value of the matrix
182: *> or vector Z. This is computed by ZLA_LIN_BERR.
183: *> \endverbatim
184: *>
185: *> \param[in] N_NORMS
186: *> \verbatim
187: *> N_NORMS is INTEGER
188: *> Determines which error bounds to return (see ERR_BNDS_NORM
189: *> and ERR_BNDS_COMP).
190: *> If N_NORMS >= 1 return normwise error bounds.
191: *> If N_NORMS >= 2 return componentwise error bounds.
192: *> \endverbatim
193: *>
194: *> \param[in,out] ERR_BNDS_NORM
195: *> \verbatim
196: *> ERR_BNDS_NORM is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
197: *> For each right-hand side, this array contains information about
198: *> various error bounds and condition numbers corresponding to the
199: *> normwise relative error, which is defined as follows:
200: *>
201: *> Normwise relative error in the ith solution vector:
202: *> max_j (abs(XTRUE(j,i) - X(j,i)))
203: *> ------------------------------
204: *> max_j abs(X(j,i))
205: *>
206: *> The array is indexed by the type of error information as described
207: *> below. There currently are up to three pieces of information
208: *> returned.
209: *>
210: *> The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
211: *> right-hand side.
212: *>
213: *> The second index in ERR_BNDS_NORM(:,err) contains the following
214: *> three fields:
215: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
216: *> reciprocal condition number is less than the threshold
217: *> sqrt(n) * slamch('Epsilon').
218: *>
219: *> err = 2 "Guaranteed" error bound: The estimated forward error,
220: *> almost certainly within a factor of 10 of the true error
221: *> so long as the next entry is greater than the threshold
222: *> sqrt(n) * slamch('Epsilon'). This error bound should only
223: *> be trusted if the previous boolean is true.
224: *>
225: *> err = 3 Reciprocal condition number: Estimated normwise
226: *> reciprocal condition number. Compared with the threshold
227: *> sqrt(n) * slamch('Epsilon') to determine if the error
228: *> estimate is "guaranteed". These reciprocal condition
229: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
230: *> appropriately scaled matrix Z.
231: *> Let Z = S*A, where S scales each row by a power of the
232: *> radix so all absolute row sums of Z are approximately 1.
233: *>
234: *> This subroutine is only responsible for setting the second field
235: *> above.
236: *> See Lapack Working Note 165 for further details and extra
237: *> cautions.
238: *> \endverbatim
239: *>
240: *> \param[in,out] ERR_BNDS_COMP
241: *> \verbatim
242: *> ERR_BNDS_COMP is DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
243: *> For each right-hand side, this array contains information about
244: *> various error bounds and condition numbers corresponding to the
245: *> componentwise relative error, which is defined as follows:
246: *>
247: *> Componentwise relative error in the ith solution vector:
248: *> abs(XTRUE(j,i) - X(j,i))
249: *> max_j ----------------------
250: *> abs(X(j,i))
251: *>
252: *> The array is indexed by the right-hand side i (on which the
253: *> componentwise relative error depends), and the type of error
254: *> information as described below. There currently are up to three
255: *> pieces of information returned for each right-hand side. If
256: *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
257: *> ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
258: *> the first (:,N_ERR_BNDS) entries are returned.
259: *>
260: *> The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
261: *> right-hand side.
262: *>
263: *> The second index in ERR_BNDS_COMP(:,err) contains the following
264: *> three fields:
265: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
266: *> reciprocal condition number is less than the threshold
267: *> sqrt(n) * slamch('Epsilon').
268: *>
269: *> err = 2 "Guaranteed" error bound: The estimated forward error,
270: *> almost certainly within a factor of 10 of the true error
271: *> so long as the next entry is greater than the threshold
272: *> sqrt(n) * slamch('Epsilon'). This error bound should only
273: *> be trusted if the previous boolean is true.
274: *>
275: *> err = 3 Reciprocal condition number: Estimated componentwise
276: *> reciprocal condition number. Compared with the threshold
277: *> sqrt(n) * slamch('Epsilon') to determine if the error
278: *> estimate is "guaranteed". These reciprocal condition
279: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
280: *> appropriately scaled matrix Z.
281: *> Let Z = S*(A*diag(x)), where x is the solution for the
282: *> current right-hand side and S scales each row of
283: *> A*diag(x) by a power of the radix so all absolute row
284: *> sums of Z are approximately 1.
285: *>
286: *> This subroutine is only responsible for setting the second field
287: *> above.
288: *> See Lapack Working Note 165 for further details and extra
289: *> cautions.
290: *> \endverbatim
291: *>
292: *> \param[in] RES
293: *> \verbatim
294: *> RES is COMPLEX*16 array, dimension (N)
295: *> Workspace to hold the intermediate residual.
296: *> \endverbatim
297: *>
298: *> \param[in] AYB
299: *> \verbatim
300: *> AYB is DOUBLE PRECISION array, dimension (N)
301: *> Workspace.
302: *> \endverbatim
303: *>
304: *> \param[in] DY
305: *> \verbatim
306: *> DY is COMPLEX*16 array, dimension (N)
307: *> Workspace to hold the intermediate solution.
308: *> \endverbatim
309: *>
310: *> \param[in] Y_TAIL
311: *> \verbatim
312: *> Y_TAIL is COMPLEX*16 array, dimension (N)
313: *> Workspace to hold the trailing bits of the intermediate solution.
314: *> \endverbatim
315: *>
316: *> \param[in] RCOND
317: *> \verbatim
318: *> RCOND is DOUBLE PRECISION
319: *> Reciprocal scaled condition number. This is an estimate of the
320: *> reciprocal Skeel condition number of the matrix A after
321: *> equilibration (if done). If this is less than the machine
322: *> precision (in particular, if it is zero), the matrix is singular
323: *> to working precision. Note that the error may still be small even
324: *> if this number is very small and the matrix appears ill-
325: *> conditioned.
326: *> \endverbatim
327: *>
328: *> \param[in] ITHRESH
329: *> \verbatim
330: *> ITHRESH is INTEGER
331: *> The maximum number of residual computations allowed for
332: *> refinement. The default is 10. For 'aggressive' set to 100 to
333: *> permit convergence using approximate factorizations or
334: *> factorizations other than LU. If the factorization uses a
335: *> technique other than Gaussian elimination, the guarantees in
336: *> ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
337: *> \endverbatim
338: *>
339: *> \param[in] RTHRESH
340: *> \verbatim
341: *> RTHRESH is DOUBLE PRECISION
342: *> Determines when to stop refinement if the error estimate stops
343: *> decreasing. Refinement will stop when the next solution no longer
344: *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
345: *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
346: *> default value is 0.5. For 'aggressive' set to 0.9 to permit
347: *> convergence on extremely ill-conditioned matrices. See LAWN 165
348: *> for more details.
349: *> \endverbatim
350: *>
351: *> \param[in] DZ_UB
352: *> \verbatim
353: *> DZ_UB is DOUBLE PRECISION
354: *> Determines when to start considering componentwise convergence.
355: *> Componentwise convergence is only considered after each component
356: *> of the solution Y is stable, which we definte as the relative
357: *> change in each component being less than DZ_UB. The default value
358: *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
359: *> more details.
360: *> \endverbatim
361: *>
362: *> \param[in] IGNORE_CWISE
363: *> \verbatim
364: *> IGNORE_CWISE is LOGICAL
365: *> If .TRUE. then ignore componentwise convergence. Default value
366: *> is .FALSE..
367: *> \endverbatim
368: *>
369: *> \param[out] INFO
370: *> \verbatim
371: *> INFO is INTEGER
372: *> = 0: Successful exit.
373: *> < 0: if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
374: *> value
375: *> \endverbatim
376: *
377: * Authors:
378: * ========
379: *
380: *> \author Univ. of Tennessee
381: *> \author Univ. of California Berkeley
382: *> \author Univ. of Colorado Denver
383: *> \author NAG Ltd.
384: *
385: *> \date June 2017
386: *
387: *> \ingroup complex16SYcomputational
388: *
389: * =====================================================================
390: SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
391: $ AF, LDAF, IPIV, COLEQU, C, B, LDB,
392: $ Y, LDY, BERR_OUT, N_NORMS,
393: $ ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
394: $ AYB, DY, Y_TAIL, RCOND, ITHRESH,
395: $ RTHRESH, DZ_UB, IGNORE_CWISE,
396: $ INFO )
397: *
398: * -- LAPACK computational routine (version 3.7.1) --
399: * -- LAPACK is a software package provided by Univ. of Tennessee, --
400: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
401: * June 2017
402: *
403: * .. Scalar Arguments ..
404: INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
405: $ N_NORMS, ITHRESH
406: CHARACTER UPLO
407: LOGICAL COLEQU, IGNORE_CWISE
408: DOUBLE PRECISION RTHRESH, DZ_UB
409: * ..
410: * .. Array Arguments ..
411: INTEGER IPIV( * )
412: COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
413: $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
414: DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
415: $ ERR_BNDS_NORM( NRHS, * ),
416: $ ERR_BNDS_COMP( NRHS, * )
417: * ..
418: *
419: * =====================================================================
420: *
421: * .. Local Scalars ..
422: INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
423: $ Y_PREC_STATE
424: DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
425: $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
426: $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
427: $ EPS, HUGEVAL, INCR_THRESH
428: LOGICAL INCR_PREC, UPPER
429: COMPLEX*16 ZDUM
430: * ..
431: * .. Parameters ..
432: INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
433: $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
434: $ EXTRA_Y
435: PARAMETER ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
436: $ CONV_STATE = 2, NOPROG_STATE = 3 )
437: PARAMETER ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
438: $ EXTRA_Y = 2 )
439: INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
440: INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
441: INTEGER CMP_ERR_I, PIV_GROWTH_I
442: PARAMETER ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
443: $ BERR_I = 3 )
444: PARAMETER ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
445: PARAMETER ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
446: $ PIV_GROWTH_I = 9 )
447: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
448: $ LA_LINRX_CWISE_I
449: PARAMETER ( LA_LINRX_ITREF_I = 1,
450: $ LA_LINRX_ITHRESH_I = 2 )
451: PARAMETER ( LA_LINRX_CWISE_I = 3 )
452: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
453: $ LA_LINRX_RCOND_I
454: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
455: PARAMETER ( LA_LINRX_RCOND_I = 3 )
456: * ..
457: * .. External Functions ..
458: LOGICAL LSAME
459: EXTERNAL ILAUPLO
460: INTEGER ILAUPLO
461: * ..
462: * .. External Subroutines ..
463: EXTERNAL ZAXPY, ZCOPY, ZSYTRS, ZSYMV, BLAS_ZSYMV_X,
464: $ BLAS_ZSYMV2_X, ZLA_SYAMV, ZLA_WWADDW,
465: $ ZLA_LIN_BERR
466: DOUBLE PRECISION DLAMCH
467: * ..
468: * .. Intrinsic Functions ..
469: INTRINSIC ABS, REAL, DIMAG, MAX, MIN
470: * ..
471: * .. Statement Functions ..
472: DOUBLE PRECISION CABS1
473: * ..
474: * .. Statement Function Definitions ..
475: CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
476: * ..
477: * .. Executable Statements ..
478: *
479: INFO = 0
480: UPPER = LSAME( UPLO, 'U' )
481: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
482: INFO = -2
483: ELSE IF( N.LT.0 ) THEN
484: INFO = -3
485: ELSE IF( NRHS.LT.0 ) THEN
486: INFO = -4
487: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
488: INFO = -6
489: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
490: INFO = -8
491: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
492: INFO = -13
493: ELSE IF( LDY.LT.MAX( 1, N ) ) THEN
494: INFO = -15
495: END IF
496: IF( INFO.NE.0 ) THEN
497: CALL XERBLA( 'ZLA_HERFSX_EXTENDED', -INFO )
498: RETURN
499: END IF
500: EPS = DLAMCH( 'Epsilon' )
501: HUGEVAL = DLAMCH( 'Overflow' )
502: * Force HUGEVAL to Inf
503: HUGEVAL = HUGEVAL * HUGEVAL
504: * Using HUGEVAL may lead to spurious underflows.
505: INCR_THRESH = DBLE( N ) * EPS
506:
507: IF ( LSAME ( UPLO, 'L' ) ) THEN
508: UPLO2 = ILAUPLO( 'L' )
509: ELSE
510: UPLO2 = ILAUPLO( 'U' )
511: ENDIF
512:
513: DO J = 1, NRHS
514: Y_PREC_STATE = EXTRA_RESIDUAL
515: IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
516: DO I = 1, N
517: Y_TAIL( I ) = 0.0D+0
518: END DO
519: END IF
520:
521: DXRAT = 0.0D+0
522: DXRATMAX = 0.0D+0
523: DZRAT = 0.0D+0
524: DZRATMAX = 0.0D+0
525: FINAL_DX_X = HUGEVAL
526: FINAL_DZ_Z = HUGEVAL
527: PREVNORMDX = HUGEVAL
528: PREV_DZ_Z = HUGEVAL
529: DZ_Z = HUGEVAL
530: DX_X = HUGEVAL
531:
532: X_STATE = WORKING_STATE
533: Z_STATE = UNSTABLE_STATE
534: INCR_PREC = .FALSE.
535:
536: DO CNT = 1, ITHRESH
537: *
538: * Compute residual RES = B_s - op(A_s) * Y,
539: * op(A) = A, A**T, or A**H depending on TRANS (and type).
540: *
541: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
542: IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
543: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
544: $ DCMPLX(1.0D+0), RES, 1 )
545: ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
546: CALL BLAS_ZSYMV_X( UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
547: $ Y( 1, J ), 1, DCMPLX(1.0D+0), RES, 1, PREC_TYPE )
548: ELSE
549: CALL BLAS_ZSYMV2_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
550: $ Y(1, J), Y_TAIL, 1, DCMPLX(1.0D+0), RES, 1,
551: $ PREC_TYPE)
552: END IF
553:
554: ! XXX: RES is no longer needed.
555: CALL ZCOPY( N, RES, 1, DY, 1 )
556: CALL ZSYTRS( UPLO, N, 1, AF, LDAF, IPIV, DY, N, INFO )
557: *
558: * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
559: *
560: NORMX = 0.0D+0
561: NORMY = 0.0D+0
562: NORMDX = 0.0D+0
563: DZ_Z = 0.0D+0
564: YMIN = HUGEVAL
565:
566: DO I = 1, N
567: YK = CABS1( Y( I, J ) )
568: DYK = CABS1( DY( I ) )
569:
570: IF ( YK .NE. 0.0D+0 ) THEN
571: DZ_Z = MAX( DZ_Z, DYK / YK )
572: ELSE IF ( DYK .NE. 0.0D+0 ) THEN
573: DZ_Z = HUGEVAL
574: END IF
575:
576: YMIN = MIN( YMIN, YK )
577:
578: NORMY = MAX( NORMY, YK )
579:
580: IF ( COLEQU ) THEN
581: NORMX = MAX( NORMX, YK * C( I ) )
582: NORMDX = MAX( NORMDX, DYK * C( I ) )
583: ELSE
584: NORMX = NORMY
585: NORMDX = MAX( NORMDX, DYK )
586: END IF
587: END DO
588:
589: IF ( NORMX .NE. 0.0D+0 ) THEN
590: DX_X = NORMDX / NORMX
591: ELSE IF ( NORMDX .EQ. 0.0D+0 ) THEN
592: DX_X = 0.0D+0
593: ELSE
594: DX_X = HUGEVAL
595: END IF
596:
597: DXRAT = NORMDX / PREVNORMDX
598: DZRAT = DZ_Z / PREV_DZ_Z
599: *
600: * Check termination criteria.
601: *
602: IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
603: $ .AND. Y_PREC_STATE .LT. EXTRA_Y )
604: $ INCR_PREC = .TRUE.
605:
606: IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
607: $ X_STATE = WORKING_STATE
608: IF ( X_STATE .EQ. WORKING_STATE ) THEN
609: IF ( DX_X .LE. EPS ) THEN
610: X_STATE = CONV_STATE
611: ELSE IF ( DXRAT .GT. RTHRESH ) THEN
612: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
613: INCR_PREC = .TRUE.
614: ELSE
615: X_STATE = NOPROG_STATE
616: END IF
617: ELSE
618: IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
619: END IF
620: IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
621: END IF
622:
623: IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
624: $ Z_STATE = WORKING_STATE
625: IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
626: $ Z_STATE = WORKING_STATE
627: IF ( Z_STATE .EQ. WORKING_STATE ) THEN
628: IF ( DZ_Z .LE. EPS ) THEN
629: Z_STATE = CONV_STATE
630: ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
631: Z_STATE = UNSTABLE_STATE
632: DZRATMAX = 0.0D+0
633: FINAL_DZ_Z = HUGEVAL
634: ELSE IF ( DZRAT .GT. RTHRESH ) THEN
635: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
636: INCR_PREC = .TRUE.
637: ELSE
638: Z_STATE = NOPROG_STATE
639: END IF
640: ELSE
641: IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
642: END IF
643: IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
644: END IF
645:
646: IF ( X_STATE.NE.WORKING_STATE.AND.
647: $ ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
648: $ GOTO 666
649:
650: IF ( INCR_PREC ) THEN
651: INCR_PREC = .FALSE.
652: Y_PREC_STATE = Y_PREC_STATE + 1
653: DO I = 1, N
654: Y_TAIL( I ) = 0.0D+0
655: END DO
656: END IF
657:
658: PREVNORMDX = NORMDX
659: PREV_DZ_Z = DZ_Z
660: *
661: * Update soluton.
662: *
663: IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
664: CALL ZAXPY( N, DCMPLX(1.0D+0), DY, 1, Y(1,J), 1 )
665: ELSE
666: CALL ZLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
667: END IF
668:
669: END DO
670: * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
671: 666 CONTINUE
672: *
673: * Set final_* when cnt hits ithresh.
674: *
675: IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
676: IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
677: *
678: * Compute error bounds.
679: *
680: IF ( N_NORMS .GE. 1 ) THEN
681: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) =
682: $ FINAL_DX_X / (1 - DXRATMAX)
683: END IF
684: IF ( N_NORMS .GE. 2 ) THEN
685: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) =
686: $ FINAL_DZ_Z / (1 - DZRATMAX)
687: END IF
688: *
689: * Compute componentwise relative backward error from formula
690: * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
691: * where abs(Z) is the componentwise absolute value of the matrix
692: * or vector Z.
693: *
694: * Compute residual RES = B_s - op(A_s) * Y,
695: * op(A) = A, A**T, or A**H depending on TRANS (and type).
696: *
697: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
698: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
699: $ DCMPLX(1.0D+0), RES, 1 )
700:
701: DO I = 1, N
702: AYB( I ) = CABS1( B( I, J ) )
703: END DO
704: *
705: * Compute abs(op(A_s))*abs(Y) + abs(B_s).
706: *
707: CALL ZLA_SYAMV ( UPLO2, N, 1.0D+0,
708: $ A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1 )
709:
710: CALL ZLA_LIN_BERR ( N, N, 1, RES, AYB, BERR_OUT( J ) )
711: *
712: * End of loop for each RHS.
713: *
714: END DO
715: *
716: RETURN
717: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zla_syrfsx_extended.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack