Annotation of rpl/lapack/lapack/zhpgvd.f, revision 1.1
1.1 ! bertrand 1: SUBROUTINE ZHPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
! 2: $ LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
! 3: *
! 4: * -- LAPACK driver routine (version 3.2) --
! 5: * -- LAPACK is a software package provided by Univ. of Tennessee, --
! 6: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
! 7: * November 2006
! 8: *
! 9: * .. Scalar Arguments ..
! 10: CHARACTER JOBZ, UPLO
! 11: INTEGER INFO, ITYPE, LDZ, LIWORK, LRWORK, LWORK, N
! 12: * ..
! 13: * .. Array Arguments ..
! 14: INTEGER IWORK( * )
! 15: DOUBLE PRECISION RWORK( * ), W( * )
! 16: COMPLEX*16 AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
! 17: * ..
! 18: *
! 19: * Purpose
! 20: * =======
! 21: *
! 22: * ZHPGVD computes all the eigenvalues and, optionally, the eigenvectors
! 23: * of a complex generalized Hermitian-definite eigenproblem, of the form
! 24: * A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
! 25: * B are assumed to be Hermitian, stored in packed format, and B is also
! 26: * positive definite.
! 27: * If eigenvectors are desired, it uses a divide and conquer algorithm.
! 28: *
! 29: * The divide and conquer algorithm makes very mild assumptions about
! 30: * floating point arithmetic. It will work on machines with a guard
! 31: * digit in add/subtract, or on those binary machines without guard
! 32: * digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
! 33: * Cray-2. It could conceivably fail on hexadecimal or decimal machines
! 34: * without guard digits, but we know of none.
! 35: *
! 36: * Arguments
! 37: * =========
! 38: *
! 39: * ITYPE (input) INTEGER
! 40: * Specifies the problem type to be solved:
! 41: * = 1: A*x = (lambda)*B*x
! 42: * = 2: A*B*x = (lambda)*x
! 43: * = 3: B*A*x = (lambda)*x
! 44: *
! 45: * JOBZ (input) CHARACTER*1
! 46: * = 'N': Compute eigenvalues only;
! 47: * = 'V': Compute eigenvalues and eigenvectors.
! 48: *
! 49: * UPLO (input) CHARACTER*1
! 50: * = 'U': Upper triangles of A and B are stored;
! 51: * = 'L': Lower triangles of A and B are stored.
! 52: *
! 53: * N (input) INTEGER
! 54: * The order of the matrices A and B. N >= 0.
! 55: *
! 56: * AP (input/output) COMPLEX*16 array, dimension (N*(N+1)/2)
! 57: * On entry, the upper or lower triangle of the Hermitian matrix
! 58: * A, packed columnwise in a linear array. The j-th column of A
! 59: * is stored in the array AP as follows:
! 60: * if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
! 61: * if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
! 62: *
! 63: * On exit, the contents of AP are destroyed.
! 64: *
! 65: * BP (input/output) COMPLEX*16 array, dimension (N*(N+1)/2)
! 66: * On entry, the upper or lower triangle of the Hermitian matrix
! 67: * B, packed columnwise in a linear array. The j-th column of B
! 68: * is stored in the array BP as follows:
! 69: * if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
! 70: * if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
! 71: *
! 72: * On exit, the triangular factor U or L from the Cholesky
! 73: * factorization B = U**H*U or B = L*L**H, in the same storage
! 74: * format as B.
! 75: *
! 76: * W (output) DOUBLE PRECISION array, dimension (N)
! 77: * If INFO = 0, the eigenvalues in ascending order.
! 78: *
! 79: * Z (output) COMPLEX*16 array, dimension (LDZ, N)
! 80: * If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
! 81: * eigenvectors. The eigenvectors are normalized as follows:
! 82: * if ITYPE = 1 or 2, Z**H*B*Z = I;
! 83: * if ITYPE = 3, Z**H*inv(B)*Z = I.
! 84: * If JOBZ = 'N', then Z is not referenced.
! 85: *
! 86: * LDZ (input) INTEGER
! 87: * The leading dimension of the array Z. LDZ >= 1, and if
! 88: * JOBZ = 'V', LDZ >= max(1,N).
! 89: *
! 90: * WORK (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
! 91: * On exit, if INFO = 0, WORK(1) returns the required LWORK.
! 92: *
! 93: * LWORK (input) INTEGER
! 94: * The dimension of array WORK.
! 95: * If N <= 1, LWORK >= 1.
! 96: * If JOBZ = 'N' and N > 1, LWORK >= N.
! 97: * If JOBZ = 'V' and N > 1, LWORK >= 2*N.
! 98: *
! 99: * If LWORK = -1, then a workspace query is assumed; the routine
! 100: * only calculates the required sizes of the WORK, RWORK and
! 101: * IWORK arrays, returns these values as the first entries of
! 102: * the WORK, RWORK and IWORK arrays, and no error message
! 103: * related to LWORK or LRWORK or LIWORK is issued by XERBLA.
! 104: *
! 105: * RWORK (workspace) DOUBLE PRECISION array, dimension (MAX(1,LRWORK))
! 106: * On exit, if INFO = 0, RWORK(1) returns the required LRWORK.
! 107: *
! 108: * LRWORK (input) INTEGER
! 109: * The dimension of array RWORK.
! 110: * If N <= 1, LRWORK >= 1.
! 111: * If JOBZ = 'N' and N > 1, LRWORK >= N.
! 112: * If JOBZ = 'V' and N > 1, LRWORK >= 1 + 5*N + 2*N**2.
! 113: *
! 114: * If LRWORK = -1, then a workspace query is assumed; the
! 115: * routine only calculates the required sizes of the WORK, RWORK
! 116: * and IWORK arrays, returns these values as the first entries
! 117: * of the WORK, RWORK and IWORK arrays, and no error message
! 118: * related to LWORK or LRWORK or LIWORK is issued by XERBLA.
! 119: *
! 120: * IWORK (workspace/output) INTEGER array, dimension (MAX(1,LIWORK))
! 121: * On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
! 122: *
! 123: * LIWORK (input) INTEGER
! 124: * The dimension of array IWORK.
! 125: * If JOBZ = 'N' or N <= 1, LIWORK >= 1.
! 126: * If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
! 127: *
! 128: * If LIWORK = -1, then a workspace query is assumed; the
! 129: * routine only calculates the required sizes of the WORK, RWORK
! 130: * and IWORK arrays, returns these values as the first entries
! 131: * of the WORK, RWORK and IWORK arrays, and no error message
! 132: * related to LWORK or LRWORK or LIWORK is issued by XERBLA.
! 133: *
! 134: * INFO (output) INTEGER
! 135: * = 0: successful exit
! 136: * < 0: if INFO = -i, the i-th argument had an illegal value
! 137: * > 0: ZPPTRF or ZHPEVD returned an error code:
! 138: * <= N: if INFO = i, ZHPEVD failed to converge;
! 139: * i off-diagonal elements of an intermediate
! 140: * tridiagonal form did not convergeto zero;
! 141: * > N: if INFO = N + i, for 1 <= i <= n, then the leading
! 142: * minor of order i of B is not positive definite.
! 143: * The factorization of B could not be completed and
! 144: * no eigenvalues or eigenvectors were computed.
! 145: *
! 146: * Further Details
! 147: * ===============
! 148: *
! 149: * Based on contributions by
! 150: * Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
! 151: *
! 152: * =====================================================================
! 153: *
! 154: * .. Local Scalars ..
! 155: LOGICAL LQUERY, UPPER, WANTZ
! 156: CHARACTER TRANS
! 157: INTEGER J, LIWMIN, LRWMIN, LWMIN, NEIG
! 158: * ..
! 159: * .. External Functions ..
! 160: LOGICAL LSAME
! 161: EXTERNAL LSAME
! 162: * ..
! 163: * .. External Subroutines ..
! 164: EXTERNAL XERBLA, ZHPEVD, ZHPGST, ZPPTRF, ZTPMV, ZTPSV
! 165: * ..
! 166: * .. Intrinsic Functions ..
! 167: INTRINSIC DBLE, MAX
! 168: * ..
! 169: * .. Executable Statements ..
! 170: *
! 171: * Test the input parameters.
! 172: *
! 173: WANTZ = LSAME( JOBZ, 'V' )
! 174: UPPER = LSAME( UPLO, 'U' )
! 175: LQUERY = ( LWORK.EQ.-1 .OR. LRWORK.EQ.-1 .OR. LIWORK.EQ.-1 )
! 176: *
! 177: INFO = 0
! 178: IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
! 179: INFO = -1
! 180: ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
! 181: INFO = -2
! 182: ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
! 183: INFO = -3
! 184: ELSE IF( N.LT.0 ) THEN
! 185: INFO = -4
! 186: ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
! 187: INFO = -9
! 188: END IF
! 189: *
! 190: IF( INFO.EQ.0 ) THEN
! 191: IF( N.LE.1 ) THEN
! 192: LWMIN = 1
! 193: LIWMIN = 1
! 194: LRWMIN = 1
! 195: ELSE
! 196: IF( WANTZ ) THEN
! 197: LWMIN = 2*N
! 198: LRWMIN = 1 + 5*N + 2*N**2
! 199: LIWMIN = 3 + 5*N
! 200: ELSE
! 201: LWMIN = N
! 202: LRWMIN = N
! 203: LIWMIN = 1
! 204: END IF
! 205: END IF
! 206: *
! 207: WORK( 1 ) = LWMIN
! 208: RWORK( 1 ) = LRWMIN
! 209: IWORK( 1 ) = LIWMIN
! 210: IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
! 211: INFO = -11
! 212: ELSE IF( LRWORK.LT.LRWMIN .AND. .NOT.LQUERY ) THEN
! 213: INFO = -13
! 214: ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
! 215: INFO = -15
! 216: END IF
! 217: END IF
! 218: *
! 219: IF( INFO.NE.0 ) THEN
! 220: CALL XERBLA( 'ZHPGVD', -INFO )
! 221: RETURN
! 222: ELSE IF( LQUERY ) THEN
! 223: RETURN
! 224: END IF
! 225: *
! 226: * Quick return if possible
! 227: *
! 228: IF( N.EQ.0 )
! 229: $ RETURN
! 230: *
! 231: * Form a Cholesky factorization of B.
! 232: *
! 233: CALL ZPPTRF( UPLO, N, BP, INFO )
! 234: IF( INFO.NE.0 ) THEN
! 235: INFO = N + INFO
! 236: RETURN
! 237: END IF
! 238: *
! 239: * Transform problem to standard eigenvalue problem and solve.
! 240: *
! 241: CALL ZHPGST( ITYPE, UPLO, N, AP, BP, INFO )
! 242: CALL ZHPEVD( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK, RWORK,
! 243: $ LRWORK, IWORK, LIWORK, INFO )
! 244: LWMIN = MAX( DBLE( LWMIN ), DBLE( WORK( 1 ) ) )
! 245: LRWMIN = MAX( DBLE( LRWMIN ), DBLE( RWORK( 1 ) ) )
! 246: LIWMIN = MAX( DBLE( LIWMIN ), DBLE( IWORK( 1 ) ) )
! 247: *
! 248: IF( WANTZ ) THEN
! 249: *
! 250: * Backtransform eigenvectors to the original problem.
! 251: *
! 252: NEIG = N
! 253: IF( INFO.GT.0 )
! 254: $ NEIG = INFO - 1
! 255: IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
! 256: *
! 257: * For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
! 258: * backtransform eigenvectors: x = inv(L)'*y or inv(U)*y
! 259: *
! 260: IF( UPPER ) THEN
! 261: TRANS = 'N'
! 262: ELSE
! 263: TRANS = 'C'
! 264: END IF
! 265: *
! 266: DO 10 J = 1, NEIG
! 267: CALL ZTPSV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
! 268: $ 1 )
! 269: 10 CONTINUE
! 270: *
! 271: ELSE IF( ITYPE.EQ.3 ) THEN
! 272: *
! 273: * For B*A*x=(lambda)*x;
! 274: * backtransform eigenvectors: x = L*y or U'*y
! 275: *
! 276: IF( UPPER ) THEN
! 277: TRANS = 'C'
! 278: ELSE
! 279: TRANS = 'N'
! 280: END IF
! 281: *
! 282: DO 20 J = 1, NEIG
! 283: CALL ZTPMV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
! 284: $ 1 )
! 285: 20 CONTINUE
! 286: END IF
! 287: END IF
! 288: *
! 289: WORK( 1 ) = LWMIN
! 290: RWORK( 1 ) = LRWMIN
! 291: IWORK( 1 ) = LIWMIN
! 292: RETURN
! 293: *
! 294: * End of ZHPGVD
! 295: *
! 296: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zhpgvd.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack