1: *> \brief \b ZGETRI
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGETRI + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgetri.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgetri.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgetri.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGETRI( N, A, LDA, IPIV, WORK, LWORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, LWORK, N
25: * ..
26: * .. Array Arguments ..
27: * INTEGER IPIV( * )
28: * COMPLEX*16 A( LDA, * ), WORK( * )
29: * ..
30: *
31: *
32: *> \par Purpose:
33: * =============
34: *>
35: *> \verbatim
36: *>
37: *> ZGETRI computes the inverse of a matrix using the LU factorization
38: *> computed by ZGETRF.
39: *>
40: *> This method inverts U and then computes inv(A) by solving the system
41: *> inv(A)*L = inv(U) for inv(A).
42: *> \endverbatim
43: *
44: * Arguments:
45: * ==========
46: *
47: *> \param[in] N
48: *> \verbatim
49: *> N is INTEGER
50: *> The order of the matrix A. N >= 0.
51: *> \endverbatim
52: *>
53: *> \param[in,out] A
54: *> \verbatim
55: *> A is COMPLEX*16 array, dimension (LDA,N)
56: *> On entry, the factors L and U from the factorization
57: *> A = P*L*U as computed by ZGETRF.
58: *> On exit, if INFO = 0, the inverse of the original matrix A.
59: *> \endverbatim
60: *>
61: *> \param[in] LDA
62: *> \verbatim
63: *> LDA is INTEGER
64: *> The leading dimension of the array A. LDA >= max(1,N).
65: *> \endverbatim
66: *>
67: *> \param[in] IPIV
68: *> \verbatim
69: *> IPIV is INTEGER array, dimension (N)
70: *> The pivot indices from ZGETRF; for 1<=i<=N, row i of the
71: *> matrix was interchanged with row IPIV(i).
72: *> \endverbatim
73: *>
74: *> \param[out] WORK
75: *> \verbatim
76: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
77: *> On exit, if INFO=0, then WORK(1) returns the optimal LWORK.
78: *> \endverbatim
79: *>
80: *> \param[in] LWORK
81: *> \verbatim
82: *> LWORK is INTEGER
83: *> The dimension of the array WORK. LWORK >= max(1,N).
84: *> For optimal performance LWORK >= N*NB, where NB is
85: *> the optimal blocksize returned by ILAENV.
86: *>
87: *> If LWORK = -1, then a workspace query is assumed; the routine
88: *> only calculates the optimal size of the WORK array, returns
89: *> this value as the first entry of the WORK array, and no error
90: *> message related to LWORK is issued by XERBLA.
91: *> \endverbatim
92: *>
93: *> \param[out] INFO
94: *> \verbatim
95: *> INFO is INTEGER
96: *> = 0: successful exit
97: *> < 0: if INFO = -i, the i-th argument had an illegal value
98: *> > 0: if INFO = i, U(i,i) is exactly zero; the matrix is
99: *> singular and its inverse could not be computed.
100: *> \endverbatim
101: *
102: * Authors:
103: * ========
104: *
105: *> \author Univ. of Tennessee
106: *> \author Univ. of California Berkeley
107: *> \author Univ. of Colorado Denver
108: *> \author NAG Ltd.
109: *
110: *> \ingroup complex16GEcomputational
111: *
112: * =====================================================================
113: SUBROUTINE ZGETRI( N, A, LDA, IPIV, WORK, LWORK, INFO )
114: *
115: * -- LAPACK computational routine --
116: * -- LAPACK is a software package provided by Univ. of Tennessee, --
117: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
118: *
119: * .. Scalar Arguments ..
120: INTEGER INFO, LDA, LWORK, N
121: * ..
122: * .. Array Arguments ..
123: INTEGER IPIV( * )
124: COMPLEX*16 A( LDA, * ), WORK( * )
125: * ..
126: *
127: * =====================================================================
128: *
129: * .. Parameters ..
130: COMPLEX*16 ZERO, ONE
131: PARAMETER ( ZERO = ( 0.0D+0, 0.0D+0 ),
132: $ ONE = ( 1.0D+0, 0.0D+0 ) )
133: * ..
134: * .. Local Scalars ..
135: LOGICAL LQUERY
136: INTEGER I, IWS, J, JB, JJ, JP, LDWORK, LWKOPT, NB,
137: $ NBMIN, NN
138: * ..
139: * .. External Functions ..
140: INTEGER ILAENV
141: EXTERNAL ILAENV
142: * ..
143: * .. External Subroutines ..
144: EXTERNAL XERBLA, ZGEMM, ZGEMV, ZSWAP, ZTRSM, ZTRTRI
145: * ..
146: * .. Intrinsic Functions ..
147: INTRINSIC MAX, MIN
148: * ..
149: * .. Executable Statements ..
150: *
151: * Test the input parameters.
152: *
153: INFO = 0
154: NB = ILAENV( 1, 'ZGETRI', ' ', N, -1, -1, -1 )
155: LWKOPT = N*NB
156: WORK( 1 ) = LWKOPT
157: LQUERY = ( LWORK.EQ.-1 )
158: IF( N.LT.0 ) THEN
159: INFO = -1
160: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
161: INFO = -3
162: ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
163: INFO = -6
164: END IF
165: IF( INFO.NE.0 ) THEN
166: CALL XERBLA( 'ZGETRI', -INFO )
167: RETURN
168: ELSE IF( LQUERY ) THEN
169: RETURN
170: END IF
171: *
172: * Quick return if possible
173: *
174: IF( N.EQ.0 )
175: $ RETURN
176: *
177: * Form inv(U). If INFO > 0 from ZTRTRI, then U is singular,
178: * and the inverse is not computed.
179: *
180: CALL ZTRTRI( 'Upper', 'Non-unit', N, A, LDA, INFO )
181: IF( INFO.GT.0 )
182: $ RETURN
183: *
184: NBMIN = 2
185: LDWORK = N
186: IF( NB.GT.1 .AND. NB.LT.N ) THEN
187: IWS = MAX( LDWORK*NB, 1 )
188: IF( LWORK.LT.IWS ) THEN
189: NB = LWORK / LDWORK
190: NBMIN = MAX( 2, ILAENV( 2, 'ZGETRI', ' ', N, -1, -1, -1 ) )
191: END IF
192: ELSE
193: IWS = N
194: END IF
195: *
196: * Solve the equation inv(A)*L = inv(U) for inv(A).
197: *
198: IF( NB.LT.NBMIN .OR. NB.GE.N ) THEN
199: *
200: * Use unblocked code.
201: *
202: DO 20 J = N, 1, -1
203: *
204: * Copy current column of L to WORK and replace with zeros.
205: *
206: DO 10 I = J + 1, N
207: WORK( I ) = A( I, J )
208: A( I, J ) = ZERO
209: 10 CONTINUE
210: *
211: * Compute current column of inv(A).
212: *
213: IF( J.LT.N )
214: $ CALL ZGEMV( 'No transpose', N, N-J, -ONE, A( 1, J+1 ),
215: $ LDA, WORK( J+1 ), 1, ONE, A( 1, J ), 1 )
216: 20 CONTINUE
217: ELSE
218: *
219: * Use blocked code.
220: *
221: NN = ( ( N-1 ) / NB )*NB + 1
222: DO 50 J = NN, 1, -NB
223: JB = MIN( NB, N-J+1 )
224: *
225: * Copy current block column of L to WORK and replace with
226: * zeros.
227: *
228: DO 40 JJ = J, J + JB - 1
229: DO 30 I = JJ + 1, N
230: WORK( I+( JJ-J )*LDWORK ) = A( I, JJ )
231: A( I, JJ ) = ZERO
232: 30 CONTINUE
233: 40 CONTINUE
234: *
235: * Compute current block column of inv(A).
236: *
237: IF( J+JB.LE.N )
238: $ CALL ZGEMM( 'No transpose', 'No transpose', N, JB,
239: $ N-J-JB+1, -ONE, A( 1, J+JB ), LDA,
240: $ WORK( J+JB ), LDWORK, ONE, A( 1, J ), LDA )
241: CALL ZTRSM( 'Right', 'Lower', 'No transpose', 'Unit', N, JB,
242: $ ONE, WORK( J ), LDWORK, A( 1, J ), LDA )
243: 50 CONTINUE
244: END IF
245: *
246: * Apply column interchanges.
247: *
248: DO 60 J = N - 1, 1, -1
249: JP = IPIV( J )
250: IF( JP.NE.J )
251: $ CALL ZSWAP( N, A( 1, J ), 1, A( 1, JP ), 1 )
252: 60 CONTINUE
253: *
254: WORK( 1 ) = IWS
255: RETURN
256: *
257: * End of ZGETRI
258: *
259: END
CVSweb interface <joel.bertrand@systella.fr>