1: *> \brief \b ZGGSVP
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGGSVP + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zggsvp.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zggsvp.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zggsvp.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGGSVP( JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB,
22: * TOLA, TOLB, K, L, U, LDU, V, LDV, Q, LDQ,
23: * IWORK, RWORK, TAU, WORK, INFO )
24: *
25: * .. Scalar Arguments ..
26: * CHARACTER JOBQ, JOBU, JOBV
27: * INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P
28: * DOUBLE PRECISION TOLA, TOLB
29: * ..
30: * .. Array Arguments ..
31: * INTEGER IWORK( * )
32: * DOUBLE PRECISION RWORK( * )
33: * COMPLEX*16 A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
34: * $ TAU( * ), U( LDU, * ), V( LDV, * ), WORK( * )
35: * ..
36: *
37: *
38: *> \par Purpose:
39: * =============
40: *>
41: *> \verbatim
42: *>
43: *> This routine is deprecated and has been replaced by routine ZGGSVP3.
44: *>
45: *> ZGGSVP computes unitary matrices U, V and Q such that
46: *>
47: *> N-K-L K L
48: *> U**H*A*Q = K ( 0 A12 A13 ) if M-K-L >= 0;
49: *> L ( 0 0 A23 )
50: *> M-K-L ( 0 0 0 )
51: *>
52: *> N-K-L K L
53: *> = K ( 0 A12 A13 ) if M-K-L < 0;
54: *> M-K ( 0 0 A23 )
55: *>
56: *> N-K-L K L
57: *> V**H*B*Q = L ( 0 0 B13 )
58: *> P-L ( 0 0 0 )
59: *>
60: *> where the K-by-K matrix A12 and L-by-L matrix B13 are nonsingular
61: *> upper triangular; A23 is L-by-L upper triangular if M-K-L >= 0,
62: *> otherwise A23 is (M-K)-by-L upper trapezoidal. K+L = the effective
63: *> numerical rank of the (M+P)-by-N matrix (A**H,B**H)**H.
64: *>
65: *> This decomposition is the preprocessing step for computing the
66: *> Generalized Singular Value Decomposition (GSVD), see subroutine
67: *> ZGGSVD.
68: *> \endverbatim
69: *
70: * Arguments:
71: * ==========
72: *
73: *> \param[in] JOBU
74: *> \verbatim
75: *> JOBU is CHARACTER*1
76: *> = 'U': Unitary matrix U is computed;
77: *> = 'N': U is not computed.
78: *> \endverbatim
79: *>
80: *> \param[in] JOBV
81: *> \verbatim
82: *> JOBV is CHARACTER*1
83: *> = 'V': Unitary matrix V is computed;
84: *> = 'N': V is not computed.
85: *> \endverbatim
86: *>
87: *> \param[in] JOBQ
88: *> \verbatim
89: *> JOBQ is CHARACTER*1
90: *> = 'Q': Unitary matrix Q is computed;
91: *> = 'N': Q is not computed.
92: *> \endverbatim
93: *>
94: *> \param[in] M
95: *> \verbatim
96: *> M is INTEGER
97: *> The number of rows of the matrix A. M >= 0.
98: *> \endverbatim
99: *>
100: *> \param[in] P
101: *> \verbatim
102: *> P is INTEGER
103: *> The number of rows of the matrix B. P >= 0.
104: *> \endverbatim
105: *>
106: *> \param[in] N
107: *> \verbatim
108: *> N is INTEGER
109: *> The number of columns of the matrices A and B. N >= 0.
110: *> \endverbatim
111: *>
112: *> \param[in,out] A
113: *> \verbatim
114: *> A is COMPLEX*16 array, dimension (LDA,N)
115: *> On entry, the M-by-N matrix A.
116: *> On exit, A contains the triangular (or trapezoidal) matrix
117: *> described in the Purpose section.
118: *> \endverbatim
119: *>
120: *> \param[in] LDA
121: *> \verbatim
122: *> LDA is INTEGER
123: *> The leading dimension of the array A. LDA >= max(1,M).
124: *> \endverbatim
125: *>
126: *> \param[in,out] B
127: *> \verbatim
128: *> B is COMPLEX*16 array, dimension (LDB,N)
129: *> On entry, the P-by-N matrix B.
130: *> On exit, B contains the triangular matrix described in
131: *> the Purpose section.
132: *> \endverbatim
133: *>
134: *> \param[in] LDB
135: *> \verbatim
136: *> LDB is INTEGER
137: *> The leading dimension of the array B. LDB >= max(1,P).
138: *> \endverbatim
139: *>
140: *> \param[in] TOLA
141: *> \verbatim
142: *> TOLA is DOUBLE PRECISION
143: *> \endverbatim
144: *>
145: *> \param[in] TOLB
146: *> \verbatim
147: *> TOLB is DOUBLE PRECISION
148: *>
149: *> TOLA and TOLB are the thresholds to determine the effective
150: *> numerical rank of matrix B and a subblock of A. Generally,
151: *> they are set to
152: *> TOLA = MAX(M,N)*norm(A)*MAZHEPS,
153: *> TOLB = MAX(P,N)*norm(B)*MAZHEPS.
154: *> The size of TOLA and TOLB may affect the size of backward
155: *> errors of the decomposition.
156: *> \endverbatim
157: *>
158: *> \param[out] K
159: *> \verbatim
160: *> K is INTEGER
161: *> \endverbatim
162: *>
163: *> \param[out] L
164: *> \verbatim
165: *> L is INTEGER
166: *>
167: *> On exit, K and L specify the dimension of the subblocks
168: *> described in Purpose section.
169: *> K + L = effective numerical rank of (A**H,B**H)**H.
170: *> \endverbatim
171: *>
172: *> \param[out] U
173: *> \verbatim
174: *> U is COMPLEX*16 array, dimension (LDU,M)
175: *> If JOBU = 'U', U contains the unitary matrix U.
176: *> If JOBU = 'N', U is not referenced.
177: *> \endverbatim
178: *>
179: *> \param[in] LDU
180: *> \verbatim
181: *> LDU is INTEGER
182: *> The leading dimension of the array U. LDU >= max(1,M) if
183: *> JOBU = 'U'; LDU >= 1 otherwise.
184: *> \endverbatim
185: *>
186: *> \param[out] V
187: *> \verbatim
188: *> V is COMPLEX*16 array, dimension (LDV,P)
189: *> If JOBV = 'V', V contains the unitary matrix V.
190: *> If JOBV = 'N', V is not referenced.
191: *> \endverbatim
192: *>
193: *> \param[in] LDV
194: *> \verbatim
195: *> LDV is INTEGER
196: *> The leading dimension of the array V. LDV >= max(1,P) if
197: *> JOBV = 'V'; LDV >= 1 otherwise.
198: *> \endverbatim
199: *>
200: *> \param[out] Q
201: *> \verbatim
202: *> Q is COMPLEX*16 array, dimension (LDQ,N)
203: *> If JOBQ = 'Q', Q contains the unitary matrix Q.
204: *> If JOBQ = 'N', Q is not referenced.
205: *> \endverbatim
206: *>
207: *> \param[in] LDQ
208: *> \verbatim
209: *> LDQ is INTEGER
210: *> The leading dimension of the array Q. LDQ >= max(1,N) if
211: *> JOBQ = 'Q'; LDQ >= 1 otherwise.
212: *> \endverbatim
213: *>
214: *> \param[out] IWORK
215: *> \verbatim
216: *> IWORK is INTEGER array, dimension (N)
217: *> \endverbatim
218: *>
219: *> \param[out] RWORK
220: *> \verbatim
221: *> RWORK is DOUBLE PRECISION array, dimension (2*N)
222: *> \endverbatim
223: *>
224: *> \param[out] TAU
225: *> \verbatim
226: *> TAU is COMPLEX*16 array, dimension (N)
227: *> \endverbatim
228: *>
229: *> \param[out] WORK
230: *> \verbatim
231: *> WORK is COMPLEX*16 array, dimension (max(3*N,M,P))
232: *> \endverbatim
233: *>
234: *> \param[out] INFO
235: *> \verbatim
236: *> INFO is INTEGER
237: *> = 0: successful exit
238: *> < 0: if INFO = -i, the i-th argument had an illegal value.
239: *> \endverbatim
240: *
241: * Authors:
242: * ========
243: *
244: *> \author Univ. of Tennessee
245: *> \author Univ. of California Berkeley
246: *> \author Univ. of Colorado Denver
247: *> \author NAG Ltd.
248: *
249: *> \ingroup complex16OTHERcomputational
250: *
251: *> \par Further Details:
252: * =====================
253: *>
254: *> \verbatim
255: *>
256: *> The subroutine uses LAPACK subroutine ZGEQPF for the QR factorization
257: *> with column pivoting to detect the effective numerical rank of the
258: *> a matrix. It may be replaced by a better rank determination strategy.
259: *> \endverbatim
260: *>
261: * =====================================================================
262: SUBROUTINE ZGGSVP( JOBU, JOBV, JOBQ, M, P, N, A, LDA, B, LDB,
263: $ TOLA, TOLB, K, L, U, LDU, V, LDV, Q, LDQ,
264: $ IWORK, RWORK, TAU, WORK, INFO )
265: *
266: * -- LAPACK computational routine --
267: * -- LAPACK is a software package provided by Univ. of Tennessee, --
268: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
269: *
270: * .. Scalar Arguments ..
271: CHARACTER JOBQ, JOBU, JOBV
272: INTEGER INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P
273: DOUBLE PRECISION TOLA, TOLB
274: * ..
275: * .. Array Arguments ..
276: INTEGER IWORK( * )
277: DOUBLE PRECISION RWORK( * )
278: COMPLEX*16 A( LDA, * ), B( LDB, * ), Q( LDQ, * ),
279: $ TAU( * ), U( LDU, * ), V( LDV, * ), WORK( * )
280: * ..
281: *
282: * =====================================================================
283: *
284: * .. Parameters ..
285: COMPLEX*16 CZERO, CONE
286: PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
287: $ CONE = ( 1.0D+0, 0.0D+0 ) )
288: * ..
289: * .. Local Scalars ..
290: LOGICAL FORWRD, WANTQ, WANTU, WANTV
291: INTEGER I, J
292: COMPLEX*16 T
293: * ..
294: * .. External Functions ..
295: LOGICAL LSAME
296: EXTERNAL LSAME
297: * ..
298: * .. External Subroutines ..
299: EXTERNAL XERBLA, ZGEQPF, ZGEQR2, ZGERQ2, ZLACPY, ZLAPMT,
300: $ ZLASET, ZUNG2R, ZUNM2R, ZUNMR2
301: * ..
302: * .. Intrinsic Functions ..
303: INTRINSIC ABS, DBLE, DIMAG, MAX, MIN
304: * ..
305: * .. Statement Functions ..
306: DOUBLE PRECISION CABS1
307: * ..
308: * .. Statement Function definitions ..
309: CABS1( T ) = ABS( DBLE( T ) ) + ABS( DIMAG( T ) )
310: * ..
311: * .. Executable Statements ..
312: *
313: * Test the input parameters
314: *
315: WANTU = LSAME( JOBU, 'U' )
316: WANTV = LSAME( JOBV, 'V' )
317: WANTQ = LSAME( JOBQ, 'Q' )
318: FORWRD = .TRUE.
319: *
320: INFO = 0
321: IF( .NOT.( WANTU .OR. LSAME( JOBU, 'N' ) ) ) THEN
322: INFO = -1
323: ELSE IF( .NOT.( WANTV .OR. LSAME( JOBV, 'N' ) ) ) THEN
324: INFO = -2
325: ELSE IF( .NOT.( WANTQ .OR. LSAME( JOBQ, 'N' ) ) ) THEN
326: INFO = -3
327: ELSE IF( M.LT.0 ) THEN
328: INFO = -4
329: ELSE IF( P.LT.0 ) THEN
330: INFO = -5
331: ELSE IF( N.LT.0 ) THEN
332: INFO = -6
333: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
334: INFO = -8
335: ELSE IF( LDB.LT.MAX( 1, P ) ) THEN
336: INFO = -10
337: ELSE IF( LDU.LT.1 .OR. ( WANTU .AND. LDU.LT.M ) ) THEN
338: INFO = -16
339: ELSE IF( LDV.LT.1 .OR. ( WANTV .AND. LDV.LT.P ) ) THEN
340: INFO = -18
341: ELSE IF( LDQ.LT.1 .OR. ( WANTQ .AND. LDQ.LT.N ) ) THEN
342: INFO = -20
343: END IF
344: IF( INFO.NE.0 ) THEN
345: CALL XERBLA( 'ZGGSVP', -INFO )
346: RETURN
347: END IF
348: *
349: * QR with column pivoting of B: B*P = V*( S11 S12 )
350: * ( 0 0 )
351: *
352: DO 10 I = 1, N
353: IWORK( I ) = 0
354: 10 CONTINUE
355: CALL ZGEQPF( P, N, B, LDB, IWORK, TAU, WORK, RWORK, INFO )
356: *
357: * Update A := A*P
358: *
359: CALL ZLAPMT( FORWRD, M, N, A, LDA, IWORK )
360: *
361: * Determine the effective rank of matrix B.
362: *
363: L = 0
364: DO 20 I = 1, MIN( P, N )
365: IF( CABS1( B( I, I ) ).GT.TOLB )
366: $ L = L + 1
367: 20 CONTINUE
368: *
369: IF( WANTV ) THEN
370: *
371: * Copy the details of V, and form V.
372: *
373: CALL ZLASET( 'Full', P, P, CZERO, CZERO, V, LDV )
374: IF( P.GT.1 )
375: $ CALL ZLACPY( 'Lower', P-1, N, B( 2, 1 ), LDB, V( 2, 1 ),
376: $ LDV )
377: CALL ZUNG2R( P, P, MIN( P, N ), V, LDV, TAU, WORK, INFO )
378: END IF
379: *
380: * Clean up B
381: *
382: DO 40 J = 1, L - 1
383: DO 30 I = J + 1, L
384: B( I, J ) = CZERO
385: 30 CONTINUE
386: 40 CONTINUE
387: IF( P.GT.L )
388: $ CALL ZLASET( 'Full', P-L, N, CZERO, CZERO, B( L+1, 1 ), LDB )
389: *
390: IF( WANTQ ) THEN
391: *
392: * Set Q = I and Update Q := Q*P
393: *
394: CALL ZLASET( 'Full', N, N, CZERO, CONE, Q, LDQ )
395: CALL ZLAPMT( FORWRD, N, N, Q, LDQ, IWORK )
396: END IF
397: *
398: IF( P.GE.L .AND. N.NE.L ) THEN
399: *
400: * RQ factorization of ( S11 S12 ) = ( 0 S12 )*Z
401: *
402: CALL ZGERQ2( L, N, B, LDB, TAU, WORK, INFO )
403: *
404: * Update A := A*Z**H
405: *
406: CALL ZUNMR2( 'Right', 'Conjugate transpose', M, N, L, B, LDB,
407: $ TAU, A, LDA, WORK, INFO )
408: IF( WANTQ ) THEN
409: *
410: * Update Q := Q*Z**H
411: *
412: CALL ZUNMR2( 'Right', 'Conjugate transpose', N, N, L, B,
413: $ LDB, TAU, Q, LDQ, WORK, INFO )
414: END IF
415: *
416: * Clean up B
417: *
418: CALL ZLASET( 'Full', L, N-L, CZERO, CZERO, B, LDB )
419: DO 60 J = N - L + 1, N
420: DO 50 I = J - N + L + 1, L
421: B( I, J ) = CZERO
422: 50 CONTINUE
423: 60 CONTINUE
424: *
425: END IF
426: *
427: * Let N-L L
428: * A = ( A11 A12 ) M,
429: *
430: * then the following does the complete QR decomposition of A11:
431: *
432: * A11 = U*( 0 T12 )*P1**H
433: * ( 0 0 )
434: *
435: DO 70 I = 1, N - L
436: IWORK( I ) = 0
437: 70 CONTINUE
438: CALL ZGEQPF( M, N-L, A, LDA, IWORK, TAU, WORK, RWORK, INFO )
439: *
440: * Determine the effective rank of A11
441: *
442: K = 0
443: DO 80 I = 1, MIN( M, N-L )
444: IF( CABS1( A( I, I ) ).GT.TOLA )
445: $ K = K + 1
446: 80 CONTINUE
447: *
448: * Update A12 := U**H*A12, where A12 = A( 1:M, N-L+1:N )
449: *
450: CALL ZUNM2R( 'Left', 'Conjugate transpose', M, L, MIN( M, N-L ),
451: $ A, LDA, TAU, A( 1, N-L+1 ), LDA, WORK, INFO )
452: *
453: IF( WANTU ) THEN
454: *
455: * Copy the details of U, and form U
456: *
457: CALL ZLASET( 'Full', M, M, CZERO, CZERO, U, LDU )
458: IF( M.GT.1 )
459: $ CALL ZLACPY( 'Lower', M-1, N-L, A( 2, 1 ), LDA, U( 2, 1 ),
460: $ LDU )
461: CALL ZUNG2R( M, M, MIN( M, N-L ), U, LDU, TAU, WORK, INFO )
462: END IF
463: *
464: IF( WANTQ ) THEN
465: *
466: * Update Q( 1:N, 1:N-L ) = Q( 1:N, 1:N-L )*P1
467: *
468: CALL ZLAPMT( FORWRD, N, N-L, Q, LDQ, IWORK )
469: END IF
470: *
471: * Clean up A: set the strictly lower triangular part of
472: * A(1:K, 1:K) = 0, and A( K+1:M, 1:N-L ) = 0.
473: *
474: DO 100 J = 1, K - 1
475: DO 90 I = J + 1, K
476: A( I, J ) = CZERO
477: 90 CONTINUE
478: 100 CONTINUE
479: IF( M.GT.K )
480: $ CALL ZLASET( 'Full', M-K, N-L, CZERO, CZERO, A( K+1, 1 ), LDA )
481: *
482: IF( N-L.GT.K ) THEN
483: *
484: * RQ factorization of ( T11 T12 ) = ( 0 T12 )*Z1
485: *
486: CALL ZGERQ2( K, N-L, A, LDA, TAU, WORK, INFO )
487: *
488: IF( WANTQ ) THEN
489: *
490: * Update Q( 1:N,1:N-L ) = Q( 1:N,1:N-L )*Z1**H
491: *
492: CALL ZUNMR2( 'Right', 'Conjugate transpose', N, N-L, K, A,
493: $ LDA, TAU, Q, LDQ, WORK, INFO )
494: END IF
495: *
496: * Clean up A
497: *
498: CALL ZLASET( 'Full', K, N-L-K, CZERO, CZERO, A, LDA )
499: DO 120 J = N - L - K + 1, N - L
500: DO 110 I = J - N + L + K + 1, K
501: A( I, J ) = CZERO
502: 110 CONTINUE
503: 120 CONTINUE
504: *
505: END IF
506: *
507: IF( M.GT.K ) THEN
508: *
509: * QR factorization of A( K+1:M,N-L+1:N )
510: *
511: CALL ZGEQR2( M-K, L, A( K+1, N-L+1 ), LDA, TAU, WORK, INFO )
512: *
513: IF( WANTU ) THEN
514: *
515: * Update U(:,K+1:M) := U(:,K+1:M)*U1
516: *
517: CALL ZUNM2R( 'Right', 'No transpose', M, M-K, MIN( M-K, L ),
518: $ A( K+1, N-L+1 ), LDA, TAU, U( 1, K+1 ), LDU,
519: $ WORK, INFO )
520: END IF
521: *
522: * Clean up
523: *
524: DO 140 J = N - L + 1, N
525: DO 130 I = J - N + K + L + 1, M
526: A( I, J ) = CZERO
527: 130 CONTINUE
528: 140 CONTINUE
529: *
530: END IF
531: *
532: RETURN
533: *
534: * End of ZGGSVP
535: *
536: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zggsvp.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack