1: *> \brief <b> ZGELSS solves overdetermined or underdetermined systems for GE matrices</b>
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGELSS + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgelss.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgelss.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgelss.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGELSS( M, N, NRHS, A, LDA, B, LDB, S, RCOND, RANK,
22: * WORK, LWORK, RWORK, INFO )
23: *
24: * .. Scalar Arguments ..
25: * INTEGER INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
26: * DOUBLE PRECISION RCOND
27: * ..
28: * .. Array Arguments ..
29: * DOUBLE PRECISION RWORK( * ), S( * )
30: * COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
31: * ..
32: *
33: *
34: *> \par Purpose:
35: * =============
36: *>
37: *> \verbatim
38: *>
39: *> ZGELSS computes the minimum norm solution to a complex linear
40: *> least squares problem:
41: *>
42: *> Minimize 2-norm(| b - A*x |).
43: *>
44: *> using the singular value decomposition (SVD) of A. A is an M-by-N
45: *> matrix which may be rank-deficient.
46: *>
47: *> Several right hand side vectors b and solution vectors x can be
48: *> handled in a single call; they are stored as the columns of the
49: *> M-by-NRHS right hand side matrix B and the N-by-NRHS solution matrix
50: *> X.
51: *>
52: *> The effective rank of A is determined by treating as zero those
53: *> singular values which are less than RCOND times the largest singular
54: *> value.
55: *> \endverbatim
56: *
57: * Arguments:
58: * ==========
59: *
60: *> \param[in] M
61: *> \verbatim
62: *> M is INTEGER
63: *> The number of rows of the matrix A. M >= 0.
64: *> \endverbatim
65: *>
66: *> \param[in] N
67: *> \verbatim
68: *> N is INTEGER
69: *> The number of columns of the matrix A. N >= 0.
70: *> \endverbatim
71: *>
72: *> \param[in] NRHS
73: *> \verbatim
74: *> NRHS is INTEGER
75: *> The number of right hand sides, i.e., the number of columns
76: *> of the matrices B and X. NRHS >= 0.
77: *> \endverbatim
78: *>
79: *> \param[in,out] A
80: *> \verbatim
81: *> A is COMPLEX*16 array, dimension (LDA,N)
82: *> On entry, the M-by-N matrix A.
83: *> On exit, the first min(m,n) rows of A are overwritten with
84: *> its right singular vectors, stored rowwise.
85: *> \endverbatim
86: *>
87: *> \param[in] LDA
88: *> \verbatim
89: *> LDA is INTEGER
90: *> The leading dimension of the array A. LDA >= max(1,M).
91: *> \endverbatim
92: *>
93: *> \param[in,out] B
94: *> \verbatim
95: *> B is COMPLEX*16 array, dimension (LDB,NRHS)
96: *> On entry, the M-by-NRHS right hand side matrix B.
97: *> On exit, B is overwritten by the N-by-NRHS solution matrix X.
98: *> If m >= n and RANK = n, the residual sum-of-squares for
99: *> the solution in the i-th column is given by the sum of
100: *> squares of the modulus of elements n+1:m in that column.
101: *> \endverbatim
102: *>
103: *> \param[in] LDB
104: *> \verbatim
105: *> LDB is INTEGER
106: *> The leading dimension of the array B. LDB >= max(1,M,N).
107: *> \endverbatim
108: *>
109: *> \param[out] S
110: *> \verbatim
111: *> S is DOUBLE PRECISION array, dimension (min(M,N))
112: *> The singular values of A in decreasing order.
113: *> The condition number of A in the 2-norm = S(1)/S(min(m,n)).
114: *> \endverbatim
115: *>
116: *> \param[in] RCOND
117: *> \verbatim
118: *> RCOND is DOUBLE PRECISION
119: *> RCOND is used to determine the effective rank of A.
120: *> Singular values S(i) <= RCOND*S(1) are treated as zero.
121: *> If RCOND < 0, machine precision is used instead.
122: *> \endverbatim
123: *>
124: *> \param[out] RANK
125: *> \verbatim
126: *> RANK is INTEGER
127: *> The effective rank of A, i.e., the number of singular values
128: *> which are greater than RCOND*S(1).
129: *> \endverbatim
130: *>
131: *> \param[out] WORK
132: *> \verbatim
133: *> WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
134: *> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
135: *> \endverbatim
136: *>
137: *> \param[in] LWORK
138: *> \verbatim
139: *> LWORK is INTEGER
140: *> The dimension of the array WORK. LWORK >= 1, and also:
141: *> LWORK >= 2*min(M,N) + max(M,N,NRHS)
142: *> For good performance, LWORK should generally be larger.
143: *>
144: *> If LWORK = -1, then a workspace query is assumed; the routine
145: *> only calculates the optimal size of the WORK array, returns
146: *> this value as the first entry of the WORK array, and no error
147: *> message related to LWORK is issued by XERBLA.
148: *> \endverbatim
149: *>
150: *> \param[out] RWORK
151: *> \verbatim
152: *> RWORK is DOUBLE PRECISION array, dimension (5*min(M,N))
153: *> \endverbatim
154: *>
155: *> \param[out] INFO
156: *> \verbatim
157: *> INFO is INTEGER
158: *> = 0: successful exit
159: *> < 0: if INFO = -i, the i-th argument had an illegal value.
160: *> > 0: the algorithm for computing the SVD failed to converge;
161: *> if INFO = i, i off-diagonal elements of an intermediate
162: *> bidiagonal form did not converge to zero.
163: *> \endverbatim
164: *
165: * Authors:
166: * ========
167: *
168: *> \author Univ. of Tennessee
169: *> \author Univ. of California Berkeley
170: *> \author Univ. of Colorado Denver
171: *> \author NAG Ltd.
172: *
173: *> \ingroup complex16GEsolve
174: *
175: * =====================================================================
176: SUBROUTINE ZGELSS( M, N, NRHS, A, LDA, B, LDB, S, RCOND, RANK,
177: $ WORK, LWORK, RWORK, INFO )
178: *
179: * -- LAPACK driver routine --
180: * -- LAPACK is a software package provided by Univ. of Tennessee, --
181: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
182: *
183: * .. Scalar Arguments ..
184: INTEGER INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
185: DOUBLE PRECISION RCOND
186: * ..
187: * .. Array Arguments ..
188: DOUBLE PRECISION RWORK( * ), S( * )
189: COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
190: * ..
191: *
192: * =====================================================================
193: *
194: * .. Parameters ..
195: DOUBLE PRECISION ZERO, ONE
196: PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
197: COMPLEX*16 CZERO, CONE
198: PARAMETER ( CZERO = ( 0.0D+0, 0.0D+0 ),
199: $ CONE = ( 1.0D+0, 0.0D+0 ) )
200: * ..
201: * .. Local Scalars ..
202: LOGICAL LQUERY
203: INTEGER BL, CHUNK, I, IASCL, IBSCL, IE, IL, IRWORK,
204: $ ITAU, ITAUP, ITAUQ, IWORK, LDWORK, MAXMN,
205: $ MAXWRK, MINMN, MINWRK, MM, MNTHR
206: INTEGER LWORK_ZGEQRF, LWORK_ZUNMQR, LWORK_ZGEBRD,
207: $ LWORK_ZUNMBR, LWORK_ZUNGBR, LWORK_ZUNMLQ,
208: $ LWORK_ZGELQF
209: DOUBLE PRECISION ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM, THR
210: * ..
211: * .. Local Arrays ..
212: COMPLEX*16 DUM( 1 )
213: * ..
214: * .. External Subroutines ..
215: EXTERNAL DLABAD, DLASCL, DLASET, XERBLA, ZBDSQR, ZCOPY,
216: $ ZDRSCL, ZGEBRD, ZGELQF, ZGEMM, ZGEMV, ZGEQRF,
217: $ ZLACPY, ZLASCL, ZLASET, ZUNGBR, ZUNMBR, ZUNMLQ,
218: $ ZUNMQR
219: * ..
220: * .. External Functions ..
221: INTEGER ILAENV
222: DOUBLE PRECISION DLAMCH, ZLANGE
223: EXTERNAL ILAENV, DLAMCH, ZLANGE
224: * ..
225: * .. Intrinsic Functions ..
226: INTRINSIC MAX, MIN
227: * ..
228: * .. Executable Statements ..
229: *
230: * Test the input arguments
231: *
232: INFO = 0
233: MINMN = MIN( M, N )
234: MAXMN = MAX( M, N )
235: LQUERY = ( LWORK.EQ.-1 )
236: IF( M.LT.0 ) THEN
237: INFO = -1
238: ELSE IF( N.LT.0 ) THEN
239: INFO = -2
240: ELSE IF( NRHS.LT.0 ) THEN
241: INFO = -3
242: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
243: INFO = -5
244: ELSE IF( LDB.LT.MAX( 1, MAXMN ) ) THEN
245: INFO = -7
246: END IF
247: *
248: * Compute workspace
249: * (Note: Comments in the code beginning "Workspace:" describe the
250: * minimal amount of workspace needed at that point in the code,
251: * as well as the preferred amount for good performance.
252: * CWorkspace refers to complex workspace, and RWorkspace refers
253: * to real workspace. NB refers to the optimal block size for the
254: * immediately following subroutine, as returned by ILAENV.)
255: *
256: IF( INFO.EQ.0 ) THEN
257: MINWRK = 1
258: MAXWRK = 1
259: IF( MINMN.GT.0 ) THEN
260: MM = M
261: MNTHR = ILAENV( 6, 'ZGELSS', ' ', M, N, NRHS, -1 )
262: IF( M.GE.N .AND. M.GE.MNTHR ) THEN
263: *
264: * Path 1a - overdetermined, with many more rows than
265: * columns
266: *
267: * Compute space needed for ZGEQRF
268: CALL ZGEQRF( M, N, A, LDA, DUM(1), DUM(1), -1, INFO )
269: LWORK_ZGEQRF = INT( DUM(1) )
270: * Compute space needed for ZUNMQR
271: CALL ZUNMQR( 'L', 'C', M, NRHS, N, A, LDA, DUM(1), B,
272: $ LDB, DUM(1), -1, INFO )
273: LWORK_ZUNMQR = INT( DUM(1) )
274: MM = N
275: MAXWRK = MAX( MAXWRK, N + N*ILAENV( 1, 'ZGEQRF', ' ', M,
276: $ N, -1, -1 ) )
277: MAXWRK = MAX( MAXWRK, N + NRHS*ILAENV( 1, 'ZUNMQR', 'LC',
278: $ M, NRHS, N, -1 ) )
279: END IF
280: IF( M.GE.N ) THEN
281: *
282: * Path 1 - overdetermined or exactly determined
283: *
284: * Compute space needed for ZGEBRD
285: CALL ZGEBRD( MM, N, A, LDA, S, S, DUM(1), DUM(1), DUM(1),
286: $ -1, INFO )
287: LWORK_ZGEBRD = INT( DUM(1) )
288: * Compute space needed for ZUNMBR
289: CALL ZUNMBR( 'Q', 'L', 'C', MM, NRHS, N, A, LDA, DUM(1),
290: $ B, LDB, DUM(1), -1, INFO )
291: LWORK_ZUNMBR = INT( DUM(1) )
292: * Compute space needed for ZUNGBR
293: CALL ZUNGBR( 'P', N, N, N, A, LDA, DUM(1),
294: $ DUM(1), -1, INFO )
295: LWORK_ZUNGBR = INT( DUM(1) )
296: * Compute total workspace needed
297: MAXWRK = MAX( MAXWRK, 2*N + LWORK_ZGEBRD )
298: MAXWRK = MAX( MAXWRK, 2*N + LWORK_ZUNMBR )
299: MAXWRK = MAX( MAXWRK, 2*N + LWORK_ZUNGBR )
300: MAXWRK = MAX( MAXWRK, N*NRHS )
301: MINWRK = 2*N + MAX( NRHS, M )
302: END IF
303: IF( N.GT.M ) THEN
304: MINWRK = 2*M + MAX( NRHS, N )
305: IF( N.GE.MNTHR ) THEN
306: *
307: * Path 2a - underdetermined, with many more columns
308: * than rows
309: *
310: * Compute space needed for ZGELQF
311: CALL ZGELQF( M, N, A, LDA, DUM(1), DUM(1),
312: $ -1, INFO )
313: LWORK_ZGELQF = INT( DUM(1) )
314: * Compute space needed for ZGEBRD
315: CALL ZGEBRD( M, M, A, LDA, S, S, DUM(1), DUM(1),
316: $ DUM(1), -1, INFO )
317: LWORK_ZGEBRD = INT( DUM(1) )
318: * Compute space needed for ZUNMBR
319: CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, N, A, LDA,
320: $ DUM(1), B, LDB, DUM(1), -1, INFO )
321: LWORK_ZUNMBR = INT( DUM(1) )
322: * Compute space needed for ZUNGBR
323: CALL ZUNGBR( 'P', M, M, M, A, LDA, DUM(1),
324: $ DUM(1), -1, INFO )
325: LWORK_ZUNGBR = INT( DUM(1) )
326: * Compute space needed for ZUNMLQ
327: CALL ZUNMLQ( 'L', 'C', N, NRHS, M, A, LDA, DUM(1),
328: $ B, LDB, DUM(1), -1, INFO )
329: LWORK_ZUNMLQ = INT( DUM(1) )
330: * Compute total workspace needed
331: MAXWRK = M + LWORK_ZGELQF
332: MAXWRK = MAX( MAXWRK, 3*M + M*M + LWORK_ZGEBRD )
333: MAXWRK = MAX( MAXWRK, 3*M + M*M + LWORK_ZUNMBR )
334: MAXWRK = MAX( MAXWRK, 3*M + M*M + LWORK_ZUNGBR )
335: IF( NRHS.GT.1 ) THEN
336: MAXWRK = MAX( MAXWRK, M*M + M + M*NRHS )
337: ELSE
338: MAXWRK = MAX( MAXWRK, M*M + 2*M )
339: END IF
340: MAXWRK = MAX( MAXWRK, M + LWORK_ZUNMLQ )
341: ELSE
342: *
343: * Path 2 - underdetermined
344: *
345: * Compute space needed for ZGEBRD
346: CALL ZGEBRD( M, N, A, LDA, S, S, DUM(1), DUM(1),
347: $ DUM(1), -1, INFO )
348: LWORK_ZGEBRD = INT( DUM(1) )
349: * Compute space needed for ZUNMBR
350: CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, M, A, LDA,
351: $ DUM(1), B, LDB, DUM(1), -1, INFO )
352: LWORK_ZUNMBR = INT( DUM(1) )
353: * Compute space needed for ZUNGBR
354: CALL ZUNGBR( 'P', M, N, M, A, LDA, DUM(1),
355: $ DUM(1), -1, INFO )
356: LWORK_ZUNGBR = INT( DUM(1) )
357: MAXWRK = 2*M + LWORK_ZGEBRD
358: MAXWRK = MAX( MAXWRK, 2*M + LWORK_ZUNMBR )
359: MAXWRK = MAX( MAXWRK, 2*M + LWORK_ZUNGBR )
360: MAXWRK = MAX( MAXWRK, N*NRHS )
361: END IF
362: END IF
363: MAXWRK = MAX( MINWRK, MAXWRK )
364: END IF
365: WORK( 1 ) = MAXWRK
366: *
367: IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY )
368: $ INFO = -12
369: END IF
370: *
371: IF( INFO.NE.0 ) THEN
372: CALL XERBLA( 'ZGELSS', -INFO )
373: RETURN
374: ELSE IF( LQUERY ) THEN
375: RETURN
376: END IF
377: *
378: * Quick return if possible
379: *
380: IF( M.EQ.0 .OR. N.EQ.0 ) THEN
381: RANK = 0
382: RETURN
383: END IF
384: *
385: * Get machine parameters
386: *
387: EPS = DLAMCH( 'P' )
388: SFMIN = DLAMCH( 'S' )
389: SMLNUM = SFMIN / EPS
390: BIGNUM = ONE / SMLNUM
391: CALL DLABAD( SMLNUM, BIGNUM )
392: *
393: * Scale A if max element outside range [SMLNUM,BIGNUM]
394: *
395: ANRM = ZLANGE( 'M', M, N, A, LDA, RWORK )
396: IASCL = 0
397: IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
398: *
399: * Scale matrix norm up to SMLNUM
400: *
401: CALL ZLASCL( 'G', 0, 0, ANRM, SMLNUM, M, N, A, LDA, INFO )
402: IASCL = 1
403: ELSE IF( ANRM.GT.BIGNUM ) THEN
404: *
405: * Scale matrix norm down to BIGNUM
406: *
407: CALL ZLASCL( 'G', 0, 0, ANRM, BIGNUM, M, N, A, LDA, INFO )
408: IASCL = 2
409: ELSE IF( ANRM.EQ.ZERO ) THEN
410: *
411: * Matrix all zero. Return zero solution.
412: *
413: CALL ZLASET( 'F', MAX( M, N ), NRHS, CZERO, CZERO, B, LDB )
414: CALL DLASET( 'F', MINMN, 1, ZERO, ZERO, S, MINMN )
415: RANK = 0
416: GO TO 70
417: END IF
418: *
419: * Scale B if max element outside range [SMLNUM,BIGNUM]
420: *
421: BNRM = ZLANGE( 'M', M, NRHS, B, LDB, RWORK )
422: IBSCL = 0
423: IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
424: *
425: * Scale matrix norm up to SMLNUM
426: *
427: CALL ZLASCL( 'G', 0, 0, BNRM, SMLNUM, M, NRHS, B, LDB, INFO )
428: IBSCL = 1
429: ELSE IF( BNRM.GT.BIGNUM ) THEN
430: *
431: * Scale matrix norm down to BIGNUM
432: *
433: CALL ZLASCL( 'G', 0, 0, BNRM, BIGNUM, M, NRHS, B, LDB, INFO )
434: IBSCL = 2
435: END IF
436: *
437: * Overdetermined case
438: *
439: IF( M.GE.N ) THEN
440: *
441: * Path 1 - overdetermined or exactly determined
442: *
443: MM = M
444: IF( M.GE.MNTHR ) THEN
445: *
446: * Path 1a - overdetermined, with many more rows than columns
447: *
448: MM = N
449: ITAU = 1
450: IWORK = ITAU + N
451: *
452: * Compute A=Q*R
453: * (CWorkspace: need 2*N, prefer N+N*NB)
454: * (RWorkspace: none)
455: *
456: CALL ZGEQRF( M, N, A, LDA, WORK( ITAU ), WORK( IWORK ),
457: $ LWORK-IWORK+1, INFO )
458: *
459: * Multiply B by transpose(Q)
460: * (CWorkspace: need N+NRHS, prefer N+NRHS*NB)
461: * (RWorkspace: none)
462: *
463: CALL ZUNMQR( 'L', 'C', M, NRHS, N, A, LDA, WORK( ITAU ), B,
464: $ LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
465: *
466: * Zero out below R
467: *
468: IF( N.GT.1 )
469: $ CALL ZLASET( 'L', N-1, N-1, CZERO, CZERO, A( 2, 1 ),
470: $ LDA )
471: END IF
472: *
473: IE = 1
474: ITAUQ = 1
475: ITAUP = ITAUQ + N
476: IWORK = ITAUP + N
477: *
478: * Bidiagonalize R in A
479: * (CWorkspace: need 2*N+MM, prefer 2*N+(MM+N)*NB)
480: * (RWorkspace: need N)
481: *
482: CALL ZGEBRD( MM, N, A, LDA, S, RWORK( IE ), WORK( ITAUQ ),
483: $ WORK( ITAUP ), WORK( IWORK ), LWORK-IWORK+1,
484: $ INFO )
485: *
486: * Multiply B by transpose of left bidiagonalizing vectors of R
487: * (CWorkspace: need 2*N+NRHS, prefer 2*N+NRHS*NB)
488: * (RWorkspace: none)
489: *
490: CALL ZUNMBR( 'Q', 'L', 'C', MM, NRHS, N, A, LDA, WORK( ITAUQ ),
491: $ B, LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
492: *
493: * Generate right bidiagonalizing vectors of R in A
494: * (CWorkspace: need 3*N-1, prefer 2*N+(N-1)*NB)
495: * (RWorkspace: none)
496: *
497: CALL ZUNGBR( 'P', N, N, N, A, LDA, WORK( ITAUP ),
498: $ WORK( IWORK ), LWORK-IWORK+1, INFO )
499: IRWORK = IE + N
500: *
501: * Perform bidiagonal QR iteration
502: * multiply B by transpose of left singular vectors
503: * compute right singular vectors in A
504: * (CWorkspace: none)
505: * (RWorkspace: need BDSPAC)
506: *
507: CALL ZBDSQR( 'U', N, N, 0, NRHS, S, RWORK( IE ), A, LDA, DUM,
508: $ 1, B, LDB, RWORK( IRWORK ), INFO )
509: IF( INFO.NE.0 )
510: $ GO TO 70
511: *
512: * Multiply B by reciprocals of singular values
513: *
514: THR = MAX( RCOND*S( 1 ), SFMIN )
515: IF( RCOND.LT.ZERO )
516: $ THR = MAX( EPS*S( 1 ), SFMIN )
517: RANK = 0
518: DO 10 I = 1, N
519: IF( S( I ).GT.THR ) THEN
520: CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
521: RANK = RANK + 1
522: ELSE
523: CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
524: END IF
525: 10 CONTINUE
526: *
527: * Multiply B by right singular vectors
528: * (CWorkspace: need N, prefer N*NRHS)
529: * (RWorkspace: none)
530: *
531: IF( LWORK.GE.LDB*NRHS .AND. NRHS.GT.1 ) THEN
532: CALL ZGEMM( 'C', 'N', N, NRHS, N, CONE, A, LDA, B, LDB,
533: $ CZERO, WORK, LDB )
534: CALL ZLACPY( 'G', N, NRHS, WORK, LDB, B, LDB )
535: ELSE IF( NRHS.GT.1 ) THEN
536: CHUNK = LWORK / N
537: DO 20 I = 1, NRHS, CHUNK
538: BL = MIN( NRHS-I+1, CHUNK )
539: CALL ZGEMM( 'C', 'N', N, BL, N, CONE, A, LDA, B( 1, I ),
540: $ LDB, CZERO, WORK, N )
541: CALL ZLACPY( 'G', N, BL, WORK, N, B( 1, I ), LDB )
542: 20 CONTINUE
543: ELSE
544: CALL ZGEMV( 'C', N, N, CONE, A, LDA, B, 1, CZERO, WORK, 1 )
545: CALL ZCOPY( N, WORK, 1, B, 1 )
546: END IF
547: *
548: ELSE IF( N.GE.MNTHR .AND. LWORK.GE.3*M+M*M+MAX( M, NRHS, N-2*M ) )
549: $ THEN
550: *
551: * Underdetermined case, M much less than N
552: *
553: * Path 2a - underdetermined, with many more columns than rows
554: * and sufficient workspace for an efficient algorithm
555: *
556: LDWORK = M
557: IF( LWORK.GE.3*M+M*LDA+MAX( M, NRHS, N-2*M ) )
558: $ LDWORK = LDA
559: ITAU = 1
560: IWORK = M + 1
561: *
562: * Compute A=L*Q
563: * (CWorkspace: need 2*M, prefer M+M*NB)
564: * (RWorkspace: none)
565: *
566: CALL ZGELQF( M, N, A, LDA, WORK( ITAU ), WORK( IWORK ),
567: $ LWORK-IWORK+1, INFO )
568: IL = IWORK
569: *
570: * Copy L to WORK(IL), zeroing out above it
571: *
572: CALL ZLACPY( 'L', M, M, A, LDA, WORK( IL ), LDWORK )
573: CALL ZLASET( 'U', M-1, M-1, CZERO, CZERO, WORK( IL+LDWORK ),
574: $ LDWORK )
575: IE = 1
576: ITAUQ = IL + LDWORK*M
577: ITAUP = ITAUQ + M
578: IWORK = ITAUP + M
579: *
580: * Bidiagonalize L in WORK(IL)
581: * (CWorkspace: need M*M+4*M, prefer M*M+3*M+2*M*NB)
582: * (RWorkspace: need M)
583: *
584: CALL ZGEBRD( M, M, WORK( IL ), LDWORK, S, RWORK( IE ),
585: $ WORK( ITAUQ ), WORK( ITAUP ), WORK( IWORK ),
586: $ LWORK-IWORK+1, INFO )
587: *
588: * Multiply B by transpose of left bidiagonalizing vectors of L
589: * (CWorkspace: need M*M+3*M+NRHS, prefer M*M+3*M+NRHS*NB)
590: * (RWorkspace: none)
591: *
592: CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, M, WORK( IL ), LDWORK,
593: $ WORK( ITAUQ ), B, LDB, WORK( IWORK ),
594: $ LWORK-IWORK+1, INFO )
595: *
596: * Generate right bidiagonalizing vectors of R in WORK(IL)
597: * (CWorkspace: need M*M+4*M-1, prefer M*M+3*M+(M-1)*NB)
598: * (RWorkspace: none)
599: *
600: CALL ZUNGBR( 'P', M, M, M, WORK( IL ), LDWORK, WORK( ITAUP ),
601: $ WORK( IWORK ), LWORK-IWORK+1, INFO )
602: IRWORK = IE + M
603: *
604: * Perform bidiagonal QR iteration, computing right singular
605: * vectors of L in WORK(IL) and multiplying B by transpose of
606: * left singular vectors
607: * (CWorkspace: need M*M)
608: * (RWorkspace: need BDSPAC)
609: *
610: CALL ZBDSQR( 'U', M, M, 0, NRHS, S, RWORK( IE ), WORK( IL ),
611: $ LDWORK, A, LDA, B, LDB, RWORK( IRWORK ), INFO )
612: IF( INFO.NE.0 )
613: $ GO TO 70
614: *
615: * Multiply B by reciprocals of singular values
616: *
617: THR = MAX( RCOND*S( 1 ), SFMIN )
618: IF( RCOND.LT.ZERO )
619: $ THR = MAX( EPS*S( 1 ), SFMIN )
620: RANK = 0
621: DO 30 I = 1, M
622: IF( S( I ).GT.THR ) THEN
623: CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
624: RANK = RANK + 1
625: ELSE
626: CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
627: END IF
628: 30 CONTINUE
629: IWORK = IL + M*LDWORK
630: *
631: * Multiply B by right singular vectors of L in WORK(IL)
632: * (CWorkspace: need M*M+2*M, prefer M*M+M+M*NRHS)
633: * (RWorkspace: none)
634: *
635: IF( LWORK.GE.LDB*NRHS+IWORK-1 .AND. NRHS.GT.1 ) THEN
636: CALL ZGEMM( 'C', 'N', M, NRHS, M, CONE, WORK( IL ), LDWORK,
637: $ B, LDB, CZERO, WORK( IWORK ), LDB )
638: CALL ZLACPY( 'G', M, NRHS, WORK( IWORK ), LDB, B, LDB )
639: ELSE IF( NRHS.GT.1 ) THEN
640: CHUNK = ( LWORK-IWORK+1 ) / M
641: DO 40 I = 1, NRHS, CHUNK
642: BL = MIN( NRHS-I+1, CHUNK )
643: CALL ZGEMM( 'C', 'N', M, BL, M, CONE, WORK( IL ), LDWORK,
644: $ B( 1, I ), LDB, CZERO, WORK( IWORK ), M )
645: CALL ZLACPY( 'G', M, BL, WORK( IWORK ), M, B( 1, I ),
646: $ LDB )
647: 40 CONTINUE
648: ELSE
649: CALL ZGEMV( 'C', M, M, CONE, WORK( IL ), LDWORK, B( 1, 1 ),
650: $ 1, CZERO, WORK( IWORK ), 1 )
651: CALL ZCOPY( M, WORK( IWORK ), 1, B( 1, 1 ), 1 )
652: END IF
653: *
654: * Zero out below first M rows of B
655: *
656: CALL ZLASET( 'F', N-M, NRHS, CZERO, CZERO, B( M+1, 1 ), LDB )
657: IWORK = ITAU + M
658: *
659: * Multiply transpose(Q) by B
660: * (CWorkspace: need M+NRHS, prefer M+NHRS*NB)
661: * (RWorkspace: none)
662: *
663: CALL ZUNMLQ( 'L', 'C', N, NRHS, M, A, LDA, WORK( ITAU ), B,
664: $ LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
665: *
666: ELSE
667: *
668: * Path 2 - remaining underdetermined cases
669: *
670: IE = 1
671: ITAUQ = 1
672: ITAUP = ITAUQ + M
673: IWORK = ITAUP + M
674: *
675: * Bidiagonalize A
676: * (CWorkspace: need 3*M, prefer 2*M+(M+N)*NB)
677: * (RWorkspace: need N)
678: *
679: CALL ZGEBRD( M, N, A, LDA, S, RWORK( IE ), WORK( ITAUQ ),
680: $ WORK( ITAUP ), WORK( IWORK ), LWORK-IWORK+1,
681: $ INFO )
682: *
683: * Multiply B by transpose of left bidiagonalizing vectors
684: * (CWorkspace: need 2*M+NRHS, prefer 2*M+NRHS*NB)
685: * (RWorkspace: none)
686: *
687: CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, N, A, LDA, WORK( ITAUQ ),
688: $ B, LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
689: *
690: * Generate right bidiagonalizing vectors in A
691: * (CWorkspace: need 3*M, prefer 2*M+M*NB)
692: * (RWorkspace: none)
693: *
694: CALL ZUNGBR( 'P', M, N, M, A, LDA, WORK( ITAUP ),
695: $ WORK( IWORK ), LWORK-IWORK+1, INFO )
696: IRWORK = IE + M
697: *
698: * Perform bidiagonal QR iteration,
699: * computing right singular vectors of A in A and
700: * multiplying B by transpose of left singular vectors
701: * (CWorkspace: none)
702: * (RWorkspace: need BDSPAC)
703: *
704: CALL ZBDSQR( 'L', M, N, 0, NRHS, S, RWORK( IE ), A, LDA, DUM,
705: $ 1, B, LDB, RWORK( IRWORK ), INFO )
706: IF( INFO.NE.0 )
707: $ GO TO 70
708: *
709: * Multiply B by reciprocals of singular values
710: *
711: THR = MAX( RCOND*S( 1 ), SFMIN )
712: IF( RCOND.LT.ZERO )
713: $ THR = MAX( EPS*S( 1 ), SFMIN )
714: RANK = 0
715: DO 50 I = 1, M
716: IF( S( I ).GT.THR ) THEN
717: CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
718: RANK = RANK + 1
719: ELSE
720: CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
721: END IF
722: 50 CONTINUE
723: *
724: * Multiply B by right singular vectors of A
725: * (CWorkspace: need N, prefer N*NRHS)
726: * (RWorkspace: none)
727: *
728: IF( LWORK.GE.LDB*NRHS .AND. NRHS.GT.1 ) THEN
729: CALL ZGEMM( 'C', 'N', N, NRHS, M, CONE, A, LDA, B, LDB,
730: $ CZERO, WORK, LDB )
731: CALL ZLACPY( 'G', N, NRHS, WORK, LDB, B, LDB )
732: ELSE IF( NRHS.GT.1 ) THEN
733: CHUNK = LWORK / N
734: DO 60 I = 1, NRHS, CHUNK
735: BL = MIN( NRHS-I+1, CHUNK )
736: CALL ZGEMM( 'C', 'N', N, BL, M, CONE, A, LDA, B( 1, I ),
737: $ LDB, CZERO, WORK, N )
738: CALL ZLACPY( 'F', N, BL, WORK, N, B( 1, I ), LDB )
739: 60 CONTINUE
740: ELSE
741: CALL ZGEMV( 'C', M, N, CONE, A, LDA, B, 1, CZERO, WORK, 1 )
742: CALL ZCOPY( N, WORK, 1, B, 1 )
743: END IF
744: END IF
745: *
746: * Undo scaling
747: *
748: IF( IASCL.EQ.1 ) THEN
749: CALL ZLASCL( 'G', 0, 0, ANRM, SMLNUM, N, NRHS, B, LDB, INFO )
750: CALL DLASCL( 'G', 0, 0, SMLNUM, ANRM, MINMN, 1, S, MINMN,
751: $ INFO )
752: ELSE IF( IASCL.EQ.2 ) THEN
753: CALL ZLASCL( 'G', 0, 0, ANRM, BIGNUM, N, NRHS, B, LDB, INFO )
754: CALL DLASCL( 'G', 0, 0, BIGNUM, ANRM, MINMN, 1, S, MINMN,
755: $ INFO )
756: END IF
757: IF( IBSCL.EQ.1 ) THEN
758: CALL ZLASCL( 'G', 0, 0, SMLNUM, BNRM, N, NRHS, B, LDB, INFO )
759: ELSE IF( IBSCL.EQ.2 ) THEN
760: CALL ZLASCL( 'G', 0, 0, BIGNUM, BNRM, N, NRHS, B, LDB, INFO )
761: END IF
762: 70 CONTINUE
763: WORK( 1 ) = MAXWRK
764: RETURN
765: *
766: * End of ZGELSS
767: *
768: END
CVSweb interface <joel.bertrand@systella.fr>