1: *> \brief \b ZGELQ2 computes the LQ factorization of a general rectangular matrix using an unblocked algorithm.
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: *> \htmlonly
9: *> Download ZGELQ2 + dependencies
10: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgelq2.f">
11: *> [TGZ]</a>
12: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgelq2.f">
13: *> [ZIP]</a>
14: *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgelq2.f">
15: *> [TXT]</a>
16: *> \endhtmlonly
17: *
18: * Definition:
19: * ===========
20: *
21: * SUBROUTINE ZGELQ2( M, N, A, LDA, TAU, WORK, INFO )
22: *
23: * .. Scalar Arguments ..
24: * INTEGER INFO, LDA, M, N
25: * ..
26: * .. Array Arguments ..
27: * COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
28: * ..
29: *
30: *
31: *> \par Purpose:
32: * =============
33: *>
34: *> \verbatim
35: *>
36: *> ZGELQ2 computes an LQ factorization of a complex m-by-n matrix A:
37: *>
38: *> A = ( L 0 ) * Q
39: *>
40: *> where:
41: *>
42: *> Q is a n-by-n orthogonal matrix;
43: *> L is an lower-triangular m-by-m matrix;
44: *> 0 is a m-by-(n-m) zero matrix, if m < n.
45: *>
46: *> \endverbatim
47: *
48: * Arguments:
49: * ==========
50: *
51: *> \param[in] M
52: *> \verbatim
53: *> M is INTEGER
54: *> The number of rows of the matrix A. M >= 0.
55: *> \endverbatim
56: *>
57: *> \param[in] N
58: *> \verbatim
59: *> N is INTEGER
60: *> The number of columns of the matrix A. N >= 0.
61: *> \endverbatim
62: *>
63: *> \param[in,out] A
64: *> \verbatim
65: *> A is COMPLEX*16 array, dimension (LDA,N)
66: *> On entry, the m by n matrix A.
67: *> On exit, the elements on and below the diagonal of the array
68: *> contain the m by min(m,n) lower trapezoidal matrix L (L is
69: *> lower triangular if m <= n); the elements above the diagonal,
70: *> with the array TAU, represent the unitary matrix Q as a
71: *> product of elementary reflectors (see Further Details).
72: *> \endverbatim
73: *>
74: *> \param[in] LDA
75: *> \verbatim
76: *> LDA is INTEGER
77: *> The leading dimension of the array A. LDA >= max(1,M).
78: *> \endverbatim
79: *>
80: *> \param[out] TAU
81: *> \verbatim
82: *> TAU is COMPLEX*16 array, dimension (min(M,N))
83: *> The scalar factors of the elementary reflectors (see Further
84: *> Details).
85: *> \endverbatim
86: *>
87: *> \param[out] WORK
88: *> \verbatim
89: *> WORK is COMPLEX*16 array, dimension (M)
90: *> \endverbatim
91: *>
92: *> \param[out] INFO
93: *> \verbatim
94: *> INFO is INTEGER
95: *> = 0: successful exit
96: *> < 0: if INFO = -i, the i-th argument had an illegal value
97: *> \endverbatim
98: *
99: * Authors:
100: * ========
101: *
102: *> \author Univ. of Tennessee
103: *> \author Univ. of California Berkeley
104: *> \author Univ. of Colorado Denver
105: *> \author NAG Ltd.
106: *
107: *> \date November 2019
108: *
109: *> \ingroup complex16GEcomputational
110: *
111: *> \par Further Details:
112: * =====================
113: *>
114: *> \verbatim
115: *>
116: *> The matrix Q is represented as a product of elementary reflectors
117: *>
118: *> Q = H(k)**H . . . H(2)**H H(1)**H, where k = min(m,n).
119: *>
120: *> Each H(i) has the form
121: *>
122: *> H(i) = I - tau * v * v**H
123: *>
124: *> where tau is a complex scalar, and v is a complex vector with
125: *> v(1:i-1) = 0 and v(i) = 1; conjg(v(i+1:n)) is stored on exit in
126: *> A(i,i+1:n), and tau in TAU(i).
127: *> \endverbatim
128: *>
129: * =====================================================================
130: SUBROUTINE ZGELQ2( M, N, A, LDA, TAU, WORK, INFO )
131: *
132: * -- LAPACK computational routine (version 3.9.0) --
133: * -- LAPACK is a software package provided by Univ. of Tennessee, --
134: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
135: * November 2019
136: *
137: * .. Scalar Arguments ..
138: INTEGER INFO, LDA, M, N
139: * ..
140: * .. Array Arguments ..
141: COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
142: * ..
143: *
144: * =====================================================================
145: *
146: * .. Parameters ..
147: COMPLEX*16 ONE
148: PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
149: * ..
150: * .. Local Scalars ..
151: INTEGER I, K
152: COMPLEX*16 ALPHA
153: * ..
154: * .. External Subroutines ..
155: EXTERNAL XERBLA, ZLACGV, ZLARF, ZLARFG
156: * ..
157: * .. Intrinsic Functions ..
158: INTRINSIC MAX, MIN
159: * ..
160: * .. Executable Statements ..
161: *
162: * Test the input arguments
163: *
164: INFO = 0
165: IF( M.LT.0 ) THEN
166: INFO = -1
167: ELSE IF( N.LT.0 ) THEN
168: INFO = -2
169: ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
170: INFO = -4
171: END IF
172: IF( INFO.NE.0 ) THEN
173: CALL XERBLA( 'ZGELQ2', -INFO )
174: RETURN
175: END IF
176: *
177: K = MIN( M, N )
178: *
179: DO 10 I = 1, K
180: *
181: * Generate elementary reflector H(i) to annihilate A(i,i+1:n)
182: *
183: CALL ZLACGV( N-I+1, A( I, I ), LDA )
184: ALPHA = A( I, I )
185: CALL ZLARFG( N-I+1, ALPHA, A( I, MIN( I+1, N ) ), LDA,
186: $ TAU( I ) )
187: IF( I.LT.M ) THEN
188: *
189: * Apply H(i) to A(i+1:m,i:n) from the right
190: *
191: A( I, I ) = ONE
192: CALL ZLARF( 'Right', M-I, N-I+1, A( I, I ), LDA, TAU( I ),
193: $ A( I+1, I ), LDA, WORK )
194: END IF
195: A( I, I ) = ALPHA
196: CALL ZLACGV( N-I+1, A( I, I ), LDA )
197: 10 CONTINUE
198: RETURN
199: *
200: * End of ZGELQ2
201: *
202: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to zgelq2.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / lapack