1: SUBROUTINE ZHERFSX( UPLO, EQUED, N, NRHS, A, LDA, AF, LDAF, IPIV,
2: $ S, B, LDB, X, LDX, RCOND, BERR, N_ERR_BNDS,
3: $ ERR_BNDS_NORM, ERR_BNDS_COMP, NPARAMS, PARAMS,
4: $ WORK, RWORK, INFO )
5: *
6: * -- LAPACK routine (version 3.2.2) --
7: * -- Contributed by James Demmel, Deaglan Halligan, Yozo Hida and --
8: * -- Jason Riedy of Univ. of California Berkeley. --
9: * -- June 2010 --
10: *
11: * -- LAPACK is a software package provided by Univ. of Tennessee, --
12: * -- Univ. of California Berkeley and NAG Ltd. --
13: *
14: IMPLICIT NONE
15: * ..
16: * .. Scalar Arguments ..
17: CHARACTER UPLO, EQUED
18: INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS, NPARAMS,
19: $ N_ERR_BNDS
20: DOUBLE PRECISION RCOND
21: * ..
22: * .. Array Arguments ..
23: INTEGER IPIV( * )
24: COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
25: $ X( LDX, * ), WORK( * )
26: DOUBLE PRECISION S( * ), PARAMS( * ), BERR( * ), RWORK( * ),
27: $ ERR_BNDS_NORM( NRHS, * ),
28: $ ERR_BNDS_COMP( NRHS, * )
29: *
30: * Purpose
31: * =======
32: *
33: * ZHERFSX improves the computed solution to a system of linear
34: * equations when the coefficient matrix is Hermitian indefinite, and
35: * provides error bounds and backward error estimates for the
36: * solution. In addition to normwise error bound, the code provides
37: * maximum componentwise error bound if possible. See comments for
38: * ERR_BNDS_NORM and ERR_BNDS_COMP for details of the error bounds.
39: *
40: * The original system of linear equations may have been equilibrated
41: * before calling this routine, as described by arguments EQUED and S
42: * below. In this case, the solution and error bounds returned are
43: * for the original unequilibrated system.
44: *
45: * Arguments
46: * =========
47: *
48: * Some optional parameters are bundled in the PARAMS array. These
49: * settings determine how refinement is performed, but often the
50: * defaults are acceptable. If the defaults are acceptable, users
51: * can pass NPARAMS = 0 which prevents the source code from accessing
52: * the PARAMS argument.
53: *
54: * UPLO (input) CHARACTER*1
55: * = 'U': Upper triangle of A is stored;
56: * = 'L': Lower triangle of A is stored.
57: *
58: * EQUED (input) CHARACTER*1
59: * Specifies the form of equilibration that was done to A
60: * before calling this routine. This is needed to compute
61: * the solution and error bounds correctly.
62: * = 'N': No equilibration
63: * = 'Y': Both row and column equilibration, i.e., A has been
64: * replaced by diag(S) * A * diag(S).
65: * The right hand side B has been changed accordingly.
66: *
67: * N (input) INTEGER
68: * The order of the matrix A. N >= 0.
69: *
70: * NRHS (input) INTEGER
71: * The number of right hand sides, i.e., the number of columns
72: * of the matrices B and X. NRHS >= 0.
73: *
74: * A (input) COMPLEX*16 array, dimension (LDA,N)
75: * The symmetric matrix A. If UPLO = 'U', the leading N-by-N
76: * upper triangular part of A contains the upper triangular
77: * part of the matrix A, and the strictly lower triangular
78: * part of A is not referenced. If UPLO = 'L', the leading
79: * N-by-N lower triangular part of A contains the lower
80: * triangular part of the matrix A, and the strictly upper
81: * triangular part of A is not referenced.
82: *
83: * LDA (input) INTEGER
84: * The leading dimension of the array A. LDA >= max(1,N).
85: *
86: * AF (input) COMPLEX*16 array, dimension (LDAF,N)
87: * The factored form of the matrix A. AF contains the block
88: * diagonal matrix D and the multipliers used to obtain the
89: * factor U or L from the factorization A = U*D*U**T or A =
90: * L*D*L**T as computed by DSYTRF.
91: *
92: * LDAF (input) INTEGER
93: * The leading dimension of the array AF. LDAF >= max(1,N).
94: *
95: * IPIV (input) INTEGER array, dimension (N)
96: * Details of the interchanges and the block structure of D
97: * as determined by DSYTRF.
98: *
99: * S (input or output) DOUBLE PRECISION array, dimension (N)
100: * The scale factors for A. If EQUED = 'Y', A is multiplied on
101: * the left and right by diag(S). S is an input argument if FACT =
102: * 'F'; otherwise, S is an output argument. If FACT = 'F' and EQUED
103: * = 'Y', each element of S must be positive. If S is output, each
104: * element of S is a power of the radix. If S is input, each element
105: * of S should be a power of the radix to ensure a reliable solution
106: * and error estimates. Scaling by powers of the radix does not cause
107: * rounding errors unless the result underflows or overflows.
108: * Rounding errors during scaling lead to refining with a matrix that
109: * is not equivalent to the input matrix, producing error estimates
110: * that may not be reliable.
111: *
112: * B (input) COMPLEX*16 array, dimension (LDB,NRHS)
113: * The right hand side matrix B.
114: *
115: * LDB (input) INTEGER
116: * The leading dimension of the array B. LDB >= max(1,N).
117: *
118: * X (input/output) COMPLEX*16 array, dimension (LDX,NRHS)
119: * On entry, the solution matrix X, as computed by DGETRS.
120: * On exit, the improved solution matrix X.
121: *
122: * LDX (input) INTEGER
123: * The leading dimension of the array X. LDX >= max(1,N).
124: *
125: * RCOND (output) DOUBLE PRECISION
126: * Reciprocal scaled condition number. This is an estimate of the
127: * reciprocal Skeel condition number of the matrix A after
128: * equilibration (if done). If this is less than the machine
129: * precision (in particular, if it is zero), the matrix is singular
130: * to working precision. Note that the error may still be small even
131: * if this number is very small and the matrix appears ill-
132: * conditioned.
133: *
134: * BERR (output) DOUBLE PRECISION array, dimension (NRHS)
135: * Componentwise relative backward error. This is the
136: * componentwise relative backward error of each solution vector X(j)
137: * (i.e., the smallest relative change in any element of A or B that
138: * makes X(j) an exact solution).
139: *
140: * N_ERR_BNDS (input) INTEGER
141: * Number of error bounds to return for each right hand side
142: * and each type (normwise or componentwise). See ERR_BNDS_NORM and
143: * ERR_BNDS_COMP below.
144: *
145: * ERR_BNDS_NORM (output) DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
146: * For each right-hand side, this array contains information about
147: * various error bounds and condition numbers corresponding to the
148: * normwise relative error, which is defined as follows:
149: *
150: * Normwise relative error in the ith solution vector:
151: * max_j (abs(XTRUE(j,i) - X(j,i)))
152: * ------------------------------
153: * max_j abs(X(j,i))
154: *
155: * The array is indexed by the type of error information as described
156: * below. There currently are up to three pieces of information
157: * returned.
158: *
159: * The first index in ERR_BNDS_NORM(i,:) corresponds to the ith
160: * right-hand side.
161: *
162: * The second index in ERR_BNDS_NORM(:,err) contains the following
163: * three fields:
164: * err = 1 "Trust/don't trust" boolean. Trust the answer if the
165: * reciprocal condition number is less than the threshold
166: * sqrt(n) * dlamch('Epsilon').
167: *
168: * err = 2 "Guaranteed" error bound: The estimated forward error,
169: * almost certainly within a factor of 10 of the true error
170: * so long as the next entry is greater than the threshold
171: * sqrt(n) * dlamch('Epsilon'). This error bound should only
172: * be trusted if the previous boolean is true.
173: *
174: * err = 3 Reciprocal condition number: Estimated normwise
175: * reciprocal condition number. Compared with the threshold
176: * sqrt(n) * dlamch('Epsilon') to determine if the error
177: * estimate is "guaranteed". These reciprocal condition
178: * numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
179: * appropriately scaled matrix Z.
180: * Let Z = S*A, where S scales each row by a power of the
181: * radix so all absolute row sums of Z are approximately 1.
182: *
183: * See Lapack Working Note 165 for further details and extra
184: * cautions.
185: *
186: * ERR_BNDS_COMP (output) DOUBLE PRECISION array, dimension (NRHS, N_ERR_BNDS)
187: * For each right-hand side, this array contains information about
188: * various error bounds and condition numbers corresponding to the
189: * componentwise relative error, which is defined as follows:
190: *
191: * Componentwise relative error in the ith solution vector:
192: * abs(XTRUE(j,i) - X(j,i))
193: * max_j ----------------------
194: * abs(X(j,i))
195: *
196: * The array is indexed by the right-hand side i (on which the
197: * componentwise relative error depends), and the type of error
198: * information as described below. There currently are up to three
199: * pieces of information returned for each right-hand side. If
200: * componentwise accuracy is not requested (PARAMS(3) = 0.0), then
201: * ERR_BNDS_COMP is not accessed. If N_ERR_BNDS .LT. 3, then at most
202: * the first (:,N_ERR_BNDS) entries are returned.
203: *
204: * The first index in ERR_BNDS_COMP(i,:) corresponds to the ith
205: * right-hand side.
206: *
207: * The second index in ERR_BNDS_COMP(:,err) contains the following
208: * three fields:
209: * err = 1 "Trust/don't trust" boolean. Trust the answer if the
210: * reciprocal condition number is less than the threshold
211: * sqrt(n) * dlamch('Epsilon').
212: *
213: * err = 2 "Guaranteed" error bound: The estimated forward error,
214: * almost certainly within a factor of 10 of the true error
215: * so long as the next entry is greater than the threshold
216: * sqrt(n) * dlamch('Epsilon'). This error bound should only
217: * be trusted if the previous boolean is true.
218: *
219: * err = 3 Reciprocal condition number: Estimated componentwise
220: * reciprocal condition number. Compared with the threshold
221: * sqrt(n) * dlamch('Epsilon') to determine if the error
222: * estimate is "guaranteed". These reciprocal condition
223: * numbers are 1 / (norm(Z^{-1},inf) * norm(Z,inf)) for some
224: * appropriately scaled matrix Z.
225: * Let Z = S*(A*diag(x)), where x is the solution for the
226: * current right-hand side and S scales each row of
227: * A*diag(x) by a power of the radix so all absolute row
228: * sums of Z are approximately 1.
229: *
230: * See Lapack Working Note 165 for further details and extra
231: * cautions.
232: *
233: * NPARAMS (input) INTEGER
234: * Specifies the number of parameters set in PARAMS. If .LE. 0, the
235: * PARAMS array is never referenced and default values are used.
236: *
237: * PARAMS (input / output) DOUBLE PRECISION array, dimension NPARAMS
238: * Specifies algorithm parameters. If an entry is .LT. 0.0, then
239: * that entry will be filled with default value used for that
240: * parameter. Only positions up to NPARAMS are accessed; defaults
241: * are used for higher-numbered parameters.
242: *
243: * PARAMS(LA_LINRX_ITREF_I = 1) : Whether to perform iterative
244: * refinement or not.
245: * Default: 1.0D+0
246: * = 0.0 : No refinement is performed, and no error bounds are
247: * computed.
248: * = 1.0 : Use the double-precision refinement algorithm,
249: * possibly with doubled-single computations if the
250: * compilation environment does not support DOUBLE
251: * PRECISION.
252: * (other values are reserved for future use)
253: *
254: * PARAMS(LA_LINRX_ITHRESH_I = 2) : Maximum number of residual
255: * computations allowed for refinement.
256: * Default: 10
257: * Aggressive: Set to 100 to permit convergence using approximate
258: * factorizations or factorizations other than LU. If
259: * the factorization uses a technique other than
260: * Gaussian elimination, the guarantees in
261: * err_bnds_norm and err_bnds_comp may no longer be
262: * trustworthy.
263: *
264: * PARAMS(LA_LINRX_CWISE_I = 3) : Flag determining if the code
265: * will attempt to find a solution with small componentwise
266: * relative error in the double-precision algorithm. Positive
267: * is true, 0.0 is false.
268: * Default: 1.0 (attempt componentwise convergence)
269: *
270: * WORK (workspace) COMPLEX*16 array, dimension (2*N)
271: *
272: * RWORK (workspace) DOUBLE PRECISION array, dimension (2*N)
273: *
274: * INFO (output) INTEGER
275: * = 0: Successful exit. The solution to every right-hand side is
276: * guaranteed.
277: * < 0: If INFO = -i, the i-th argument had an illegal value
278: * > 0 and <= N: U(INFO,INFO) is exactly zero. The factorization
279: * has been completed, but the factor U is exactly singular, so
280: * the solution and error bounds could not be computed. RCOND = 0
281: * is returned.
282: * = N+J: The solution corresponding to the Jth right-hand side is
283: * not guaranteed. The solutions corresponding to other right-
284: * hand sides K with K > J may not be guaranteed as well, but
285: * only the first such right-hand side is reported. If a small
286: * componentwise error is not requested (PARAMS(3) = 0.0) then
287: * the Jth right-hand side is the first with a normwise error
288: * bound that is not guaranteed (the smallest J such
289: * that ERR_BNDS_NORM(J,1) = 0.0). By default (PARAMS(3) = 1.0)
290: * the Jth right-hand side is the first with either a normwise or
291: * componentwise error bound that is not guaranteed (the smallest
292: * J such that either ERR_BNDS_NORM(J,1) = 0.0 or
293: * ERR_BNDS_COMP(J,1) = 0.0). See the definition of
294: * ERR_BNDS_NORM(:,1) and ERR_BNDS_COMP(:,1). To get information
295: * about all of the right-hand sides check ERR_BNDS_NORM or
296: * ERR_BNDS_COMP.
297: *
298: * ==================================================================
299: *
300: * .. Parameters ..
301: DOUBLE PRECISION ZERO, ONE
302: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
303: DOUBLE PRECISION ITREF_DEFAULT, ITHRESH_DEFAULT
304: DOUBLE PRECISION COMPONENTWISE_DEFAULT, RTHRESH_DEFAULT
305: DOUBLE PRECISION DZTHRESH_DEFAULT
306: PARAMETER ( ITREF_DEFAULT = 1.0D+0 )
307: PARAMETER ( ITHRESH_DEFAULT = 10.0D+0 )
308: PARAMETER ( COMPONENTWISE_DEFAULT = 1.0D+0 )
309: PARAMETER ( RTHRESH_DEFAULT = 0.5D+0 )
310: PARAMETER ( DZTHRESH_DEFAULT = 0.25D+0 )
311: INTEGER LA_LINRX_ITREF_I, LA_LINRX_ITHRESH_I,
312: $ LA_LINRX_CWISE_I
313: PARAMETER ( LA_LINRX_ITREF_I = 1,
314: $ LA_LINRX_ITHRESH_I = 2 )
315: PARAMETER ( LA_LINRX_CWISE_I = 3 )
316: INTEGER LA_LINRX_TRUST_I, LA_LINRX_ERR_I,
317: $ LA_LINRX_RCOND_I
318: PARAMETER ( LA_LINRX_TRUST_I = 1, LA_LINRX_ERR_I = 2 )
319: PARAMETER ( LA_LINRX_RCOND_I = 3 )
320: * ..
321: * .. Local Scalars ..
322: CHARACTER(1) NORM
323: LOGICAL RCEQU
324: INTEGER J, PREC_TYPE, REF_TYPE
325: INTEGER N_NORMS
326: DOUBLE PRECISION ANORM, RCOND_TMP
327: DOUBLE PRECISION ILLRCOND_THRESH, ERR_LBND, CWISE_WRONG
328: LOGICAL IGNORE_CWISE
329: INTEGER ITHRESH
330: DOUBLE PRECISION RTHRESH, UNSTABLE_THRESH
331: * ..
332: * .. External Subroutines ..
333: EXTERNAL XERBLA, ZHECON, ZLA_HERFSX_EXTENDED
334: * ..
335: * .. Intrinsic Functions ..
336: INTRINSIC MAX, SQRT, TRANSFER
337: * ..
338: * .. External Functions ..
339: EXTERNAL LSAME, BLAS_FPINFO_X, ILATRANS, ILAPREC
340: EXTERNAL DLAMCH, ZLANHE, ZLA_HERCOND_X, ZLA_HERCOND_C
341: DOUBLE PRECISION DLAMCH, ZLANHE, ZLA_HERCOND_X, ZLA_HERCOND_C
342: LOGICAL LSAME
343: INTEGER BLAS_FPINFO_X
344: INTEGER ILATRANS, ILAPREC
345: * ..
346: * .. Executable Statements ..
347: *
348: * Check the input parameters.
349: *
350: INFO = 0
351: REF_TYPE = INT( ITREF_DEFAULT )
352: IF ( NPARAMS .GE. LA_LINRX_ITREF_I ) THEN
353: IF ( PARAMS( LA_LINRX_ITREF_I ) .LT. 0.0D+0 ) THEN
354: PARAMS( LA_LINRX_ITREF_I ) = ITREF_DEFAULT
355: ELSE
356: REF_TYPE = PARAMS( LA_LINRX_ITREF_I )
357: END IF
358: END IF
359: *
360: * Set default parameters.
361: *
362: ILLRCOND_THRESH = DBLE( N ) * DLAMCH( 'Epsilon' )
363: ITHRESH = INT( ITHRESH_DEFAULT )
364: RTHRESH = RTHRESH_DEFAULT
365: UNSTABLE_THRESH = DZTHRESH_DEFAULT
366: IGNORE_CWISE = COMPONENTWISE_DEFAULT .EQ. 0.0D+0
367: *
368: IF ( NPARAMS.GE.LA_LINRX_ITHRESH_I ) THEN
369: IF ( PARAMS( LA_LINRX_ITHRESH_I ).LT.0.0D+0 ) THEN
370: PARAMS( LA_LINRX_ITHRESH_I ) = ITHRESH
371: ELSE
372: ITHRESH = INT( PARAMS( LA_LINRX_ITHRESH_I ) )
373: END IF
374: END IF
375: IF ( NPARAMS.GE.LA_LINRX_CWISE_I ) THEN
376: IF ( PARAMS(LA_LINRX_CWISE_I ).LT.0.0D+0 ) THEN
377: IF ( IGNORE_CWISE ) THEN
378: PARAMS( LA_LINRX_CWISE_I ) = 0.0D+0
379: ELSE
380: PARAMS( LA_LINRX_CWISE_I ) = 1.0D+0
381: END IF
382: ELSE
383: IGNORE_CWISE = PARAMS( LA_LINRX_CWISE_I ) .EQ. 0.0D+0
384: END IF
385: END IF
386: IF ( REF_TYPE .EQ. 0 .OR. N_ERR_BNDS .EQ. 0 ) THEN
387: N_NORMS = 0
388: ELSE IF ( IGNORE_CWISE ) THEN
389: N_NORMS = 1
390: ELSE
391: N_NORMS = 2
392: END IF
393: *
394: RCEQU = LSAME( EQUED, 'Y' )
395: *
396: * Test input parameters.
397: *
398: IF (.NOT.LSAME( UPLO, 'U' ) .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
399: INFO = -1
400: ELSE IF( .NOT.RCEQU .AND. .NOT.LSAME( EQUED, 'N' ) ) THEN
401: INFO = -2
402: ELSE IF( N.LT.0 ) THEN
403: INFO = -3
404: ELSE IF( NRHS.LT.0 ) THEN
405: INFO = -4
406: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
407: INFO = -6
408: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
409: INFO = -8
410: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
411: INFO = -11
412: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
413: INFO = -13
414: END IF
415: IF( INFO.NE.0 ) THEN
416: CALL XERBLA( 'ZHERFSX', -INFO )
417: RETURN
418: END IF
419: *
420: * Quick return if possible.
421: *
422: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
423: RCOND = 1.0D+0
424: DO J = 1, NRHS
425: BERR( J ) = 0.0D+0
426: IF ( N_ERR_BNDS .GE. 1 ) THEN
427: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
428: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
429: END IF
430: IF ( N_ERR_BNDS .GE. 2 ) THEN
431: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 0.0D+0
432: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 0.0D+0
433: END IF
434: IF ( N_ERR_BNDS .GE. 3 ) THEN
435: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = 1.0D+0
436: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = 1.0D+0
437: END IF
438: END DO
439: RETURN
440: END IF
441: *
442: * Default to failure.
443: *
444: RCOND = 0.0D+0
445: DO J = 1, NRHS
446: BERR( J ) = 1.0D+0
447: IF ( N_ERR_BNDS .GE. 1 ) THEN
448: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
449: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
450: END IF
451: IF ( N_ERR_BNDS .GE. 2 ) THEN
452: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
453: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
454: END IF
455: IF ( N_ERR_BNDS .GE. 3 ) THEN
456: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = 0.0D+0
457: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = 0.0D+0
458: END IF
459: END DO
460: *
461: * Compute the norm of A and the reciprocal of the condition
462: * number of A.
463: *
464: NORM = 'I'
465: ANORM = ZLANHE( NORM, UPLO, N, A, LDA, RWORK )
466: CALL ZHECON( UPLO, N, AF, LDAF, IPIV, ANORM, RCOND, WORK,
467: $ INFO )
468: *
469: * Perform refinement on each right-hand side
470: *
471: IF ( REF_TYPE .NE. 0 ) THEN
472:
473: PREC_TYPE = ILAPREC( 'E' )
474:
475: CALL ZLA_HERFSX_EXTENDED( PREC_TYPE, UPLO, N,
476: $ NRHS, A, LDA, AF, LDAF, IPIV, RCEQU, S, B,
477: $ LDB, X, LDX, BERR, N_NORMS, ERR_BNDS_NORM, ERR_BNDS_COMP,
478: $ WORK, RWORK, WORK(N+1),
479: $ TRANSFER (RWORK(1:2*N), (/ (ZERO, ZERO) /), N), RCOND,
480: $ ITHRESH, RTHRESH, UNSTABLE_THRESH, IGNORE_CWISE,
481: $ INFO )
482: END IF
483:
484: ERR_LBND = MAX( 10.0D+0, SQRT( DBLE( N ) ) ) * DLAMCH( 'Epsilon' )
485: IF ( N_ERR_BNDS .GE. 1 .AND. N_NORMS .GE. 1 ) THEN
486: *
487: * Compute scaled normwise condition number cond(A*C).
488: *
489: IF ( RCEQU ) THEN
490: RCOND_TMP = ZLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV,
491: $ S, .TRUE., INFO, WORK, RWORK )
492: ELSE
493: RCOND_TMP = ZLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV,
494: $ S, .FALSE., INFO, WORK, RWORK )
495: END IF
496: DO J = 1, NRHS
497: *
498: * Cap the error at 1.0.
499: *
500: IF ( N_ERR_BNDS .GE. LA_LINRX_ERR_I
501: $ .AND. ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) .GT. 1.0D+0 )
502: $ ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
503: *
504: * Threshold the error (see LAWN).
505: *
506: IF (RCOND_TMP .LT. ILLRCOND_THRESH) THEN
507: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = 1.0D+0
508: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 0.0D+0
509: IF ( INFO .LE. N ) INFO = N + J
510: ELSE IF ( ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) .LT. ERR_LBND )
511: $ THEN
512: ERR_BNDS_NORM( J, LA_LINRX_ERR_I ) = ERR_LBND
513: ERR_BNDS_NORM( J, LA_LINRX_TRUST_I ) = 1.0D+0
514: END IF
515: *
516: * Save the condition number.
517: *
518: IF ( N_ERR_BNDS .GE. LA_LINRX_RCOND_I ) THEN
519: ERR_BNDS_NORM( J, LA_LINRX_RCOND_I ) = RCOND_TMP
520: END IF
521: END DO
522: END IF
523:
524: IF ( N_ERR_BNDS .GE. 1 .AND. N_NORMS .GE. 2 ) THEN
525: *
526: * Compute componentwise condition number cond(A*diag(Y(:,J))) for
527: * each right-hand side using the current solution as an estimate of
528: * the true solution. If the componentwise error estimate is too
529: * large, then the solution is a lousy estimate of truth and the
530: * estimated RCOND may be too optimistic. To avoid misleading users,
531: * the inverse condition number is set to 0.0 when the estimated
532: * cwise error is at least CWISE_WRONG.
533: *
534: CWISE_WRONG = SQRT( DLAMCH( 'Epsilon' ) )
535: DO J = 1, NRHS
536: IF ( ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) .LT. CWISE_WRONG )
537: $ THEN
538: RCOND_TMP = ZLA_HERCOND_X( UPLO, N, A, LDA, AF, LDAF,
539: $ IPIV, X( 1, J ), INFO, WORK, RWORK )
540: ELSE
541: RCOND_TMP = 0.0D+0
542: END IF
543: *
544: * Cap the error at 1.0.
545: *
546: IF ( N_ERR_BNDS .GE. LA_LINRX_ERR_I
547: $ .AND. ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) .GT. 1.0D+0 )
548: $ ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
549: *
550: * Threshold the error (see LAWN).
551: *
552: IF ( RCOND_TMP .LT. ILLRCOND_THRESH ) THEN
553: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = 1.0D+0
554: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 0.0D+0
555: IF ( PARAMS( LA_LINRX_CWISE_I ) .EQ. 1.0D+0
556: $ .AND. INFO.LT.N + J ) INFO = N + J
557: ELSE IF ( ERR_BNDS_COMP( J, LA_LINRX_ERR_I )
558: $ .LT. ERR_LBND ) THEN
559: ERR_BNDS_COMP( J, LA_LINRX_ERR_I ) = ERR_LBND
560: ERR_BNDS_COMP( J, LA_LINRX_TRUST_I ) = 1.0D+0
561: END IF
562: *
563: * Save the condition number.
564: *
565: IF ( N_ERR_BNDS .GE. LA_LINRX_RCOND_I ) THEN
566: ERR_BNDS_COMP( J, LA_LINRX_RCOND_I ) = RCOND_TMP
567: END IF
568:
569: END DO
570: END IF
571: *
572: RETURN
573: *
574: * End of ZHERFSX
575: *
576: END
CVSweb interface <joel.bertrand@systella.fr>