Return to zhetrf.f CVS log

Up to [local] / rpl / lapack / lapack

Cohérence.

    1: *> \brief \b ZHETRF
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at 
    6: *            http://www.netlib.org/lapack/explore-html/ 
    7: *
    8: *> \htmlonly
    9: *> Download ZHETRF + dependencies 
   10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhetrf.f"> 
   11: *> [TGZ]</a> 
   12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhetrf.f"> 
   13: *> [ZIP]</a> 
   14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhetrf.f"> 
   15: *> [TXT]</a>
   16: *> \endhtmlonly 
   17: *
   18: *  Definition:
   19: *  ===========
   20: *
   21: *       SUBROUTINE ZHETRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
   22: * 
   23: *       .. Scalar Arguments ..
   24: *       CHARACTER          UPLO
   25: *       INTEGER            INFO, LDA, LWORK, N
   26: *       ..
   27: *       .. Array Arguments ..
   28: *       INTEGER            IPIV( * )
   29: *       COMPLEX*16         A( LDA, * ), WORK( * )
   30: *       ..
   31: *  
   32: *
   33: *> \par Purpose:
   34: *  =============
   35: *>
   36: *> \verbatim
   37: *>
   38: *> ZHETRF computes the factorization of a complex Hermitian matrix A
   39: *> using the Bunch-Kaufman diagonal pivoting method.  The form of the
   40: *> factorization is
   41: *>
   42: *>    A = U*D*U**H  or  A = L*D*L**H
   43: *>
   44: *> where U (or L) is a product of permutation and unit upper (lower)
   45: *> triangular matrices, and D is Hermitian and block diagonal with
   46: *> 1-by-1 and 2-by-2 diagonal blocks.
   47: *>
   48: *> This is the blocked version of the algorithm, calling Level 3 BLAS.
   49: *> \endverbatim
   50: *
   51: *  Arguments:
   52: *  ==========
   53: *
   54: *> \param[in] UPLO
   55: *> \verbatim
   56: *>          UPLO is CHARACTER*1
   57: *>          = 'U':  Upper triangle of A is stored;
   58: *>          = 'L':  Lower triangle of A is stored.
   59: *> \endverbatim
   60: *>
   61: *> \param[in] N
   62: *> \verbatim
   63: *>          N is INTEGER
   64: *>          The order of the matrix A.  N >= 0.
   65: *> \endverbatim
   66: *>
   67: *> \param[in,out] A
   68: *> \verbatim
   69: *>          A is COMPLEX*16 array, dimension (LDA,N)
   70: *>          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
   71: *>          N-by-N upper triangular part of A contains the upper
   72: *>          triangular part of the matrix A, and the strictly lower
   73: *>          triangular part of A is not referenced.  If UPLO = 'L', the
   74: *>          leading N-by-N lower triangular part of A contains the lower
   75: *>          triangular part of the matrix A, and the strictly upper
   76: *>          triangular part of A is not referenced.
   77: *>
   78: *>          On exit, the block diagonal matrix D and the multipliers used
   79: *>          to obtain the factor U or L (see below for further details).
   80: *> \endverbatim
   81: *>
   82: *> \param[in] LDA
   83: *> \verbatim
   84: *>          LDA is INTEGER
   85: *>          The leading dimension of the array A.  LDA >= max(1,N).
   86: *> \endverbatim
   87: *>
   88: *> \param[out] IPIV
   89: *> \verbatim
   90: *>          IPIV is INTEGER array, dimension (N)
   91: *>          Details of the interchanges and the block structure of D.
   92: *>          If IPIV(k) > 0, then rows and columns k and IPIV(k) were
   93: *>          interchanged and D(k,k) is a 1-by-1 diagonal block.
   94: *>          If UPLO = 'U' and IPIV(k) = IPIV(k-1) < 0, then rows and
   95: *>          columns k-1 and -IPIV(k) were interchanged and D(k-1:k,k-1:k)
   96: *>          is a 2-by-2 diagonal block.  If UPLO = 'L' and IPIV(k) =
   97: *>          IPIV(k+1) < 0, then rows and columns k+1 and -IPIV(k) were
   98: *>          interchanged and D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
   99: *> \endverbatim
  100: *>
  101: *> \param[out] WORK
  102: *> \verbatim
  103: *>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
  104: *>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  105: *> \endverbatim
  106: *>
  107: *> \param[in] LWORK
  108: *> \verbatim
  109: *>          LWORK is INTEGER
  110: *>          The length of WORK.  LWORK >=1.  For best performance
  111: *>          LWORK >= N*NB, where NB is the block size returned by ILAENV.
  112: *> \endverbatim
  113: *>
  114: *> \param[out] INFO
  115: *> \verbatim
  116: *>          INFO is INTEGER
  117: *>          = 0:  successful exit
  118: *>          < 0:  if INFO = -i, the i-th argument had an illegal value
  119: *>          > 0:  if INFO = i, D(i,i) is exactly zero.  The factorization
  120: *>                has been completed, but the block diagonal matrix D is
  121: *>                exactly singular, and division by zero will occur if it
  122: *>                is used to solve a system of equations.
  123: *> \endverbatim
  124: *
  125: *  Authors:
  126: *  ========
  127: *
  128: *> \author Univ. of Tennessee 
  129: *> \author Univ. of California Berkeley 
  130: *> \author Univ. of Colorado Denver 
  131: *> \author NAG Ltd. 
  132: *
  133: *> \date November 2011
  134: *
  135: *> \ingroup complex16HEcomputational
  136: *
  137: *> \par Further Details:
  138: *  =====================
  139: *>
  140: *> \verbatim
  141: *>
  142: *>  If UPLO = 'U', then A = U*D*U**H, where
  143: *>     U = P(n)*U(n)* ... *P(k)U(k)* ...,
  144: *>  i.e., U is a product of terms P(k)*U(k), where k decreases from n to
  145: *>  1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  146: *>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  147: *>  defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
  148: *>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
  149: *>
  150: *>             (   I    v    0   )   k-s
  151: *>     U(k) =  (   0    I    0   )   s
  152: *>             (   0    0    I   )   n-k
  153: *>                k-s   s   n-k
  154: *>
  155: *>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
  156: *>  If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
  157: *>  and A(k,k), and v overwrites A(1:k-2,k-1:k).
  158: *>
  159: *>  If UPLO = 'L', then A = L*D*L**H, where
  160: *>     L = P(1)*L(1)* ... *P(k)*L(k)* ...,
  161: *>  i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
  162: *>  n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
  163: *>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
  164: *>  defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
  165: *>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
  166: *>
  167: *>             (   I    0     0   )  k-1
  168: *>     L(k) =  (   0    I     0   )  s
  169: *>             (   0    v     I   )  n-k-s+1
  170: *>                k-1   s  n-k-s+1
  171: *>
  172: *>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
  173: *>  If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
  174: *>  and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
  175: *> \endverbatim
  176: *>
  177: *  =====================================================================
  178:       SUBROUTINE ZHETRF( UPLO, N, A, LDA, IPIV, WORK, LWORK, INFO )
  179: *
  180: *  -- LAPACK computational routine (version 3.4.0) --
  181: *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
  182: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
  183: *     November 2011
  184: *
  185: *     .. Scalar Arguments ..
  186:       CHARACTER          UPLO
  187:       INTEGER            INFO, LDA, LWORK, N
  188: *     ..
  189: *     .. Array Arguments ..
  190:       INTEGER            IPIV( * )
  191:       COMPLEX*16         A( LDA, * ), WORK( * )
  192: *     ..
  193: *
  194: *  =====================================================================
  195: *
  196: *     .. Local Scalars ..
  197:       LOGICAL            LQUERY, UPPER
  198:       INTEGER            IINFO, IWS, J, K, KB, LDWORK, LWKOPT, NB, NBMIN
  199: *     ..
  200: *     .. External Functions ..
  201:       LOGICAL            LSAME
  202:       INTEGER            ILAENV
  203:       EXTERNAL           LSAME, ILAENV
  204: *     ..
  205: *     .. External Subroutines ..
  206:       EXTERNAL           XERBLA, ZHETF2, ZLAHEF
  207: *     ..
  208: *     .. Intrinsic Functions ..
  209:       INTRINSIC          MAX
  210: *     ..
  211: *     .. Executable Statements ..
  212: *
  213: *     Test the input parameters.
  214: *
  215:       INFO = 0
  216:       UPPER = LSAME( UPLO, 'U' )
  217:       LQUERY = ( LWORK.EQ.-1 )
  218:       IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
  219:          INFO = -1
  220:       ELSE IF( N.LT.0 ) THEN
  221:          INFO = -2
  222:       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  223:          INFO = -4
  224:       ELSE IF( LWORK.LT.1 .AND. .NOT.LQUERY ) THEN
  225:          INFO = -7
  226:       END IF
  227: *
  228:       IF( INFO.EQ.0 ) THEN
  229: *
  230: *        Determine the block size
  231: *
  232:          NB = ILAENV( 1, 'ZHETRF', UPLO, N, -1, -1, -1 )
  233:          LWKOPT = N*NB
  234:          WORK( 1 ) = LWKOPT
  235:       END IF
  236: *
  237:       IF( INFO.NE.0 ) THEN
  238:          CALL XERBLA( 'ZHETRF', -INFO )
  239:          RETURN
  240:       ELSE IF( LQUERY ) THEN
  241:          RETURN
  242:       END IF
  243: *
  244:       NBMIN = 2
  245:       LDWORK = N
  246:       IF( NB.GT.1 .AND. NB.LT.N ) THEN
  247:          IWS = LDWORK*NB
  248:          IF( LWORK.LT.IWS ) THEN
  249:             NB = MAX( LWORK / LDWORK, 1 )
  250:             NBMIN = MAX( 2, ILAENV( 2, 'ZHETRF', UPLO, N, -1, -1, -1 ) )
  251:          END IF
  252:       ELSE
  253:          IWS = 1
  254:       END IF
  255:       IF( NB.LT.NBMIN )
  256:      $   NB = N
  257: *
  258:       IF( UPPER ) THEN
  259: *
  260: *        Factorize A as U*D*U**H using the upper triangle of A
  261: *
  262: *        K is the main loop index, decreasing from N to 1 in steps of
  263: *        KB, where KB is the number of columns factorized by ZLAHEF;
  264: *        KB is either NB or NB-1, or K for the last block
  265: *
  266:          K = N
  267:    10    CONTINUE
  268: *
  269: *        If K < 1, exit from loop
  270: *
  271:          IF( K.LT.1 )
  272:      $      GO TO 40
  273: *
  274:          IF( K.GT.NB ) THEN
  275: *
  276: *           Factorize columns k-kb+1:k of A and use blocked code to
  277: *           update columns 1:k-kb
  278: *
  279:             CALL ZLAHEF( UPLO, K, NB, KB, A, LDA, IPIV, WORK, N, IINFO )
  280:          ELSE
  281: *
  282: *           Use unblocked code to factorize columns 1:k of A
  283: *
  284:             CALL ZHETF2( UPLO, K, A, LDA, IPIV, IINFO )
  285:             KB = K
  286:          END IF
  287: *
  288: *        Set INFO on the first occurrence of a zero pivot
  289: *
  290:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
  291:      $      INFO = IINFO
  292: *
  293: *        Decrease K and return to the start of the main loop
  294: *
  295:          K = K - KB
  296:          GO TO 10
  297: *
  298:       ELSE
  299: *
  300: *        Factorize A as L*D*L**H using the lower triangle of A
  301: *
  302: *        K is the main loop index, increasing from 1 to N in steps of
  303: *        KB, where KB is the number of columns factorized by ZLAHEF;
  304: *        KB is either NB or NB-1, or N-K+1 for the last block
  305: *
  306:          K = 1
  307:    20    CONTINUE
  308: *
  309: *        If K > N, exit from loop
  310: *
  311:          IF( K.GT.N )
  312:      $      GO TO 40
  313: *
  314:          IF( K.LE.N-NB ) THEN
  315: *
  316: *           Factorize columns k:k+kb-1 of A and use blocked code to
  317: *           update columns k+kb:n
  318: *
  319:             CALL ZLAHEF( UPLO, N-K+1, NB, KB, A( K, K ), LDA, IPIV( K ),
  320:      $                   WORK, N, IINFO )
  321:          ELSE
  322: *
  323: *           Use unblocked code to factorize columns k:n of A
  324: *
  325:             CALL ZHETF2( UPLO, N-K+1, A( K, K ), LDA, IPIV( K ), IINFO )
  326:             KB = N - K + 1
  327:          END IF
  328: *
  329: *        Set INFO on the first occurrence of a zero pivot
  330: *
  331:          IF( INFO.EQ.0 .AND. IINFO.GT.0 )
  332:      $      INFO = IINFO + K - 1
  333: *
  334: *        Adjust IPIV
  335: *
  336:          DO 30 J = K, K + KB - 1
  337:             IF( IPIV( J ).GT.0 ) THEN
  338:                IPIV( J ) = IPIV( J ) + K - 1
  339:             ELSE
  340:                IPIV( J ) = IPIV( J ) - K + 1
  341:             END IF
  342:    30    CONTINUE
  343: *
  344: *        Increase K and return to the start of the main loop
  345: *
  346:          K = K + KB
  347:          GO TO 20
  348: *
  349:       END IF
  350: *
  351:    40 CONTINUE
  352:       WORK( 1 ) = LWKOPT
  353:       RETURN
  354: *
  355: *     End of ZHETRF
  356: *
  357:       END