1: *> \brief \b ZLA_SYRFSX_EXTENDED
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZLA_SYRFSX_EXTENDED + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_syrfsx_extended.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
22: * AF, LDAF, IPIV, COLEQU, C, B, LDB,
23: * Y, LDY, BERR_OUT, N_NORMS,
24: * ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
25: * AYB, DY, Y_TAIL, RCOND, ITHRESH,
26: * RTHRESH, DZ_UB, IGNORE_CWISE,
27: * INFO )
28: *
29: * .. Scalar Arguments ..
30: * INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
31: * $ N_NORMS, ITHRESH
32: * CHARACTER UPLO
33: * LOGICAL COLEQU, IGNORE_CWISE
34: * DOUBLE PRECISION RTHRESH, DZ_UB
35: * ..
36: * .. Array Arguments ..
37: * INTEGER IPIV( * )
38: * COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
39: * $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
40: * DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
41: * $ ERR_BNDS_NORM( NRHS, * ),
42: * $ ERR_BNDS_COMP( NRHS, * )
43: * ..
44: *
45: *
46: *> \par Purpose:
47: * =============
48: *>
49: *> \verbatim
50: *>
51: *> ZLA_SYRFSX_EXTENDED improves the computed solution to a system of
52: *> linear equations by performing extra-precise iterative refinement
53: *> and provides error bounds and backward error estimates for the solution.
54: *> This subroutine is called by ZSYRFSX to perform iterative refinement.
55: *> In addition to normwise error bound, the code provides maximum
56: *> componentwise error bound if possible. See comments for ERR_BNDS_NORM
57: *> and ERR_BNDS_COMP for details of the error bounds. Note that this
58: *> subroutine is only resonsible for setting the second fields of
59: *> ERR_BNDS_NORM and ERR_BNDS_COMP.
60: *> \endverbatim
61: *
62: * Arguments:
63: * ==========
64: *
65: *> \param[in] PREC_TYPE
66: *> \verbatim
67: *> PREC_TYPE is INTEGER
68: *> Specifies the intermediate precision to be used in refinement.
69: *> The value is defined by ILAPREC(P) where P is a CHARACTER and
70: *> P = 'S': Single
71: *> = 'D': Double
72: *> = 'I': Indigenous
73: *> = 'X', 'E': Extra
74: *> \endverbatim
75: *>
76: *> \param[in] UPLO
77: *> \verbatim
78: *> UPLO is CHARACTER*1
79: *> = 'U': Upper triangle of A is stored;
80: *> = 'L': Lower triangle of A is stored.
81: *> \endverbatim
82: *>
83: *> \param[in] N
84: *> \verbatim
85: *> N is INTEGER
86: *> The number of linear equations, i.e., the order of the
87: *> matrix A. N >= 0.
88: *> \endverbatim
89: *>
90: *> \param[in] NRHS
91: *> \verbatim
92: *> NRHS is INTEGER
93: *> The number of right-hand-sides, i.e., the number of columns of the
94: *> matrix B.
95: *> \endverbatim
96: *>
97: *> \param[in] A
98: *> \verbatim
99: *> A is COMPLEX*16 array, dimension (LDA,N)
100: *> On entry, the N-by-N matrix A.
101: *> \endverbatim
102: *>
103: *> \param[in] LDA
104: *> \verbatim
105: *> LDA is INTEGER
106: *> The leading dimension of the array A. LDA >= max(1,N).
107: *> \endverbatim
108: *>
109: *> \param[in] AF
110: *> \verbatim
111: *> AF is COMPLEX*16 array, dimension (LDAF,N)
112: *> The block diagonal matrix D and the multipliers used to
113: *> obtain the factor U or L as computed by ZSYTRF.
114: *> \endverbatim
115: *>
116: *> \param[in] LDAF
117: *> \verbatim
118: *> LDAF is INTEGER
119: *> The leading dimension of the array AF. LDAF >= max(1,N).
120: *> \endverbatim
121: *>
122: *> \param[in] IPIV
123: *> \verbatim
124: *> IPIV is INTEGER array, dimension (N)
125: *> Details of the interchanges and the block structure of D
126: *> as determined by ZSYTRF.
127: *> \endverbatim
128: *>
129: *> \param[in] COLEQU
130: *> \verbatim
131: *> COLEQU is LOGICAL
132: *> If .TRUE. then column equilibration was done to A before calling
133: *> this routine. This is needed to compute the solution and error
134: *> bounds correctly.
135: *> \endverbatim
136: *>
137: *> \param[in] C
138: *> \verbatim
139: *> C is DOUBLE PRECISION array, dimension (N)
140: *> The column scale factors for A. If COLEQU = .FALSE., C
141: *> is not accessed. If C is input, each element of C should be a power
142: *> of the radix to ensure a reliable solution and error estimates.
143: *> Scaling by powers of the radix does not cause rounding errors unless
144: *> the result underflows or overflows. Rounding errors during scaling
145: *> lead to refining with a matrix that is not equivalent to the
146: *> input matrix, producing error estimates that may not be
147: *> reliable.
148: *> \endverbatim
149: *>
150: *> \param[in] B
151: *> \verbatim
152: *> B is COMPLEX*16 array, dimension (LDB,NRHS)
153: *> The right-hand-side matrix B.
154: *> \endverbatim
155: *>
156: *> \param[in] LDB
157: *> \verbatim
158: *> LDB is INTEGER
159: *> The leading dimension of the array B. LDB >= max(1,N).
160: *> \endverbatim
161: *>
162: *> \param[in,out] Y
163: *> \verbatim
164: *> Y is COMPLEX*16 array, dimension
165: *> (LDY,NRHS)
166: *> On entry, the solution matrix X, as computed by ZSYTRS.
167: *> On exit, the improved solution matrix Y.
168: *> \endverbatim
169: *>
170: *> \param[in] LDY
171: *> \verbatim
172: *> LDY is INTEGER
173: *> The leading dimension of the array Y. LDY >= max(1,N).
174: *> \endverbatim
175: *>
176: *> \param[out] BERR_OUT
177: *> \verbatim
178: *> BERR_OUT is DOUBLE PRECISION array, dimension (NRHS)
179: *> On exit, BERR_OUT(j) contains the componentwise relative backward
180: *> error for right-hand-side j from the formula
181: *> max(i) ( abs(RES(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
182: *> where abs(Z) is the componentwise absolute value of the matrix
183: *> or vector Z. This is computed by ZLA_LIN_BERR.
184: *> \endverbatim
185: *>
186: *> \param[in] N_NORMS
187: *> \verbatim
188: *> N_NORMS is INTEGER
189: *> Determines which error bounds to return (see ERR_BNDS_NORM
190: *> and ERR_BNDS_COMP).
191: *> If N_NORMS >= 1 return normwise error bounds.
192: *> If N_NORMS >= 2 return componentwise error bounds.
193: *> \endverbatim
194: *>
195: *> \param[in,out] ERR_BNDS_NORM
196: *> \verbatim
197: *> ERR_BNDS_NORM is DOUBLE PRECISION array, dimension
198: *> (NRHS, N_ERR_BNDS)
199: *> For each right-hand side, this array contains information about
200: *> various error bounds and condition numbers corresponding to the
201: *> normwise relative error, which is defined as follows:
202: *>
203: *> Normwise relative error in the ith solution vector:
204: *> max_j (abs(XTRUE(j,i) - X(j,i)))
205: *> ------------------------------
206: *> max_j abs(X(j,i))
207: *>
208: *> The array is indexed by the type of error information as described
209: *> below. There currently are up to three pieces of information
210: *> returned.
211: *>
212: *> The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
213: *> right-hand side.
214: *>
215: *> The second index in ERR_BNDS_NORM(:,err) contains the following
216: *> three fields:
217: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
218: *> reciprocal condition number is less than the threshold
219: *> sqrt(n) * slamch('Epsilon').
220: *>
221: *> err = 2 "Guaranteed" error bound: The estimated forward error,
222: *> almost certainly within a factor of 10 of the true error
223: *> so long as the next entry is greater than the threshold
224: *> sqrt(n) * slamch('Epsilon'). This error bound should only
225: *> be trusted if the previous boolean is true.
226: *>
227: *> err = 3 Reciprocal condition number: Estimated normwise
228: *> reciprocal condition number. Compared with the threshold
229: *> sqrt(n) * slamch('Epsilon') to determine if the error
230: *> estimate is "guaranteed". These reciprocal condition
231: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
232: *> appropriately scaled matrix Z.
233: *> Let Z = S*A, where S scales each row by a power of the
234: *> radix so all absolute row sums of Z are approximately 1.
235: *>
236: *> This subroutine is only responsible for setting the second field
237: *> above.
238: *> See Lapack Working Note 165 for further details and extra
239: *> cautions.
240: *> \endverbatim
241: *>
242: *> \param[in,out] ERR_BNDS_COMP
243: *> \verbatim
244: *> ERR_BNDS_COMP is DOUBLE PRECISION array, dimension
245: *> (NRHS, N_ERR_BNDS)
246: *> For each right-hand side, this array contains information about
247: *> various error bounds and condition numbers corresponding to the
248: *> componentwise relative error, which is defined as follows:
249: *>
250: *> Componentwise relative error in the ith solution vector:
251: *> abs(XTRUE(j,i) - X(j,i))
252: *> max_j ----------------------
253: *> abs(X(j,i))
254: *>
255: *> The array is indexed by the right-hand side i (on which the
256: *> componentwise relative error depends), and the type of error
257: *> information as described below. There currently are up to three
258: *> pieces of information returned for each right-hand side. If
259: *> componentwise accuracy is not requested (PARAMS(3) = 0.0), then
260: *> ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
261: *> the first (:,N_ERR_BNDS) entries are returned.
262: *>
263: *> The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
264: *> right-hand side.
265: *>
266: *> The second index in ERR_BNDS_COMP(:,err) contains the following
267: *> three fields:
268: *> err = 1 "Trust/don't trust" boolean. Trust the answer if the
269: *> reciprocal condition number is less than the threshold
270: *> sqrt(n) * slamch('Epsilon').
271: *>
272: *> err = 2 "Guaranteed" error bound: The estimated forward error,
273: *> almost certainly within a factor of 10 of the true error
274: *> so long as the next entry is greater than the threshold
275: *> sqrt(n) * slamch('Epsilon'). This error bound should only
276: *> be trusted if the previous boolean is true.
277: *>
278: *> err = 3 Reciprocal condition number: Estimated componentwise
279: *> reciprocal condition number. Compared with the threshold
280: *> sqrt(n) * slamch('Epsilon') to determine if the error
281: *> estimate is "guaranteed". These reciprocal condition
282: *> numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
283: *> appropriately scaled matrix Z.
284: *> Let Z = S*(A*diag(x)), where x is the solution for the
285: *> current right-hand side and S scales each row of
286: *> A*diag(x) by a power of the radix so all absolute row
287: *> sums of Z are approximately 1.
288: *>
289: *> This subroutine is only responsible for setting the second field
290: *> above.
291: *> See Lapack Working Note 165 for further details and extra
292: *> cautions.
293: *> \endverbatim
294: *>
295: *> \param[in] RES
296: *> \verbatim
297: *> RES is COMPLEX*16 array, dimension (N)
298: *> Workspace to hold the intermediate residual.
299: *> \endverbatim
300: *>
301: *> \param[in] AYB
302: *> \verbatim
303: *> AYB is DOUBLE PRECISION array, dimension (N)
304: *> Workspace.
305: *> \endverbatim
306: *>
307: *> \param[in] DY
308: *> \verbatim
309: *> DY is COMPLEX*16 array, dimension (N)
310: *> Workspace to hold the intermediate solution.
311: *> \endverbatim
312: *>
313: *> \param[in] Y_TAIL
314: *> \verbatim
315: *> Y_TAIL is COMPLEX*16 array, dimension (N)
316: *> Workspace to hold the trailing bits of the intermediate solution.
317: *> \endverbatim
318: *>
319: *> \param[in] RCOND
320: *> \verbatim
321: *> RCOND is DOUBLE PRECISION
322: *> Reciprocal scaled condition number. This is an estimate of the
323: *> reciprocal Skeel condition number of the matrix A after
324: *> equilibration (if done). If this is less than the machine
325: *> precision (in particular, if it is zero), the matrix is singular
326: *> to working precision. Note that the error may still be small even
327: *> if this number is very small and the matrix appears ill-
328: *> conditioned.
329: *> \endverbatim
330: *>
331: *> \param[in] ITHRESH
332: *> \verbatim
333: *> ITHRESH is INTEGER
334: *> The maximum number of residual computations allowed for
335: *> refinement. The default is 10. For 'aggressive' set to 100 to
336: *> permit convergence using approximate factorizations or
337: *> factorizations other than LU. If the factorization uses a
338: *> technique other than Gaussian elimination, the guarantees in
339: *> ERR_BNDS_NORM and ERR_BNDS_COMP may no longer be trustworthy.
340: *> \endverbatim
341: *>
342: *> \param[in] RTHRESH
343: *> \verbatim
344: *> RTHRESH is DOUBLE PRECISION
345: *> Determines when to stop refinement if the error estimate stops
346: *> decreasing. Refinement will stop when the next solution no longer
347: *> satisfies norm(dx_{i+1}) < RTHRESH * norm(dx_i) where norm(Z) is
348: *> the infinity norm of Z. RTHRESH satisfies 0 < RTHRESH <= 1. The
349: *> default value is 0.5. For 'aggressive' set to 0.9 to permit
350: *> convergence on extremely ill-conditioned matrices. See LAWN 165
351: *> for more details.
352: *> \endverbatim
353: *>
354: *> \param[in] DZ_UB
355: *> \verbatim
356: *> DZ_UB is DOUBLE PRECISION
357: *> Determines when to start considering componentwise convergence.
358: *> Componentwise convergence is only considered after each component
359: *> of the solution Y is stable, which we definte as the relative
360: *> change in each component being less than DZ_UB. The default value
361: *> is 0.25, requiring the first bit to be stable. See LAWN 165 for
362: *> more details.
363: *> \endverbatim
364: *>
365: *> \param[in] IGNORE_CWISE
366: *> \verbatim
367: *> IGNORE_CWISE is LOGICAL
368: *> If .TRUE. then ignore componentwise convergence. Default value
369: *> is .FALSE..
370: *> \endverbatim
371: *>
372: *> \param[out] INFO
373: *> \verbatim
374: *> INFO is INTEGER
375: *> = 0: Successful exit.
376: *> < 0: if INFO = -i, the ith argument to ZSYTRS had an illegal
377: *> value
378: *> \endverbatim
379: *
380: * Authors:
381: * ========
382: *
383: *> \author Univ. of Tennessee
384: *> \author Univ. of California Berkeley
385: *> \author Univ. of Colorado Denver
386: *> \author NAG Ltd.
387: *
388: *> \date November 2011
389: *
390: *> \ingroup complex16SYcomputational
391: *
392: * =====================================================================
393: SUBROUTINE ZLA_SYRFSX_EXTENDED( PREC_TYPE, UPLO, N, NRHS, A, LDA,
394: $ AF, LDAF, IPIV, COLEQU, C, B, LDB,
395: $ Y, LDY, BERR_OUT, N_NORMS,
396: $ ERR_BNDS_NORM, ERR_BNDS_COMP, RES,
397: $ AYB, DY, Y_TAIL, RCOND, ITHRESH,
398: $ RTHRESH, DZ_UB, IGNORE_CWISE,
399: $ INFO )
400: *
401: * -- LAPACK computational routine (version 3.4.0) --
402: * -- LAPACK is a software package provided by Univ. of Tennessee, --
403: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
404: * November 2011
405: *
406: * .. Scalar Arguments ..
407: INTEGER INFO, LDA, LDAF, LDB, LDY, N, NRHS, PREC_TYPE,
408: $ N_NORMS, ITHRESH
409: CHARACTER UPLO
410: LOGICAL COLEQU, IGNORE_CWISE
411: DOUBLE PRECISION RTHRESH, DZ_UB
412: * ..
413: * .. Array Arguments ..
414: INTEGER IPIV( * )
415: COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
416: $ Y( LDY, * ), RES( * ), DY( * ), Y_TAIL( * )
417: DOUBLE PRECISION C( * ), AYB( * ), RCOND, BERR_OUT( * ),
418: $ ERR_BNDS_NORM( NRHS, * ),
419: $ ERR_BNDS_COMP( NRHS, * )
420: * ..
421: *
422: * =====================================================================
423: *
424: * .. Local Scalars ..
425: INTEGER UPLO2, CNT, I, J, X_STATE, Z_STATE,
426: $ Y_PREC_STATE
427: DOUBLE PRECISION YK, DYK, YMIN, NORMY, NORMX, NORMDX, DXRAT,
428: $ DZRAT, PREVNORMDX, PREV_DZ_Z, DXRATMAX,
429: $ DZRATMAX, DX_X, DZ_Z, FINAL_DX_X, FINAL_DZ_Z,
430: $ EPS, HUGEVAL, INCR_THRESH
431: LOGICAL INCR_PREC
432: COMPLEX*16 ZDUM
433: * ..
434: * .. Parameters ..
435: INTEGER UNSTABLE_STATE, WORKING_STATE, CONV_STATE,
436: $ NOPROG_STATE, BASE_RESIDUAL, EXTRA_RESIDUAL,
437: $ EXTRA_Y
438: PARAMETER ( UNSTABLE_STATE = 0, WORKING_STATE = 1,
439: $ CONV_STATE = 2, NOPROG_STATE = 3 )
440: PARAMETER ( BASE_RESIDUAL = 0, EXTRA_RESIDUAL = 1,
441: $ EXTRA_Y = 2 )
442: INTEGER FINAL_NRM_ERR_I, FINAL_CMP_ERR_I, BERR_I
443: INTEGER RCOND_I, NRM_RCOND_I, NRM_ERR_I, CMP_RCOND_I
444: INTEGER CMP_ERR_I, PIV_GROWTH_I
445: PARAMETER ( FINAL_NRM_ERR_I = 1, FINAL_CMP_ERR_I = 2,
446: $ BERR_I = 3 )
447: PARAMETER ( RCOND_I = 4, NRM_RCOND_I = 5, NRM_ERR_I = 6 )
448: PARAMETER ( CMP_RCOND_I = 7, CMP_ERR_I = 8,
449: $ PIV_GROWTH_I = 9 )
450: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
451: $ LA_LINRX_CWISE_I
452: PARAMETER ( LA_LINRX_ITREF_I = 1,
453: $ LA_LINRX_ITHRESH_I = 2 )
454: PARAMETER ( LA_LINRX_CWISE_I = 3 )
455: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
456: $ LA_LINRX_RCOND_I
457: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
458: PARAMETER ( LA_LINRX_RCOND_I = 3 )
459: * ..
460: * .. External Functions ..
461: LOGICAL LSAME
462: EXTERNAL ILAUPLO
463: INTEGER ILAUPLO
464: * ..
465: * .. External Subroutines ..
466: EXTERNAL ZAXPY, ZCOPY, ZSYTRS, ZSYMV, BLAS_ZSYMV_X,
467: $ BLAS_ZSYMV2_X, ZLA_SYAMV, ZLA_WWADDW,
468: $ ZLA_LIN_BERR
469: DOUBLE PRECISION DLAMCH
470: * ..
471: * .. Intrinsic Functions ..
472: INTRINSIC ABS, REAL, DIMAG, MAX, MIN
473: * ..
474: * .. Statement Functions ..
475: DOUBLE PRECISION CABS1
476: * ..
477: * .. Statement Function Definitions ..
478: CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
479: * ..
480: * .. Executable Statements ..
481: *
482: IF ( INFO.NE.0 ) RETURN
483: EPS = DLAMCH( 'Epsilon' )
484: HUGEVAL = DLAMCH( 'Overflow' )
485: * Force HUGEVAL to Inf
486: HUGEVAL = HUGEVAL * HUGEVAL
487: * Using HUGEVAL may lead to spurious underflows.
488: INCR_THRESH = DBLE( N ) * EPS
489:
490: IF ( LSAME ( UPLO, 'L' ) ) THEN
491: UPLO2 = ILAUPLO( 'L' )
492: ELSE
493: UPLO2 = ILAUPLO( 'U' )
494: ENDIF
495:
496: DO J = 1, NRHS
497: Y_PREC_STATE = EXTRA_RESIDUAL
498: IF ( Y_PREC_STATE .EQ. EXTRA_Y ) THEN
499: DO I = 1, N
500: Y_TAIL( I ) = 0.0D+0
501: END DO
502: END IF
503:
504: DXRAT = 0.0D+0
505: DXRATMAX = 0.0D+0
506: DZRAT = 0.0D+0
507: DZRATMAX = 0.0D+0
508: FINAL_DX_X = HUGEVAL
509: FINAL_DZ_Z = HUGEVAL
510: PREVNORMDX = HUGEVAL
511: PREV_DZ_Z = HUGEVAL
512: DZ_Z = HUGEVAL
513: DX_X = HUGEVAL
514:
515: X_STATE = WORKING_STATE
516: Z_STATE = UNSTABLE_STATE
517: INCR_PREC = .FALSE.
518:
519: DO CNT = 1, ITHRESH
520: *
521: * Compute residual RES = B_s - op(A_s) * Y,
522: * op(A) = A, A**T, or A**H depending on TRANS (and type).
523: *
524: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
525: IF ( Y_PREC_STATE .EQ. BASE_RESIDUAL ) THEN
526: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
527: $ DCMPLX(1.0D+0), RES, 1 )
528: ELSE IF ( Y_PREC_STATE .EQ. EXTRA_RESIDUAL ) THEN
529: CALL BLAS_ZSYMV_X( UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
530: $ Y( 1, J ), 1, DCMPLX(1.0D+0), RES, 1, PREC_TYPE )
531: ELSE
532: CALL BLAS_ZSYMV2_X(UPLO2, N, DCMPLX(-1.0D+0), A, LDA,
533: $ Y(1, J), Y_TAIL, 1, DCMPLX(1.0D+0), RES, 1,
534: $ PREC_TYPE)
535: END IF
536:
537: ! XXX: RES is no longer needed.
538: CALL ZCOPY( N, RES, 1, DY, 1 )
539: CALL ZSYTRS( UPLO, N, 1, AF, LDAF, IPIV, DY, N, INFO )
540: *
541: * Calculate relative changes DX_X, DZ_Z and ratios DXRAT, DZRAT.
542: *
543: NORMX = 0.0D+0
544: NORMY = 0.0D+0
545: NORMDX = 0.0D+0
546: DZ_Z = 0.0D+0
547: YMIN = HUGEVAL
548:
549: DO I = 1, N
550: YK = CABS1( Y( I, J ) )
551: DYK = CABS1( DY( I ) )
552:
553: IF ( YK .NE. 0.0D+0 ) THEN
554: DZ_Z = MAX( DZ_Z, DYK / YK )
555: ELSE IF ( DYK .NE. 0.0D+0 ) THEN
556: DZ_Z = HUGEVAL
557: END IF
558:
559: YMIN = MIN( YMIN, YK )
560:
561: NORMY = MAX( NORMY, YK )
562:
563: IF ( COLEQU ) THEN
564: NORMX = MAX( NORMX, YK * C( I ) )
565: NORMDX = MAX( NORMDX, DYK * C( I ) )
566: ELSE
567: NORMX = NORMY
568: NORMDX = MAX( NORMDX, DYK )
569: END IF
570: END DO
571:
572: IF ( NORMX .NE. 0.0D+0 ) THEN
573: DX_X = NORMDX / NORMX
574: ELSE IF ( NORMDX .EQ. 0.0D+0 ) THEN
575: DX_X = 0.0D+0
576: ELSE
577: DX_X = HUGEVAL
578: END IF
579:
580: DXRAT = NORMDX / PREVNORMDX
581: DZRAT = DZ_Z / PREV_DZ_Z
582: *
583: * Check termination criteria.
584: *
585: IF ( YMIN*RCOND .LT. INCR_THRESH*NORMY
586: $ .AND. Y_PREC_STATE .LT. EXTRA_Y )
587: $ INCR_PREC = .TRUE.
588:
589: IF ( X_STATE .EQ. NOPROG_STATE .AND. DXRAT .LE. RTHRESH )
590: $ X_STATE = WORKING_STATE
591: IF ( X_STATE .EQ. WORKING_STATE ) THEN
592: IF ( DX_X .LE. EPS ) THEN
593: X_STATE = CONV_STATE
594: ELSE IF ( DXRAT .GT. RTHRESH ) THEN
595: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
596: INCR_PREC = .TRUE.
597: ELSE
598: X_STATE = NOPROG_STATE
599: END IF
600: ELSE
601: IF (DXRAT .GT. DXRATMAX) DXRATMAX = DXRAT
602: END IF
603: IF ( X_STATE .GT. WORKING_STATE ) FINAL_DX_X = DX_X
604: END IF
605:
606: IF ( Z_STATE .EQ. UNSTABLE_STATE .AND. DZ_Z .LE. DZ_UB )
607: $ Z_STATE = WORKING_STATE
608: IF ( Z_STATE .EQ. NOPROG_STATE .AND. DZRAT .LE. RTHRESH )
609: $ Z_STATE = WORKING_STATE
610: IF ( Z_STATE .EQ. WORKING_STATE ) THEN
611: IF ( DZ_Z .LE. EPS ) THEN
612: Z_STATE = CONV_STATE
613: ELSE IF ( DZ_Z .GT. DZ_UB ) THEN
614: Z_STATE = UNSTABLE_STATE
615: DZRATMAX = 0.0D+0
616: FINAL_DZ_Z = HUGEVAL
617: ELSE IF ( DZRAT .GT. RTHRESH ) THEN
618: IF ( Y_PREC_STATE .NE. EXTRA_Y ) THEN
619: INCR_PREC = .TRUE.
620: ELSE
621: Z_STATE = NOPROG_STATE
622: END IF
623: ELSE
624: IF ( DZRAT .GT. DZRATMAX ) DZRATMAX = DZRAT
625: END IF
626: IF ( Z_STATE .GT. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
627: END IF
628:
629: IF ( X_STATE.NE.WORKING_STATE.AND.
630: $ ( IGNORE_CWISE.OR.Z_STATE.NE.WORKING_STATE ) )
631: $ GOTO 666
632:
633: IF ( INCR_PREC ) THEN
634: INCR_PREC = .FALSE.
635: Y_PREC_STATE = Y_PREC_STATE + 1
636: DO I = 1, N
637: Y_TAIL( I ) = 0.0D+0
638: END DO
639: END IF
640:
641: PREVNORMDX = NORMDX
642: PREV_DZ_Z = DZ_Z
643: *
644: * Update soluton.
645: *
646: IF ( Y_PREC_STATE .LT. EXTRA_Y ) THEN
647: CALL ZAXPY( N, DCMPLX(1.0D+0), DY, 1, Y(1,J), 1 )
648: ELSE
649: CALL ZLA_WWADDW( N, Y(1,J), Y_TAIL, DY )
650: END IF
651:
652: END DO
653: * Target of "IF (Z_STOP .AND. X_STOP)". Sun's f77 won't EXIT.
654: 666 CONTINUE
655: *
656: * Set final_* when cnt hits ithresh.
657: *
658: IF ( X_STATE .EQ. WORKING_STATE ) FINAL_DX_X = DX_X
659: IF ( Z_STATE .EQ. WORKING_STATE ) FINAL_DZ_Z = DZ_Z
660: *
661: * Compute error bounds.
662: *
663: IF ( N_NORMS .GE. 1 ) THEN
664: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) =
665: $ FINAL_DX_X / (1 - DXRATMAX)
666: END IF
667: IF ( N_NORMS .GE. 2 ) THEN
668: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) =
669: $ FINAL_DZ_Z / (1 - DZRATMAX)
670: END IF
671: *
672: * Compute componentwise relative backward error from formula
673: * max(i) ( abs(R(i)) / ( abs(op(A_s))*abs(Y) + abs(B_s) )(i) )
674: * where abs(Z) is the componentwise absolute value of the matrix
675: * or vector Z.
676: *
677: * Compute residual RES = B_s - op(A_s) * Y,
678: * op(A) = A, A**T, or A**H depending on TRANS (and type).
679: *
680: CALL ZCOPY( N, B( 1, J ), 1, RES, 1 )
681: CALL ZSYMV( UPLO, N, DCMPLX(-1.0D+0), A, LDA, Y(1,J), 1,
682: $ DCMPLX(1.0D+0), RES, 1 )
683:
684: DO I = 1, N
685: AYB( I ) = CABS1( B( I, J ) )
686: END DO
687: *
688: * Compute abs(op(A_s))*abs(Y) + abs(B_s).
689: *
690: CALL ZLA_SYAMV ( UPLO2, N, 1.0D+0,
691: $ A, LDA, Y(1, J), 1, 1.0D+0, AYB, 1 )
692:
693: CALL ZLA_LIN_BERR ( N, N, 1, RES, AYB, BERR_OUT( J ) )
694: *
695: * End of loop for each RHS.
696: *
697: END DO
698: *
699: RETURN
700: END
CVSweb interface <joel.bertrand@systella.fr>