1: *> \brief \b ZLA_SYRFSX_EXTENDED
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLA_SYRFSX_EXTENDED + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
22: * AF, LDAF, IPIV, COLEQU, C, B, LDB,
23: * Y, LDY, BERR_OUT, N_NORMS,
24: * ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
25: * AYB, DY, Y_TAIL, RCOND, ITHRESH,
26: * RTHRESH, DZ_UB, IGNORE_CWISE,
27: * INFO )
28: *
29: * .. Scalar Arguments ..
30: * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
31: * $ N_NORMS, ITHRESH
32: * CHARACTER UPLO
33: * LOGICAL COLEQU, IGNORE_CWISE
34: * DOUBLE PRECISION RTHRESH, DZ_UB
35: * ..
36: * .. Array Arguments ..
37: * INTEGER IPIV( * )
38: * COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
39: * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
40: * DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
41: * $ ERR_BNDS_NORM( NRHS, * ),
42: * $ ERR_BNDS_COMP( NRHS, * )
43: * ..
44: *
45: *
46: *> \par Purpose:
47: * =============
48: *>
49: *> \verbatim
50: *>
51: *> ZLA_SYRFSX_EXTENDED improves the computed solution to a system of
52: *> linear equations by performing extra-precise iterative refinement
53: *> and provides error bounds and backward error estimates for the solution.
54: *> This subroutine is called by ZSYRFSX to perform iterative refinement.
55: *> In addition to normwise error bound, the code provides maximum
56: *> componentwise error bound if possible. See comments for ERR_BNDS_NORM
57: *> and ERR_BNDS_COMP for details of the error bounds. Note that this
58: *> subroutine is only resonsible for setting the second fields of
59: *> ERR_BNDS_NORM and ERR_BNDS_COMP.
60: *> \endverbatim
61: *
62: * Arguments:
63: * ==========
64: *
65: *> \param[in] PREC_TYPE
66: *> \verbatim
67: *> PREC_TYPE is INTEGER
68: *> Specifies the intermediate precision to be used in refinement.
69: *> The value is defined by ILAPREC(P) where P is a CHARACTER and
70: *> P = 'S': Single
71: *> = 'D': Double
72: *> = 'I': Indigenous
73: *> = 'X', 'E': Extra
74: *> \endverbatim
75: *>
76: *> \param[in] UPLO
77: *> \verbatim
78: *> UPLO is CHARACTER*1
79: *> = 'U': Upper triangle of A is stored;
80: *> = 'L': Lower triangle of A is stored.
81: *> \endverbatim
82: *>
83: *> \param[in] N
84: *> \verbatim
85: *> N is INTEGER
86: *> The number of linear equations, i.e., the order of the
87: *> matrix A. N >= 0.
88: *> \endverbatim
89: *>
90: *> \param[in] NRHS
91: *> \verbatim
92: *> NRHS is INTEGER
93: *> The number of right-hand-sides, i.e., the number of columns of the
94: *> matrix B.
95: *> \endverbatim
96: *>
97: *> \param[in] A
98: *> \verbatim
99: *> A is COMPLEX*16 array, dimension (LDA,N)
100: *> On entry, the N-by-N matrix A.
101: *> \endverbatim
102: *>
103: *> \param[in] LDA
104: *> \verbatim
105: *> LDA is INTEGER
106: *> The leading dimension of the array A. LDA >= max(1,N).
107: *> \endverbatim
108: *>
109: *> \param[in] AF
110: *> \verbatim
111: *> AF is COMPLEX*16 array, dimension (LDAF,N)
112: *> The block diagonal matrix D and the multipliers used to
113: *> obtain the factor U or L as computed by ZSYTRF.
114: *> \endverbatim
115: *>
116: *> \param[in] LDAF
117: *> \verbatim
118: *> LDAF is INTEGER
119: *> The leading dimension of the array AF. LDAF >= max(1,N).
120: *> \endverbatim
121: *>
122: *> \param[in] IPIV
123: *> \verbatim
124: *> IPIV is INTEGER array, dimension (N)
125: *> Details of the interchanges and the block structure of D
126: *> as determined by ZSYTRF.
127: *> \endverbatim
128: *>
129: *> \param[in] COLEQU
130: *> \verbatim
131: *> COLEQU is LOGICAL
132: *> If .TRUE. then column equilibration was done to A before calling
133: *> this routine. This is needed to compute the solution and error
134: *> bounds correctly.
135: *> \endverbatim
136: *>
137: *> \param[in] C
138: *> \verbatim
139: *> C is DOUBLE PRECISION array, dimension (N)
140: *> The column scale factors for A. If COLEQU = .FALSE., C
141: *> is not accessed. If C is input, each element of C should be a power
142: *> of the radix to ensure a reliable solution and error estimates.
143: *> Scaling by powers of the radix does not cause rounding errors unless
144: *> the result underflows or overflows. Rounding errors during scaling
145: *> lead to refining with a matrix that is not equivalent to the
146: *> input matrix, producing error estimates that may not be
147: *> reliable.
148: *> \endverbatim
149: *>
150: *> \param[in] B
151: *> \verbatim
152: *> B is COMPLEX*16 array, dimension (LDB,NRHS)
153: *> The right-hand-side matrix B.
154: *> \endverbatim
155: *>
156: *> \param[in] LDB
157: *> \verbatim
158: *> LDB is INTEGER
159: *> The leading dimension of the array B. LDB >= max(1,N).
160: *> \endverbatim
161: *>
162: *> \param[in,out] Y
163: *> \verbatim
164: *> Y is COMPLEX*16 array, dimension
165: *> (LDY,NRHS)
166: *> On entry, the solution matrix X, as computed by ZSYTRS.
167: *> On exit, the improved solution matrix Y.
168: *> \endverbatim
169: *>
170: *> \param[in] LDY
171: *> \verbatim
172: *> LDY is INTEGER
173: *> The leading dimension of the array Y. LDY >= max(1,N).
174: *> \endverbatim
175: *>
176: *> \param[out] BERR_OUT
177: *> \verbatim
178: *> BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
179: *> On exit, BERR_OUT(j) contains the componentwise relative backward
180: *> error for right-hand-side j from the formula
181: *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
182: *> where abs(Z) is the componentwise absolute value of the matrix
183: *> or vector Z. This is computed by ZLA_LIN_BERR.
184: *> \endverbatim
185: *>
186: *> \param[in] N_NORMS
187: *> \verbatim
188: *> N_NORMS is INTEGER
189: *> Determines which error bounds to return (see ERR_BNDS_NORM
190: *> and ERR_BNDS_COMP).
191: *> If N_NORMS >= 1 return normwise error bounds.
192: *> If N_NORMS >= 2 return componentwise error bounds.
193: *> \endverbatim
194: *>
195: *> \param[in,out] ERR_BNDS_NORM
196: *> \verbatim
197: *> ERR_BNDS_NORM is DOUBLE PRECISION array, dimension
198: *> (NRHS, N_ERR_BNDS)
199: *> For each right-hand side, this array contains information about
200: *> various error bounds and condition numbers corresponding to the
201: *> normwise relative error, which is defined as follows:
202: *>
203: *> Normwise relative error in the ith solution vector:
204: *> max_j (abs(XTRUE(j,i) - X(j,i)))
205: *> ------------------------------
206: *> max_j abs(X(j,i))
207: *>
208: *> The array is indexed by the type of error information as described
209: *> below. There currently are up to three pieces of information
210: *> returned.
211: *>
212: *> The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
213: *> right-hand side.
214: *>
215: *> The second index in ERR_BNDS_NORM(:,err) contains the following
216: *> three fields:
217: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
218: *> reciprocal condition number is less than the threshold
219: *> sqrt(n) * slamch('Epsilon').
220: *>
221: *> err = 2 "Guaranteed" error bound: The estimated forward error,
222: *> almost certainly within a factor of 10 of the true error
223: *> so long as the next entry is greater than the threshold
224: *> sqrt(n) * slamch('Epsilon'). This error bound should only
225: *> be trusted if the previous boolean is true.
226: *>
227: *> err = 3 Reciprocal condition number: Estimated normwise
228: *> reciprocal condition number. Compared with the threshold
229: *> sqrt(n) * slamch('Epsilon') to determine if the error
230: *> estimate is "guaranteed". These reciprocal condition
231: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
232: *> appropriately scaled matrix Z.
233: *> Let Z = S*A, where S scales each row by a power of the
234: *> radix so all absolute row sums of Z are approximately 1.
235: *>
236: *> This subroutine is only responsible for setting the second field
237: *> above.
238: *> See Lapack Working Note 165 for further details and extra
239: *> cautions.
240: *> \endverbatim
241: *>
242: *> \param[in,out] ERR_BNDS_COMP
243: *> \verbatim
244: *> ERR_BNDS_COMP is DOUBLE PRECISION array, dimension
245: *> (NRHS, N_ERR_BNDS)
246: *> For each right-hand side, this array contains information about
247: *> various error bounds and condition numbers corresponding to the
248: *> componentwise relative error, which is defined as follows:
249: *>
250: *> Componentwise relative error in the ith solution vector:
251: *> abs(XTRUE(j,i) - X(j,i))
252: *> max_j ----------------------
253: *> abs(X(j,i))
254: *>
255: *> The array is indexed by the right-hand side i (on which the
256: *> componentwise relative error depends), and the type of error
257: *> information as described below. There currently are up to three
258: *> pieces of information returned for each right-hand side. If
259: *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
260: *> ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
261: *> the first (:,N_ERR_BNDS) entries are returned.
262: *>
263: *> The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
264: *> right-hand side.
265: *>
266: *> The second index in ERR_BNDS_COMP(:,err) contains the following
267: *> three fields:
268: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
269: *> reciprocal condition number is less than the threshold
270: *> sqrt(n) * slamch('Epsilon').
271: *>
272: *> err = 2 "Guaranteed" error bound: The estimated forward error,
273: *> almost certainly within a factor of 10 of the true error
274: *> so long as the next entry is greater than the threshold
275: *> sqrt(n) * slamch('Epsilon'). This error bound should only
276: *> be trusted if the previous boolean is true.
277: *>
278: *> err = 3 Reciprocal condition number: Estimated componentwise
279: *> reciprocal condition number. Compared with the threshold
280: *> sqrt(n) * slamch('Epsilon') to determine if the error
281: *> estimate is "guaranteed". These reciprocal condition
282: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
283: *> appropriately scaled matrix Z.
284: *> Let Z = S*(A*diag(x)), where x is the solution for the
285: *> current right-hand side and S scales each row of
286: *> A*diag(x) by a power of the radix so all absolute row
287: *> sums of Z are approximately 1.
288: *>
289: *> This subroutine is only responsible for setting the second field
290: *> above.
291: *> See Lapack Working Note 165 for further details and extra
292: *> cautions.
293: *> \endverbatim
294: *>
295: *> \param[in] RES
296: *> \verbatim
297: *> RES is COMPLEX*16 array, dimension (N)
298: *> Workspace to hold the intermediate residual.
299: *> \endverbatim
300: *>
301: *> \param[in] AYB
302: *> \verbatim
303: *> AYB is DOUBLE PRECISION array, dimension (N)
304: *> Workspace.
305: *> \endverbatim
306: *>
307: *> \param[in] DY
308: *> \verbatim
309: *> DY is COMPLEX*16 array, dimension (N)
310: *> Workspace to hold the intermediate solution.
311: *> \endverbatim
312: *>
313: *> \param[in] Y_TAIL
314: *> \verbatim
315: *> Y_TAIL is COMPLEX*16 array, dimension (N)
316: *> Workspace to hold the trailing bits of the intermediate solution.
317: *> \endverbatim
318: *>
319: *> \param[in] RCOND
320: *> \verbatim
321: *> RCOND is DOUBLE PRECISION
322: *> Reciprocal scaled condition number. This is an estimate of the
323: *> reciprocal Skeel condition number of the matrix A after
324: *> equilibration (if done). If this is less than the machine
325: *> precision (in particular, if it is zero), the matrix is singular
326: *> to working precision. Note that the error may still be small even
327: *> if this number is very small and the matrix appears ill-
328: *> conditioned.
329: *> \endverbatim
330: *>
331: *> \param[in] ITHRESH
332: *> \verbatim
333: *> ITHRESH is INTEGER
334: *> The maximum number of residual computations allowed for
335: *> refinement. The default is 10. For 'aggressive' set to 100 to
336: *> permit convergence using approximate factorizations or
337: *> factorizations other than LU. If the factorization uses a
338: *> technique other than Gaussian elimination, the guarantees in
339: *> ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
340: *> \endverbatim
341: *>
342: *> \param[in] RTHRESH
343: *> \verbatim
344: *> RTHRESH is DOUBLE PRECISION
345: *> Determines when to stop refinement if the error estimate stops
346: *> decreasing. Refinement will stop when the next solution no longer
347: *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
348: *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
349: *> default value is 0.5. For 'aggressive' set to 0.9 to permit
350: *> convergence on extremely ill-conditioned matrices. See LAWN 165
351: *> for more details.
352: *> \endverbatim
353: *>
354: *> \param[in] DZ_UB
355: *> \verbatim
356: *> DZ_UB is DOUBLE PRECISION
357: *> Determines when to start considering componentwise convergence.
358: *> Componentwise convergence is only considered after each component
359: *> of the solution Y is stable, which we definte as the relative
360: *> change in each component being less than DZ_UB. The default value
361: *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
362: *> more details.
363: *> \endverbatim
364: *>
365: *> \param[in] IGNORE_CWISE
366: *> \verbatim
367: *> IGNORE_CWISE is LOGICAL
368: *> If .TRUE. then ignore componentwise convergence. Default value
369: *> is .FALSE..
370: *> \endverbatim
371: *>
372: *> \param[out] INFO
373: *> \verbatim
374: *> INFO is INTEGER
375: *> = 0: Successful exit.
376: *> < 0: if INFO = -i, the ith argument to ZLA_HERFSX_EXTENDED had an illegal
377: *> value
378: *> \endverbatim
379: *
380: * Authors:
381: * ========
382: *
383: *> \author Univ. of Tennessee
384: *> \author Univ. of California Berkeley
385: *> \author Univ. of Colorado Denver
386: *> \author NAG Ltd.
387: *
388: *> \date November 2011
389: *
390: *> \ingroup complex16SYcomputational
391: *
392: * =====================================================================
393: SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
394: $ AF, LDAF, IPIV, COLEQU, C, B, LDB,
395: $ Y, LDY, BERR_OUT, N_NORMS,
396: $ ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
397: $ AYB, DY, Y_TAIL, RCOND, ITHRESH,
398: $ RTHRESH, DZ_UB, IGNORE_CWISE,
399: $ INFO )
400: *
401: * -- LAPACK computational routine (version 3.4.0) --
402: * -- LAPACK is a software package provided by Univ. of Tennessee, --
403: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
404: * November 2011
405: *
406: * .. Scalar Arguments ..
407: INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
408: $ N_NORMS, ITHRESH
409: CHARACTER UPLO
410: LOGICAL COLEQU, IGNORE_CWISE
411: DOUBLE PRECISION RTHRESH, DZ_UB
412: * ..
413: * .. Array Arguments ..
414: INTEGER IPIV( * )
415: COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
416: $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
417: DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
418: $ ERR_BNDS_NORM( NRHS, * ),
419: $ ERR_BNDS_COMP( NRHS, * )
420: * ..
421: *
422: * =====================================================================
423: *
424: * .. Local Scalars ..
425: INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
426: $ Y_PREC_STATE
427: DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
428: $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
429: $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
430: $ EPS, HUGEVAL, INCR_THRESH
431: LOGICAL INCR_PREC, UPPER
432: COMPLEX*16 ZDUM
433: * ..
434: * .. Parameters ..
435: INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
436: $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
437: $ EXTRA_Y
438: PARAMETER ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
439: $ CONV_STATE = 2, NOPROG_STATE = 3 )
440: PARAMETER ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
441: $ EXTRA_Y = 2 )
442: INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
443: INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
444: INTEGER CMP_ERR_I, PIV_GROWTH_I
445: PARAMETER ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
446: $ BERR_I = 3 )
447: PARAMETER ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
448: PARAMETER ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
449: $ PIV_GROWTH_I = 9 )
450: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
451: $ LA_LINRX_CWISE_I
452: PARAMETER ( LA_LINRX_ITREF_I = 1,
453: $ LA_LINRX_ITHRESH_I = 2 )
454: PARAMETER ( LA_LINRX_CWISE_I = 3 )
455: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
456: $ LA_LINRX_RCOND_I
457: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
458: PARAMETER ( LA_LINRX_RCOND_I = 3 )
459: * ..
460: * .. External Functions ..
461: LOGICAL LSAME
462: EXTERNAL ILAUPLO
463: INTEGER ILAUPLO
464: * ..
465: * .. External Subroutines ..
466: EXTERNAL ZAXPY, ZCOPY, ZSYTRS, ZSYMV, BLAS_ZSYMV_X,
467: $ BLAS_ZSYMV2_X, ZLA_SYAMV, ZLA_WWADDW,
468: $ ZLA_LIN_BERR
469: DOUBLE PRECISION DLAMCH
470: * ..
471: * .. Intrinsic Functions ..
472: INTRINSIC ABS, REAL, DIMAG, MAX, MIN
473: * ..
474: * .. Statement Functions ..
475: DOUBLE PRECISION CABS1
476: * ..
477: * .. Statement Function Definitions ..
478: CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
479: * ..
480: * .. Executable Statements ..
481: *
482: INFO = 0
483: UPPER = LSAME( UPLO, 'U' )
484: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
485: INFO = -2
486: ELSE IF( N.LT.0 ) THEN
487: INFO = -3
488: ELSE IF( NRHS.LT.0 ) THEN
489: INFO = -4
490: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
491: INFO = -6
492: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
493: INFO = -8
494: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
495: INFO = -13
496: ELSE IF( LDY.LT.MAX( 1, N ) ) THEN
497: INFO = -15
498: END IF
499: IF( INFO.NE.0 ) THEN
500: CALL XERBLA( 'ZLA_HERFSX_EXTENDED', -INFO )
501: RETURN
502: END IF
503: EPS = DLAMCH( 'Epsilon' )
504: HUGEVAL = DLAMCH( 'Overflow' )
505: * Force HUGEVAL to Inf
506: HUGEVAL = HUGEVAL * HUGEVAL
507: * Using HUGEVAL may lead to spurious underflows.
508: INCR_THRESH = DBLE( N ) * EPS
509:
510: IF ( LSAME ( UPLO, 'L' ) ) THEN
511: UPLO2 = ILAUPLO( 'L' )
512: ELSE
513: UPLO2 = ILAUPLO( 'U' )
514: ENDIF
515:
516: DO J = 1, NRHS
517: Y_PREC_STATE = EXTRA_RESIDUAL
518: IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
519: DO I = 1, N
520: Y_TAIL( I ) = 0.0D+0
521: END DO
522: END IF
523:
524: DXRAT = 0.0D+0
525: DXRATMAX = 0.0D+0
526: DZRAT = 0.0D+0
527: DZRATMAX = 0.0D+0
528: FINAL_DX_X = HUGEVAL
529: FINAL_DZ_Z = HUGEVAL
530: PREVNORMDX = HUGEVAL
531: PREV_DZ_Z = HUGEVAL
532: DZ_Z = HUGEVAL
533: DX_X = HUGEVAL
534:
535: X_STATE = WORKING_STATE
536: Z_STATE = UNSTABLE_STATE
537: INCR_PREC = .FALSE.
538:
539: DO CNT = 1, ITHRESH
540: *
541: * Compute residual RES = B_s - op(A_s) * Y,
542: * op(A) = A, A**T, or A**H depending on TRANS (and type).
543: *
544: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
545: IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
546: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
547: $ DCMPLX(1.0D+0), RES, 1 )
548: ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
549: CALL BLAS_ZSYMV_X( UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
550: $ Y( 1, J ), 1, DCMPLX(1.0D+0), RES, 1, PREC_TYPE )
551: ELSE
552: CALL BLAS_ZSYMV2_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
553: $ Y(1, J), Y_TAIL, 1, DCMPLX(1.0D+0), RES, 1,
554: $ PREC_TYPE)
555: END IF
556:
557: ! XXX: RES is no longer needed.
558: CALL ZCOPY( N, RES, 1, DY, 1 )
559: CALL ZSYTRS( UPLO, N, 1, AF, LDAF, IPIV, DY, N, INFO )
560: *
561: * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
562: *
563: NORMX = 0.0D+0
564: NORMY = 0.0D+0
565: NORMDX = 0.0D+0
566: DZ_Z = 0.0D+0
567: YMIN = HUGEVAL
568:
569: DO I = 1, N
570: YK = CABS1( Y( I, J ) )
571: DYK = CABS1( DY( I ) )
572:
573: IF ( YK .NE. 0.0D+0 ) THEN
574: DZ_Z = MAX( DZ_Z, DYK / YK )
575: ELSE IF ( DYK .NE. 0.0D+0 ) THEN
576: DZ_Z = HUGEVAL
577: END IF
578:
579: YMIN = MIN( YMIN, YK )
580:
581: NORMY = MAX( NORMY, YK )
582:
583: IF ( COLEQU ) THEN
584: NORMX = MAX( NORMX, YK * C( I ) )
585: NORMDX = MAX( NORMDX, DYK * C( I ) )
586: ELSE
587: NORMX = NORMY
588: NORMDX = MAX( NORMDX, DYK )
589: END IF
590: END DO
591:
592: IF ( NORMX .NE. 0.0D+0 ) THEN
593: DX_X = NORMDX / NORMX
594: ELSE IF ( NORMDX .EQ. 0.0D+0 ) THEN
595: DX_X = 0.0D+0
596: ELSE
597: DX_X = HUGEVAL
598: END IF
599:
600: DXRAT = NORMDX / PREVNORMDX
601: DZRAT = DZ_Z / PREV_DZ_Z
602: *
603: * Check termination criteria.
604: *
605: IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
606: $ .AND. Y_PREC_STATE .LT. EXTRA_Y )
607: $ INCR_PREC = .TRUE.
608:
609: IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
610: $ X_STATE = WORKING_STATE
611: IF ( X_STATE .EQ. WORKING_STATE ) THEN
612: IF ( DX_X .LE. EPS ) THEN
613: X_STATE = CONV_STATE
614: ELSE IF ( DXRAT .GT. RTHRESH ) THEN
615: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
616: INCR_PREC = .TRUE.
617: ELSE
618: X_STATE = NOPROG_STATE
619: END IF
620: ELSE
621: IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
622: END IF
623: IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
624: END IF
625:
626: IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
627: $ Z_STATE = WORKING_STATE
628: IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
629: $ Z_STATE = WORKING_STATE
630: IF ( Z_STATE .EQ. WORKING_STATE ) THEN
631: IF ( DZ_Z .LE. EPS ) THEN
632: Z_STATE = CONV_STATE
633: ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
634: Z_STATE = UNSTABLE_STATE
635: DZRATMAX = 0.0D+0
636: FINAL_DZ_Z = HUGEVAL
637: ELSE IF ( DZRAT .GT. RTHRESH ) THEN
638: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
639: INCR_PREC = .TRUE.
640: ELSE
641: Z_STATE = NOPROG_STATE
642: END IF
643: ELSE
644: IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
645: END IF
646: IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
647: END IF
648:
649: IF ( X_STATE.NE.WORKING_STATE.AND.
650: $ ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
651: $ GOTO 666
652:
653: IF ( INCR_PREC ) THEN
654: INCR_PREC = .FALSE.
655: Y_PREC_STATE = Y_PREC_STATE + 1
656: DO I = 1, N
657: Y_TAIL( I ) = 0.0D+0
658: END DO
659: END IF
660:
661: PREVNORMDX = NORMDX
662: PREV_DZ_Z = DZ_Z
663: *
664: * Update soluton.
665: *
666: IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
667: CALL ZAXPY( N, DCMPLX(1.0D+0), DY, 1, Y(1,J), 1 )
668: ELSE
669: CALL ZLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
670: END IF
671:
672: END DO
673: * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
674: 666 CONTINUE
675: *
676: * Set final_* when cnt hits ithresh.
677: *
678: IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
679: IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
680: *
681: * Compute error bounds.
682: *
683: IF ( N_NORMS .GE. 1 ) THEN
684: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) =
685: $ FINAL_DX_X / (1 - DXRATMAX)
686: END IF
687: IF ( N_NORMS .GE. 2 ) THEN
688: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) =
689: $ FINAL_DZ_Z / (1 - DZRATMAX)
690: END IF
691: *
692: * Compute componentwise relative backward error from formula
693: * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
694: * where abs(Z) is the componentwise absolute value of the matrix
695: * or vector Z.
696: *
697: * Compute residual RES = B_s - op(A_s) * Y,
698: * op(A) = A, A**T, or A**H depending on TRANS (and type).
699: *
700: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
701: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
702: $ DCMPLX(1.0D+0), RES, 1 )
703:
704: DO I = 1, N
705: AYB( I ) = CABS1( B( I, J ) )
706: END DO
707: *
708: * Compute abs(op(A_s))*abs(Y) + abs(B_s).
709: *
710: CALL ZLA_SYAMV ( UPLO2, N, 1.0D+0,
711: $ A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1 )
712:
713: CALL ZLA_LIN_BERR ( N, N, 1, RES, AYB, BERR_OUT( J ) )
714: *
715: * End of loop for each RHS.
716: *
717: END DO
718: *
719: RETURN
720: END
CVSweb interface <joel.bertrand@systella.fr>