Annotation of rpl/lapack/lapack/zheevx_2stage.f, revision 1.2
1.1 bertrand 1: *> \brief <b> ZHEEVX_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for HE matrices</b>
2: *
3: * @precisions fortran z -> s d c
4: *
5: * =========== DOCUMENTATION ===========
6: *
7: * Online html documentation available at
8: * http://www.netlib.org/lapack/explore-html/
9: *
10: *> \htmlonly
11: *> Download ZHEEVX_2STAGE + dependencies
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zheevx_2stage.f">
13: *> [TGZ]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zheevx_2stage.f">
15: *> [ZIP]</a>
16: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zheevx_2stage.f">
17: *> [TXT]</a>
18: *> \endhtmlonly
19: *
20: * Definition:
21: * ===========
22: *
23: * SUBROUTINE ZHEEVX_2STAGE( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU,
24: * IL, IU, ABSTOL, M, W, Z, LDZ, WORK,
25: * LWORK, RWORK, IWORK, IFAIL, INFO )
26: *
27: * IMPLICIT NONE
28: *
29: * .. Scalar Arguments ..
30: * CHARACTER JOBZ, RANGE, UPLO
31: * INTEGER IL, INFO, IU, LDA, LDZ, LWORK, M, N
32: * DOUBLE PRECISION ABSTOL, VL, VU
33: * ..
34: * .. Array Arguments ..
35: * INTEGER IFAIL( * ), IWORK( * )
36: * DOUBLE PRECISION RWORK( * ), W( * )
37: * COMPLEX*16 A( LDA, * ), WORK( * ), Z( LDZ, * )
38: * ..
39: *
40: *
41: *> \par Purpose:
42: * =============
43: *>
44: *> \verbatim
45: *>
46: *> ZHEEVX_2STAGE computes selected eigenvalues and, optionally, eigenvectors
47: *> of a complex Hermitian matrix A using the 2stage technique for
48: *> the reduction to tridiagonal. Eigenvalues and eigenvectors can
49: *> be selected by specifying either a range of values or a range of
50: *> indices for the desired eigenvalues.
51: *> \endverbatim
52: *
53: * Arguments:
54: * ==========
55: *
56: *> \param[in] JOBZ
57: *> \verbatim
58: *> JOBZ is CHARACTER*1
59: *> = 'N': Compute eigenvalues only;
60: *> = 'V': Compute eigenvalues and eigenvectors.
61: *> Not available in this release.
62: *> \endverbatim
63: *>
64: *> \param[in] RANGE
65: *> \verbatim
66: *> RANGE is CHARACTER*1
67: *> = 'A': all eigenvalues will be found.
68: *> = 'V': all eigenvalues in the half-open interval (VL,VU]
69: *> will be found.
70: *> = 'I': the IL-th through IU-th eigenvalues will be found.
71: *> \endverbatim
72: *>
73: *> \param[in] UPLO
74: *> \verbatim
75: *> UPLO is CHARACTER*1
76: *> = 'U': Upper triangle of A is stored;
77: *> = 'L': Lower triangle of A is stored.
78: *> \endverbatim
79: *>
80: *> \param[in] N
81: *> \verbatim
82: *> N is INTEGER
83: *> The order of the matrix A. N >= 0.
84: *> \endverbatim
85: *>
86: *> \param[in,out] A
87: *> \verbatim
88: *> A is COMPLEX*16 array, dimension (LDA, N)
89: *> On entry, the Hermitian matrix A. If UPLO = 'U', the
90: *> leading N-by-N upper triangular part of A contains the
91: *> upper triangular part of the matrix A. If UPLO = 'L',
92: *> the leading N-by-N lower triangular part of A contains
93: *> the lower triangular part of the matrix A.
94: *> On exit, the lower triangle (if UPLO='L') or the upper
95: *> triangle (if UPLO='U') of A, including the diagonal, is
96: *> destroyed.
97: *> \endverbatim
98: *>
99: *> \param[in] LDA
100: *> \verbatim
101: *> LDA is INTEGER
102: *> The leading dimension of the array A. LDA >= max(1,N).
103: *> \endverbatim
104: *>
105: *> \param[in] VL
106: *> \verbatim
107: *> VL is DOUBLE PRECISION
108: *> If RANGE='V', the lower bound of the interval to
109: *> be searched for eigenvalues. VL < VU.
110: *> Not referenced if RANGE = 'A' or 'I'.
111: *> \endverbatim
112: *>
113: *> \param[in] VU
114: *> \verbatim
115: *> VU is DOUBLE PRECISION
116: *> If RANGE='V', the upper bound of the interval to
117: *> be searched for eigenvalues. VL < VU.
118: *> Not referenced if RANGE = 'A' or 'I'.
119: *> \endverbatim
120: *>
121: *> \param[in] IL
122: *> \verbatim
123: *> IL is INTEGER
124: *> If RANGE='I', the index of the
125: *> smallest eigenvalue to be returned.
126: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
127: *> Not referenced if RANGE = 'A' or 'V'.
128: *> \endverbatim
129: *>
130: *> \param[in] IU
131: *> \verbatim
132: *> IU is INTEGER
133: *> If RANGE='I', the index of the
134: *> largest eigenvalue to be returned.
135: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
136: *> Not referenced if RANGE = 'A' or 'V'.
137: *> \endverbatim
138: *>
139: *> \param[in] ABSTOL
140: *> \verbatim
141: *> ABSTOL is DOUBLE PRECISION
142: *> The absolute error tolerance for the eigenvalues.
143: *> An approximate eigenvalue is accepted as converged
144: *> when it is determined to lie in an interval [a,b]
145: *> of width less than or equal to
146: *>
147: *> ABSTOL + EPS * max( |a|,|b| ) ,
148: *>
149: *> where EPS is the machine precision. If ABSTOL is less than
150: *> or equal to zero, then EPS*|T| will be used in its place,
151: *> where |T| is the 1-norm of the tridiagonal matrix obtained
152: *> by reducing A to tridiagonal form.
153: *>
154: *> Eigenvalues will be computed most accurately when ABSTOL is
155: *> set to twice the underflow threshold 2*DLAMCH('S'), not zero.
156: *> If this routine returns with INFO>0, indicating that some
157: *> eigenvectors did not converge, try setting ABSTOL to
158: *> 2*DLAMCH('S').
159: *>
160: *> See "Computing Small Singular Values of Bidiagonal Matrices
161: *> with Guaranteed High Relative Accuracy," by Demmel and
162: *> Kahan, LAPACK Working Note #3.
163: *> \endverbatim
164: *>
165: *> \param[out] M
166: *> \verbatim
167: *> M is INTEGER
168: *> The total number of eigenvalues found. 0 <= M <= N.
169: *> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
170: *> \endverbatim
171: *>
172: *> \param[out] W
173: *> \verbatim
174: *> W is DOUBLE PRECISION array, dimension (N)
175: *> On normal exit, the first M elements contain the selected
176: *> eigenvalues in ascending order.
177: *> \endverbatim
178: *>
179: *> \param[out] Z
180: *> \verbatim
181: *> Z is COMPLEX*16 array, dimension (LDZ, max(1,M))
182: *> If JOBZ = 'V', then if INFO = 0, the first M columns of Z
183: *> contain the orthonormal eigenvectors of the matrix A
184: *> corresponding to the selected eigenvalues, with the i-th
185: *> column of Z holding the eigenvector associated with W(i).
186: *> If an eigenvector fails to converge, then that column of Z
187: *> contains the latest approximation to the eigenvector, and the
188: *> index of the eigenvector is returned in IFAIL.
189: *> If JOBZ = 'N', then Z is not referenced.
190: *> Note: the user must ensure that at least max(1,M) columns are
191: *> supplied in the array Z; if RANGE = 'V', the exact value of M
192: *> is not known in advance and an upper bound must be used.
193: *> \endverbatim
194: *>
195: *> \param[in] LDZ
196: *> \verbatim
197: *> LDZ is INTEGER
198: *> The leading dimension of the array Z. LDZ >= 1, and if
199: *> JOBZ = 'V', LDZ >= max(1,N).
200: *> \endverbatim
201: *>
202: *> \param[out] WORK
203: *> \verbatim
204: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
205: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
206: *> \endverbatim
207: *>
208: *> \param[in] LWORK
209: *> \verbatim
210: *> LWORK is INTEGER
211: *> The length of the array WORK. LWORK >= 1, when N <= 1;
212: *> otherwise
213: *> If JOBZ = 'N' and N > 1, LWORK must be queried.
214: *> LWORK = MAX(1, 8*N, dimension) where
215: *> dimension = max(stage1,stage2) + (KD+1)*N + N
216: *> = N*KD + N*max(KD+1,FACTOPTNB)
217: *> + max(2*KD*KD, KD*NTHREADS)
218: *> + (KD+1)*N + N
219: *> where KD is the blocking size of the reduction,
220: *> FACTOPTNB is the blocking used by the QR or LQ
221: *> algorithm, usually FACTOPTNB=128 is a good choice
222: *> NTHREADS is the number of threads used when
223: *> openMP compilation is enabled, otherwise =1.
224: *> If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available
225: *>
226: *> If LWORK = -1, then a workspace query is assumed; the routine
227: *> only calculates the optimal size of the WORK array, returns
228: *> this value as the first entry of the WORK array, and no error
229: *> message related to LWORK is issued by XERBLA.
230: *> \endverbatim
231: *>
232: *> \param[out] RWORK
233: *> \verbatim
234: *> RWORK is DOUBLE PRECISION array, dimension (7*N)
235: *> \endverbatim
236: *>
237: *> \param[out] IWORK
238: *> \verbatim
239: *> IWORK is INTEGER array, dimension (5*N)
240: *> \endverbatim
241: *>
242: *> \param[out] IFAIL
243: *> \verbatim
244: *> IFAIL is INTEGER array, dimension (N)
245: *> If JOBZ = 'V', then if INFO = 0, the first M elements of
246: *> IFAIL are zero. If INFO > 0, then IFAIL contains the
247: *> indices of the eigenvectors that failed to converge.
248: *> If JOBZ = 'N', then IFAIL is not referenced.
249: *> \endverbatim
250: *>
251: *> \param[out] INFO
252: *> \verbatim
253: *> INFO is INTEGER
254: *> = 0: successful exit
255: *> < 0: if INFO = -i, the i-th argument had an illegal value
256: *> > 0: if INFO = i, then i eigenvectors failed to converge.
257: *> Their indices are stored in array IFAIL.
258: *> \endverbatim
259: *
260: * Authors:
261: * ========
262: *
263: *> \author Univ. of Tennessee
264: *> \author Univ. of California Berkeley
265: *> \author Univ. of Colorado Denver
266: *> \author NAG Ltd.
267: *
268: *> \date June 2016
269: *
270: *> \ingroup complex16HEeigen
271: *
272: *> \par Further Details:
273: * =====================
274: *>
275: *> \verbatim
276: *>
277: *> All details about the 2stage techniques are available in:
278: *>
279: *> Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
280: *> Parallel reduction to condensed forms for symmetric eigenvalue problems
281: *> using aggregated fine-grained and memory-aware kernels. In Proceedings
282: *> of 2011 International Conference for High Performance Computing,
283: *> Networking, Storage and Analysis (SC '11), New York, NY, USA,
284: *> Article 8 , 11 pages.
285: *> http://doi.acm.org/10.1145/2063384.2063394
286: *>
287: *> A. Haidar, J. Kurzak, P. Luszczek, 2013.
288: *> An improved parallel singular value algorithm and its implementation
289: *> for multicore hardware, In Proceedings of 2013 International Conference
290: *> for High Performance Computing, Networking, Storage and Analysis (SC '13).
291: *> Denver, Colorado, USA, 2013.
292: *> Article 90, 12 pages.
293: *> http://doi.acm.org/10.1145/2503210.2503292
294: *>
295: *> A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
296: *> A novel hybrid CPU-GPU generalized eigensolver for electronic structure
297: *> calculations based on fine-grained memory aware tasks.
298: *> International Journal of High Performance Computing Applications.
299: *> Volume 28 Issue 2, Pages 196-209, May 2014.
300: *> http://hpc.sagepub.com/content/28/2/196
301: *>
302: *> \endverbatim
303: *
304: * =====================================================================
305: SUBROUTINE ZHEEVX_2STAGE( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU,
306: $ IL, IU, ABSTOL, M, W, Z, LDZ, WORK,
307: $ LWORK, RWORK, IWORK, IFAIL, INFO )
308: *
309: IMPLICIT NONE
310: *
311: * -- LAPACK driver routine (version 3.7.0) --
312: * -- LAPACK is a software package provided by Univ. of Tennessee, --
313: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
314: * June 2016
315: *
316: * .. Scalar Arguments ..
317: CHARACTER JOBZ, RANGE, UPLO
318: INTEGER IL, INFO, IU, LDA, LDZ, LWORK, M, N
319: DOUBLE PRECISION ABSTOL, VL, VU
320: * ..
321: * .. Array Arguments ..
322: INTEGER IFAIL( * ), IWORK( * )
323: DOUBLE PRECISION RWORK( * ), W( * )
324: COMPLEX*16 A( LDA, * ), WORK( * ), Z( LDZ, * )
325: * ..
326: *
327: * =====================================================================
328: *
329: * .. Parameters ..
330: DOUBLE PRECISION ZERO, ONE
331: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
332: COMPLEX*16 CONE
333: PARAMETER ( CONE = ( 1.0D+0, 0.0D+0 ) )
334: * ..
335: * .. Local Scalars ..
336: LOGICAL ALLEIG, INDEIG, LOWER, LQUERY, TEST, VALEIG,
337: $ WANTZ
338: CHARACTER ORDER
339: INTEGER I, IINFO, IMAX, INDD, INDE, INDEE, INDIBL,
340: $ INDISP, INDIWK, INDRWK, INDTAU, INDWRK, ISCALE,
341: $ ITMP1, J, JJ, LLWORK,
342: $ NSPLIT, LWMIN, LHTRD, LWTRD, KD, IB, INDHOUS
343: DOUBLE PRECISION ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
344: $ SIGMA, SMLNUM, TMP1, VLL, VUU
345: * ..
346: * .. External Functions ..
347: LOGICAL LSAME
348: INTEGER ILAENV
349: DOUBLE PRECISION DLAMCH, ZLANHE
350: EXTERNAL LSAME, ILAENV, DLAMCH, ZLANHE
351: * ..
352: * .. External Subroutines ..
353: EXTERNAL DCOPY, DSCAL, DSTEBZ, DSTERF, XERBLA, ZDSCAL,
354: $ ZLACPY, ZSTEIN, ZSTEQR, ZSWAP, ZUNGTR, ZUNMTR,
355: $ ZHETRD_2STAGE
356: * ..
357: * .. Intrinsic Functions ..
358: INTRINSIC DBLE, MAX, MIN, SQRT
359: * ..
360: * .. Executable Statements ..
361: *
362: * Test the input parameters.
363: *
364: LOWER = LSAME( UPLO, 'L' )
365: WANTZ = LSAME( JOBZ, 'V' )
366: ALLEIG = LSAME( RANGE, 'A' )
367: VALEIG = LSAME( RANGE, 'V' )
368: INDEIG = LSAME( RANGE, 'I' )
369: LQUERY = ( LWORK.EQ.-1 )
370: *
371: INFO = 0
372: IF( .NOT.( LSAME( JOBZ, 'N' ) ) ) THEN
373: INFO = -1
374: ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
375: INFO = -2
376: ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
377: INFO = -3
378: ELSE IF( N.LT.0 ) THEN
379: INFO = -4
380: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
381: INFO = -6
382: ELSE
383: IF( VALEIG ) THEN
384: IF( N.GT.0 .AND. VU.LE.VL )
385: $ INFO = -8
386: ELSE IF( INDEIG ) THEN
387: IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
388: INFO = -9
389: ELSE IF( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
390: INFO = -10
391: END IF
392: END IF
393: END IF
394: IF( INFO.EQ.0 ) THEN
395: IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
396: INFO = -15
397: END IF
398: END IF
399: *
400: IF( INFO.EQ.0 ) THEN
401: IF( N.LE.1 ) THEN
402: LWMIN = 1
403: WORK( 1 ) = LWMIN
404: ELSE
405: KD = ILAENV( 17, 'ZHETRD_2STAGE', JOBZ, N, -1, -1, -1 )
406: IB = ILAENV( 18, 'ZHETRD_2STAGE', JOBZ, N, KD, -1, -1 )
407: LHTRD = ILAENV( 19, 'ZHETRD_2STAGE', JOBZ, N, KD, IB, -1 )
408: LWTRD = ILAENV( 20, 'ZHETRD_2STAGE', JOBZ, N, KD, IB, -1 )
409: LWMIN = N + LHTRD + LWTRD
410: WORK( 1 ) = LWMIN
411: END IF
412: *
413: IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY )
414: $ INFO = -17
415: END IF
416: *
417: IF( INFO.NE.0 ) THEN
418: CALL XERBLA( 'ZHEEVX_2STAGE', -INFO )
419: RETURN
420: ELSE IF( LQUERY ) THEN
421: RETURN
422: END IF
423: *
424: * Quick return if possible
425: *
426: M = 0
427: IF( N.EQ.0 ) THEN
428: RETURN
429: END IF
430: *
431: IF( N.EQ.1 ) THEN
432: IF( ALLEIG .OR. INDEIG ) THEN
433: M = 1
434: W( 1 ) = DBLE( A( 1, 1 ) )
435: ELSE IF( VALEIG ) THEN
436: IF( VL.LT.DBLE( A( 1, 1 ) ) .AND. VU.GE.DBLE( A( 1, 1 ) ) )
437: $ THEN
438: M = 1
439: W( 1 ) = DBLE( A( 1, 1 ) )
440: END IF
441: END IF
442: IF( WANTZ )
443: $ Z( 1, 1 ) = CONE
444: RETURN
445: END IF
446: *
447: * Get machine constants.
448: *
449: SAFMIN = DLAMCH( 'Safe minimum' )
450: EPS = DLAMCH( 'Precision' )
451: SMLNUM = SAFMIN / EPS
452: BIGNUM = ONE / SMLNUM
453: RMIN = SQRT( SMLNUM )
454: RMAX = MIN( SQRT( BIGNUM ), ONE / SQRT( SQRT( SAFMIN ) ) )
455: *
456: * Scale matrix to allowable range, if necessary.
457: *
458: ISCALE = 0
459: ABSTLL = ABSTOL
460: IF( VALEIG ) THEN
461: VLL = VL
462: VUU = VU
463: END IF
464: ANRM = ZLANHE( 'M', UPLO, N, A, LDA, RWORK )
465: IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
466: ISCALE = 1
467: SIGMA = RMIN / ANRM
468: ELSE IF( ANRM.GT.RMAX ) THEN
469: ISCALE = 1
470: SIGMA = RMAX / ANRM
471: END IF
472: IF( ISCALE.EQ.1 ) THEN
473: IF( LOWER ) THEN
474: DO 10 J = 1, N
475: CALL ZDSCAL( N-J+1, SIGMA, A( J, J ), 1 )
476: 10 CONTINUE
477: ELSE
478: DO 20 J = 1, N
479: CALL ZDSCAL( J, SIGMA, A( 1, J ), 1 )
480: 20 CONTINUE
481: END IF
482: IF( ABSTOL.GT.0 )
483: $ ABSTLL = ABSTOL*SIGMA
484: IF( VALEIG ) THEN
485: VLL = VL*SIGMA
486: VUU = VU*SIGMA
487: END IF
488: END IF
489: *
490: * Call ZHETRD_2STAGE to reduce Hermitian matrix to tridiagonal form.
491: *
492: INDD = 1
493: INDE = INDD + N
494: INDRWK = INDE + N
495: INDTAU = 1
496: INDHOUS = INDTAU + N
497: INDWRK = INDHOUS + LHTRD
498: LLWORK = LWORK - INDWRK + 1
499: *
500: CALL ZHETRD_2STAGE( JOBZ, UPLO, N, A, LDA, RWORK( INDD ),
501: $ RWORK( INDE ), WORK( INDTAU ),
502: $ WORK( INDHOUS ), LHTRD, WORK( INDWRK ),
503: $ LLWORK, IINFO )
504: *
505: * If all eigenvalues are desired and ABSTOL is less than or equal to
506: * zero, then call DSTERF or ZUNGTR and ZSTEQR. If this fails for
507: * some eigenvalue, then try DSTEBZ.
508: *
509: TEST = .FALSE.
510: IF( INDEIG ) THEN
511: IF( IL.EQ.1 .AND. IU.EQ.N ) THEN
512: TEST = .TRUE.
513: END IF
514: END IF
515: IF( ( ALLEIG .OR. TEST ) .AND. ( ABSTOL.LE.ZERO ) ) THEN
516: CALL DCOPY( N, RWORK( INDD ), 1, W, 1 )
517: INDEE = INDRWK + 2*N
518: IF( .NOT.WANTZ ) THEN
519: CALL DCOPY( N-1, RWORK( INDE ), 1, RWORK( INDEE ), 1 )
520: CALL DSTERF( N, W, RWORK( INDEE ), INFO )
521: ELSE
522: CALL ZLACPY( 'A', N, N, A, LDA, Z, LDZ )
523: CALL ZUNGTR( UPLO, N, Z, LDZ, WORK( INDTAU ),
524: $ WORK( INDWRK ), LLWORK, IINFO )
525: CALL DCOPY( N-1, RWORK( INDE ), 1, RWORK( INDEE ), 1 )
526: CALL ZSTEQR( JOBZ, N, W, RWORK( INDEE ), Z, LDZ,
527: $ RWORK( INDRWK ), INFO )
528: IF( INFO.EQ.0 ) THEN
529: DO 30 I = 1, N
530: IFAIL( I ) = 0
531: 30 CONTINUE
532: END IF
533: END IF
534: IF( INFO.EQ.0 ) THEN
535: M = N
536: GO TO 40
537: END IF
538: INFO = 0
539: END IF
540: *
541: * Otherwise, call DSTEBZ and, if eigenvectors are desired, ZSTEIN.
542: *
543: IF( WANTZ ) THEN
544: ORDER = 'B'
545: ELSE
546: ORDER = 'E'
547: END IF
548: INDIBL = 1
549: INDISP = INDIBL + N
550: INDIWK = INDISP + N
551: CALL DSTEBZ( RANGE, ORDER, N, VLL, VUU, IL, IU, ABSTLL,
552: $ RWORK( INDD ), RWORK( INDE ), M, NSPLIT, W,
553: $ IWORK( INDIBL ), IWORK( INDISP ), RWORK( INDRWK ),
554: $ IWORK( INDIWK ), INFO )
555: *
556: IF( WANTZ ) THEN
557: CALL ZSTEIN( N, RWORK( INDD ), RWORK( INDE ), M, W,
558: $ IWORK( INDIBL ), IWORK( INDISP ), Z, LDZ,
559: $ RWORK( INDRWK ), IWORK( INDIWK ), IFAIL, INFO )
560: *
561: * Apply unitary matrix used in reduction to tridiagonal
562: * form to eigenvectors returned by ZSTEIN.
563: *
564: CALL ZUNMTR( 'L', UPLO, 'N', N, M, A, LDA, WORK( INDTAU ), Z,
565: $ LDZ, WORK( INDWRK ), LLWORK, IINFO )
566: END IF
567: *
568: * If matrix was scaled, then rescale eigenvalues appropriately.
569: *
570: 40 CONTINUE
571: IF( ISCALE.EQ.1 ) THEN
572: IF( INFO.EQ.0 ) THEN
573: IMAX = M
574: ELSE
575: IMAX = INFO - 1
576: END IF
577: CALL DSCAL( IMAX, ONE / SIGMA, W, 1 )
578: END IF
579: *
580: * If eigenvalues are not in order, then sort them, along with
581: * eigenvectors.
582: *
583: IF( WANTZ ) THEN
584: DO 60 J = 1, M - 1
585: I = 0
586: TMP1 = W( J )
587: DO 50 JJ = J + 1, M
588: IF( W( JJ ).LT.TMP1 ) THEN
589: I = JJ
590: TMP1 = W( JJ )
591: END IF
592: 50 CONTINUE
593: *
594: IF( I.NE.0 ) THEN
595: ITMP1 = IWORK( INDIBL+I-1 )
596: W( I ) = W( J )
597: IWORK( INDIBL+I-1 ) = IWORK( INDIBL+J-1 )
598: W( J ) = TMP1
599: IWORK( INDIBL+J-1 ) = ITMP1
600: CALL ZSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
601: IF( INFO.NE.0 ) THEN
602: ITMP1 = IFAIL( I )
603: IFAIL( I ) = IFAIL( J )
604: IFAIL( J ) = ITMP1
605: END IF
606: END IF
607: 60 CONTINUE
608: END IF
609: *
610: * Set WORK(1) to optimal complex workspace size.
611: *
612: WORK( 1 ) = LWMIN
613: *
614: RETURN
615: *
616: * End of ZHEEVX_2STAGE
617: *
618: END
CVSweb interface <joel.bertrand@systella.fr>