Annotation of rpl/lapack/lapack/zgeqp3.f, revision 1.14
1.9 bertrand 1: *> \brief \b ZGEQP3
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGEQP3 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgeqp3.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgeqp3.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgeqp3.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGEQP3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, RWORK,
22: * INFO )
23: *
24: * .. Scalar Arguments ..
25: * INTEGER INFO, LDA, LWORK, M, N
26: * ..
27: * .. Array Arguments ..
28: * INTEGER JPVT( * )
29: * DOUBLE PRECISION RWORK( * )
30: * COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZGEQP3 computes a QR factorization with column pivoting of a
40: *> matrix A: A*P = Q*R using Level 3 BLAS.
41: *> \endverbatim
42: *
43: * Arguments:
44: * ==========
45: *
46: *> \param[in] M
47: *> \verbatim
48: *> M is INTEGER
49: *> The number of rows of the matrix A. M >= 0.
50: *> \endverbatim
51: *>
52: *> \param[in] N
53: *> \verbatim
54: *> N is INTEGER
55: *> The number of columns of the matrix A. N >= 0.
56: *> \endverbatim
57: *>
58: *> \param[in,out] A
59: *> \verbatim
60: *> A is COMPLEX*16 array, dimension (LDA,N)
61: *> On entry, the M-by-N matrix A.
62: *> On exit, the upper triangle of the array contains the
63: *> min(M,N)-by-N upper trapezoidal matrix R; the elements below
64: *> the diagonal, together with the array TAU, represent the
65: *> unitary matrix Q as a product of min(M,N) elementary
66: *> reflectors.
67: *> \endverbatim
68: *>
69: *> \param[in] LDA
70: *> \verbatim
71: *> LDA is INTEGER
72: *> The leading dimension of the array A. LDA >= max(1,M).
73: *> \endverbatim
74: *>
75: *> \param[in,out] JPVT
76: *> \verbatim
77: *> JPVT is INTEGER array, dimension (N)
78: *> On entry, if JPVT(J).ne.0, the J-th column of A is permuted
79: *> to the front of A*P (a leading column); if JPVT(J)=0,
80: *> the J-th column of A is a free column.
81: *> On exit, if JPVT(J)=K, then the J-th column of A*P was the
82: *> the K-th column of A.
83: *> \endverbatim
84: *>
85: *> \param[out] TAU
86: *> \verbatim
87: *> TAU is COMPLEX*16 array, dimension (min(M,N))
88: *> The scalar factors of the elementary reflectors.
89: *> \endverbatim
90: *>
91: *> \param[out] WORK
92: *> \verbatim
93: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
94: *> On exit, if INFO=0, WORK(1) returns the optimal LWORK.
95: *> \endverbatim
96: *>
97: *> \param[in] LWORK
98: *> \verbatim
99: *> LWORK is INTEGER
100: *> The dimension of the array WORK. LWORK >= N+1.
101: *> For optimal performance LWORK >= ( N+1 )*NB, where NB
102: *> is the optimal blocksize.
103: *>
104: *> If LWORK = -1, then a workspace query is assumed; the routine
105: *> only calculates the optimal size of the WORK array, returns
106: *> this value as the first entry of the WORK array, and no error
107: *> message related to LWORK is issued by XERBLA.
108: *> \endverbatim
109: *>
110: *> \param[out] RWORK
111: *> \verbatim
112: *> RWORK is DOUBLE PRECISION array, dimension (2*N)
113: *> \endverbatim
114: *>
115: *> \param[out] INFO
116: *> \verbatim
117: *> INFO is INTEGER
118: *> = 0: successful exit.
119: *> < 0: if INFO = -i, the i-th argument had an illegal value.
120: *> \endverbatim
121: *
122: * Authors:
123: * ========
124: *
125: *> \author Univ. of Tennessee
126: *> \author Univ. of California Berkeley
127: *> \author Univ. of Colorado Denver
128: *> \author NAG Ltd.
129: *
1.12 bertrand 130: *> \date September 2012
1.9 bertrand 131: *
132: *> \ingroup complex16GEcomputational
133: *
134: *> \par Further Details:
135: * =====================
136: *>
137: *> \verbatim
138: *>
139: *> The matrix Q is represented as a product of elementary reflectors
140: *>
141: *> Q = H(1) H(2) . . . H(k), where k = min(m,n).
142: *>
143: *> Each H(i) has the form
144: *>
145: *> H(i) = I - tau * v * v**H
146: *>
1.12 bertrand 147: *> where tau is a complex scalar, and v is a real/complex vector
1.9 bertrand 148: *> with v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in
149: *> A(i+1:m,i), and tau in TAU(i).
150: *> \endverbatim
151: *
152: *> \par Contributors:
153: * ==================
154: *>
155: *> G. Quintana-Orti, Depto. de Informatica, Universidad Jaime I, Spain
156: *> X. Sun, Computer Science Dept., Duke University, USA
157: *>
158: * =====================================================================
1.1 bertrand 159: SUBROUTINE ZGEQP3( M, N, A, LDA, JPVT, TAU, WORK, LWORK, RWORK,
160: $ INFO )
161: *
1.12 bertrand 162: * -- LAPACK computational routine (version 3.4.2) --
1.1 bertrand 163: * -- LAPACK is a software package provided by Univ. of Tennessee, --
164: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
1.12 bertrand 165: * September 2012
1.1 bertrand 166: *
167: * .. Scalar Arguments ..
168: INTEGER INFO, LDA, LWORK, M, N
169: * ..
170: * .. Array Arguments ..
171: INTEGER JPVT( * )
172: DOUBLE PRECISION RWORK( * )
173: COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
174: * ..
175: *
176: * =====================================================================
177: *
178: * .. Parameters ..
179: INTEGER INB, INBMIN, IXOVER
180: PARAMETER ( INB = 1, INBMIN = 2, IXOVER = 3 )
181: * ..
182: * .. Local Scalars ..
183: LOGICAL LQUERY
184: INTEGER FJB, IWS, J, JB, LWKOPT, MINMN, MINWS, NA, NB,
185: $ NBMIN, NFXD, NX, SM, SMINMN, SN, TOPBMN
186: * ..
187: * .. External Subroutines ..
188: EXTERNAL XERBLA, ZGEQRF, ZLAQP2, ZLAQPS, ZSWAP, ZUNMQR
189: * ..
190: * .. External Functions ..
191: INTEGER ILAENV
192: DOUBLE PRECISION DZNRM2
193: EXTERNAL ILAENV, DZNRM2
194: * ..
195: * .. Intrinsic Functions ..
196: INTRINSIC INT, MAX, MIN
197: * ..
198: * .. Executable Statements ..
199: *
200: * Test input arguments
1.9 bertrand 201: * ====================
1.1 bertrand 202: *
203: INFO = 0
204: LQUERY = ( LWORK.EQ.-1 )
205: IF( M.LT.0 ) THEN
206: INFO = -1
207: ELSE IF( N.LT.0 ) THEN
208: INFO = -2
209: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
210: INFO = -4
211: END IF
212: *
213: IF( INFO.EQ.0 ) THEN
214: MINMN = MIN( M, N )
215: IF( MINMN.EQ.0 ) THEN
216: IWS = 1
217: LWKOPT = 1
218: ELSE
219: IWS = N + 1
220: NB = ILAENV( INB, 'ZGEQRF', ' ', M, N, -1, -1 )
221: LWKOPT = ( N + 1 )*NB
222: END IF
223: WORK( 1 ) = LWKOPT
224: *
225: IF( ( LWORK.LT.IWS ) .AND. .NOT.LQUERY ) THEN
226: INFO = -8
227: END IF
228: END IF
229: *
230: IF( INFO.NE.0 ) THEN
231: CALL XERBLA( 'ZGEQP3', -INFO )
232: RETURN
233: ELSE IF( LQUERY ) THEN
234: RETURN
235: END IF
236: *
237: * Quick return if possible.
238: *
239: IF( MINMN.EQ.0 ) THEN
240: RETURN
241: END IF
242: *
243: * Move initial columns up front.
244: *
245: NFXD = 1
246: DO 10 J = 1, N
247: IF( JPVT( J ).NE.0 ) THEN
248: IF( J.NE.NFXD ) THEN
249: CALL ZSWAP( M, A( 1, J ), 1, A( 1, NFXD ), 1 )
250: JPVT( J ) = JPVT( NFXD )
251: JPVT( NFXD ) = J
252: ELSE
253: JPVT( J ) = J
254: END IF
255: NFXD = NFXD + 1
256: ELSE
257: JPVT( J ) = J
258: END IF
259: 10 CONTINUE
260: NFXD = NFXD - 1
261: *
262: * Factorize fixed columns
1.9 bertrand 263: * =======================
1.1 bertrand 264: *
265: * Compute the QR factorization of fixed columns and update
266: * remaining columns.
267: *
268: IF( NFXD.GT.0 ) THEN
269: NA = MIN( M, NFXD )
270: *CC CALL ZGEQR2( M, NA, A, LDA, TAU, WORK, INFO )
271: CALL ZGEQRF( M, NA, A, LDA, TAU, WORK, LWORK, INFO )
272: IWS = MAX( IWS, INT( WORK( 1 ) ) )
273: IF( NA.LT.N ) THEN
274: *CC CALL ZUNM2R( 'Left', 'Conjugate Transpose', M, N-NA,
275: *CC $ NA, A, LDA, TAU, A( 1, NA+1 ), LDA, WORK,
276: *CC $ INFO )
277: CALL ZUNMQR( 'Left', 'Conjugate Transpose', M, N-NA, NA, A,
278: $ LDA, TAU, A( 1, NA+1 ), LDA, WORK, LWORK,
279: $ INFO )
280: IWS = MAX( IWS, INT( WORK( 1 ) ) )
281: END IF
282: END IF
283: *
284: * Factorize free columns
1.9 bertrand 285: * ======================
1.1 bertrand 286: *
287: IF( NFXD.LT.MINMN ) THEN
288: *
289: SM = M - NFXD
290: SN = N - NFXD
291: SMINMN = MINMN - NFXD
292: *
293: * Determine the block size.
294: *
295: NB = ILAENV( INB, 'ZGEQRF', ' ', SM, SN, -1, -1 )
296: NBMIN = 2
297: NX = 0
298: *
299: IF( ( NB.GT.1 ) .AND. ( NB.LT.SMINMN ) ) THEN
300: *
301: * Determine when to cross over from blocked to unblocked code.
302: *
303: NX = MAX( 0, ILAENV( IXOVER, 'ZGEQRF', ' ', SM, SN, -1,
304: $ -1 ) )
305: *
306: *
307: IF( NX.LT.SMINMN ) THEN
308: *
309: * Determine if workspace is large enough for blocked code.
310: *
311: MINWS = ( SN+1 )*NB
312: IWS = MAX( IWS, MINWS )
313: IF( LWORK.LT.MINWS ) THEN
314: *
315: * Not enough workspace to use optimal NB: Reduce NB and
316: * determine the minimum value of NB.
317: *
318: NB = LWORK / ( SN+1 )
319: NBMIN = MAX( 2, ILAENV( INBMIN, 'ZGEQRF', ' ', SM, SN,
320: $ -1, -1 ) )
321: *
322: *
323: END IF
324: END IF
325: END IF
326: *
327: * Initialize partial column norms. The first N elements of work
328: * store the exact column norms.
329: *
330: DO 20 J = NFXD + 1, N
331: RWORK( J ) = DZNRM2( SM, A( NFXD+1, J ), 1 )
332: RWORK( N+J ) = RWORK( J )
333: 20 CONTINUE
334: *
335: IF( ( NB.GE.NBMIN ) .AND. ( NB.LT.SMINMN ) .AND.
336: $ ( NX.LT.SMINMN ) ) THEN
337: *
338: * Use blocked code initially.
339: *
340: J = NFXD + 1
341: *
342: * Compute factorization: while loop.
343: *
344: *
345: TOPBMN = MINMN - NX
346: 30 CONTINUE
347: IF( J.LE.TOPBMN ) THEN
348: JB = MIN( NB, TOPBMN-J+1 )
349: *
350: * Factorize JB columns among columns J:N.
351: *
352: CALL ZLAQPS( M, N-J+1, J-1, JB, FJB, A( 1, J ), LDA,
353: $ JPVT( J ), TAU( J ), RWORK( J ),
354: $ RWORK( N+J ), WORK( 1 ), WORK( JB+1 ),
355: $ N-J+1 )
356: *
357: J = J + FJB
358: GO TO 30
359: END IF
360: ELSE
361: J = NFXD + 1
362: END IF
363: *
364: * Use unblocked code to factor the last or only block.
365: *
366: *
367: IF( J.LE.MINMN )
368: $ CALL ZLAQP2( M, N-J+1, J-1, A( 1, J ), LDA, JPVT( J ),
369: $ TAU( J ), RWORK( J ), RWORK( N+J ), WORK( 1 ) )
370: *
371: END IF
372: *
373: WORK( 1 ) = IWS
374: RETURN
375: *
376: * End of ZGEQP3
377: *
378: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zgeqp3.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack