1: *> \brief \b ZHETRF_ROOK computes the factorization of a complex Hermitian indefinite matrix using the bounded Bunch-Kaufman ("rook") diagonal pivoting method (blocked algorithm, calling Level 3 BLAS).
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZHETRF_ROOK + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhetrf_rook.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhetrf_rook.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhetrf_rook.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZHETRF_ROOK( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * CHARACTER UPLO
25: * INTEGER INFO, LDA, LWORK, N
26: * ..
27: * .. Array Arguments ..
28: * INTEGER IPIV( * )
29: * COMPLEX*16 A( LDA, * ), WORK( * )
30: * ..
31: *
32: *
33: *> \par Purpose:
34: * =============
35: *>
36: *> \verbatim
37: *>
38: *> ZHETRF_ROOK computes the factorization of a complex Hermitian matrix A
39: *> using the bounded Bunch-Kaufman ("rook") diagonal pivoting method.
40: *> The form of the factorization is
41: *>
42: *> A = U*D*U**T or A = L*D*L**T
43: *>
44: *> where U (or L) is a product of permutation and unit upper (lower)
45: *> triangular matrices, and D is Hermitian and block diagonal with
46: *> 1-by-1 and 2-by-2 diagonal blocks.
47: *>
48: *> This is the blocked version of the algorithm, calling Level 3 BLAS.
49: *> \endverbatim
50: *
51: * Arguments:
52: * ==========
53: *
54: *> \param[in] UPLO
55: *> \verbatim
56: *> UPLO is CHARACTER*1
57: *> = 'U': Upper triangle of A is stored;
58: *> = 'L': Lower triangle of A is stored.
59: *> \endverbatim
60: *>
61: *> \param[in] N
62: *> \verbatim
63: *> N is INTEGER
64: *> The order of the matrix A. N >= 0.
65: *> \endverbatim
66: *>
67: *> \param[in,out] A
68: *> \verbatim
69: *> A is COMPLEX*16 array, dimension (LDA,N)
70: *> On entry, the Hermitian matrix A. If UPLO = 'U', the leading
71: *> N-by-N upper triangular part of A contains the upper
72: *> triangular part of the matrix A, and the strictly lower
73: *> triangular part of A is not referenced. If UPLO = 'L', the
74: *> leading N-by-N lower triangular part of A contains the lower
75: *> triangular part of the matrix A, and the strictly upper
76: *> triangular part of A is not referenced.
77: *>
78: *> On exit, the block diagonal matrix D and the multipliers used
79: *> to obtain the factor U or L (see below for further details).
80: *> \endverbatim
81: *>
82: *> \param[in] LDA
83: *> \verbatim
84: *> LDA is INTEGER
85: *> The leading dimension of the array A. LDA >= max(1,N).
86: *> \endverbatim
87: *>
88: *> \param[out] IPIV
89: *> \verbatim
90: *> IPIV is INTEGER array, dimension (N)
91: *> Details of the interchanges and the block structure of D.
92: *>
93: *> If UPLO = 'U':
94: *> Only the last KB elements of IPIV are set.
95: *>
96: *> If IPIV(k) > 0, then rows and columns k and IPIV(k) were
97: *> interchanged and D(k,k) is a 1-by-1 diagonal block.
98: *>
99: *> If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and
100: *> columns k and -IPIV(k) were interchanged and rows and
101: *> columns k-1 and -IPIV(k-1) were inerchaged,
102: *> D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
103: *>
104: *> If UPLO = 'L':
105: *> Only the first KB elements of IPIV are set.
106: *>
107: *> If IPIV(k) > 0, then rows and columns k and IPIV(k)
108: *> were interchanged and D(k,k) is a 1-by-1 diagonal block.
109: *>
110: *> If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and
111: *> columns k and -IPIV(k) were interchanged and rows and
112: *> columns k+1 and -IPIV(k+1) were inerchaged,
113: *> D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
114: *> \endverbatim
115: *>
116: *> \param[out] WORK
117: *> \verbatim
118: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK)).
119: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
120: *> \endverbatim
121: *>
122: *> \param[in] LWORK
123: *> \verbatim
124: *> LWORK is INTEGER
125: *> The length of WORK. LWORK >=1. For best performance
126: *> LWORK >= N*NB, where NB is the block size returned by ILAENV.
127: *>
128: *> If LWORK = -1, then a workspace query is assumed; the routine
129: *> only calculates the optimal size of the WORK array, returns
130: *> this value as the first entry of the WORK array, and no error
131: *> message related to LWORK is issued by XERBLA.
132: *> \endverbatim
133: *>
134: *> \param[out] INFO
135: *> \verbatim
136: *> INFO is INTEGER
137: *> = 0: successful exit
138: *> < 0: if INFO = -i, the i-th argument had an illegal value
139: *> > 0: if INFO = i, D(i,i) is exactly zero. The factorization
140: *> has been completed, but the block diagonal matrix D is
141: *> exactly singular, and division by zero will occur if it
142: *> is used to solve a system of equations.
143: *> \endverbatim
144: *
145: * Authors:
146: * ========
147: *
148: *> \author Univ. of Tennessee
149: *> \author Univ. of California Berkeley
150: *> \author Univ. of Colorado Denver
151: *> \author NAG Ltd.
152: *
153: *> \ingroup complex16HEcomputational
154: *
155: *> \par Further Details:
156: * =====================
157: *>
158: *> \verbatim
159: *>
160: *> If UPLO = 'U', then A = U*D*U**T, where
161: *> U = P(n)*U(n)* ... *P(k)U(k)* ...,
162: *> i.e., U is a product of terms P(k)*U(k), where k decreases from n to
163: *> 1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
164: *> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
165: *> defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
166: *> that if the diagonal block D(k) is of order s (s = 1 or 2), then
167: *>
168: *> ( I v 0 ) k-s
169: *> U(k) = ( 0 I 0 ) s
170: *> ( 0 0 I ) n-k
171: *> k-s s n-k
172: *>
173: *> If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
174: *> If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
175: *> and A(k,k), and v overwrites A(1:k-2,k-1:k).
176: *>
177: *> If UPLO = 'L', then A = L*D*L**T, where
178: *> L = P(1)*L(1)* ... *P(k)*L(k)* ...,
179: *> i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
180: *> n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
181: *> and 2-by-2 diagonal blocks D(k). P(k) is a permutation matrix as
182: *> defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
183: *> that if the diagonal block D(k) is of order s (s = 1 or 2), then
184: *>
185: *> ( I 0 0 ) k-1
186: *> L(k) = ( 0 I 0 ) s
187: *> ( 0 v I ) n-k-s+1
188: *> k-1 s n-k-s+1
189: *>
190: *> If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
191: *> If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
192: *> and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
193: *> \endverbatim
194: *
195: *> \par Contributors:
196: * ==================
197: *>
198: *> \verbatim
199: *>
200: *> June 2016, Igor Kozachenko,
201: *> Computer Science Division,
202: *> University of California, Berkeley
203: *>
204: *> September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
205: *> School of Mathematics,
206: *> University of Manchester
207: *>
208: *> \endverbatim
209: *
210: * =====================================================================
211: SUBROUTINE ZHETRF_ROOK( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
212: *
213: * -- LAPACK computational routine --
214: * -- LAPACK is a software package provided by Univ. of Tennessee, --
215: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
216: *
217: * .. Scalar Arguments ..
218: CHARACTER UPLO
219: INTEGER INFO, LDA, LWORK, N
220: * ..
221: * .. Array Arguments ..
222: INTEGER IPIV( * )
223: COMPLEX*16 A( LDA, * ), WORK( * )
224: * ..
225: *
226: * =====================================================================
227: *
228: * .. Local Scalars ..
229: LOGICAL LQUERY, UPPER
230: INTEGER IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
231: * ..
232: * .. External Functions ..
233: LOGICAL LSAME
234: INTEGER ILAENV
235: EXTERNAL LSAME, ILAENV
236: * ..
237: * .. External Subroutines ..
238: EXTERNAL ZLAHEF_ROOK, ZHETF2_ROOK, XERBLA
239: * ..
240: * .. Intrinsic Functions ..
241: INTRINSIC MAX
242: * ..
243: * .. Executable Statements ..
244: *
245: * Test the input parameters.
246: *
247: INFO = 0
248: UPPER = LSAME( UPLO, 'U' )
249: LQUERY = ( LWORK.EQ.-1 )
250: IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
251: INFO = -1
252: ELSE IF( N.LT.0 ) THEN
253: INFO = -2
254: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
255: INFO = -4
256: ELSE IF( LWORK.LT.1 .AND. .NOT.LQUERY ) THEN
257: INFO = -7
258: END IF
259: *
260: IF( INFO.EQ.0 ) THEN
261: *
262: * Determine the block size
263: *
264: NB = ILAENV( 1, 'ZHETRF_ROOK', UPLO, N, -1, -1, -1 )
265: LWKOPT = MAX( 1, N*NB )
266: WORK( 1 ) = LWKOPT
267: END IF
268: *
269: IF( INFO.NE.0 ) THEN
270: CALL XERBLA( 'ZHETRF_ROOK', -INFO )
271: RETURN
272: ELSE IF( LQUERY ) THEN
273: RETURN
274: END IF
275: *
276: NBMIN = 2
277: LDWORK = N
278: IF( NB.GT.1 .AND. NB.LT.N ) THEN
279: IWS = LDWORK*NB
280: IF( LWORK.LT.IWS ) THEN
281: NB = MAX( LWORK / LDWORK, 1 )
282: NBMIN = MAX( 2, ILAENV( 2, 'ZHETRF_ROOK',
283: $ UPLO, N, -1, -1, -1 ) )
284: END IF
285: ELSE
286: IWS = 1
287: END IF
288: IF( NB.LT.NBMIN )
289: $ NB = N
290: *
291: IF( UPPER ) THEN
292: *
293: * Factorize A as U*D*U**T using the upper triangle of A
294: *
295: * K is the main loop index, decreasing from N to 1 in steps of
296: * KB, where KB is the number of columns factorized by ZLAHEF_ROOK;
297: * KB is either NB or NB-1, or K for the last block
298: *
299: K = N
300: 10 CONTINUE
301: *
302: * If K < 1, exit from loop
303: *
304: IF( K.LT.1 )
305: $ GO TO 40
306: *
307: IF( K.GT.NB ) THEN
308: *
309: * Factorize columns k-kb+1:k of A and use blocked code to
310: * update columns 1:k-kb
311: *
312: CALL ZLAHEF_ROOK( UPLO, K, NB, KB, A, LDA,
313: $ IPIV, WORK, LDWORK, IINFO )
314: ELSE
315: *
316: * Use unblocked code to factorize columns 1:k of A
317: *
318: CALL ZHETF2_ROOK( UPLO, K, A, LDA, IPIV, IINFO )
319: KB = K
320: END IF
321: *
322: * Set INFO on the first occurrence of a zero pivot
323: *
324: IF( INFO.EQ.0 .AND. IINFO.GT.0 )
325: $ INFO = IINFO
326: *
327: * No need to adjust IPIV
328: *
329: * Decrease K and return to the start of the main loop
330: *
331: K = K - KB
332: GO TO 10
333: *
334: ELSE
335: *
336: * Factorize A as L*D*L**T using the lower triangle of A
337: *
338: * K is the main loop index, increasing from 1 to N in steps of
339: * KB, where KB is the number of columns factorized by ZLAHEF_ROOK;
340: * KB is either NB or NB-1, or N-K+1 for the last block
341: *
342: K = 1
343: 20 CONTINUE
344: *
345: * If K > N, exit from loop
346: *
347: IF( K.GT.N )
348: $ GO TO 40
349: *
350: IF( K.LE.N-NB ) THEN
351: *
352: * Factorize columns k:k+kb-1 of A and use blocked code to
353: * update columns k+kb:n
354: *
355: CALL ZLAHEF_ROOK( UPLO, N-K+1, NB, KB, A( K, K ), LDA,
356: $ IPIV( K ), WORK, LDWORK, IINFO )
357: ELSE
358: *
359: * Use unblocked code to factorize columns k:n of A
360: *
361: CALL ZHETF2_ROOK( UPLO, N-K+1, A( K, K ), LDA, IPIV( K ),
362: $ IINFO )
363: KB = N - K + 1
364: END IF
365: *
366: * Set INFO on the first occurrence of a zero pivot
367: *
368: IF( INFO.EQ.0 .AND. IINFO.GT.0 )
369: $ INFO = IINFO + K - 1
370: *
371: * Adjust IPIV
372: *
373: DO 30 J = K, K + KB - 1
374: IF( IPIV( J ).GT.0 ) THEN
375: IPIV( J ) = IPIV( J ) + K - 1
376: ELSE
377: IPIV( J ) = IPIV( J ) - K + 1
378: END IF
379: 30 CONTINUE
380: *
381: * Increase K and return to the start of the main loop
382: *
383: K = K + KB
384: GO TO 20
385: *
386: END IF
387: *
388: 40 CONTINUE
389: WORK( 1 ) = LWKOPT
390: RETURN
391: *
392: * End of ZHETRF_ROOK
393: *
394: END
CVSweb interface <joel.bertrand@systella.fr>