Annotation of rpl/lapack/lapack/zhbgvx.f, revision 1.9
1.8 bertrand 1: *> \brief \b ZHBGST
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZHBGVX + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zhbgvx.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zhbgvx.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zhbgvx.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZHBGVX( JOBZ, RANGE, UPLO, N, KA, KB, AB, LDAB, BB,
22: * LDBB, Q, LDQ, VL, VU, IL, IU, ABSTOL, M, W, Z,
23: * LDZ, WORK, RWORK, IWORK, IFAIL, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER JOBZ, RANGE, UPLO
27: * INTEGER IL, INFO, IU, KA, KB, LDAB, LDBB, LDQ, LDZ, M,
28: * $ N
29: * DOUBLE PRECISION ABSTOL, VL, VU
30: * ..
31: * .. Array Arguments ..
32: * INTEGER IFAIL( * ), IWORK( * )
33: * DOUBLE PRECISION RWORK( * ), W( * )
34: * COMPLEX*16 AB( LDAB, * ), BB( LDBB, * ), Q( LDQ, * ),
35: * $ WORK( * ), Z( LDZ, * )
36: * ..
37: *
38: *
39: *> \par Purpose:
40: * =============
41: *>
42: *> \verbatim
43: *>
44: *> ZHBGVX computes all the eigenvalues, and optionally, the eigenvectors
45: *> of a complex generalized Hermitian-definite banded eigenproblem, of
46: *> the form A*x=(lambda)*B*x. Here A and B are assumed to be Hermitian
47: *> and banded, and B is also positive definite. Eigenvalues and
48: *> eigenvectors can be selected by specifying either all eigenvalues,
49: *> a range of values or a range of indices for the desired eigenvalues.
50: *> \endverbatim
51: *
52: * Arguments:
53: * ==========
54: *
55: *> \param[in] JOBZ
56: *> \verbatim
57: *> JOBZ is CHARACTER*1
58: *> = 'N': Compute eigenvalues only;
59: *> = 'V': Compute eigenvalues and eigenvectors.
60: *> \endverbatim
61: *>
62: *> \param[in] RANGE
63: *> \verbatim
64: *> RANGE is CHARACTER*1
65: *> = 'A': all eigenvalues will be found;
66: *> = 'V': all eigenvalues in the half-open interval (VL,VU]
67: *> will be found;
68: *> = 'I': the IL-th through IU-th eigenvalues will be found.
69: *> \endverbatim
70: *>
71: *> \param[in] UPLO
72: *> \verbatim
73: *> UPLO is CHARACTER*1
74: *> = 'U': Upper triangles of A and B are stored;
75: *> = 'L': Lower triangles of A and B are stored.
76: *> \endverbatim
77: *>
78: *> \param[in] N
79: *> \verbatim
80: *> N is INTEGER
81: *> The order of the matrices A and B. N >= 0.
82: *> \endverbatim
83: *>
84: *> \param[in] KA
85: *> \verbatim
86: *> KA is INTEGER
87: *> The number of superdiagonals of the matrix A if UPLO = 'U',
88: *> or the number of subdiagonals if UPLO = 'L'. KA >= 0.
89: *> \endverbatim
90: *>
91: *> \param[in] KB
92: *> \verbatim
93: *> KB is INTEGER
94: *> The number of superdiagonals of the matrix B if UPLO = 'U',
95: *> or the number of subdiagonals if UPLO = 'L'. KB >= 0.
96: *> \endverbatim
97: *>
98: *> \param[in,out] AB
99: *> \verbatim
100: *> AB is COMPLEX*16 array, dimension (LDAB, N)
101: *> On entry, the upper or lower triangle of the Hermitian band
102: *> matrix A, stored in the first ka+1 rows of the array. The
103: *> j-th column of A is stored in the j-th column of the array AB
104: *> as follows:
105: *> if UPLO = 'U', AB(ka+1+i-j,j) = A(i,j) for max(1,j-ka)<=i<=j;
106: *> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+ka).
107: *>
108: *> On exit, the contents of AB are destroyed.
109: *> \endverbatim
110: *>
111: *> \param[in] LDAB
112: *> \verbatim
113: *> LDAB is INTEGER
114: *> The leading dimension of the array AB. LDAB >= KA+1.
115: *> \endverbatim
116: *>
117: *> \param[in,out] BB
118: *> \verbatim
119: *> BB is COMPLEX*16 array, dimension (LDBB, N)
120: *> On entry, the upper or lower triangle of the Hermitian band
121: *> matrix B, stored in the first kb+1 rows of the array. The
122: *> j-th column of B is stored in the j-th column of the array BB
123: *> as follows:
124: *> if UPLO = 'U', BB(kb+1+i-j,j) = B(i,j) for max(1,j-kb)<=i<=j;
125: *> if UPLO = 'L', BB(1+i-j,j) = B(i,j) for j<=i<=min(n,j+kb).
126: *>
127: *> On exit, the factor S from the split Cholesky factorization
128: *> B = S**H*S, as returned by ZPBSTF.
129: *> \endverbatim
130: *>
131: *> \param[in] LDBB
132: *> \verbatim
133: *> LDBB is INTEGER
134: *> The leading dimension of the array BB. LDBB >= KB+1.
135: *> \endverbatim
136: *>
137: *> \param[out] Q
138: *> \verbatim
139: *> Q is COMPLEX*16 array, dimension (LDQ, N)
140: *> If JOBZ = 'V', the n-by-n matrix used in the reduction of
141: *> A*x = (lambda)*B*x to standard form, i.e. C*x = (lambda)*x,
142: *> and consequently C to tridiagonal form.
143: *> If JOBZ = 'N', the array Q is not referenced.
144: *> \endverbatim
145: *>
146: *> \param[in] LDQ
147: *> \verbatim
148: *> LDQ is INTEGER
149: *> The leading dimension of the array Q. If JOBZ = 'N',
150: *> LDQ >= 1. If JOBZ = 'V', LDQ >= max(1,N).
151: *> \endverbatim
152: *>
153: *> \param[in] VL
154: *> \verbatim
155: *> VL is DOUBLE PRECISION
156: *> \endverbatim
157: *>
158: *> \param[in] VU
159: *> \verbatim
160: *> VU is DOUBLE PRECISION
161: *>
162: *> If RANGE='V', the lower and upper bounds of the interval to
163: *> be searched for eigenvalues. VL < VU.
164: *> Not referenced if RANGE = 'A' or 'I'.
165: *> \endverbatim
166: *>
167: *> \param[in] IL
168: *> \verbatim
169: *> IL is INTEGER
170: *> \endverbatim
171: *>
172: *> \param[in] IU
173: *> \verbatim
174: *> IU is INTEGER
175: *>
176: *> If RANGE='I', the indices (in ascending order) of the
177: *> smallest and largest eigenvalues to be returned.
178: *> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
179: *> Not referenced if RANGE = 'A' or 'V'.
180: *> \endverbatim
181: *>
182: *> \param[in] ABSTOL
183: *> \verbatim
184: *> ABSTOL is DOUBLE PRECISION
185: *> The absolute error tolerance for the eigenvalues.
186: *> An approximate eigenvalue is accepted as converged
187: *> when it is determined to lie in an interval [a,b]
188: *> of width less than or equal to
189: *>
190: *> ABSTOL + EPS * max( |a|,|b| ) ,
191: *>
192: *> where EPS is the machine precision. If ABSTOL is less than
193: *> or equal to zero, then EPS*|T| will be used in its place,
194: *> where |T| is the 1-norm of the tridiagonal matrix obtained
195: *> by reducing AP to tridiagonal form.
196: *>
197: *> Eigenvalues will be computed most accurately when ABSTOL is
198: *> set to twice the underflow threshold 2*DLAMCH('S'), not zero.
199: *> If this routine returns with INFO>0, indicating that some
200: *> eigenvectors did not converge, try setting ABSTOL to
201: *> 2*DLAMCH('S').
202: *> \endverbatim
203: *>
204: *> \param[out] M
205: *> \verbatim
206: *> M is INTEGER
207: *> The total number of eigenvalues found. 0 <= M <= N.
208: *> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
209: *> \endverbatim
210: *>
211: *> \param[out] W
212: *> \verbatim
213: *> W is DOUBLE PRECISION array, dimension (N)
214: *> If INFO = 0, the eigenvalues in ascending order.
215: *> \endverbatim
216: *>
217: *> \param[out] Z
218: *> \verbatim
219: *> Z is COMPLEX*16 array, dimension (LDZ, N)
220: *> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
221: *> eigenvectors, with the i-th column of Z holding the
222: *> eigenvector associated with W(i). The eigenvectors are
223: *> normalized so that Z**H*B*Z = I.
224: *> If JOBZ = 'N', then Z is not referenced.
225: *> \endverbatim
226: *>
227: *> \param[in] LDZ
228: *> \verbatim
229: *> LDZ is INTEGER
230: *> The leading dimension of the array Z. LDZ >= 1, and if
231: *> JOBZ = 'V', LDZ >= N.
232: *> \endverbatim
233: *>
234: *> \param[out] WORK
235: *> \verbatim
236: *> WORK is COMPLEX*16 array, dimension (N)
237: *> \endverbatim
238: *>
239: *> \param[out] RWORK
240: *> \verbatim
241: *> RWORK is DOUBLE PRECISION array, dimension (7*N)
242: *> \endverbatim
243: *>
244: *> \param[out] IWORK
245: *> \verbatim
246: *> IWORK is INTEGER array, dimension (5*N)
247: *> \endverbatim
248: *>
249: *> \param[out] IFAIL
250: *> \verbatim
251: *> IFAIL is INTEGER array, dimension (N)
252: *> If JOBZ = 'V', then if INFO = 0, the first M elements of
253: *> IFAIL are zero. If INFO > 0, then IFAIL contains the
254: *> indices of the eigenvectors that failed to converge.
255: *> If JOBZ = 'N', then IFAIL is not referenced.
256: *> \endverbatim
257: *>
258: *> \param[out] INFO
259: *> \verbatim
260: *> INFO is INTEGER
261: *> = 0: successful exit
262: *> < 0: if INFO = -i, the i-th argument had an illegal value
263: *> > 0: if INFO = i, and i is:
264: *> <= N: then i eigenvectors failed to converge. Their
265: *> indices are stored in array IFAIL.
266: *> > N: if INFO = N + i, for 1 <= i <= N, then ZPBSTF
267: *> returned INFO = i: B is not positive definite.
268: *> The factorization of B could not be completed and
269: *> no eigenvalues or eigenvectors were computed.
270: *> \endverbatim
271: *
272: * Authors:
273: * ========
274: *
275: *> \author Univ. of Tennessee
276: *> \author Univ. of California Berkeley
277: *> \author Univ. of Colorado Denver
278: *> \author NAG Ltd.
279: *
280: *> \date November 2011
281: *
282: *> \ingroup complex16OTHEReigen
283: *
284: *> \par Contributors:
285: * ==================
286: *>
287: *> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
288: *
289: * =====================================================================
1.1 bertrand 290: SUBROUTINE ZHBGVX( JOBZ, RANGE, UPLO, N, KA, KB, AB, LDAB, BB,
291: $ LDBB, Q, LDQ, VL, VU, IL, IU, ABSTOL, M, W, Z,
292: $ LDZ, WORK, RWORK, IWORK, IFAIL, INFO )
293: *
1.8 bertrand 294: * -- LAPACK driver routine (version 3.4.0) --
1.1 bertrand 295: * -- LAPACK is a software package provided by Univ. of Tennessee, --
296: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.8 bertrand 297: * November 2011
1.1 bertrand 298: *
299: * .. Scalar Arguments ..
300: CHARACTER JOBZ, RANGE, UPLO
301: INTEGER IL, INFO, IU, KA, KB, LDAB, LDBB, LDQ, LDZ, M,
302: $ N
303: DOUBLE PRECISION ABSTOL, VL, VU
304: * ..
305: * .. Array Arguments ..
306: INTEGER IFAIL( * ), IWORK( * )
307: DOUBLE PRECISION RWORK( * ), W( * )
308: COMPLEX*16 AB( LDAB, * ), BB( LDBB, * ), Q( LDQ, * ),
309: $ WORK( * ), Z( LDZ, * )
310: * ..
311: *
312: * =====================================================================
313: *
314: * .. Parameters ..
315: DOUBLE PRECISION ZERO
316: PARAMETER ( ZERO = 0.0D+0 )
317: COMPLEX*16 CZERO, CONE
318: PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
319: $ CONE = ( 1.0D+0, 0.0D+0 ) )
320: * ..
321: * .. Local Scalars ..
322: LOGICAL ALLEIG, INDEIG, TEST, UPPER, VALEIG, WANTZ
323: CHARACTER ORDER, VECT
324: INTEGER I, IINFO, INDD, INDE, INDEE, INDIBL, INDISP,
325: $ INDIWK, INDRWK, INDWRK, ITMP1, J, JJ, NSPLIT
326: DOUBLE PRECISION TMP1
327: * ..
328: * .. External Functions ..
329: LOGICAL LSAME
330: EXTERNAL LSAME
331: * ..
332: * .. External Subroutines ..
333: EXTERNAL DCOPY, DSTEBZ, DSTERF, XERBLA, ZCOPY, ZGEMV,
334: $ ZHBGST, ZHBTRD, ZLACPY, ZPBSTF, ZSTEIN, ZSTEQR,
335: $ ZSWAP
336: * ..
337: * .. Intrinsic Functions ..
338: INTRINSIC MIN
339: * ..
340: * .. Executable Statements ..
341: *
342: * Test the input parameters.
343: *
344: WANTZ = LSAME( JOBZ, 'V' )
345: UPPER = LSAME( UPLO, 'U' )
346: ALLEIG = LSAME( RANGE, 'A' )
347: VALEIG = LSAME( RANGE, 'V' )
348: INDEIG = LSAME( RANGE, 'I' )
349: *
350: INFO = 0
351: IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
352: INFO = -1
353: ELSE IF( .NOT.( ALLEIG .OR. VALEIG .OR. INDEIG ) ) THEN
354: INFO = -2
355: ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
356: INFO = -3
357: ELSE IF( N.LT.0 ) THEN
358: INFO = -4
359: ELSE IF( KA.LT.0 ) THEN
360: INFO = -5
361: ELSE IF( KB.LT.0 .OR. KB.GT.KA ) THEN
362: INFO = -6
363: ELSE IF( LDAB.LT.KA+1 ) THEN
364: INFO = -8
365: ELSE IF( LDBB.LT.KB+1 ) THEN
366: INFO = -10
367: ELSE IF( LDQ.LT.1 .OR. ( WANTZ .AND. LDQ.LT.N ) ) THEN
368: INFO = -12
369: ELSE
370: IF( VALEIG ) THEN
371: IF( N.GT.0 .AND. VU.LE.VL )
372: $ INFO = -14
373: ELSE IF( INDEIG ) THEN
374: IF( IL.LT.1 .OR. IL.GT.MAX( 1, N ) ) THEN
375: INFO = -15
376: ELSE IF ( IU.LT.MIN( N, IL ) .OR. IU.GT.N ) THEN
377: INFO = -16
378: END IF
379: END IF
380: END IF
381: IF( INFO.EQ.0) THEN
382: IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
383: INFO = -21
384: END IF
385: END IF
386: *
387: IF( INFO.NE.0 ) THEN
388: CALL XERBLA( 'ZHBGVX', -INFO )
389: RETURN
390: END IF
391: *
392: * Quick return if possible
393: *
394: M = 0
395: IF( N.EQ.0 )
396: $ RETURN
397: *
398: * Form a split Cholesky factorization of B.
399: *
400: CALL ZPBSTF( UPLO, N, KB, BB, LDBB, INFO )
401: IF( INFO.NE.0 ) THEN
402: INFO = N + INFO
403: RETURN
404: END IF
405: *
406: * Transform problem to standard eigenvalue problem.
407: *
408: CALL ZHBGST( JOBZ, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, Q, LDQ,
409: $ WORK, RWORK, IINFO )
410: *
411: * Solve the standard eigenvalue problem.
412: * Reduce Hermitian band matrix to tridiagonal form.
413: *
414: INDD = 1
415: INDE = INDD + N
416: INDRWK = INDE + N
417: INDWRK = 1
418: IF( WANTZ ) THEN
419: VECT = 'U'
420: ELSE
421: VECT = 'N'
422: END IF
423: CALL ZHBTRD( VECT, UPLO, N, KA, AB, LDAB, RWORK( INDD ),
424: $ RWORK( INDE ), Q, LDQ, WORK( INDWRK ), IINFO )
425: *
426: * If all eigenvalues are desired and ABSTOL is less than or equal
427: * to zero, then call DSTERF or ZSTEQR. If this fails for some
428: * eigenvalue, then try DSTEBZ.
429: *
430: TEST = .FALSE.
431: IF( INDEIG ) THEN
432: IF( IL.EQ.1 .AND. IU.EQ.N ) THEN
433: TEST = .TRUE.
434: END IF
435: END IF
436: IF( ( ALLEIG .OR. TEST ) .AND. ( ABSTOL.LE.ZERO ) ) THEN
437: CALL DCOPY( N, RWORK( INDD ), 1, W, 1 )
438: INDEE = INDRWK + 2*N
439: CALL DCOPY( N-1, RWORK( INDE ), 1, RWORK( INDEE ), 1 )
440: IF( .NOT.WANTZ ) THEN
441: CALL DSTERF( N, W, RWORK( INDEE ), INFO )
442: ELSE
443: CALL ZLACPY( 'A', N, N, Q, LDQ, Z, LDZ )
444: CALL ZSTEQR( JOBZ, N, W, RWORK( INDEE ), Z, LDZ,
445: $ RWORK( INDRWK ), INFO )
446: IF( INFO.EQ.0 ) THEN
447: DO 10 I = 1, N
448: IFAIL( I ) = 0
449: 10 CONTINUE
450: END IF
451: END IF
452: IF( INFO.EQ.0 ) THEN
453: M = N
454: GO TO 30
455: END IF
456: INFO = 0
457: END IF
458: *
459: * Otherwise, call DSTEBZ and, if eigenvectors are desired,
460: * call ZSTEIN.
461: *
462: IF( WANTZ ) THEN
463: ORDER = 'B'
464: ELSE
465: ORDER = 'E'
466: END IF
467: INDIBL = 1
468: INDISP = INDIBL + N
469: INDIWK = INDISP + N
470: CALL DSTEBZ( RANGE, ORDER, N, VL, VU, IL, IU, ABSTOL,
471: $ RWORK( INDD ), RWORK( INDE ), M, NSPLIT, W,
472: $ IWORK( INDIBL ), IWORK( INDISP ), RWORK( INDRWK ),
473: $ IWORK( INDIWK ), INFO )
474: *
475: IF( WANTZ ) THEN
476: CALL ZSTEIN( N, RWORK( INDD ), RWORK( INDE ), M, W,
477: $ IWORK( INDIBL ), IWORK( INDISP ), Z, LDZ,
478: $ RWORK( INDRWK ), IWORK( INDIWK ), IFAIL, INFO )
479: *
480: * Apply unitary matrix used in reduction to tridiagonal
481: * form to eigenvectors returned by ZSTEIN.
482: *
483: DO 20 J = 1, M
484: CALL ZCOPY( N, Z( 1, J ), 1, WORK( 1 ), 1 )
485: CALL ZGEMV( 'N', N, N, CONE, Q, LDQ, WORK, 1, CZERO,
486: $ Z( 1, J ), 1 )
487: 20 CONTINUE
488: END IF
489: *
490: 30 CONTINUE
491: *
492: * If eigenvalues are not in order, then sort them, along with
493: * eigenvectors.
494: *
495: IF( WANTZ ) THEN
496: DO 50 J = 1, M - 1
497: I = 0
498: TMP1 = W( J )
499: DO 40 JJ = J + 1, M
500: IF( W( JJ ).LT.TMP1 ) THEN
501: I = JJ
502: TMP1 = W( JJ )
503: END IF
504: 40 CONTINUE
505: *
506: IF( I.NE.0 ) THEN
507: ITMP1 = IWORK( INDIBL+I-1 )
508: W( I ) = W( J )
509: IWORK( INDIBL+I-1 ) = IWORK( INDIBL+J-1 )
510: W( J ) = TMP1
511: IWORK( INDIBL+J-1 ) = ITMP1
512: CALL ZSWAP( N, Z( 1, I ), 1, Z( 1, J ), 1 )
513: IF( INFO.NE.0 ) THEN
514: ITMP1 = IFAIL( I )
515: IFAIL( I ) = IFAIL( J )
516: IFAIL( J ) = ITMP1
517: END IF
518: END IF
519: 50 CONTINUE
520: END IF
521: *
522: RETURN
523: *
524: * End of ZHBGVX
525: *
526: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zhbgvx.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack