Annotation of rpl/lapack/lapack/zgerfs.f, revision 1.6
1.1 bertrand 1: SUBROUTINE ZGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
2: $ X, LDX, FERR, BERR, WORK, RWORK, INFO )
3: *
4: * -- LAPACK routine (version 3.2) --
5: * -- LAPACK is a software package provided by Univ. of Tennessee, --
6: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
7: * November 2006
8: *
9: * Modified to call ZLACN2 in place of ZLACON, 10 Feb 03, SJH.
10: *
11: * .. Scalar Arguments ..
12: CHARACTER TRANS
13: INTEGER INFO, LDA, LDAF, LDB, LDX, N, NRHS
14: * ..
15: * .. Array Arguments ..
16: INTEGER IPIV( * )
17: DOUBLE PRECISION BERR( * ), FERR( * ), RWORK( * )
18: COMPLEX*16 A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
19: $ WORK( * ), X( LDX, * )
20: * ..
21: *
22: * Purpose
23: * =======
24: *
25: * ZGERFS improves the computed solution to a system of linear
26: * equations and provides error bounds and backward error estimates for
27: * the solution.
28: *
29: * Arguments
30: * =========
31: *
32: * TRANS (input) CHARACTER*1
33: * Specifies the form of the system of equations:
34: * = 'N': A * X = B (No transpose)
35: * = 'T': A**T * X = B (Transpose)
36: * = 'C': A**H * X = B (Conjugate transpose)
37: *
38: * N (input) INTEGER
39: * The order of the matrix A. N >= 0.
40: *
41: * NRHS (input) INTEGER
42: * The number of right hand sides, i.e., the number of columns
43: * of the matrices B and X. NRHS >= 0.
44: *
45: * A (input) COMPLEX*16 array, dimension (LDA,N)
46: * The original N-by-N matrix A.
47: *
48: * LDA (input) INTEGER
49: * The leading dimension of the array A. LDA >= max(1,N).
50: *
51: * AF (input) COMPLEX*16 array, dimension (LDAF,N)
52: * The factors L and U from the factorization A = P*L*U
53: * as computed by ZGETRF.
54: *
55: * LDAF (input) INTEGER
56: * The leading dimension of the array AF. LDAF >= max(1,N).
57: *
58: * IPIV (input) INTEGER array, dimension (N)
59: * The pivot indices from ZGETRF; for 1<=i<=N, row i of the
60: * matrix was interchanged with row IPIV(i).
61: *
62: * B (input) COMPLEX*16 array, dimension (LDB,NRHS)
63: * The right hand side matrix B.
64: *
65: * LDB (input) INTEGER
66: * The leading dimension of the array B. LDB >= max(1,N).
67: *
68: * X (input/output) COMPLEX*16 array, dimension (LDX,NRHS)
69: * On entry, the solution matrix X, as computed by ZGETRS.
70: * On exit, the improved solution matrix X.
71: *
72: * LDX (input) INTEGER
73: * The leading dimension of the array X. LDX >= max(1,N).
74: *
75: * FERR (output) DOUBLE PRECISION array, dimension (NRHS)
76: * The estimated forward error bound for each solution vector
77: * X(j) (the j-th column of the solution matrix X).
78: * If XTRUE is the true solution corresponding to X(j), FERR(j)
79: * is an estimated upper bound for the magnitude of the largest
80: * element in (X(j) - XTRUE) divided by the magnitude of the
81: * largest element in X(j). The estimate is as reliable as
82: * the estimate for RCOND, and is almost always a slight
83: * overestimate of the true error.
84: *
85: * BERR (output) DOUBLE PRECISION array, dimension (NRHS)
86: * The componentwise relative backward error of each solution
87: * vector X(j) (i.e., the smallest relative change in
88: * any element of A or B that makes X(j) an exact solution).
89: *
90: * WORK (workspace) COMPLEX*16 array, dimension (2*N)
91: *
92: * RWORK (workspace) DOUBLE PRECISION array, dimension (N)
93: *
94: * INFO (output) INTEGER
95: * = 0: successful exit
96: * < 0: if INFO = -i, the i-th argument had an illegal value
97: *
98: * Internal Parameters
99: * ===================
100: *
101: * ITMAX is the maximum number of steps of iterative refinement.
102: *
103: * =====================================================================
104: *
105: * .. Parameters ..
106: INTEGER ITMAX
107: PARAMETER ( ITMAX = 5 )
108: DOUBLE PRECISION ZERO
109: PARAMETER ( ZERO = 0.0D+0 )
110: COMPLEX*16 ONE
111: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
112: DOUBLE PRECISION TWO
113: PARAMETER ( TWO = 2.0D+0 )
114: DOUBLE PRECISION THREE
115: PARAMETER ( THREE = 3.0D+0 )
116: * ..
117: * .. Local Scalars ..
118: LOGICAL NOTRAN
119: CHARACTER TRANSN, TRANST
120: INTEGER COUNT, I, J, K, KASE, NZ
121: DOUBLE PRECISION EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
122: COMPLEX*16 ZDUM
123: * ..
124: * .. Local Arrays ..
125: INTEGER ISAVE( 3 )
126: * ..
127: * .. External Functions ..
128: LOGICAL LSAME
129: DOUBLE PRECISION DLAMCH
130: EXTERNAL LSAME, DLAMCH
131: * ..
132: * .. External Subroutines ..
133: EXTERNAL XERBLA, ZAXPY, ZCOPY, ZGEMV, ZGETRS, ZLACN2
134: * ..
135: * .. Intrinsic Functions ..
136: INTRINSIC ABS, DBLE, DIMAG, MAX
137: * ..
138: * .. Statement Functions ..
139: DOUBLE PRECISION CABS1
140: * ..
141: * .. Statement Function definitions ..
142: CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
143: * ..
144: * .. Executable Statements ..
145: *
146: * Test the input parameters.
147: *
148: INFO = 0
149: NOTRAN = LSAME( TRANS, 'N' )
150: IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
151: $ LSAME( TRANS, 'C' ) ) THEN
152: INFO = -1
153: ELSE IF( N.LT.0 ) THEN
154: INFO = -2
155: ELSE IF( NRHS.LT.0 ) THEN
156: INFO = -3
157: ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
158: INFO = -5
159: ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
160: INFO = -7
161: ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
162: INFO = -10
163: ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
164: INFO = -12
165: END IF
166: IF( INFO.NE.0 ) THEN
167: CALL XERBLA( 'ZGERFS', -INFO )
168: RETURN
169: END IF
170: *
171: * Quick return if possible
172: *
173: IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
174: DO 10 J = 1, NRHS
175: FERR( J ) = ZERO
176: BERR( J ) = ZERO
177: 10 CONTINUE
178: RETURN
179: END IF
180: *
181: IF( NOTRAN ) THEN
182: TRANSN = 'N'
183: TRANST = 'C'
184: ELSE
185: TRANSN = 'C'
186: TRANST = 'N'
187: END IF
188: *
189: * NZ = maximum number of nonzero elements in each row of A, plus 1
190: *
191: NZ = N + 1
192: EPS = DLAMCH( 'Epsilon' )
193: SAFMIN = DLAMCH( 'Safe minimum' )
194: SAFE1 = NZ*SAFMIN
195: SAFE2 = SAFE1 / EPS
196: *
197: * Do for each right hand side
198: *
199: DO 140 J = 1, NRHS
200: *
201: COUNT = 1
202: LSTRES = THREE
203: 20 CONTINUE
204: *
205: * Loop until stopping criterion is satisfied.
206: *
207: * Compute residual R = B - op(A) * X,
208: * where op(A) = A, A**T, or A**H, depending on TRANS.
209: *
210: CALL ZCOPY( N, B( 1, J ), 1, WORK, 1 )
211: CALL ZGEMV( TRANS, N, N, -ONE, A, LDA, X( 1, J ), 1, ONE, WORK,
212: $ 1 )
213: *
214: * Compute componentwise relative backward error from formula
215: *
216: * max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
217: *
218: * where abs(Z) is the componentwise absolute value of the matrix
219: * or vector Z. If the i-th component of the denominator is less
220: * than SAFE2, then SAFE1 is added to the i-th components of the
221: * numerator and denominator before dividing.
222: *
223: DO 30 I = 1, N
224: RWORK( I ) = CABS1( B( I, J ) )
225: 30 CONTINUE
226: *
227: * Compute abs(op(A))*abs(X) + abs(B).
228: *
229: IF( NOTRAN ) THEN
230: DO 50 K = 1, N
231: XK = CABS1( X( K, J ) )
232: DO 40 I = 1, N
233: RWORK( I ) = RWORK( I ) + CABS1( A( I, K ) )*XK
234: 40 CONTINUE
235: 50 CONTINUE
236: ELSE
237: DO 70 K = 1, N
238: S = ZERO
239: DO 60 I = 1, N
240: S = S + CABS1( A( I, K ) )*CABS1( X( I, J ) )
241: 60 CONTINUE
242: RWORK( K ) = RWORK( K ) + S
243: 70 CONTINUE
244: END IF
245: S = ZERO
246: DO 80 I = 1, N
247: IF( RWORK( I ).GT.SAFE2 ) THEN
248: S = MAX( S, CABS1( WORK( I ) ) / RWORK( I ) )
249: ELSE
250: S = MAX( S, ( CABS1( WORK( I ) )+SAFE1 ) /
251: $ ( RWORK( I )+SAFE1 ) )
252: END IF
253: 80 CONTINUE
254: BERR( J ) = S
255: *
256: * Test stopping criterion. Continue iterating if
257: * 1) The residual BERR(J) is larger than machine epsilon, and
258: * 2) BERR(J) decreased by at least a factor of 2 during the
259: * last iteration, and
260: * 3) At most ITMAX iterations tried.
261: *
262: IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
263: $ COUNT.LE.ITMAX ) THEN
264: *
265: * Update solution and try again.
266: *
267: CALL ZGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK, N, INFO )
268: CALL ZAXPY( N, ONE, WORK, 1, X( 1, J ), 1 )
269: LSTRES = BERR( J )
270: COUNT = COUNT + 1
271: GO TO 20
272: END IF
273: *
274: * Bound error from formula
275: *
276: * norm(X - XTRUE) / norm(X) .le. FERR =
277: * norm( abs(inv(op(A)))*
278: * ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
279: *
280: * where
281: * norm(Z) is the magnitude of the largest component of Z
282: * inv(op(A)) is the inverse of op(A)
283: * abs(Z) is the componentwise absolute value of the matrix or
284: * vector Z
285: * NZ is the maximum number of nonzeros in any row of A, plus 1
286: * EPS is machine epsilon
287: *
288: * The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
289: * is incremented by SAFE1 if the i-th component of
290: * abs(op(A))*abs(X) + abs(B) is less than SAFE2.
291: *
292: * Use ZLACN2 to estimate the infinity-norm of the matrix
293: * inv(op(A)) * diag(W),
294: * where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
295: *
296: DO 90 I = 1, N
297: IF( RWORK( I ).GT.SAFE2 ) THEN
298: RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I )
299: ELSE
300: RWORK( I ) = CABS1( WORK( I ) ) + NZ*EPS*RWORK( I ) +
301: $ SAFE1
302: END IF
303: 90 CONTINUE
304: *
305: KASE = 0
306: 100 CONTINUE
307: CALL ZLACN2( N, WORK( N+1 ), WORK, FERR( J ), KASE, ISAVE )
308: IF( KASE.NE.0 ) THEN
309: IF( KASE.EQ.1 ) THEN
310: *
311: * Multiply by diag(W)*inv(op(A)**H).
312: *
313: CALL ZGETRS( TRANST, N, 1, AF, LDAF, IPIV, WORK, N,
314: $ INFO )
315: DO 110 I = 1, N
316: WORK( I ) = RWORK( I )*WORK( I )
317: 110 CONTINUE
318: ELSE
319: *
320: * Multiply by inv(op(A))*diag(W).
321: *
322: DO 120 I = 1, N
323: WORK( I ) = RWORK( I )*WORK( I )
324: 120 CONTINUE
325: CALL ZGETRS( TRANSN, N, 1, AF, LDAF, IPIV, WORK, N,
326: $ INFO )
327: END IF
328: GO TO 100
329: END IF
330: *
331: * Normalize error.
332: *
333: LSTRES = ZERO
334: DO 130 I = 1, N
335: LSTRES = MAX( LSTRES, CABS1( X( I, J ) ) )
336: 130 CONTINUE
337: IF( LSTRES.NE.ZERO )
338: $ FERR( J ) = FERR( J ) / LSTRES
339: *
340: 140 CONTINUE
341: *
342: RETURN
343: *
344: * End of ZGERFS
345: *
346: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zgerfs.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack